New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfmxl.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/ZDF – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/ZDF/zdfmxl.F90 @ 15641

Last change on this file since 15641 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 8.0 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!            3.7  ! 2012-03  (G. Madec)  make public the density criteria for trdmxl
9   !!             -   ! 2014-02  (F. Roquet)  mixed layer depth calculated using N2 instead of rhop
10   !!----------------------------------------------------------------------
11   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE isf_oce        ! ice shelf
15   USE dom_oce        ! ocean space and time domain variables
16   USE trc_oce  , ONLY: l_offline         ! ocean space and time domain variables
17   USE zdf_oce        ! ocean vertical physics
18   !
19   USE in_out_manager ! I/O manager
20   USE prtctl         ! Print control
21   USE phycst         ! physical constants
22   USE iom            ! I/O library
23   USE lib_mpp        ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_mxl, zdf_mxl_turb   ! called by zdfphy.F90
29
30   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by LDF, ZDF, TRD, TOP)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]   (used by TOP)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]   (used by LDF)
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: depth of the last T-point inside the mixed layer [m] (used by LDF)
34
35   REAL(dp), PUBLIC ::   rho_c = 0.01_wp    !: density criterion for mixed layer depth
36   REAL(dp), PUBLIC ::   avt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "single_precision_substitute.h90"
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   INTEGER FUNCTION zdf_mxl_alloc()
50      !!----------------------------------------------------------------------
51      !!               ***  FUNCTION zdf_mxl_alloc  ***
52      !!----------------------------------------------------------------------
53      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
54      IF( .NOT. ALLOCATED( nmln ) ) THEN
55         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
56         !
57         CALL mpp_sum ( 'zdfmxl', zdf_mxl_alloc )
58         IF( zdf_mxl_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl_alloc: failed to allocate arrays.' )
59         !
60      ENDIF
61   END FUNCTION zdf_mxl_alloc
62
63
64   SUBROUTINE zdf_mxl( kt, Kmm )
65      !!----------------------------------------------------------------------
66      !!                  ***  ROUTINE zdfmxl  ***
67      !!                   
68      !! ** Purpose :   Compute the mixed layer depth with density criteria.
69      !!
70      !! ** Method  :   The mixed layer depth is the shallowest W depth with
71      !!      the density of the corresponding T point (just bellow) bellow a
72      !!      given value defined locally as rho(10m) + rho_c
73      !!
74      !! ** Action  :   nmln, hmlp, hmlpt
75      !!----------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
77      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
78      !
79      INTEGER  ::   ji, jj, jk      ! dummy loop indices
80      INTEGER  ::   iik, ikt        ! local integer
81      REAL(wp) ::   zN2_c           ! local scalar
82      !!----------------------------------------------------------------------
83      !
84      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
85         IF( kt == nit000 ) THEN
86            IF(lwp) WRITE(numout,*)
87            IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
88            IF(lwp) WRITE(numout,*) '~~~~~~~ '
89            !                             ! allocate zdfmxl arrays
90            IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
91         ENDIF
92      ENDIF
93      !
94      ! w-level of the mixing and mixed layers
95      DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
96         nmln(ji,jj)  = nlb10                  ! Initialization to the number of w ocean point
97         hmlp(ji,jj)  = 0._wp                  ! here hmlp used as a dummy variable, integrating vertically N^2
98      END_2D
99      zN2_c = grav * rho_c * r1_rho0      ! convert density criteria into N^2 criteria
100      DO_3D_OVR( nn_hls, nn_hls, nn_hls, nn_hls, nlb10, jpkm1 )   ! Mixed layer level: w-level
101         ikt = mbkt(ji,jj)
102         hmlp(ji,jj) =   &
103            & hmlp(ji,jj) + MAX( rn2b(ji,jj,jk) , 0._wp ) * e3w(ji,jj,jk,Kmm)
104         IF( hmlp(ji,jj) < zN2_c )   nmln(ji,jj) = MIN( jk , ikt ) + 1   ! Mixed layer level
105      END_3D
106      ! depth of the mixed layer
107      DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
108         iik = nmln(ji,jj)
109         hmlp (ji,jj) = gdepw(ji,jj,iik  ,Kmm) * ssmask(ji,jj)    ! Mixed layer depth
110         hmlpt(ji,jj) = gdept(ji,jj,iik-1,Kmm) * ssmask(ji,jj)    ! depth of the last T-point inside the mixed layer
111      END_2D
112      !
113      IF( .NOT.l_offline .AND. iom_use("mldr10_1") ) THEN
114         IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldr10_1", hmlp - risfdep)   ! mixed layer thickness
115         ELSE                  ;  CALL iom_put( "mldr10_1", hmlp )            ! mixed layer depth
116         END IF
117      ENDIF
118      !
119      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=REAL(nmln, dp), clinfo1=' nmln : ', tab2d_2=CASTDP(hmlp), clinfo2=' hmlp : ' )
120      !
121   END SUBROUTINE zdf_mxl
122
123
124   SUBROUTINE zdf_mxl_turb( kt, Kmm )
125      !!----------------------------------------------------------------------
126      !!                  ***  ROUTINE zdf_mxl_turb  ***
127      !!
128      !! ** Purpose :   Compute the turbocline depth.
129      !!
130      !! ** Method  :   The turbocline depth is the depth at which the vertical
131      !!      eddy diffusivity coefficient (resulting from the vertical physics
132      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
133      !!      value defined locally (avt_c here taken equal to 5 cm/s2 by default)
134      !!
135      !! ** Action  :   hmld
136      !!----------------------------------------------------------------------
137      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
138      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
139      !
140      INTEGER  ::   ji, jj, jk      ! dummy loop indices
141      INTEGER  ::   iik             ! local integer
142      INTEGER, DIMENSION(A2D(nn_hls)) ::   imld   ! 2D workspace
143      !!----------------------------------------------------------------------
144      !
145      ! w-level of the turbocline and mixing layer (iom_use)
146      imld(:,:) = mbkt(A2D(nn_hls)) + 1                ! Initialization to the number of w ocean point
147      DO_3DS( 1, 1, 1, 1, jpkm1, nlb10, -1 )   ! from the bottom to nlb10
148         IF( avt (ji,jj,jk) < avt_c * wmask(ji,jj,jk) )   imld(ji,jj) = jk      ! Turbocline
149      END_3D
150      ! depth of the mixing layer
151      DO_2D_OVR( 1, 1, 1, 1 )
152         iik = imld(ji,jj)
153         hmld (ji,jj) = gdepw(ji,jj,iik  ,Kmm) * ssmask(ji,jj)    ! Turbocline depth
154      END_2D
155      !
156      IF( .NOT.l_offline .AND. iom_use("mldkz5") ) THEN
157         IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldkz5"  , hmld - risfdep )   ! turbocline thickness
158         ELSE                  ;  CALL iom_put( "mldkz5"  , hmld )             ! turbocline depth
159         END IF
160      ENDIF
161      !
162   END SUBROUTINE zdf_mxl_turb
163   !!======================================================================
164END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.