New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z/p5zprod.F90 @ 14416

Last change on this file since 14416 was 14416, checked in by cetlod, 3 years ago

dev_r14383_PISCES_NEWDEV_PISCO : minor improvments
  • Property svn:keywords set to Id
File size: 37.2 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the three phytoplanktons groups
5   !!        PISCES-QUOTA version of the module
6   !!======================================================================
7   !! History :   1.0  !  2004     (O. Aumont) Original code
8   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
9   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
10   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
11   !!----------------------------------------------------------------------
12   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
13   !!   p5z_prod_init  :   Initialization of the parameters for growth
14   !!   p5z_prod_alloc :   Allocate variables for growth
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zlim
20   USE p5zlim          !  Co-limitations of differents nutrients
21   USE prtctl          !  print control for debugging
22   USE iom             !  I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p5z_prod         ! called in p5zbio.F90
28   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
29   PUBLIC   p5z_prod_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  pislopen        !: P-I slope of nanophytoplankton
33   REAL(wp), PUBLIC ::  pislopep        !: P-I slope of picophytoplankton
34   REAL(wp), PUBLIC ::  pisloped        !: P-I slope of diatoms
35   REAL(wp), PUBLIC ::  xadap           !: Adaptation factor to low light
36   REAL(wp), PUBLIC ::  excretn         !: Excretion ratio of nanophyto
37   REAL(wp), PUBLIC ::  excretp         !: Excretion ratio of picophyto
38   REAL(wp), PUBLIC ::  excretd         !: Excretion ratio of diatoms
39   REAL(wp), PUBLIC ::  bresp           !: Basal respiration rate
40   REAL(wp), PUBLIC ::  thetanpm        !: Maximum Chl/N ratio of picophyto
41   REAL(wp), PUBLIC ::  thetannm        !: Maximum Chl/N ratio of nanophyto
42   REAL(wp), PUBLIC ::  thetandm        !: Maximum Chl/N ratio of diatoms
43   REAL(wp), PUBLIC ::  chlcmin         !: Minimum Chl/C ratio of phytoplankton
44   REAL(wp), PUBLIC ::  grosip          !: Mean Si/C ratio of diatoms
45
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen ! day length
47   
48   REAL(wp) :: r1_rday                !: 1 / rday
49   REAL(wp) :: texcretn               !: 1 - excretn
50   REAL(wp) :: texcretp               !: 1 - excretp
51   REAL(wp) :: texcretd               !: 1 - excretd       
52
53   !! * Substitutions
54#  include "do_loop_substitute.h90"
55#  include "domzgr_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
58   !! $Id$
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p5z_prod( kt , knt, Kbb, Kmm, Krhs )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p5z_prod  ***
66      !!
67      !! ** Purpose :   Compute the phytoplankton production depending on
68      !!              light, temperature and nutrient availability
69      !!              Computes also the uptake of nutrients. PISCES-quota
70      !!              relies on a full quota formalism
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) :: kt, knt
74      INTEGER, INTENT(in) :: Kbb, Kmm, Krhs      ! time level indices
75      !
76      INTEGER  ::   ji, jj, jk
77      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
78      REAL(wp) ::   zration, zratiop, zratiof, zmax, ztn, zadap
79      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zratio
80      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
81      REAL(wp) ::   zproddoc, zproddon, zproddop, zprodsil, zprodfer, zprodlig, zresptot     
82      REAL(wp) ::   zprnutmax, zprochln, zprochld, zprochlp
83      REAL(wp) ::   zpislopen, zpislopep, zpisloped
84      REAL(wp) ::   zval, zpptot, zpnewtot, zpregtot
85      REAL(wp) ::   zqfpmax, zqfnmax, zqfdmax
86      REAL(wp) ::   zfact, zrfact2, zmaxsi, zratiosi, zsizetmp, zlimfac, zsilim
87      CHARACTER (len=25) :: charout
88      REAL(wp), DIMENSION(jpi,jpj    ) :: zmixnano, zmixpico, zmixdiat
89      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadp, zpislopeadd
90      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprnut, zprmaxp, zprmaxn, zprmaxd
91      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprbio, zprpic, zprdia, zysopt
92      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprchln, zprchlp, zprchld
93      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcap, zprorcad 
94      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprofed, zprofep, zprofen
95      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewp, zpronewd
96      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zproregn, zproregp, zproregd
97      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpropo4n, zpropo4p, zpropo4d
98      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprodopn, zprodopp, zprodopd
99      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespn, zrespp, zrespd
100      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
101      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zpligprod
102      !!---------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('p5z_prod')
105
106      ! Initialize the local arrays
107      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
108      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
109      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
110      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
111      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
112      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
113      zprodopn(:,:,:) = 0._wp ; zprodopp(:,:,:) = 0._wp ; zprodopd(:,:,:) = 0._wp
114      zysopt  (:,:,:) = 0._wp 
115      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
116      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp
117
118      ! Computation of the optimal production rates and nutrient uptake
119      ! rates. Based on a Q10 description of the thermal dependency.
120      zprnut (:,:,:) =  0.8_wp * r1_rday * tgfunc(:,:,:)
121      zprmaxn(:,:,:) =  0.8_wp * (1. + xpsino3 * qnnmax ) * r1_rday * tgfunc(:,:,:)
122      zprmaxd(:,:,:) =  0.8_wp * (1. + xpsino3 * qndmax ) * r1_rday * tgfunc(:,:,:)
123      zprmaxp(:,:,:) =  0.6_wp * (1. + xpsino3 * qnpmax ) * r1_rday * tgfunc(:,:,:)
124
125      ! Impact of the day duration and light intermittency on phytoplankton growth
126      ! Intermittency is supposed to have a similar effect on production as
127      ! day length (Shatwell et al., 2012). The correcting factor is zmxl_fac.
128      ! zmxl_chl is the fractional day length and is used to compute the mean
129      ! PAR during daytime. The effect of mixing is computed using the
130      ! absolute light level definition of the euphotic zone
131      ! -------------------------------------------------------------------------
132      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
133         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
134            zval = MAX( 1., strn(ji,jj) )
135            IF( gdepw(ji,jj,jk+1,Kmm) <= hmld(ji,jj) ) THEN
136               zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
137            ENDIF
138            zmxl_chl(ji,jj,jk) = zval / 24.
139            zmxl_fac(ji,jj,jk) = 1.0 - exp( -0.26 * zval )
140         ENDIF
141      END_3D
142
143      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
144      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
145      zprpic(:,:,:) = zprmaxp(:,:,:) * zmxl_fac(:,:,:)
146
147      ! Maximum light intensity
148      zdaylen(:,:) = MAX(1., strn(:,:)) / 24.
149
150      ! Computation of the P-I slope for nanos, picos and diatoms
151      ! The formulation proposed by Geider et al. (1997) has been used.
152      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
153         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
154            ! Computation of the P-I slope for nanos and diatoms
155            ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
156            zadap       = xadap * ztn / ( 2.+ ztn )
157            !
158            ! Nanophytoplankton
159            zpislopeadn(ji,jj,jk) = pislopen * tr(ji,jj,jk,jpnch,Kbb)    &
160            &                       /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
161
162            ! Picophytoplankton
163            zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
164            &                       * tr(ji,jj,jk,jppch,Kbb) /( tr(ji,jj,jk,jppic,Kbb) * 12. + rtrn)
165
166            ! Diatoms
167            zpislopeadd(ji,jj,jk) = pisloped * tr(ji,jj,jk,jpdch,Kbb)    &
168               &                    /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
169            !
170            zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
171            zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
172            zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
173
174            ! Computation of production function for Carbon
175            ! Actual light levels are used here
176            !  ---------------------------------------------
177            zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
178            zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
179            zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
180
181            !  Computation of production function for Chlorophyll
182            !  Mean light level in the mixed layer (when appropriate)
183            !  is used here (acclimation is in general slower than
184            !  the characteristic time scales of vertical mixing)
185            !  ------------------------------------------------------
186            zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
187            zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
188            zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
189            zprchln(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) )  )
190            zprchlp(ji,jj,jk) = zprmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epicom(ji,jj,jk) )  )
191            zprchld(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) )  )
192         ENDIF
193      END_3D
194
195      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
196          IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
197            ! Si/C of diatoms
198            ! ------------------------
199            ! Si/C increases with iron stress and silicate availability (zsilfac)
200            ! Si/C is arbitrariliy increased for very high Si concentrations
201            ! to mimic the very high ratios observed in the Southern Ocean (zsilfac2)
202            ! A parameterization derived from Flynn (2003) is used for the control
203            ! when Si is not limiting which is similar to the parameterisation
204            ! proposed by Gurney and Davidson (1999).
205            ! -----------------------------------------------------------------------
206            zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
207            zsilim = xlimdia(ji,jj,jk) * zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn )
208            zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
209            IF (gphit(ji,jj) < -30 ) THEN
210              zsilfac2 = 1. + 1. * zsiborn / ( zsiborn + xksi2**3 )
211            ELSE
212              zsilfac2 = 1.
213            ENDIF
214            zratiosi = 1.0 - tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn ) / ( zsilfac2 * grosip * 3.0 + rtrn )
215            zratiosi = MAX(0., MIN(1.0, zratiosi) )
216            zmaxsi  = (1.0 + 0.1**4) * zratiosi**4 / ( zratiosi**4 + 0.1**4 )
217            IF ( xlimsi(ji,jj,jk) /= xlimdia(ji,jj,jk) ) THEN
218               zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zmaxsi
219            ELSE
220               zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zsilim**0.7 * zmaxsi
221            ENDIF
222         ENDIF
223      END_3D
224
225      !  Sea-ice effect on production
226      ! No production is assumed below sea ice
227      ! --------------------------------------
228      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
229         zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
230         zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
231         zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
232         zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
233      END_3D
234
235      ! Computation of the various production and uptake terms of nanophytoplankton
236      ! Interactions between N and P are modeled according to the Chain Model
237      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
238      ! Droop kinetics. When the quota is approaching the maximum achievable
239      ! quota, uptake is downregulated according to a sigmoidal function
240      ! (power 2), as proposed by Flynn (2003)
241      ! ---------------------------------------------------------------------------
242      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
243         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
244            !  production terms for nanophyto.
245            zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
246
247            ! Size computation
248            ! Size is made a function of the limitation of of phytoplankton growth
249            ! Strongly limited cells are supposed to be smaller. sizena is the
250            ! size at time step t+1 and is thus updated at the end of the
251            ! current time step
252            ! --------------------------------------------------------------------
253            zlimfac = xlimphys(ji,jj,jk) * zprchln(ji,jj,jk) / ( zprmaxn(ji,jj,jk) + rtrn )
254            zsizetmp = 1.0 + 1.3 * ( xsizern - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
255            sizena(ji,jj,jk) = MIN(xsizern, MAX( sizena(ji,jj,jk), zsizetmp ) )
256            ! Maximum potential uptake rate
257            zration = tr(ji,jj,jk,jpnph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
258            zratiop = tr(ji,jj,jk,jppph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
259            zratiof = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
260            zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpphy,Kbb) * rfact2
261            ! Uptake of nitrogen
262            zratio = 1.0 - MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) )
263            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
264            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
265            &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
266            zpronmax = zpronmax * xqnnmin(ji,jj,jk) / qnnmin
267            zpronewn(ji,jj,jk) = zpronmax * xnanono3(ji,jj,jk)
268            zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
269            ! Uptake of phosphorus and DOP
270            zratio = 1.0 - MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
271            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
272            zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
273            zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
274            zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
275            ! Uptake of iron
276            zqfnmax = xqfuncfecn(ji,jj,jk) + ( qfnmax - xqfuncfecn(ji,jj,jk) ) * xlimnpn(ji,jj,jk)
277            zratio = 1.0 - MIN( 1., zratiof / zqfnmax )
278            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
279            zprofmax = zprnutmax * zqfnmax * zmax 
280            zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk)    &
281            &          * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
282            &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
283         ENDIF
284      END_3D
285
286      ! Computation of the various production and uptake terms of picophytoplankton
287      ! Interactions between N and P are modeled according to the Chain Model
288      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
289      ! Droop kinetics. When the quota is approaching the maximum achievable
290      ! quota, uptake is downregulated according to a sigmoidal function
291      ! (power 2), as proposed by Flynn (2003)
292      ! ---------------------------------------------------------------------------
293      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
294         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
295            !  production terms for picophyto.
296            zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * tr(ji,jj,jk,jppic,Kbb) * rfact2
297            ! Size computation
298            ! Size is made a function of the limitation of of phytoplankton growth
299            ! Strongly limited cells are supposed to be smaller. sizepa is
300            ! size at time step t+1 and is thus updated at the end of the
301            ! current time step
302            ! --------------------------------------------------------------------
303            zlimfac = zprchlp(ji,jj,jk)  * xlimpics(ji,jj,jk) / ( zprmaxp(ji,jj,jk) + rtrn )
304            zsizetmp = 1.0 + 1.3 * ( xsizerp - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
305            sizepa(ji,jj,jk) = min(xsizerp, max( sizepa(ji,jj,jk), zsizetmp ) )
306            ! Maximum potential uptake rate of nutrients
307            zration = tr(ji,jj,jk,jpnpi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
308            zratiop = tr(ji,jj,jk,jpppi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
309            zratiof = tr(ji,jj,jk,jppfe,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
310            zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jppic,Kbb) * rfact2
311            ! Uptake of nitrogen
312            zratio = 1.0 - MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
313            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
314            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
315            &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
316            zpronmax = zpronmax * xqnpmin(ji,jj,jk) / qnnmin
317            zpronewp(ji,jj,jk) = zpronmax * xpicono3(ji,jj,jk) 
318            zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
319            ! Uptake of phosphorus
320            zratio = 1.0 - MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
321            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
322            zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk) 
323            zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
324            zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
325            ! Uptake of iron
326            zqfpmax = xqfuncfecp(ji,jj,jk) + ( qfpmax - xqfuncfecp(ji,jj,jk) ) * xlimnpp(ji,jj,jk)
327            zratio = 1.0 - MIN( 1., zratiof / zqfpmax )
328            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
329            zprofmax = zprnutmax * zqfpmax * zmax
330            zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk)  &
331            &          * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
332            &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
333         ENDIF
334      END_3D
335
336      ! Computation of the various production and uptake terms of diatoms
337      ! Interactions between N and P are modeled according to the Chain Model
338      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
339      ! Droop kinetics. When the quota is approaching the maximum achievable
340      ! quota, uptake is downregulated according to a sigmoidal function
341      ! (power 2), as proposed by Flynn (2003)
342      ! ---------------------------------------------------------------------------
343      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
344         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
345            !  production terms for diatomees
346            zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
347            ! Size computation
348            ! Size is made a function of the limitation of of phytoplankton growth
349            ! Strongly limited cells are supposed to be smaller. sizeda is
350            ! size at time step t+1 and is thus updated at the end of the
351            ! current time step.
352            ! --------------------------------------------------------------------
353            zlimfac = zprchld(ji,jj,jk) * xlimdias(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn )
354            zsizetmp = 1.0 + 1.3 * ( xsizerd - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
355            sizeda(ji,jj,jk) = min(xsizerd, max( sizeda(ji,jj,jk), zsizetmp ) )
356            ! Maximum potential uptake rate of nutrients
357            zration = tr(ji,jj,jk,jpndi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
358            zratiop = tr(ji,jj,jk,jppdi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
359            zratiof = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
360            zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpdia,Kbb) * rfact2
361            ! Uptake of nitrogen
362            zratio = 1.0 - MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
363            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
364            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
365            &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimdfe(ji,jj,jk) ) )
366            zpronmax = zpronmax * xqndmin(ji,jj,jk) / qnnmin
367            zpronewd(ji,jj,jk) = zpronmax * xdiatno3(ji,jj,jk)
368            zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
369            ! Uptake of phosphorus
370            zratio = 1.0 - MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
371            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
372            zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
373            zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
374            zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
375            ! Uptake of iron
376            zqfdmax = xqfuncfecd(ji,jj,jk) + ( qfdmax - xqfuncfecd(ji,jj,jk) ) * xlimnpd(ji,jj,jk)
377            zratio = 1.0 - MIN( 1., zratiof / zqfdmax )
378            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
379            zprofmax = zprnutmax * zqfdmax * zmax
380            zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk)    &
381            &          * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
382            &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
383         ENDIF
384      END_3D
385
386      ! Production of Chlorophyll. The formulation proposed by Geider et al.
387      ! is adopted here.
388      ! --------------------------------------------------------------------
389      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
390         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
391               !  production terms for nanophyto. ( chlorophyll )
392            znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
393            zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
394            zprochln = thetannm * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
395            zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
396               !  production terms for picophyto. ( chlorophyll )
397            zpicotot = epicom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
398            zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
399            zprochlp = thetanpm * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
400            zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
401            !  production terms for diatoms ( chlorophyll )
402            zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
403            zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
404            zprochld = thetandm * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
405            zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
406            !   Update the arrays TRA which contain the Chla sources and sinks
407            tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
408            tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
409            tr(ji,jj,jk,jppch,Krhs) = tr(ji,jj,jk,jppch,Krhs) + zprochlp * texcretp
410         ENDIF
411      END_3D
412
413      !   Update the arrays TRA which contain the biological sources and sinks
414      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
415        zpptot   = zpropo4n(ji,jj,jk) + zpropo4d(ji,jj,jk) + zpropo4p(ji,jj,jk)
416        zpnewtot = zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk)
417        zpregtot = zproregn(ji,jj,jk) + zproregd(ji,jj,jk) + zproregp(ji,jj,jk)
418
419        zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
420        zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
421        zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
422        !
423        zproddoc = excretd * zprorcad(ji,jj,jk) &
424        &        + excretn * zprorcan(ji,jj,jk) &
425        &        + excretp * zprorcap(ji,jj,jk)
426        !
427        zproddop = excretd * zpropo4d(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) &
428        &        + excretn * zpropo4n(ji,jj,jk) - texcretn * zprodopn(ji,jj,jk) &
429        &        + excretp * zpropo4p(ji,jj,jk) - texcretp * zprodopp(ji,jj,jk)
430
431        zproddon =  excretd * zprodtot + excretn * zprontot + excretp * zproptot
432
433        zprodfer = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
434        zresptot = zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) 
435 
436        !
437        tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zpptot
438        tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpnewtot
439        tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zpregtot 
440        !
441        tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs)         &
442           &                     + zprorcan(ji,jj,jk) * texcretn  &
443           &                     - xpsino3 * zpronewn(ji,jj,jk)   &
444           &                     - xpsinh4 * zproregn(ji,jj,jk)   &
445           &                     - zrespn(ji,jj,jk) 
446
447        tr(ji,jj,jk,jpnph,Krhs) = tr(ji,jj,jk,jpnph,Krhs) + zprontot * texcretn
448        tr(ji,jj,jk,jppph,Krhs) = tr(ji,jj,jk,jppph,Krhs) + ( zpropo4n(ji,jj,jk) + zprodopn(ji,jj,jk) ) * texcretn
449        tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
450
451        !
452        tr(ji,jj,jk,jppic,Krhs) = tr(ji,jj,jk,jppic,Krhs)         &
453           &                     + zprorcap(ji,jj,jk) * texcretp  &
454           &                     - xpsino3 * zpronewp(ji,jj,jk)   &
455           &                     - xpsinh4 * zproregp(ji,jj,jk)   &
456           &                     - zrespp(ji,jj,jk) 
457
458        tr(ji,jj,jk,jpnpi,Krhs) = tr(ji,jj,jk,jpnpi,Krhs) + zproptot * texcretp
459        tr(ji,jj,jk,jpppi,Krhs) = tr(ji,jj,jk,jpppi,Krhs) + ( zpropo4p(ji,jj,jk) + zprodopp(ji,jj,jk) ) * texcretp
460        tr(ji,jj,jk,jppfe,Krhs) = tr(ji,jj,jk,jppfe,Krhs) + zprofep(ji,jj,jk) * texcretp
461
462        !
463        tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs)         &
464           &                    + zprorcad(ji,jj,jk) * texcretd   &
465           &                    - xpsino3 * zpronewd(ji,jj,jk)    &
466           &                    - xpsinh4 * zproregd(ji,jj,jk)    &
467           &                    - zrespd(ji,jj,jk) 
468
469        tr(ji,jj,jk,jpndi,Krhs) = tr(ji,jj,jk,jpndi,Krhs) + zprodtot * texcretd
470        tr(ji,jj,jk,jppdi,Krhs) = tr(ji,jj,jk,jppdi,Krhs) + ( zpropo4d(ji,jj,jk) + zprodopd(ji,jj,jk) ) * texcretd
471        tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
472        tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
473
474        tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zproddoc
475        tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zproddon                                       
476        tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + zproddop
477 
478        tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) &
479           &                     + o2ut * zpregtot + ( o2ut + o2nit ) * zpnewtot - o2ut * zresptot 
480
481        tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zprodfer
482        consfe3(ji,jj,jk)       = zprodfer * 75.0 / ( rtrn + ( plig(ji,jj,jk) + 75.0 * (1.0 - plig(ji,jj,jk) ) )   &
483           &                   * tr(ji,jj,jk,jpfer,Kbb) ) / rfact2
484       
485        tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) 
486
487        tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zpptot  &
488           &                     + xpsino3 * zpronewn(ji,jj,jk) + xpsinh4 * zproregn(ji,jj,jk)   &
489           &                     + xpsino3 * zpronewp(ji,jj,jk) + xpsinh4 * zproregp(ji,jj,jk)   &
490           &                     + xpsino3 * zpronewd(ji,jj,jk) + xpsinh4 * zproregd(ji,jj,jk) 
491
492        tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpnewtot - zpregtot )
493        !
494      END_3D
495     
496     ! Production and uptake of ligands by phytoplankton. This part is activated
497     ! when ln_ligand is set to .true. in the namelist. Ligand uptake is small
498     ! and based on the FeL model by Morel et al. (2008) and on the study of
499     ! Shaked and Lis (2012)
500     ! -------------------------------------------------------------------------
501     IF( ln_ligand ) THEN
502         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
503           zproddoc = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
504           zprodfer = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
505           zprodlig = plig(ji,jj,jk) / ( rtrn + plig(ji,jj,jk) + 75.0 * (1.0 - plig(ji,jj,jk) ) ) * lthet 
506           !
507           tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zproddoc * ldocp - zprodfer * zprodlig
508        END_3D
509     ENDIF
510
511    ! Total primary production per year
512    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
513      & tpp = glob_sum( 'p5zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
514
515    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
516       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
517       !
518       CALL iom_put( "PPPHYP"  , zprorcap(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by picophyto
519       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
520       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
521       CALL iom_put( "PPNEWN"  , zpronewp(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by picophyto
522       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
523       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
524       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
525       CALL iom_put( "PFeP"    , zprofep(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by picophyto
526       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
527       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
528       IF( ln_ligand .AND. ( iom_use( "LPRODP" ) .OR. iom_use( "LDETP" ) ) ) THEN
529           ALLOCATE(  zpligprod(jpi,jpj,jpk) )
530           zpligprod(:,:,:) = excretd * zprorcad(:,:,:) + excretn * zprorcan(:,:,:) + excretp * zprorcap(:,:,:)
531           CALL iom_put( "LPRODP"  , zpligprod(:,:,:) * ldocp * 1e9 * zfact * tmask(:,:,:) )
532           !
533           zpligprod(:,:,:) = ( texcretn * zprofen(:,:,:) + texcretd * zprofed(:,:,:) + texcretp * zprofep(:,:,:) ) & 
534             &                  * plig(:,:,:) / ( rtrn + plig(:,:,:) + 75.0 * (1.0 - plig(:,:,:) ) )
535           CALL iom_put( "LDETP"   , zpligprod(:,:,:)  * lthet * 1e9 * zfact * tmask(:,:,:) )
536           DEALLOCATE(  zpligprod )
537       ENDIF
538       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
539       CALL iom_put( "MuP"     , zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for picophyto
540       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
541       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
542       CALL iom_put( "LPlight" , zprpic(:,:,:) / (zprmaxp(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
543       CALL iom_put( "LNlight" , zprbio(:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
544       CALL iom_put( "LDlight" , zprdia(:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
545       CALL iom_put( "MunetP"  , ( tr(:,:,:,jppic,Krhs)/rfact2/(tr(:,:,:,jppic,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
546       CALL iom_put( "MunetN"  , ( tr(:,:,:,jpphy,Krhs)/rfact2/(tr(:,:,:,jpphy,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
547       CALL iom_put( "MunetD"  , ( tr(:,:,:,jpdia,Krhs)/rfact2/(tr(:,:,:,jpdia,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
548       CALL iom_put( "TPP"     , ( zprorcap(:,:,:) + zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
549       CALL iom_put( "TPNEW"   , ( zpronewp(:,:,:) + zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
550       CALL iom_put( "TPBFE"   , ( zprofep (:,:,:) + zprofen (:,:,:) + zprofed (:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
551       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
552     ENDIF
553
554      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
555         WRITE(charout, FMT="('prod')")
556         CALL prt_ctl_info( charout, cdcomp = 'top' )
557         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
558      ENDIF
559      !
560      IF( ln_timing )   CALL timing_stop('p5z_prod')
561      !
562   END SUBROUTINE p5z_prod
563
564
565   SUBROUTINE p5z_prod_init
566      !!----------------------------------------------------------------------
567      !!                  ***  ROUTINE p5z_prod_init  ***
568      !!
569      !! ** Purpose :   Initialization of phytoplankton production parameters
570      !!
571      !! ** Method  :   Read the namp5zprod namelist and check the parameters
572      !!      called at the first timestep (nittrc000)
573      !!
574      !! ** input   :   Namelist namp5zprod
575      !!----------------------------------------------------------------------
576      INTEGER :: ios    ! Local integer output status for namelist read
577      !!
578      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
579         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
580      !!----------------------------------------------------------------------
581
582      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
583901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist' )
584
585      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
586902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist' )
587      IF(lwm) WRITE ( numonp, namp5zprod )
588
589      IF(lwp) THEN                         ! control print
590         WRITE(numout,*) ' '
591         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
592         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
593         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
594         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
595         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
596         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
597         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
598         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
599         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
600         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
601         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
602         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
603         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
604         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
605         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
606      ENDIF
607      !
608      r1_rday   = 1._wp / rday 
609      texcretn  = 1._wp - excretn
610      texcretp  = 1._wp - excretp
611      texcretd  = 1._wp - excretd
612      tpp       = 0._wp
613      !
614   END SUBROUTINE p5z_prod_init
615
616
617   INTEGER FUNCTION p5z_prod_alloc()
618      !!----------------------------------------------------------------------
619      !!                     ***  ROUTINE p5z_prod_alloc  ***
620      !!----------------------------------------------------------------------
621      ALLOCATE( zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
622      !
623      IF( p5z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p5z_prod_alloc : failed to allocate arrays.' )
624      !
625   END FUNCTION p5z_prod_alloc
626   !!======================================================================
627END MODULE p5zprod
Note: See TracBrowser for help on using the repository browser.