New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icerst.F90 in NEMO/branches/UKMO/NEMO_4.0.3_GO8_package/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.3_GO8_package/src/ICE/icerst.F90 @ 13590

Last change on this file since 13590 was 13590, checked in by cguiavarch, 4 years ago

UKMO/NEMO_4.0.3_GO8_package: copy over changes from NEMO_4.0.2_GO8_package branch @13304.
File size: 14.0 KB
Line 
1MODULE icerst
2   !!======================================================================
3   !!                     ***  MODULE  icerst  ***
4   !!   sea-ice :  write/read the ice restart file
5   !!======================================================================
6   !! History:   4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_rst_opn   : open  restart file
13   !!   ice_rst_write : write restart file
14   !!   ice_rst_read  : read  restart file
15   !!----------------------------------------------------------------------
16   USE ice            ! sea-ice: variables
17   USE dom_oce        ! ocean domain
18   USE phycst  , ONLY : rt0
19   USE sbc_oce , ONLY : nn_fsbc, ln_cpl
20   USE iceistate      ! sea-ice: initial state
21   USE icectl         ! sea-ice: control
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE ioipsl, ONLY : ju2ymds    ! for calendar
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   ice_rst_opn     ! called by icestp
33   PUBLIC   ice_rst_write   ! called by icestp
34   PUBLIC   ice_rst_read    ! called by ice_init
35
36   !!----------------------------------------------------------------------
37   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE ice_rst_opn( kt )
44      !!----------------------------------------------------------------------
45      !!                    ***  ice_rst_opn  ***
46      !!
47      !! ** purpose  :   open restart file
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt       ! number of iteration
50      !
51      INTEGER             ::   iyear, imonth, iday
52      REAL (wp)           ::   zsec
53      REAL (wp)           ::   zfjulday
54      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
55      CHARACTER(len=50)   ::   clname   ! ice output restart file name
56      CHARACTER(len=256)  ::   clpath   ! full path to ice output restart file
57      !!----------------------------------------------------------------------
58      !
59      IF( kt == nit000 )   lrst_ice = .FALSE.   ! default definition
60
61      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN
62      ! in order to get better performances with NetCDF format, we open and define the ice restart file
63      ! one ice time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write ice
64      ! restart files every ice time step or if an ice restart file was writen at nitend - 2*nn_fsbc + 1
65      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nn_stock == nn_fsbc    &
66         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_ice ) ) THEN
67         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
68            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
69            IF ( ln_rstdate ) THEN
70               zfjulday = fjulday + (2*nn_fsbc+1)*rdt / rday
71               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
72               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
73               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
74            ELSE
75               IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
76               ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
77               ENDIF
78            ENDIF
79            ! create the file
80            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_icerst_out)
81            clpath = TRIM(cn_icerst_outdir) 
82            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
83            IF(lwp) THEN
84               WRITE(numout,*)
85               WRITE(numout,*) '             open ice restart NetCDF file: ',TRIM(clpath)//clname
86               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
87                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
88               ELSE
89                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
90               ENDIF
91            ENDIF
92            !
93            CALL iom_open( TRIM(clpath)//TRIM(clname), numriw, ldwrt = .TRUE., kdlev = jpl )
94            lrst_ice = .TRUE.
95         ENDIF
96      ENDIF
97      ENDIF
98      !
99      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - Beginning the time step - ' )   ! control print
100      !
101   END SUBROUTINE ice_rst_opn
102
103
104   SUBROUTINE ice_rst_write( kt )
105      !!----------------------------------------------------------------------
106      !!                    ***  ice_rst_write  ***
107      !!
108      !! ** purpose  :   write restart file
109      !!----------------------------------------------------------------------
110      INTEGER, INTENT(in) ::   kt     ! number of iteration
111      !!
112      INTEGER ::   jk    ! dummy loop indices
113      INTEGER ::   iter
114      CHARACTER(len=25) ::   znam
115      CHARACTER(len=2)  ::   zchar, zchar1
116      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
117      !!----------------------------------------------------------------------
118
119      iter = kt + nn_fsbc - 1   ! ice restarts are written at kt == nitrst - nn_fsbc + 1
120
121      IF( iter == nitrst ) THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'ice_rst_write : write ice restart file  kt =', kt
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
125      ENDIF
126
127      ! Write in numriw (if iter == nitrst)
128      ! ------------------
129      !                                                                        ! calendar control
130      CALL iom_rstput( iter, nitrst, numriw, 'nn_fsbc', REAL( nn_fsbc, wp ) )      ! time-step
131      CALL iom_rstput( iter, nitrst, numriw, 'kt_ice' , REAL( iter   , wp ) )      ! date
132      CALL iom_delay_rst( 'WRITE', 'ICE', numriw )   ! save only ice delayed global communication variables
133
134      ! Prognostic variables
135      CALL iom_rstput( iter, nitrst, numriw, 'v_i'  , v_i   )
136      CALL iom_rstput( iter, nitrst, numriw, 'v_s'  , v_s   )
137      CALL iom_rstput( iter, nitrst, numriw, 'sv_i' , sv_i  )
138      CALL iom_rstput( iter, nitrst, numriw, 'a_i'  , a_i   )
139      CALL iom_rstput( iter, nitrst, numriw, 't_su' , t_su  )
140      CALL iom_rstput( iter, nitrst, numriw, 'u_ice', u_ice )
141      CALL iom_rstput( iter, nitrst, numriw, 'v_ice', v_ice )
142      CALL iom_rstput( iter, nitrst, numriw, 'oa_i' , oa_i  )
143      CALL iom_rstput( iter, nitrst, numriw, 'a_ip' , a_ip  )
144      CALL iom_rstput( iter, nitrst, numriw, 'v_ip' , v_ip  )
145      CALL iom_rstput( iter, nitrst, numriw, 'v_il' , v_il  )
146      ! Snow enthalpy
147      DO jk = 1, nlay_s 
148         WRITE(zchar1,'(I2.2)') jk
149         znam = 'e_s'//'_l'//zchar1
150         z3d(:,:,:) = e_s(:,:,jk,:)
151         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
152      END DO
153      ! Ice enthalpy
154      DO jk = 1, nlay_i 
155         WRITE(zchar1,'(I2.2)') jk
156         znam = 'e_i'//'_l'//zchar1
157         z3d(:,:,:) = e_i(:,:,jk,:)
158         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
159      END DO
160      ! fields needed for Met Office (Jules) coupling
161      IF( ln_cpl ) THEN
162         CALL iom_rstput( iter, nitrst, numriw, 'cnd_ice', cnd_ice )
163         CALL iom_rstput( iter, nitrst, numriw, 't1_ice' , t1_ice  )
164      ENDIF
165      !
166
167      ! close restart file
168      ! ------------------
169      IF( iter == nitrst ) THEN
170         CALL iom_close( numriw )
171         lrst_ice = .FALSE.
172      ENDIF
173      !
174   END SUBROUTINE ice_rst_write
175
176
177   SUBROUTINE ice_rst_read
178      !!----------------------------------------------------------------------
179      !!                    ***  ice_rst_read  ***
180      !!
181      !! ** purpose  :   read restart file
182      !!----------------------------------------------------------------------
183      INTEGER           ::   jk
184      LOGICAL           ::   llok
185      INTEGER           ::   id0, id1, id2, id3, id4, id5   ! local integer
186      CHARACTER(len=25) ::   znam
187      CHARACTER(len=2)  ::   zchar, zchar1
188      REAL(wp)          ::   zfice, ziter
189      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
190      !!----------------------------------------------------------------------
191
192      IF(lwp) THEN
193         WRITE(numout,*)
194         WRITE(numout,*) 'ice_rst_read: read ice NetCDF restart file'
195         WRITE(numout,*) '~~~~~~~~~~~~'
196      ENDIF
197
198      CALL iom_open ( TRIM(cn_icerst_indir)//'/'//cn_icerst_in, numrir, kdlev = jpl )
199
200      ! test if v_i exists
201      id0 = iom_varid( numrir, 'v_i' , ldstop = .FALSE. )
202
203      !                    ! ------------------------------ !
204      IF( id0 > 0 ) THEN   ! == case of a normal restart == !
205         !                 ! ------------------------------ !
206         
207         ! Time info
208         CALL iom_get( numrir, 'nn_fsbc', zfice )
209         CALL iom_get( numrir, 'kt_ice' , ziter )   
210         IF(lwp) WRITE(numout,*) '   read ice restart file at time step    : ', ziter
211         IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
212
213         ! Control of date
214         IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
215            &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nit000 in ice restart',  &
216            &                   '   verify the file or rerun with the value 0 for the',        &
217            &                   '   control of time parameter  nrstdt' )
218         IF( NINT(zfice) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
219            &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nn_fsbc in ice restart',  &
220            &                   '   verify the file or rerun with the value 0 for the',         &
221            &                   '   control of time parameter  nrstdt' )
222
223         ! --- mandatory fields --- !
224         CALL iom_get( numrir, jpdom_autoglo, 'v_i'  , v_i   )
225         CALL iom_get( numrir, jpdom_autoglo, 'v_s'  , v_s   )
226         CALL iom_get( numrir, jpdom_autoglo, 'sv_i' , sv_i  )
227         CALL iom_get( numrir, jpdom_autoglo, 'a_i'  , a_i   )
228         CALL iom_get( numrir, jpdom_autoglo, 't_su' , t_su  )
229         CALL iom_get( numrir, jpdom_autoglo, 'u_ice', u_ice )
230         CALL iom_get( numrir, jpdom_autoglo, 'v_ice', v_ice )
231         ! Snow enthalpy
232         DO jk = 1, nlay_s
233            WRITE(zchar1,'(I2.2)') jk
234            znam = 'e_s'//'_l'//zchar1
235            CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
236            e_s(:,:,jk,:) = z3d(:,:,:)
237         END DO
238         ! Ice enthalpy
239         DO jk = 1, nlay_i
240            WRITE(zchar1,'(I2.2)') jk
241            znam = 'e_i'//'_l'//zchar1
242            CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
243            e_i(:,:,jk,:) = z3d(:,:,:)
244         END DO
245         ! -- optional fields -- !
246         ! ice age
247         id1 = iom_varid( numrir, 'oa_i' , ldstop = .FALSE. )
248         IF( id1 > 0 ) THEN                       ! fields exist
249            CALL iom_get( numrir, jpdom_autoglo, 'oa_i', oa_i )
250         ELSE                                     ! start from rest
251            IF(lwp) WRITE(numout,*) '   ==>>   previous run without ice age output then set it to zero'
252            oa_i(:,:,:) = 0._wp
253         ENDIF
254         ! melt ponds
255         id2 = iom_varid( numrir, 'a_ip' , ldstop = .FALSE. )
256         IF( id2 > 0 ) THEN                       ! fields exist
257            CALL iom_get( numrir, jpdom_autoglo, 'a_ip' , a_ip )
258            CALL iom_get( numrir, jpdom_autoglo, 'v_ip' , v_ip )
259         ELSE                                     ! start from rest
260            IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds output then set it to zero'
261            a_ip(:,:,:) = 0._wp
262            v_ip(:,:,:) = 0._wp
263         ENDIF
264         ! melt pond lids
265         id3 = iom_varid( numrir, 'v_il' , ldstop = .FALSE. )
266         IF( id3 > 0 ) THEN
267            CALL iom_get( numrir, jpdom_autoglo, 'v_il', v_il)
268         ELSE
269            IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds lids output then set it to zero'
270            v_il(:,:,:) = 0._wp
271         ENDIF
272         ! fields needed for Met Office (Jules) coupling
273         IF( ln_cpl ) THEN
274            id4 = iom_varid( numrir, 'cnd_ice' , ldstop = .FALSE. )
275            id5 = iom_varid( numrir, 't1_ice'  , ldstop = .FALSE. )
276            IF( id4 > 0 .AND. id5 > 0 ) THEN         ! fields exist
277               CALL iom_get( numrir, jpdom_autoglo, 'cnd_ice', cnd_ice )
278               CALL iom_get( numrir, jpdom_autoglo, 't1_ice' , t1_ice  )
279            ELSE                                     ! start from rest
280               IF(lwp) WRITE(numout,*) '   ==>>   previous run without conductivity output then set it to zero'
281               cnd_ice(:,:,:) = 0._wp
282               t1_ice (:,:,:) = rt0
283            ENDIF
284         ENDIF
285
286         CALL iom_delay_rst( 'READ', 'ICE', numrir )   ! read only ice delayed global communication variables
287
288         !                 ! ---------------------------------- !
289      ELSE                 ! == case of a simplified restart == !
290         !                 ! ---------------------------------- !
291         CALL ctl_warn('ice_rst_read: you are using a simplified ice restart')
292         !
293         CALL ice_istate_init
294         CALL ice_istate( nit000 )
295         !
296         IF( .NOT.ln_iceini .OR. nn_iceini_file == 0 ) &
297            &   CALL ctl_stop('STOP', 'ice_rst_read: you need ln_ice_ini=T and nn_iceini_file=0')
298         !
299      ENDIF
300
301   END SUBROUTINE ice_rst_read
302
303#else
304   !!----------------------------------------------------------------------
305   !!   Default option :       Empty module           NO SI3 sea-ice model
306   !!----------------------------------------------------------------------
307#endif
308
309   !!======================================================================
310END MODULE icerst
Note: See TracBrowser for help on using the repository browser.