Context Navigation

nemogcm.F90 @ 15637

Last change on this file since 15637 was 15378, checked in by hadjt, 3 years ago

Updated Region mean and noos cross-sections, but may be slower.
Region mean:
no dummy IOM_put
verbose namelist switch
Region mean and noos consistent heat and salt calc.

NOOS:
instanteous transport arrays added, transport_3d_inst
logical switch in tranport subroutine to update transport_3d, or use transport_3d_inst
New simplified routine to pass instantaneous tranpost to xios via new subroutine

dia_dct_wri_NOOS_iom

Namelist integer to output iom via new routine, old routine, or neither
Verbose name list switch
...

File size: 36.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
33	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
34	!!----------------------------------------------------------------------
35
36	!!----------------------------------------------------------------------
37	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38	!! nemo_init : initialization of the NEMO system
39	!! nemo_ctl : initialisation of the contol print
40	!! nemo_closefile: close remaining open files
41	!! nemo_alloc : dynamical allocation
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module (step.F90)
44	USE phycst ! physical constant (par_cst routine)
45	USE domain ! domain initialization (dom_init & dom_cfg routines)
46	USE closea ! treatment of closed seas (for ln_closea)
47	USE usrdef_nam ! user defined configuration
48	USE tideini ! tidal components initialization (tide_ini routine)
49	USE bdy_oce, ONLY : ln_bdy
50	USE bdyini ! open boundary cond. setting (bdy_init routine)
51	USE istate ! initial state setting (istate_init routine)
52	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
53	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
54	USE trdini ! dyn/tra trends initialization (trd_init routine)
55	USE asminc ! assimilation increments
56	USE asmbkg ! writing out state trajectory
57	USE diaptr ! poleward transports (dia_ptr_init routine)
58	USE diadct ! sections transports (dia_dct_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
61	USE diaharm ! tidal harmonics diagnostics (dia_harm_init routine)
62	USE step ! NEMO time-stepping (stp routine)
63	USE icbini ! handle bergs, initialisation
64	USE icbstp ! handle bergs, calving, themodynamics and transport
65	USE cpl_oasis3 ! OASIS3 coupling
66	USE c1d ! 1D configuration
67	USE step_c1d ! Time stepping loop for the 1D configuration
68	USE dyndmp ! Momentum damping
69	USE stopar ! Stochastic param.: ???
70	USE stopts ! Stochastic param.: ???
71	USE diurnal_bulk ! diurnal bulk SST
72	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
73	USE crsini ! initialise grid coarsening utility
74	USE dia25h ! 25h mean output
75	!JT
76	USE diaregmean ! Top,middle,bottom output
77	USE diapea ! pea
78	!JT
79
80	USE sbc_oce , ONLY : lk_oasis
81	USE wet_dry ! Wetting and drying setting (wad_init routine)
82	#if defined key_top
83	USE trcini ! passive tracer initialisation
84	#endif
85	#if defined key_nemocice_decomp
86	USE ice_domain_size, only: nx_global, ny_global
87	#endif
88	!
89	USE in_out_manager ! I/O manager
90	USE lib_mpp ! distributed memory computing
91	USE mppini ! shared/distributed memory setting (mpp_init routine)
92	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
93	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
94	#if defined key_iomput
95	USE xios ! xIOserver
96	#endif
97	#if defined key_agrif
98	USE agrif_all_update ! Master Agrif update
99	#endif
100
101	IMPLICIT NONE
102	PRIVATE
103
104	PUBLIC nemo_gcm ! called by model.F90
105	PUBLIC nemo_init ! needed by AGRIF
106	PUBLIC nemo_alloc ! needed by TAM
107
108	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
109
110	#if defined key_mpp_mpi
111	! need MPI_Wtime
112	INCLUDE 'mpif.h'
113	#endif
114
115	!!----------------------------------------------------------------------
116	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
117	!! $Id$
118	!! Software governed by the CeCILL license (see ./LICENSE)
119	!!----------------------------------------------------------------------
120	CONTAINS
121
122	SUBROUTINE nemo_gcm
123	!!----------------------------------------------------------------------
124	!! * ROUTINE nemo_gcm *
125	!!
126	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
127	!! curvilinear mesh on the sphere.
128	!!
129	!! ** Method : - model general initialization
130	!! - launch the time-stepping (stp routine)
131	!! - finalize the run by closing files and communications
132	!!
133	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
134	!! Madec, 2008, internal report, IPSL.
135	!!----------------------------------------------------------------------
136	INTEGER :: istp ! time step index
137	REAL(wp):: zstptiming ! elapsed time for 1 time step
138	!!----------------------------------------------------------------------
139	!
140	#if defined key_agrif
141	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
142	#endif
143	! !-----------------------!
144	CALL nemo_init !== Initialisations ==!
145	! !-----------------------!
146	#if defined key_agrif
147	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
148	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
149	# if defined key_top
150	CALL Agrif_Declare_Var_top ! " " " " " TOP
151	# endif
152	# if defined key_si3
153	CALL Agrif_Declare_Var_ice ! " " " " " Sea ice
154	# endif
155	#endif
156	! check that all process are still there... If some process have an error,
157	! they will never enter in step and other processes will wait until the end of the cpu time!
158	CALL mpp_max( 'nemogcm', nstop )
159
160	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
161
162	! !-----------------------!
163	! !== time stepping ==!
164	! !-----------------------!
165	istp = nit000
166	!
167	#if defined key_c1d
168	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==!
169	CALL stp_c1d( istp )
170	istp = istp + 1
171	END DO
172	#else
173	!
174	# if defined key_agrif
175	! !== AGRIF time-stepping ==!
176	CALL Agrif_Regrid()
177	!
178	! Recursive update from highest nested level to lowest:
179	CALL Agrif_step_child_adj(Agrif_Update_All)
180	!
181	DO WHILE( istp <= nitend .AND. nstop == 0 )
182	CALL stp
183	istp = istp + 1
184	END DO
185	!
186	# else
187	!
188	IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==!
189	!
190	DO WHILE( istp <= nitend .AND. nstop == 0 )
191
192	ncom_stp = istp
193	IF( ln_timing ) THEN
194	zstptiming = MPI_Wtime()
195	IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
196	IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time
197	ENDIF
198
199	CALL stp ( istp )
200	istp = istp + 1
201
202	IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
203
204	END DO
205	!
206	ELSE !== diurnal SST time-steeping only ==!
207	!
208	DO WHILE( istp <= nitend .AND. nstop == 0 )
209	CALL stp_diurnal( istp ) ! time step only the diurnal SST
210	istp = istp + 1
211	END DO
212	!
213	ENDIF
214	!
215	# endif
216	!
217	#endif
218	!
219	IF( ln_diaobs ) CALL dia_obs_wri
220	!
221	IF( ln_icebergs ) CALL icb_end( nitend )
222
223	! !------------------------!
224	! !== finalize the run ==!
225	! !------------------------!
226	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
227	!
228	IF( nstop /= 0 .AND. lwp ) THEN ! error print
229	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
230	IF( ngrdstop > 0 ) THEN
231	WRITE(ctmp9,'(i2)') ngrdstop
232	WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9)
233	WRITE(ctmp3,) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output files'
234	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
235	ELSE
236	WRITE(ctmp2,) ' Look for "E R R O R" messages in all existing ocean_output files'
237	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
238	ENDIF
239	ENDIF
240	!
241	IF( ln_timing ) CALL timing_finalize
242	!
243	CALL nemo_closefile
244	!
245	#if defined key_iomput
246	CALL xios_finalize ! end mpp communications with xios
247	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
248	#else
249	IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS
250	ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications
251	ENDIF
252	#endif
253	!
254	IF(lwm) THEN
255	IF( nstop == 0 ) THEN ; STOP 0
256	ELSE ; STOP 123
257	ENDIF
258	ENDIF
259	!
260	END SUBROUTINE nemo_gcm
261
262
263	SUBROUTINE nemo_init
264	!!----------------------------------------------------------------------
265	!! * ROUTINE nemo_init *
266	!!
267	!! ** Purpose : initialization of the NEMO GCM
268	!!----------------------------------------------------------------------
269	INTEGER :: ios, ilocal_comm ! local integers
270	!!
271	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
272	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
273	& ln_timing, ln_diacfl
274	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
275	!!----------------------------------------------------------------------
276	!
277	cxios_context = 'nemo'
278	!
279	! !-------------------------------------------------!
280	! ! set communicator & select the local rank !
281	! ! must be done as soon as possible to get narea !
282	! !-------------------------------------------------!
283	!
284	#if defined key_iomput
285	IF( Agrif_Root() ) THEN
286	IF( lk_oasis ) THEN
287	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
288	CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios
289	ELSE
290	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
291	ENDIF
292	ENDIF
293	CALL mpp_start( ilocal_comm )
294	#else
295	IF( lk_oasis ) THEN
296	IF( Agrif_Root() ) THEN
297	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
298	ENDIF
299	CALL mpp_start( ilocal_comm )
300	ELSE
301	CALL mpp_start( )
302	ENDIF
303	#endif
304	!
305	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
306	lwm = (narea == 1) ! control of output namelists
307	!
308	! !---------------------------------------------------------------!
309	! ! Open output files, reference and configuration namelist files !
310	! !---------------------------------------------------------------!
311	!
312	! open ocean.output as soon as possible to get all output prints (including errors messages)
313	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
314	! open reference and configuration namelist files
315	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
316	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
317	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
318	! open /dev/null file to be able to supress output write easily
319	IF( Agrif_Root() ) THEN
320	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
321	#ifdef key_agrif
322	ELSE
323	numnul = Agrif_Parent(numnul)
324	#endif
325	ENDIF
326	!
327	! !--------------------!
328	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
329	! !--------------------!
330	!
331	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
332	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
333	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
334	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
335	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
336	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
337	!
338	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
339	!
340	IF(lwp) THEN ! open listing units
341	!
342	IF( .NOT. lwm ) & ! alreay opened for narea == 1
343	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
344	!
345	WRITE(numout,*)
346	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
347	WRITE(numout,*) ' NEMO team'
348	WRITE(numout,*) ' Ocean General Circulation Model'
349	WRITE(numout,*) ' NEMO version 4.0 (2019) '
350	WRITE(numout,*)
351	WRITE(numout,*) " ._ ._ ._ ._ ._ "
352	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
353	WRITE(numout,*)
354	WRITE(numout,*) " o _, _, "
355	WRITE(numout,*) " o .' ( .-' / "
356	WRITE(numout,*) " o _/..._'. .' / "
357	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
358	WRITE(numout,*) " ) ( o) ;= <_ ( "
359	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
360	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
361	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
362	WRITE(numout,*) " ) ) jgs ` ( ( "
363	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
364	WRITE(numout,*)
365	!
366	WRITE(numout,cform_aaa) ! Flag AAAAAAA
367	!
368	ENDIF
369	!
370	! finalize the definition of namctl variables
371	IF( sn_cfctl%l_config ) THEN
372	! Activate finer control of report outputs
373	! optionally switch off output from selected areas (note this only
374	! applies to output which does not involve global communications)
375	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
376	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
377	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
378	ELSE
379	! Use ln_ctl to turn on or off all options.
380	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
381	ENDIF
382	!
383	IF(lwm) WRITE( numond, namctl )
384	!
385	! !------------------------------------!
386	! ! Set global domain size parameters !
387	! !------------------------------------!
388	!
389	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
390	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
391	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
392	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
393	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
394	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
395	!
396	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
397	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
398	ELSE ! user-defined namelist
399	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
400	ENDIF
401	!
402	IF(lwm) WRITE( numond, namcfg )
403	!
404	! !-----------------------------------------!
405	! ! mpp parameters and domain decomposition !
406	! !-----------------------------------------!
407	CALL mpp_init
408
409	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
410	CALL nemo_alloc()
411
412	! !-------------------------------!
413	! ! NEMO general initialization !
414	! !-------------------------------!
415
416	CALL nemo_ctl ! Control prints
417	!
418	! ! General initialization
419	IF( ln_timing ) CALL timing_init ! timing
420	IF( ln_timing ) CALL timing_start( 'nemo_init')
421	!
422	CALL phy_cst ! Physical constants
423	CALL eos_init ! Equation of state
424	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
425	CALL wad_init ! Wetting and drying options
426	CALL dom_init("OPA") ! Domain
427	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
428	IF( ln_ctl ) CALL prt_ctl_init ! Print control
429
430	CALL diurnal_sst_bulk_init ! diurnal sst
431	IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
432	!
433	IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines
434	CALL istate_init ! ocean initial state (Dynamics and tracers)
435	CALL sbc_init ! Forcings : surface module
436	CALL tra_qsr_init ! penetrative solar radiation qsr
437	IF( ln_diaobs ) THEN ! Observation & model comparison
438	CALL dia_obs_init ! Initialize observational data
439	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
440	ENDIF
441	IF( lk_asminc ) CALL asm_inc_init ! Assimilation increments
442	!
443	RETURN ! end of initialization
444	ENDIF
445
446	CALL istate_init ! ocean initial state (Dynamics and tracers)
447
448	! ! external forcing
449	CALL tide_init ! tidal harmonics
450	CALL sbc_init ! surface boundary conditions (including sea-ice)
451	CALL bdy_init ! Open boundaries initialisation
452
453	! ! Ocean physics
454	CALL zdf_phy_init ! Vertical physics
455
456	! ! Lateral physics
457	CALL ldf_tra_init ! Lateral ocean tracer physics
458	CALL ldf_eiv_init ! eddy induced velocity param.
459	CALL ldf_dyn_init ! Lateral ocean momentum physics
460
461	! ! Active tracers
462	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr
463	CALL tra_bbc_init ! bottom heat flux
464	CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
465	CALL tra_dmp_init ! internal tracer damping
466	CALL tra_adv_init ! horizontal & vertical advection
467	CALL tra_ldf_init ! lateral mixing
468
469	! ! Dynamics
470	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
471	CALL dyn_adv_init ! advection (vector or flux form)
472	CALL dyn_vor_init ! vorticity term including Coriolis
473	CALL dyn_ldf_init ! lateral mixing
474	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
475	CALL dyn_spg_init ! surface pressure gradient
476
477	#if defined key_top
478	! ! Passive tracers
479	CALL trc_init
480	#endif
481	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
482
483	! ! Icebergs
484	CALL icb_init( rdt, nit000) ! initialise icebergs instance
485
486	! ! Misc. options
487	CALL sto_par_init ! Stochastic parametrization
488	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
489
490	! ! Diagnostics
491	CALL flo_init ! drifting Floats
492	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
493	CALL dia_ptr_init ! Poleward TRansports initialization
494	CALL dia_dct_init ! Sections tranports
495	CALL dia_hsb_init ! heat content, salt content and volume budgets
496	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
497	CALL dia_obs_init ! Initialize observational data
498	CALL dia_25h_init ! 25h mean outputs
499	CALL dia_harm_init ! tidal harmonics outputs
500	IF( ln_diaobs ) CALL dia_obs( nit000-1 ) ! Observation operator for restart
501	!JT
502	CALL dia_regmean_init ! Initialise Regiona mean
503	CALL dia_pea_init ! Initialise PEA
504	!JT
505
506
507	! ! Assimilation increments
508	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
509	!
510	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
511	!
512	IF( ln_timing ) CALL timing_stop( 'nemo_init')
513	!
514	END SUBROUTINE nemo_init
515
516
517	SUBROUTINE nemo_ctl
518	!!----------------------------------------------------------------------
519	!! * ROUTINE nemo_ctl *
520	!!
521	!! ** Purpose : control print setting
522	!!
523	!! ** Method : - print namctl and namcfg information and check some consistencies
524	!!----------------------------------------------------------------------
525	!
526	IF(lwp) THEN ! control print
527	WRITE(numout,*)
528	WRITE(numout,*) 'nemo_ctl: Control prints'
529	WRITE(numout,*) '~~~~~~~~'
530	WRITE(numout,*) ' Namelist namctl'
531	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
532	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
533	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
534	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
535	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
536	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
537	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
538	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
539	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
540	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
541	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
542	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
543	WRITE(numout,*) ' level of print nn_print = ', nn_print
544	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
545	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
546	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
547	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
548	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
549	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
550	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
551	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
552	ENDIF
553	!
554	nprint = nn_print ! convert DOCTOR namelist names into OLD names
555	nictls = nn_ictls
556	nictle = nn_ictle
557	njctls = nn_jctls
558	njctle = nn_jctle
559	isplt = nn_isplt
560	jsplt = nn_jsplt
561
562	IF(lwp) THEN ! control print
563	WRITE(numout,*)
564	WRITE(numout,*) ' Namelist namcfg'
565	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
566	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
567	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
568	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
569	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
570	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
571	ENDIF
572	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
573	!
574	! ! Parameter control
575	!
576	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
577	IF( lk_mpp .AND. jpnij > 1 ) THEN
578	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
579	ELSE
580	IF( isplt == 1 .AND. jsplt == 1 ) THEN
581	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
582	& ' - the print control will be done over the whole domain' )
583	ENDIF
584	ijsplt = isplt * jsplt ! total number of processors ijsplt
585	ENDIF
586	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
587	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
588	!
589	! ! indices used for the SUM control
590	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
591	lsp_area = .FALSE.
592	ELSE ! print control done over a specific area
593	lsp_area = .TRUE.
594	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
595	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
596	nictls = 1
597	ENDIF
598	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
599	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
600	nictle = jpiglo
601	ENDIF
602	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
603	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
604	njctls = 1
605	ENDIF
606	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
607	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
608	njctle = jpjglo
609	ENDIF
610	ENDIF
611	ENDIF
612	!
613	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
614	& 'Compile with key_nosignedzero enabled:', &
615	& '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
616	!
617	#if defined key_agrif
618	IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
619	#endif
620	!
621	END SUBROUTINE nemo_ctl
622
623
624	SUBROUTINE nemo_closefile
625	!!----------------------------------------------------------------------
626	!! * ROUTINE nemo_closefile *
627	!!
628	!! ** Purpose : Close the files
629	!!----------------------------------------------------------------------
630	!
631	IF( lk_mpp ) CALL mppsync
632	!
633	CALL iom_close ! close all input/output files managed by iom_*
634	!
635	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
636	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
637	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
638	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
639	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
640	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
641	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
642	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
643	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
644	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
645	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
646	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
647	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
648	!JT
649	IF( numdct_NOOS /= -1 ) CLOSE( numdct_NOOS ) ! NOOS transports
650	IF( numdct_NOOS_h /= -1 ) CLOSE( numdct_NOOS_h ) ! NOOS transports
651	!JT
652
653	!
654	numout = 6 ! redefine numout in case it is used after this point...
655	!
656	END SUBROUTINE nemo_closefile
657
658
659	SUBROUTINE nemo_alloc
660	!!----------------------------------------------------------------------
661	!! * ROUTINE nemo_alloc *
662	!!
663	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
664	!!
665	!! ** Method :
666	!!----------------------------------------------------------------------
667	USE diawri , ONLY : dia_wri_alloc
668	USE dom_oce , ONLY : dom_oce_alloc
669	USE trc_oce , ONLY : trc_oce_alloc
670	USE bdy_oce , ONLY : bdy_oce_alloc
671	!
672	INTEGER :: ierr
673	!!----------------------------------------------------------------------
674	!
675	ierr = oce_alloc () ! ocean
676	ierr = ierr + dia_wri_alloc()
677	ierr = ierr + dom_oce_alloc() ! ocean domain
678	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
679	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
680	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
681	!
682	CALL mpp_sum( 'nemogcm', ierr )
683	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
684	!
685	END SUBROUTINE nemo_alloc
686
687
688	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
689	!!----------------------------------------------------------------------
690	!! * ROUTINE nemo_set_cfctl *
691	!!
692	!! ** Purpose : Set elements of the output control structure to setto.
693	!! for_all should be .false. unless all areas are to be
694	!! treated identically.
695	!!
696	!! ** Method : Note this routine can be used to switch on/off some
697	!! types of output for selected areas but any output types
698	!! that involve global communications (e.g. mpp_max, glob_sum)
699	!! should be protected from selective switching by the
700	!! for_all argument
701	!!----------------------------------------------------------------------
702	LOGICAL :: setto, for_all
703	TYPE(sn_ctl) :: sn_cfctl
704	!!----------------------------------------------------------------------
705	IF( for_all ) THEN
706	sn_cfctl%l_runstat = setto
707	sn_cfctl%l_trcstat = setto
708	ENDIF
709	sn_cfctl%l_oceout = setto
710	sn_cfctl%l_layout = setto
711	sn_cfctl%l_mppout = setto
712	sn_cfctl%l_mpptop = setto
713	END SUBROUTINE nemo_set_cfctl
714
715	!!======================================================================
716	END MODULE nemogcm
717

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/UKMO/NEMO_4.0.4_CO9_shelf_climate/src/OCE/nemogcm.F90 @ 15637

Download in other formats: