1 | MODULE dynadv_cen2 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynadv *** |
---|
4 | !! Ocean dynamics: Update the momentum trend with the flux form advection |
---|
5 | !! using a 2nd order centred scheme |
---|
6 | !!====================================================================== |
---|
7 | !! History : 2.0 ! 2006-08 (G. Madec, S. Theetten) Original code |
---|
8 | !! 3.2 ! 2009-07 (R. Benshila) Suppression of rigid-lid option |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! dyn_adv_cen2 : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | USE oce ! ocean dynamics and tracers |
---|
15 | USE dom_oce ! ocean space and time domain |
---|
16 | USE trd_oce ! trends: ocean variables |
---|
17 | USE trddyn ! trend manager: dynamics |
---|
18 | ! |
---|
19 | USE in_out_manager ! I/O manager |
---|
20 | USE lib_mpp ! MPP library |
---|
21 | USE prtctl ! Print control |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | PUBLIC dyn_adv_cen2 ! routine called by step.F90 |
---|
27 | |
---|
28 | !! * Substitutions |
---|
29 | # include "do_loop_substitute.h90" |
---|
30 | # include "domzgr_substitute.h90" |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
33 | !! $Id$ |
---|
34 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | CONTAINS |
---|
37 | |
---|
38 | SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs ) |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! *** ROUTINE dyn_adv_cen2 *** |
---|
41 | !! |
---|
42 | !! ** Purpose : Compute the now momentum advection trend in flux form |
---|
43 | !! and the general trend of the momentum equation. |
---|
44 | !! |
---|
45 | !! ** Method : Trend evaluated using now fields (centered in time) |
---|
46 | !! |
---|
47 | !! ** Action : (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) updated with the now vorticity term trend |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
---|
50 | INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices |
---|
51 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
---|
52 | ! |
---|
53 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
54 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfu_t, zfu_f, zfu_uw, zfu |
---|
55 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfv_t, zfv_f, zfv_vw, zfv, zfw |
---|
56 | !!---------------------------------------------------------------------- |
---|
57 | ! |
---|
58 | IF( kt == nit000 .AND. lwp ) THEN |
---|
59 | WRITE(numout,*) |
---|
60 | WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection' |
---|
61 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
62 | ENDIF |
---|
63 | ! |
---|
64 | IF( l_trddyn ) THEN ! trends: store the input trends |
---|
65 | zfu_uw(:,:,:) = puu(:,:,:,Krhs) |
---|
66 | zfv_vw(:,:,:) = pvv(:,:,:,Krhs) |
---|
67 | ENDIF |
---|
68 | ! |
---|
69 | ! !== Horizontal advection ==! |
---|
70 | ! |
---|
71 | DO jk = 1, jpkm1 ! horizontal transport |
---|
72 | zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) |
---|
73 | zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) |
---|
74 | DO_2D( 1, 0, 1, 0 ) ! horizontal momentum fluxes (at T- and F-point) |
---|
75 | zfu_t(ji+1,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj ,jk,Kmm) ) |
---|
76 | zfv_f(ji ,jj ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji ,jj+1,jk,Kmm) ) |
---|
77 | zfu_f(ji ,jj ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj ,jk,Kmm) ) |
---|
78 | zfv_t(ji ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji ,jj+1,jk,Kmm) ) |
---|
79 | END_2D |
---|
80 | DO_2D( 0, 0, 0, 0 ) ! divergence of horizontal momentum fluxes |
---|
81 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_t(ji+1,jj,jk) - zfu_t(ji,jj ,jk) & |
---|
82 | & + zfv_f(ji ,jj,jk) - zfv_f(ji,jj-1,jk) ) * r1_e1e2u(ji,jj) & |
---|
83 | & / e3u(ji,jj,jk,Kmm) |
---|
84 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfu_f(ji,jj ,jk) - zfu_f(ji-1,jj,jk) & |
---|
85 | & + zfv_t(ji,jj+1,jk) - zfv_t(ji ,jj,jk) ) * r1_e1e2v(ji,jj) & |
---|
86 | & / e3v(ji,jj,jk,Kmm) |
---|
87 | END_2D |
---|
88 | END DO |
---|
89 | ! |
---|
90 | IF( l_trddyn ) THEN ! trends: send trend to trddyn for diagnostic |
---|
91 | zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:) |
---|
92 | zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:) |
---|
93 | CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm ) |
---|
94 | zfu_t(:,:,:) = puu(:,:,:,Krhs) |
---|
95 | zfv_t(:,:,:) = pvv(:,:,:,Krhs) |
---|
96 | ENDIF |
---|
97 | ! |
---|
98 | ! !== Vertical advection ==! |
---|
99 | ! |
---|
100 | DO_2D( 0, 0, 0, 0 ) ! surface/bottom advective fluxes set to zero |
---|
101 | zfu_uw(ji,jj,jpk) = 0._wp ; zfv_vw(ji,jj,jpk) = 0._wp |
---|
102 | zfu_uw(ji,jj, 1 ) = 0._wp ; zfv_vw(ji,jj, 1 ) = 0._wp |
---|
103 | END_2D |
---|
104 | IF( ln_linssh ) THEN ! linear free surface: advection through the surface |
---|
105 | DO_2D( 0, 0, 0, 0 ) |
---|
106 | zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji+1,jj) * ww(ji+1,jj,1) ) * puu(ji,jj,1,Kmm) |
---|
107 | zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji,jj+1) * ww(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm) |
---|
108 | END_2D |
---|
109 | ENDIF |
---|
110 | DO jk = 2, jpkm1 ! interior advective fluxes |
---|
111 | DO_2D( 0, 1, 0, 1 ) ! 1/4 * Vertical transport |
---|
112 | zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk) |
---|
113 | END_2D |
---|
114 | DO_2D( 0, 0, 0, 0 ) |
---|
115 | zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) ) |
---|
116 | zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) ) |
---|
117 | END_2D |
---|
118 | END DO |
---|
119 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) ! divergence of vertical momentum flux divergence |
---|
120 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) & |
---|
121 | & / e3u(ji,jj,jk,Kmm) |
---|
122 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) & |
---|
123 | & / e3v(ji,jj,jk,Kmm) |
---|
124 | END_3D |
---|
125 | ! |
---|
126 | IF( l_trddyn ) THEN ! trends: send trend to trddyn for diagnostic |
---|
127 | zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:) |
---|
128 | zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:) |
---|
129 | CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm ) |
---|
130 | ENDIF |
---|
131 | ! ! Control print |
---|
132 | IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' cen2 adv - Ua: ', mask1=umask, & |
---|
133 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
---|
134 | ! |
---|
135 | END SUBROUTINE dyn_adv_cen2 |
---|
136 | |
---|
137 | !!============================================================================== |
---|
138 | END MODULE dynadv_cen2 |
---|