New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icbutl.F90 in NEMO/branches/2020/tickets_icb_1900/src/OCE/ICB – NEMO

source: NEMO/branches/2020/tickets_icb_1900/src/OCE/ICB/icbutl.F90 @ 13374

Last change on this file since 13374 was 13374, checked in by mathiot, 4 years ago

ticket #1900: fix issue about mask management in icb_utl_bilin_3d_h; add option to ground icb if icb bottom lvl hit oce bottom lvl
  • Property svn:keywords set to Id
File size: 42.2 KB
Line 
1MODULE icbutl
2   !!======================================================================
3   !!                       ***  MODULE  icbutl  ***
4   !! Icebergs:  various iceberg utility routines
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!           4.2   !  2020-07  (P. Mathiot)     simplification of interpolation routine
11   !!                 !                            and add Nacho Merino work
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   icb_utl_interp   :
16   !!   icb_utl_pos      : compute bottom left corner indice, weight and mask
17   !!   icb_utl_bilin_h  : interpolation field to icb position
18   !!   icb_utl_bilin_e  : interpolation of scale factor to icb position
19   !!----------------------------------------------------------------------
20   USE par_oce                             ! ocean parameters
21   USE oce,    ONLY: ts, uu, vv
22   USE dom_oce                             ! ocean domain
23   USE in_out_manager                      ! IO parameters
24   USE lbclnk                              ! lateral boundary condition
25   USE lib_mpp                             ! MPI code and lk_mpp in particular
26   USE icb_oce                             ! define iceberg arrays
27   USE sbc_oce                             ! ocean surface boundary conditions
28#if defined key_si3
29   USE ice,    ONLY: u_ice, v_ice, hm_i    ! SI3 variables
30   USE icevar                              ! ice_var_sshdyn
31   USE sbc_ice, ONLY: snwice_mass, snwice_mass_b
32#endif
33
34   IMPLICIT NONE
35   PRIVATE
36
37   INTERFACE icb_utl_bilin_h
38      MODULE PROCEDURE icb_utl_bilin_2d_h, icb_utl_bilin_3d_h
39   END INTERFACE
40
41   PUBLIC   icb_utl_copy          ! routine called in icbstp module
42   PUBLIC   icb_utl_getkb         ! routine called in icbdyn and icbthm modules
43   PUBLIC   test_icb_utl_getkb    ! routine called in icbdyn and icbthm modules
44   PUBLIC   icb_utl_zavg          ! routine called in icbdyn and icbthm modules
45   PUBLIC   icb_utl_interp        ! routine called in icbdyn, icbthm modules
46   PUBLIC   icb_utl_bilin_h       ! routine called in icbdyn module
47   PUBLIC   icb_utl_add           ! routine called in icbini.F90, icbclv, icblbc and icbrst modules
48   PUBLIC   icb_utl_delete        ! routine called in icblbc, icbthm modules
49   PUBLIC   icb_utl_destroy       ! routine called in icbstp module
50   PUBLIC   icb_utl_track         ! routine not currently used, retain just in case
51   PUBLIC   icb_utl_print_berg    ! routine called in icbthm module
52   PUBLIC   icb_utl_print         ! routine called in icbini, icbstp module
53   PUBLIC   icb_utl_count         ! routine called in icbdia, icbini, icblbc, icbrst modules
54   PUBLIC   icb_utl_incr          ! routine called in icbini, icbclv modules
55   PUBLIC   icb_utl_yearday       ! routine called in icbclv, icbstp module
56   PUBLIC   icb_utl_mass          ! routine called in icbdia module
57   PUBLIC   icb_utl_heat          ! routine called in icbdia module
58
59   !!----------------------------------------------------------------------
60   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
61   !! $Id$
62   !! Software governed by the CeCILL license (see ./LICENSE)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE icb_utl_copy( Kmm )
67      !!----------------------------------------------------------------------
68      !!                  ***  ROUTINE icb_utl_copy  ***
69      !!
70      !! ** Purpose :   iceberg initialization.
71      !!
72      !! ** Method  : - blah blah
73      !!----------------------------------------------------------------------
74      REAL(wp), DIMENSION(0:jpi+1,0:jpj+1) :: ztmp
75#if defined key_si3
76      REAL(wp), DIMENSION(jpi,jpj) :: zssh_lead_m    !    ocean surface (ssh_m) if ice is not embedded
77      !                                              !    ocean surface in leads if ice is embedded   
78#endif
79      INTEGER :: jk   ! vertical loop index
80      INTEGER :: Kmm  ! ocean time levelindex
81      !
82      ! copy nemo forcing arrays into iceberg versions with extra halo
83      ! only necessary for variables not on T points
84      ! and ssh which is used to calculate gradients
85      !
86      ! surface forcing
87      !
88      ssu_e(1:jpi,1:jpj) = ssu_m(:,:) * umask(:,:,1)
89      ssv_e(1:jpi,1:jpj) = ssv_m(:,:) * vmask(:,:,1)
90      sst_e(1:jpi,1:jpj) = sst_m(:,:)
91      fr_e (1:jpi,1:jpj) = fr_i (:,:)
92      ua_e (1:jpi,1:jpj) = utau (:,:) * umask(:,:,1) ! maybe mask useless because mask applied in sbcblk
93      va_e (1:jpi,1:jpj) = vtau (:,:) * vmask(:,:,1) ! maybe mask useless because mask applied in sbcblk
94      !
95      CALL lbc_lnk_icb( 'icbutl', ssu_e, 'U', -1._wp, 1, 1 )
96      CALL lbc_lnk_icb( 'icbutl', ssv_e, 'V', -1._wp, 1, 1 )
97      CALL lbc_lnk_icb( 'icbutl', ua_e, 'U', -1._wp, 1, 1 )
98      CALL lbc_lnk_icb( 'icbutl', va_e, 'V', -1._wp, 1, 1 )
99#if defined key_si3
100      hi_e(1:jpi, 1:jpj) = hm_i (:,:) 
101      ui_e(1:jpi, 1:jpj) = u_ice(:,:)
102      vi_e(1:jpi, 1:jpj) = v_ice(:,:)
103      !     
104      ! compute ssh slope using ssh_lead if embedded
105      zssh_lead_m(:,:) = ice_var_sshdyn(ssh_m, snwice_mass, snwice_mass_b)
106      ssh_e(1:jpi, 1:jpj) = zssh_lead_m(:,:) * tmask(:,:,1)
107      !
108      CALL lbc_lnk_icb( 'icbutl', ui_e , 'U', -1._wp, 1, 1 )
109      CALL lbc_lnk_icb( 'icbutl', vi_e , 'V', -1._wp, 1, 1 )
110#else
111      ssh_e(1:jpi, 1:jpj) = ssh_m(:,:) * tmask(:,:,1)         
112#endif
113      !
114      ! (PM) could be improve with a 3d lbclnk gathering both variables
115      ! should be done once extra haloe generalised
116      IF ( ln_M2016 ) THEN
117         DO jk = 1,jpk
118            ! uoce
119            ztmp(1:jpi,1:jpj) = uu(:,:,jk,Kmm)
120            CALL lbc_lnk_icb( 'icbutl', ztmp, 'U', -1._wp, 1, 1 )
121            uoce_e(:,:,jk) = ztmp(:,:)
122            !
123            ! voce
124            ztmp(1:jpi,1:jpj) = vv(:,:,jk,Kmm)
125            CALL lbc_lnk_icb( 'icbutl', ztmp, 'V', -1._wp, 1, 1 )
126            voce_e(:,:,jk) = ztmp(:,:)
127         END DO
128         toce_e(1:jpi,1:jpj,1:jpk) = ts(:,:,:,1,Kmm)
129         e3t_e (1:jpi,1:jpj,1:jpk) = e3t(:,:,:,Kmm)
130      END IF
131      !
132   END SUBROUTINE icb_utl_copy
133
134
135   SUBROUTINE icb_utl_interp( pi, pj, pe1, pssu, pui, pua, pssh_i,     &
136      &                               pe2, pssv, pvi, pva, pssh_j,     &
137      &                               psst, pcn, phi, pff, plon, plat, &
138      &                               ptoce, puoce, pvoce, pe3t       )
139      !!----------------------------------------------------------------------
140      !!                  ***  ROUTINE icb_utl_interp  ***
141      !!
142      !! ** Purpose :   interpolation
143      !!
144      !! ** Method  : - interpolate from various ocean arrays onto iceberg position
145      !!
146      !!       !!gm  CAUTION here I do not care of the slip/no-slip conditions
147      !!             this can be done later (not that easy to do...)
148      !!             right now, U is 0 in land so that the coastal value of velocity parallel to the coast
149      !!             is half the off shore value, wile the normal-to-the-coast value is zero.
150      !!             This is OK as a starting point.
151      !!       !!pm  HARD CODED: - rho_air now computed in sbcblk (what are the effect ?)
152      !!                         - drag coefficient (should it be namelist parameter ?)
153      !!
154      !!----------------------------------------------------------------------
155      REAL(wp), INTENT(in   ) ::   pi , pj                        ! position in (i,j) referential
156      REAL(wp), INTENT(  out), OPTIONAL ::   pe1, pe2                       ! i- and j scale factors
157      REAL(wp), INTENT(  out), OPTIONAL ::   pssu, pssv, pui, pvi, pua, pva   ! ocean, ice and wind speeds
158      REAL(wp), INTENT(  out), OPTIONAL ::   pssh_i, pssh_j                 ! ssh i- & j-gradients
159      REAL(wp), INTENT(  out), OPTIONAL ::   psst, pcn, phi, pff            ! SST, ice concentration, ice thickness, Coriolis
160      REAL(wp), INTENT(  out), OPTIONAL ::   plat, plon                     ! position
161      REAL(wp), DIMENSION(jpk), INTENT(  out), OPTIONAL ::   ptoce, puoce, pvoce, pe3t   ! 3D variables
162      !
163      REAL(wp), DIMENSION(4) :: zwT  , zwU  , zwV  , zwF   ! interpolation weight
164      REAL(wp), DIMENSION(4) :: zmskF, zmskU, zmskV, zmskT ! mask
165      REAL(wp), DIMENSION(4) :: zwTp, zmskTp, zwTm, zmskTm
166      REAL(wp), DIMENSION(4,jpk) :: zw1d
167      INTEGER                :: iiT, iiU, iiV, iiF, ijT, ijU, ijV, ijF ! bottom left corner
168      INTEGER                :: iiTp, iiTm, ijTp, ijTm
169      REAL(wp) ::   zcd, zmod       ! local scalars
170      !!----------------------------------------------------------------------
171      !
172      ! get position, weight and mask
173      CALL icb_utl_pos( pi, pj, 'T', iiT, ijT, zwT, zmskT )
174      CALL icb_utl_pos( pi, pj, 'U', iiU, ijU, zwU, zmskU )
175      CALL icb_utl_pos( pi, pj, 'V', iiV, ijV, zwV, zmskV )
176      CALL icb_utl_pos( pi, pj, 'F', iiF, ijF, zwF, zmskF )
177      !
178      ! metrics and coordinates
179      IF ( PRESENT(pe1 ) ) pe1 = icb_utl_bilin_e( e1t, e1u, e1v, e1f, pi, pj )      ! scale factors
180      IF ( PRESENT(pe2 ) ) pe2 = icb_utl_bilin_e( e2t, e2u, e2v, e2f, pi, pj )
181      IF ( PRESENT(plon) ) plon= icb_utl_bilin_h( rlon_e, iiT, ijT, zwT, .true.  )
182      IF ( PRESENT(plat) ) plat= icb_utl_bilin_h( rlat_e, iiT, ijT, zwT, .false. )
183      !
184      IF ( PRESENT(pssu) ) pssu = icb_utl_bilin_h( ssu_e, iiU, ijU, zwU        , .false. )         ! ocean velocities
185      IF ( PRESENT(pssv) ) pssv = icb_utl_bilin_h( ssv_e, iiV, ijV, zwV        , .false. )         !
186      IF ( PRESENT(psst) ) psst = icb_utl_bilin_h( sst_e, iiT, ijT, zwT * zmskT, .false. ) ! sst
187      IF ( PRESENT(pcn ) ) pcn  = icb_utl_bilin_h( fr_e , iiT, ijT, zwT * zmskT, .false. ) ! ice concentration
188      IF ( PRESENT(pff ) ) pff  = icb_utl_bilin_h( ff_e , iiF, ijF, zwF        , .false. )         ! Coriolis parameter
189      !
190      IF ( PRESENT(pua) .AND. PRESENT(pva) ) THEN
191         pua  = icb_utl_bilin_h( ua_e, iiU, ijU, zwU * zmskU, .false. ) ! 10m wind
192         pva  = icb_utl_bilin_h( va_e, iiV, ijV, zwV * zmskV, .false. ) ! here (ua,va) are stress => rough conversion from stress to speed
193         zcd  = 1.22_wp * 1.5e-3_wp                               ! air density * drag coefficient
194         zmod = 1._wp / MAX(  1.e-20, SQRT(  zcd * SQRT( pua*pua + pva*pva)  )  )
195         pua  = pua * zmod                                       ! note: stress module=0 necessarly implies ua=va=0
196         pva  = pva * zmod
197      END IF
198      !
199#if defined key_si3
200      IF ( PRESENT(pui) ) pui = icb_utl_bilin_h( ui_e , iiU, ijU, zwU        , .false. ) ! sea-ice velocities
201      IF ( PRESENT(pvi) ) pvi = icb_utl_bilin_h( vi_e , iiV, ijV, zwV        , .false. )
202      IF ( PRESENT(phi) ) phi = icb_utl_bilin_h( hi_e , iiT, ijT, zwT * zmskT, .false. ) ! ice thickness
203#else
204      IF ( PRESENT(pui) ) pui = 0._wp
205      IF ( PRESENT(pvi) ) pvi = 0._wp
206      IF ( PRESENT(phi) ) phi = 0._wp
207#endif
208      !
209      ! Estimate SSH gradient in i- and j-direction (centred evaluation)
210      IF ( PRESENT(pssh_i) .AND. PRESENT(pssh_j) ) THEN
211         CALL icb_utl_pos( pi+0.1, pj    , 'T', iiTp, ijTp, zwTp, zmskTp )
212         CALL icb_utl_pos( pi-0.1, pj    , 'T', iiTm, ijTm, zwTm, zmskTm )
213         !
214         IF ( .NOT. PRESENT(pe1) ) pe1 = icb_utl_bilin_e( e1t, e1u, e1v, e1f, pi, pj )
215         pssh_i = ( icb_utl_bilin_h( ssh_e, iiTp, ijTp, zwTp*zmskTp, .false. ) -   &
216            &       icb_utl_bilin_h( ssh_e, iiTm, ijTm, zwTm*zmskTm, .false. )  ) / ( 0.2_wp * pe1 )
217         !
218         CALL icb_utl_pos( pi    , pj+0.1, 'T', iiTp, ijTp, zwTp, zmskTp )
219         CALL icb_utl_pos( pi    , pj-0.1, 'T', iiTm, ijTm, zwTm, zmskTm )
220         !
221         IF ( .NOT. PRESENT(pe2) ) pe2 = icb_utl_bilin_e( e2t, e2u, e2v, e2f, pi, pj )
222         pssh_j = ( icb_utl_bilin_h( ssh_e, iiTp, ijTp, zwTp*zmskTp, .false. ) -   &
223            &       icb_utl_bilin_h( ssh_e, iiTm, ijTm, zwTm*zmskTm, .false. )  ) / ( 0.2_wp * pe2 )
224      END IF
225      !
226      ! 3d interpolation
227      IF ( PRESENT(puoce) .AND. PRESENT(pvoce) ) THEN
228         ! no need to mask as 0 is a valid data for land
229         zw1d(1,:) = zwU(1) ; zw1d(2,:) = zwU(2) ; zw1d(3,:) = zwU(3) ; zw1d(4,:) = zwU(4) ;
230         puoce(:) = icb_utl_bilin_h( uoce_e , iiU, ijU, zw1d )
231
232         zw1d(1,:) = zwV(1) ; zw1d(2,:) = zwV(2) ; zw1d(3,:) = zwV(3) ; zw1d(4,:) = zwV(4) ;
233         pvoce(:) = icb_utl_bilin_h( voce_e , iiV, ijV, zw1d )
234      END IF
235
236      IF ( PRESENT(ptoce) ) THEN
237         ! for temperature we need to mask the weight properly
238         ! no need of extra halo as it is a T point variable
239         zw1d(1,:) = tmask(iiT  ,ijT  ,:) * zwT(1) * zmskT(1)
240         zw1d(2,:) = tmask(iiT+1,ijT  ,:) * zwT(2) * zmskT(2)
241         zw1d(3,:) = tmask(iiT  ,ijT+1,:) * zwT(3) * zmskT(3)
242         zw1d(4,:) = tmask(iiT+1,ijT+1,:) * zwT(4) * zmskT(4)
243         ptoce(:) = icb_utl_bilin_h( toce_e , iiT, ijT, zw1d )
244      END IF
245      !
246      IF ( PRESENT(pe3t)  ) pe3t(:)  = e3t_e(iiT,ijT,:)    ! as in Nacho tarball need to be fix once we are able to reproduce Nacho results
247      !
248   END SUBROUTINE icb_utl_interp
249
250   SUBROUTINE icb_utl_pos( pi, pj, cd_type, kii, kij, pw, pmsk )
251      !!----------------------------------------------------------------------
252      !!                  ***  FUNCTION icb_utl_bilin  ***
253      !!
254      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
255      !!                this version deals with extra halo points
256      !!
257      !!       !!gm  CAUTION an optional argument should be added to handle
258      !!             the slip/no-slip conditions  ==>>> to be done later
259      !!
260      !!----------------------------------------------------------------------
261      REAL(wp)              , INTENT(IN)  ::   pi, pj    ! targeted coordinates in (i,j) referential
262      CHARACTER(len=1)      , INTENT(IN)  ::   cd_type   ! point type
263      REAL(wp), DIMENSION(4), INTENT(OUT) ::   pw, pmsk  ! weight and mask
264      INTEGER ,               INTENT(OUT) ::   kii, kij  ! bottom left corner position in local domain
265      !
266      REAL(wp) :: zwi, zwj ! distance to bottom left corner
267      INTEGER  :: ierr 
268      !
269      !!----------------------------------------------------------------------
270      !
271      SELECT CASE ( cd_type )
272      CASE ( 'T' )
273         ! note that here there is no +0.5 added
274         ! since we're looking for four T points containing quadrant we're in of
275         ! current T cell
276         kii = MAX(0, INT( pi     ))
277         kij = MAX(0, INT( pj     ))    ! T-point
278         zwi = pi - REAL(kii,wp)
279         zwj = pj - REAL(kij,wp)
280      CASE ( 'U' )
281         kii = MAX(0, INT( pi-0.5_wp ))
282         kij = MAX(0, INT( pj     ))    ! U-point
283         zwi = pi - 0.5_wp - REAL(kii,wp)
284         zwj = pj - REAL(kij,wp)
285      CASE ( 'V' )
286         kii = MAX(0, INT( pi     ))
287         kij = MAX(0, INT( pj-0.5_wp ))    ! V-point
288         zwi = pi - REAL(kii,wp)
289         zwj = pj - 0.5_wp - REAL(kij,wp)
290      CASE ( 'F' )
291         kii = MAX(0, INT( pi-0.5_wp ))
292         kij = MAX(0, INT( pj-0.5_wp ))    ! F-point
293         zwi = pi - 0.5_wp - REAL(kii,wp)
294         zwj = pj - 0.5_wp - REAL(kij,wp)
295      END SELECT
296      !
297      ! compute weight
298      pw(1) = (1._wp-zwi) * (1._wp-zwj)
299      pw(2) =        zwi  * (1._wp-zwj)
300      pw(3) = (1._wp-zwi) *        zwj
301      pw(4) =        zwi  *        zwj
302      !
303      ! find position in this processor. Prevent near edge problems (see #1389)
304      !
305      IF (TRIM(cd_type) == 'T' ) THEN
306         ierr = 0
307         IF    ( kii <  mig( 1 ) ) THEN   ;  ierr = ierr + 1
308         ELSEIF( kii >= mig(jpi) ) THEN   ;  ierr = ierr + 1
309         ENDIF
310         !
311         IF    ( kij <  mjg( 1 ) ) THEN   ;   ierr = ierr + 1
312         ELSEIF( kij >= mjg(jpj) ) THEN   ;   ierr = ierr + 1
313         ENDIF
314         !
315         IF ( ierr > 0 ) THEN
316            WRITE(numout,*) 'bottom left corner T point out of bound'
317            WRITE(numout,*) pi, kii, mig( 1 ), mig(jpi)
318            WRITE(numout,*) pj, kij, mjg( 1 ), mjg(jpj)
319            WRITE(numout,*) pmsk
320            CALL ctl_stop('STOP','icb_utl_bilin_h: an icebergs coordinates is out of valid range (out of bound error)')
321         END IF
322      END IF
323      !
324      ! find position in this processor. Prevent near edge problems (see #1389)
325      ! (PM) will be useless if extra halo is used in NEMO
326      !
327      IF    ( kii <= mig(1)-1 ) THEN   ;   kii = 0
328      ELSEIF( kii  > mig(jpi) ) THEN   ;   kii = jpi
329      ELSE                             ;   kii = mi1(kii)
330      ENDIF
331      IF    ( kij <= mjg(1)-1 ) THEN   ;   kij = 0
332      ELSEIF( kij  > mjg(jpj) ) THEN   ;   kij = jpj
333      ELSE                             ;   kij = mj1(kij)
334      ENDIF
335      !
336      ! define mask array
337      ! land value is not used in the interpolation
338      SELECT CASE ( cd_type )
339      CASE ( 'T' )
340         pmsk = (/tmask_e(kii,kij), tmask_e(kii+1,kij), tmask_e(kii,kij+1), tmask_e(kii+1,kij+1)/)
341      CASE ( 'U' )
342         pmsk = (/umask_e(kii,kij), umask_e(kii+1,kij), umask_e(kii,kij+1), umask_e(kii+1,kij+1)/)
343      CASE ( 'V' )
344         pmsk = (/vmask_e(kii,kij), vmask_e(kii+1,kij), vmask_e(kii,kij+1), vmask_e(kii+1,kij+1)/)
345      CASE ( 'F' )
346         ! F case only used for coriolis, ff_f is not mask so zmask = 1
347         pmsk = 1.
348      END SELECT
349   END SUBROUTINE icb_utl_pos
350
351   REAL(wp) FUNCTION icb_utl_bilin_2d_h( pfld, pii, pij, pw, pllon )
352      !!----------------------------------------------------------------------
353      !!                  ***  FUNCTION icb_utl_bilin  ***
354      !!
355      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
356      !!                this version deals with extra halo points
357      !!
358      !!       !!gm  CAUTION an optional argument should be added to handle
359      !!             the slip/no-slip conditions  ==>>> to be done later
360      !!
361      !!----------------------------------------------------------------------
362      REAL(wp), DIMENSION(0:jpi+1,0:jpj+1), INTENT(in) ::   pfld      ! field to be interpolated
363      REAL(wp), DIMENSION(4)              , INTENT(in) ::   pw        ! weight
364      LOGICAL                             , INTENT(in) ::   pllon     ! input data is a longitude
365      INTEGER ,                             INTENT(in) ::   pii, pij  ! bottom left corner
366      !
367      REAL(wp), DIMENSION(4) :: zdat ! input data
368      !!----------------------------------------------------------------------
369      !
370      ! data
371      zdat(1) = pfld(pii  ,pij  )
372      zdat(2) = pfld(pii+1,pij  )
373      zdat(3) = pfld(pii  ,pij+1)
374      zdat(4) = pfld(pii+1,pij+1)
375      !
376      IF( pllon .AND. MAXVAL(zdat) - MINVAL(zdat) > 90._wp ) THEN
377         WHERE( zdat < 0._wp ) zdat = zdat + 360._wp
378      ENDIF
379      !
380      ! compute interpolated value
381      icb_utl_bilin_2d_h = ( zdat(1)*pw(1) + zdat(2)*pw(2) + zdat(3)*pw(3) + zdat(4)*pw(4) ) / MAX(1.e-20, pw(1)+pw(2)+pw(3)+pw(4)) 
382      !
383      IF( pllon .AND. icb_utl_bilin_2d_h > 180._wp ) icb_utl_bilin_2d_h = icb_utl_bilin_2d_h - 360._wp
384      !
385   END FUNCTION icb_utl_bilin_2d_h
386
387   FUNCTION icb_utl_bilin_3d_h( pfld, pii, pij, pw )
388      !!----------------------------------------------------------------------
389      !!                  ***  FUNCTION icb_utl_bilin  ***
390      !!
391      !! ** Purpose :   bilinear interpolation at berg location depending on the grid-point type
392      !!                this version deals with extra halo points
393      !!
394      !!       !!gm  CAUTION an optional argument should be added to handle
395      !!             the slip/no-slip conditions  ==>>> to be done later
396      !!
397      !!----------------------------------------------------------------------
398      REAL(wp), DIMENSION(0:jpi+1,0:jpj+1, jpk), INTENT(in) ::   pfld      ! field to be interpolated
399      REAL(wp), DIMENSION(4,jpk)               , INTENT(in) ::   pw        ! weight
400      INTEGER ,                                  INTENT(in) ::   pii, pij  ! bottom left corner
401      REAL(wp), DIMENSION(jpk) :: icb_utl_bilin_3d_h
402      !
403      REAL(wp), DIMENSION(4,jpk) :: zdat ! input data
404      INTEGER :: jk
405      !!----------------------------------------------------------------------
406      !
407      ! data
408      zdat(1,:) = pfld(pii  ,pij  ,:)
409      zdat(2,:) = pfld(pii+1,pij  ,:)
410      zdat(3,:) = pfld(pii  ,pij+1,:)
411      zdat(4,:) = pfld(pii+1,pij+1,:)
412      !
413      ! compute interpolated value
414      DO jk=1,jpk
415         icb_utl_bilin_3d_h(jk) =   ( zdat(1,jk)*pw(1,jk) + zdat(2,jk)*pw(2,jk) + zdat(3,jk)*pw(3,jk) + zdat(4,jk)*pw(4,jk) ) &
416            &                     /   MAX(1.e-20, pw(1,jk)+pw(2,jk)+pw(3,jk)+pw(4,jk)) 
417      END DO
418      !
419   END FUNCTION icb_utl_bilin_3d_h
420
421   REAL(wp) FUNCTION icb_utl_bilin_e( pet, peu, pev, pef, pi, pj )
422      !!----------------------------------------------------------------------
423      !!                  ***  FUNCTION dom_init  ***
424      !!
425      !! ** Purpose :   bilinear interpolation at berg location of horizontal scale factor
426      !! ** Method  :   interpolation done using the 4 nearest grid points among
427      !!                t-, u-, v-, and f-points.
428      !!----------------------------------------------------------------------
429      REAL(wp), DIMENSION(:,:), INTENT(in) ::   pet, peu, pev, pef   ! horizontal scale factor to be interpolated at t-,u-,v- & f-pts
430      REAL(wp)                , INTENT(IN) ::   pi , pj              ! iceberg position
431      !
432      ! weights corresponding to corner points of a T cell quadrant
433      REAL(wp) ::   zi, zj          ! local real
434      INTEGER  ::   ii, ij          ! bottom left corner coordinate in local domain
435      !
436      ! values at corner points of a T cell quadrant
437      ! 00 = bottom left, 10 = bottom right, 01 = top left, 11 = top right
438      REAL(wp) ::   ze00, ze10, ze01, ze11
439      !!----------------------------------------------------------------------
440      !
441      ! cannot used iiT because need ii/ij reltaive to global indices not local one
442      ii = MAX(1, INT( pi ))   ;   ij = MAX(1, INT( pj ))            ! left bottom T-point (i,j) indices
443      !
444      ! fractional box spacing
445      ! 0   <= zi < 0.5, 0   <= zj < 0.5   -->  NW quadrant of current T cell
446      ! 0.5 <= zi < 1  , 0   <= zj < 0.5   -->  NE quadrant
447      ! 0   <= zi < 0.5, 0.5 <= zj < 1     -->  SE quadrant
448      ! 0.5 <= zi < 1  , 0.5 <= zj < 1     -->  SW quadrant
449
450      zi = pi - REAL(ii,wp)          !!gm use here mig, mjg arrays
451      zj = pj - REAL(ij,wp)
452
453      ! conversion to local domain (no need to do a sanity check already done in icbpos)
454      ii = mi1(ii)
455      ij = mj1(ij)
456      !
457      IF(    0.0_wp <= zi .AND. zi < 0.5_wp   ) THEN
458         IF( 0.0_wp <= zj .AND. zj < 0.5_wp        )   THEN        !  NE quadrant
459            !                                                      !             i=I       i=I+1/2
460            ze01 = pev(ii  ,ij  )   ;   ze11 = pef(ii  ,ij  )      !   j=J+1/2    V ------- F
461            ze00 = pet(ii  ,ij  )   ;   ze10 = peu(ii  ,ij  )      !   j=J        T ------- U
462            zi = 2._wp * zi
463            zj = 2._wp * zj
464         ELSE                                                      !  SE quadrant
465            !                                                                    !             i=I       i=I+1/2
466            ze01 = pet(ii  ,ij+1)   ;   ze11 = peu(ii  ,ij+1)      !   j=J+1      T ------- U
467            ze00 = pev(ii  ,ij  )   ;   ze10 = pef(ii  ,ij  )      !   j=J+1/2    V ------- F
468            zi = 2._wp *  zi
469            zj = 2._wp * (zj-0.5_wp)
470         ENDIF
471      ELSE
472         IF( 0.0_wp <= zj .AND. zj < 0.5_wp        )   THEN        !  NW quadrant
473            !                                                                    !             i=I       i=I+1/2
474            ze01 = pef(ii  ,ij  )   ;   ze11 = pev(ii+1,ij)        !   j=J+1/2    F ------- V
475            ze00 = peu(ii  ,ij  )   ;   ze10 = pet(ii+1,ij)        !   j=J        U ------- T
476            zi = 2._wp * (zi-0.5_wp)
477            zj = 2._wp *  zj
478         ELSE                                                      !  SW quadrant
479            !                                                                    !             i=I+1/2   i=I+1
480            ze01 = peu(ii  ,ij+1)   ;   ze11 = pet(ii+1,ij+1)      !   j=J+1      U ------- T
481            ze00 = pef(ii  ,ij  )   ;   ze10 = pev(ii+1,ij  )      !   j=J+1/2    F ------- V
482            zi = 2._wp * (zi-0.5_wp)
483            zj = 2._wp * (zj-0.5_wp)
484         ENDIF
485      ENDIF
486      !
487      icb_utl_bilin_e = ( ze01 * (1._wp-zi) + ze11 * zi ) *        zj    &
488         &            + ( ze00 * (1._wp-zi) + ze10 * zi ) * (1._wp-zj)
489      !
490   END FUNCTION icb_utl_bilin_e
491
492   SUBROUTINE icb_utl_getkb( kb, pe3, pD )
493      !!----------------------------------------------------------------------
494      !!                ***  ROUTINE icb_utl_getkb         ***
495      !!
496      !! ** Purpose :   compute the latest level affected by icb
497      !!
498      !!----------------------------------------------------------------------
499      INTEGER,                INTENT(out):: kb
500      REAL(wp), DIMENSION(:), INTENT(in) :: pe3
501      REAL(wp),               INTENT(in) :: pD
502      !!
503      INTEGER  :: jk
504      REAL(wp) :: zdepw
505      !!----------------------------------------------------------------------
506      !!
507      zdepw = pe3(1) ; kb = 2
508      DO WHILE ( zdepw <  pD)
509         zdepw = zdepw + pe3(kb)
510         kb = kb + 1
511      END DO
512      kb = MIN(kb - 1,jpk)
513   END SUBROUTINE
514
515   SUBROUTINE icb_utl_zavg(pzavg, pdat, pe3, pD, kb )
516      !!----------------------------------------------------------------------
517      !!                ***  ROUTINE icb_utl_getkb         ***
518      !!
519      !! ** Purpose :   compute the vertical average of ocean properties affected by icb
520      !!
521      !!----------------------------------------------------------------------
522      INTEGER,                INTENT(in ) :: kb        ! deepest level affected by icb
523      REAL(wp), DIMENSION(:), INTENT(in ) :: pe3, pdat ! vertical profile
524      REAL(wp),               INTENT(in ) :: pD        ! draft
525      REAL(wp),               INTENT(out) :: pzavg     ! z average
526      !!----------------------------------------------------------------------
527      INTEGER  :: jk
528      REAL(wp) :: zdep
529      !!----------------------------------------------------------------------
530      pzavg = 0.0 ; zdep = 0.0
531      DO jk = 1,kb-1
532         pzavg = pzavg + pe3(jk)*pdat(jk)
533         zdep  = zdep  + pe3(jk)
534      END DO
535      ! if kb is limited by mbkt  => bottom value is used between bathy and icb tail
536      ! if kb not limited by mbkt => ocean value over mask is used (ie 0.0 for u, v)
537      pzavg = ( pzavg + (pD - zdep)*pdat(kb)) / pD
538   END SUBROUTINE
539
540   SUBROUTINE icb_utl_add( bergvals, ptvals )
541      !!----------------------------------------------------------------------
542      !!                ***  ROUTINE icb_utl_add           ***
543      !!
544      !! ** Purpose :   add a new berg to the iceberg list
545      !!
546      !!----------------------------------------------------------------------
547      TYPE(iceberg), INTENT(in)           ::   bergvals
548      TYPE(point)  , INTENT(in)           ::   ptvals
549      !
550      TYPE(iceberg), POINTER ::   new => NULL()
551      !!----------------------------------------------------------------------
552      !
553      new => NULL()
554      CALL icb_utl_create( new, bergvals, ptvals )
555      CALL icb_utl_insert( new )
556      new => NULL()     ! Clear new
557      !
558   END SUBROUTINE icb_utl_add         
559
560
561   SUBROUTINE icb_utl_create( berg, bergvals, ptvals )
562      !!----------------------------------------------------------------------
563      !!                ***  ROUTINE icb_utl_create  ***
564      !!
565      !! ** Purpose :   add a new berg to the iceberg list
566      !!
567      !!----------------------------------------------------------------------
568      TYPE(iceberg), INTENT(in) ::   bergvals
569      TYPE(point)  , INTENT(in) ::   ptvals
570      TYPE(iceberg), POINTER    ::   berg
571      !
572      TYPE(point)  , POINTER    ::   pt
573      INTEGER                   ::   istat
574      !!----------------------------------------------------------------------
575      !
576      IF( ASSOCIATED(berg) )   CALL ctl_stop( 'icebergs, icb_utl_create: berg already associated' )
577      ALLOCATE(berg, STAT=istat)
578      IF( istat /= 0 ) CALL ctl_stop( 'failed to allocate iceberg' )
579      berg%number(:) = bergvals%number(:)
580      berg%mass_scaling = bergvals%mass_scaling
581      berg%prev => NULL()
582      berg%next => NULL()
583      !
584      ALLOCATE(pt, STAT=istat)
585      IF( istat /= 0 ) CALL ctl_stop( 'failed to allocate first iceberg point' )
586      pt = ptvals
587      berg%current_point => pt
588      !
589   END SUBROUTINE icb_utl_create
590
591
592   SUBROUTINE icb_utl_insert( newberg )
593      !!----------------------------------------------------------------------
594      !!                 ***  ROUTINE icb_utl_insert  ***
595      !!
596      !! ** Purpose :   add a new berg to the iceberg list
597      !!
598      !!----------------------------------------------------------------------
599      TYPE(iceberg), POINTER  ::   newberg
600      !
601      TYPE(iceberg), POINTER  ::   this, prev, last
602      !!----------------------------------------------------------------------
603      !
604      IF( ASSOCIATED( first_berg ) ) THEN
605         last => first_berg
606         DO WHILE (ASSOCIATED(last%next))
607            last => last%next
608         ENDDO
609         newberg%prev => last
610         last%next    => newberg
611         last         => newberg
612      ELSE                       ! list is empty so create it
613         first_berg => newberg
614      ENDIF
615      !
616   END SUBROUTINE icb_utl_insert
617
618
619   REAL(wp) FUNCTION icb_utl_yearday(kmon, kday, khr, kmin, ksec)
620      !!----------------------------------------------------------------------
621      !!                 ***  FUNCTION icb_utl_yearday  ***
622      !!
623      !! ** Purpose :   
624      !!
625      ! sga - improved but still only applies to 365 day year, need to do this properly
626      !
627      !!gm  all these info are already known in daymod, no???
628      !!
629      !!----------------------------------------------------------------------
630      INTEGER, INTENT(in)     :: kmon, kday, khr, kmin, ksec
631      !
632      INTEGER, DIMENSION(12)  :: imonths = (/ 0,31,28,31,30,31,30,31,31,30,31,30 /)
633      !!----------------------------------------------------------------------
634      !
635      icb_utl_yearday = REAL( SUM( imonths(1:kmon) ), wp )
636      icb_utl_yearday = icb_utl_yearday + REAL(kday-1,wp) + (REAL(khr,wp) + (REAL(kmin,wp) + REAL(ksec,wp)/60.)/60.)/24.
637      !
638   END FUNCTION icb_utl_yearday
639
640   !!-------------------------------------------------------------------------
641
642   SUBROUTINE icb_utl_delete( first, berg )
643      !!----------------------------------------------------------------------
644      !!                 ***  ROUTINE icb_utl_delete  ***
645      !!
646      !! ** Purpose :   
647      !!
648      !!----------------------------------------------------------------------
649      TYPE(iceberg), POINTER :: first, berg
650      !!----------------------------------------------------------------------
651      ! Connect neighbors to each other
652      IF ( ASSOCIATED(berg%prev) ) THEN
653        berg%prev%next => berg%next
654      ELSE
655        first => berg%next
656      ENDIF
657      IF (ASSOCIATED(berg%next)) berg%next%prev => berg%prev
658      !
659      CALL icb_utl_destroy(berg)
660      !
661   END SUBROUTINE icb_utl_delete
662
663
664   SUBROUTINE icb_utl_destroy( berg )
665      !!----------------------------------------------------------------------
666      !!                 ***  ROUTINE icb_utl_destroy  ***
667      !!
668      !! ** Purpose :   remove a single iceberg instance
669      !!
670      !!----------------------------------------------------------------------
671      TYPE(iceberg), POINTER :: berg
672      !!----------------------------------------------------------------------
673      !
674      ! Remove any points
675      IF( ASSOCIATED( berg%current_point ) )   DEALLOCATE( berg%current_point )
676      !
677      DEALLOCATE(berg)
678      !
679   END SUBROUTINE icb_utl_destroy
680
681
682   SUBROUTINE icb_utl_track( knum, cd_label, kt )
683      !!----------------------------------------------------------------------
684      !!                 ***  ROUTINE icb_utl_track  ***
685      !!
686      !! ** Purpose :   
687      !!
688      !!----------------------------------------------------------------------
689      INTEGER, DIMENSION(nkounts)    :: knum       ! iceberg number
690      CHARACTER(len=*)               :: cd_label   !
691      INTEGER                        :: kt         ! timestep number
692      !
693      TYPE(iceberg), POINTER         :: this
694      LOGICAL                        :: match
695      INTEGER                        :: k
696      !!----------------------------------------------------------------------
697      !
698      this => first_berg
699      DO WHILE( ASSOCIATED(this) )
700         match = .TRUE.
701         DO k = 1, nkounts
702            IF( this%number(k) /= knum(k) ) match = .FALSE.
703         END DO
704         IF( match )   CALL icb_utl_print_berg(this, kt)
705         this => this%next
706      END DO
707      !
708   END SUBROUTINE icb_utl_track
709
710
711   SUBROUTINE icb_utl_print_berg( berg, kt )
712      !!----------------------------------------------------------------------
713      !!                 ***  ROUTINE icb_utl_print_berg  ***
714      !!
715      !! ** Purpose :   print one
716      !!
717      !!----------------------------------------------------------------------
718      TYPE(iceberg), POINTER :: berg
719      TYPE(point)  , POINTER :: pt
720      INTEGER                :: kt      ! timestep number
721      !!----------------------------------------------------------------------
722      !
723      IF (nn_verbose_level == 0) RETURN
724      pt => berg%current_point
725      WRITE(numicb, 9200) kt, berg%number(1), &
726                   pt%xi, pt%yj, pt%lon, pt%lat, pt%uvel, pt%vvel,  &
727                   pt%ssu, pt%ssv, pt%ua, pt%va, pt%ui, pt%vi
728      CALL flush( numicb )
729 9200 FORMAT(5x,i5,2x,i10,6(2x,2f10.4))
730      !
731   END SUBROUTINE icb_utl_print_berg
732
733
734   SUBROUTINE icb_utl_print( cd_label, kt )
735      !!----------------------------------------------------------------------
736      !!                 ***  ROUTINE icb_utl_print  ***
737      !!
738      !! ** Purpose :   print many
739      !!
740      !!----------------------------------------------------------------------
741      CHARACTER(len=*)       :: cd_label
742      INTEGER                :: kt             ! timestep number
743      !
744      INTEGER                :: ibergs, inbergs
745      TYPE(iceberg), POINTER :: this
746      !!----------------------------------------------------------------------
747      !
748      IF (nn_verbose_level == 0) RETURN
749      this => first_berg
750      IF( ASSOCIATED(this) ) THEN
751         WRITE(numicb,'(a," pe=(",i3,")")' ) cd_label, narea
752         WRITE(numicb,'(a8,4x,a6,12x,a5,15x,a7,19x,a3,17x,a5,17x,a5,17x,a5)' )   &
753            &         'timestep', 'number', 'xi,yj','lon,lat','u,v','ssu,ssv','ua,va','ui,vi'
754      ENDIF
755      DO WHILE( ASSOCIATED(this) )
756        CALL icb_utl_print_berg(this, kt)
757        this => this%next
758      END DO
759      ibergs = icb_utl_count()
760      inbergs = ibergs
761      CALL mpp_sum('icbutl', inbergs)
762      IF( ibergs > 0 )   WRITE(numicb,'(a," there are",i5," bergs out of",i6," on PE ",i4)')   &
763         &                                  cd_label, ibergs, inbergs, narea
764      !
765   END SUBROUTINE icb_utl_print
766
767
768   SUBROUTINE icb_utl_incr()
769      !!----------------------------------------------------------------------
770      !!                 ***  ROUTINE icb_utl_incr  ***
771      !!
772      !! ** Purpose :   
773      !!
774      ! Small routine for coping with very large integer values labelling icebergs
775      ! num_bergs is a array of integers
776      ! the first member is incremented in steps of jpnij starting from narea
777      ! this means each iceberg is labelled with a unique number
778      ! when this gets to the maximum allowed integer the second and subsequent members are
779      ! used to count how many times the member before cycles
780      !!----------------------------------------------------------------------
781      INTEGER ::   ii, ibig
782      !!----------------------------------------------------------------------
783
784      ibig = HUGE(num_bergs(1))
785      IF( ibig-jpnij < num_bergs(1) ) THEN
786         num_bergs(1) = narea
787         DO ii = 2,nkounts
788            IF( num_bergs(ii) == ibig ) THEN
789               num_bergs(ii) = 0
790               IF( ii == nkounts ) CALL ctl_stop('Sorry, run out of iceberg number space')
791            ELSE
792               num_bergs(ii) = num_bergs(ii) + 1
793               EXIT
794            ENDIF
795         END DO
796      ELSE
797         num_bergs(1) = num_bergs(1) + jpnij
798      ENDIF
799      !
800   END SUBROUTINE icb_utl_incr
801
802
803   INTEGER FUNCTION icb_utl_count()
804      !!----------------------------------------------------------------------
805      !!                 ***  FUNCTION icb_utl_count  ***
806      !!
807      !! ** Purpose :   
808      !!----------------------------------------------------------------------
809      TYPE(iceberg), POINTER :: this
810      !!----------------------------------------------------------------------
811      !
812      icb_utl_count = 0
813      this => first_berg
814      DO WHILE( ASSOCIATED(this) )
815         icb_utl_count = icb_utl_count+1
816         this => this%next
817      END DO
818      !
819   END FUNCTION icb_utl_count
820
821
822   REAL(wp) FUNCTION icb_utl_mass( first, justbits, justbergs )
823      !!----------------------------------------------------------------------
824      !!                 ***  FUNCTION icb_utl_mass  ***
825      !!
826      !! ** Purpose :   compute the mass all iceberg, all berg bits or all bergs.
827      !!----------------------------------------------------------------------
828      TYPE(iceberg)      , POINTER  ::   first
829      TYPE(point)        , POINTER  ::   pt
830      LOGICAL, INTENT(in), OPTIONAL ::   justbits, justbergs
831      !
832      TYPE(iceberg), POINTER ::   this
833      !!----------------------------------------------------------------------
834      icb_utl_mass = 0._wp
835      this => first
836      !
837      IF( PRESENT( justbergs  ) ) THEN
838         DO WHILE( ASSOCIATED( this ) )
839            pt => this%current_point
840            icb_utl_mass = icb_utl_mass + pt%mass         * this%mass_scaling
841            this => this%next
842         END DO
843      ELSEIF( PRESENT(justbits) ) THEN
844         DO WHILE( ASSOCIATED( this ) )
845            pt => this%current_point
846            icb_utl_mass = icb_utl_mass + pt%mass_of_bits * this%mass_scaling
847            this => this%next
848         END DO
849      ELSE
850         DO WHILE( ASSOCIATED( this ) )
851            pt => this%current_point
852            icb_utl_mass = icb_utl_mass + ( pt%mass + pt%mass_of_bits ) * this%mass_scaling
853            this => this%next
854         END DO
855      ENDIF
856      !
857   END FUNCTION icb_utl_mass
858
859
860   REAL(wp) FUNCTION icb_utl_heat( first, justbits, justbergs )
861      !!----------------------------------------------------------------------
862      !!                 ***  FUNCTION icb_utl_heat  ***
863      !!
864      !! ** Purpose :   compute the heat in all iceberg, all bergies or all bergs.
865      !!----------------------------------------------------------------------
866      TYPE(iceberg)      , POINTER  ::   first
867      LOGICAL, INTENT(in), OPTIONAL ::   justbits, justbergs
868      !
869      TYPE(iceberg)      , POINTER  ::   this
870      TYPE(point)        , POINTER  ::   pt
871      !!----------------------------------------------------------------------
872      icb_utl_heat = 0._wp
873      this => first
874      !
875      IF( PRESENT( justbergs  ) ) THEN
876         DO WHILE( ASSOCIATED( this ) )
877            pt => this%current_point
878            icb_utl_heat = icb_utl_heat + pt%mass         * this%mass_scaling * pt%heat_density
879            this => this%next
880         END DO
881      ELSEIF( PRESENT(justbits) ) THEN
882         DO WHILE( ASSOCIATED( this ) )
883            pt => this%current_point
884            icb_utl_heat = icb_utl_heat + pt%mass_of_bits * this%mass_scaling * pt%heat_density
885            this => this%next
886         END DO
887      ELSE
888         DO WHILE( ASSOCIATED( this ) )
889            pt => this%current_point
890            icb_utl_heat = icb_utl_heat + ( pt%mass + pt%mass_of_bits ) * this%mass_scaling * pt%heat_density
891            this => this%next
892         END DO
893      ENDIF
894      !
895   END FUNCTION icb_utl_heat
896
897   SUBROUTINE test_icb_utl_getkb
898      INTEGER :: ikb
899      REAL(wp) :: zD, zout
900      REAL(wp), DIMENSION(jpk) :: ze3, zin
901      WRITE(numout,*) 'Test icb_utl_getkb : '
902      zD = 0.0 ; ze3= 20.0
903      WRITE(numout,*) 'INPUT : zD = ',zD,' ze3 = ',ze3(1)
904      CALL icb_utl_getkb(ikb, ze3, zD)
905      WRITE(numout,*) 'OUTPUT : kb = ',ikb
906
907      zD = 8000000.0 ; ze3= 20.0
908      WRITE(numout,*) 'INPUT : zD = ',zD,' ze3 = ',ze3(1)
909      CALL icb_utl_getkb(ikb, ze3, zD)
910      WRITE(numout,*) 'OUTPUT : kb = ',ikb
911
912      zD = 80.0 ; ze3= 20.0
913      WRITE(numout,*) 'INPUT : zD = ',zD,' ze3 = ',ze3(1)
914      CALL icb_utl_getkb(ikb, ze3, zD)
915      WRITE(numout,*) 'OUTPUT : kb = ',ikb
916
917      zD = 85.0 ; ze3= 20.0
918      WRITE(numout,*) 'INPUT : zD = ',zD,' ze3 = ',ze3(1)
919      CALL icb_utl_getkb(ikb, ze3, zD)
920      WRITE(numout,*) 'OUTPUT : kb = ',ikb
921
922      zD = 75.0 ; ze3= 20.0
923      WRITE(numout,*) 'INPUT : zD = ',zD,' ze3 = ',ze3(1)
924      CALL icb_utl_getkb(ikb, ze3, zD)
925      WRITE(numout,*) 'OUTPUT : kb = ',ikb
926
927      WRITE(numout,*) '=================================='
928      WRITE(numout,*) 'Test icb_utl_zavg'
929      zD = 0.0 ; ze3= 20.0 ; zin=1.0
930      CALL icb_utl_getkb(ikb, ze3, zD)
931      CALL icb_utl_zavg(zout, zin, ze3, zD, ikb)
932      WRITE(numout,*) 'INPUT  : zD = ',zD,' ze3 = ',ze3(1),' zin = ', zin, ' ikb = ',ikb
933      WRITE(numout,*) 'OUTPUT : zout = ',zout
934
935      zD = 50.0 ; ze3= 20.0 ; zin=1.0; zin(3:jpk) = 0.0
936      CALL icb_utl_getkb(ikb, ze3, zD)
937      CALL icb_utl_zavg(zout, zin, ze3, zD, ikb)
938      WRITE(numout,*) 'INPUT  : zD = ',zD,' ze3 = ',ze3(1),' zin = ', zin, ' ikb = ',ikb
939      WRITE(numout,*) 'OUTPUT : zout = ',zout
940      CALL FLUSH(numout)
941
942      zD = 80.0 ; ze3= 20.0 ; zin=1.0; zin(3:jpk) = 0.0
943      CALL icb_utl_getkb(ikb, ze3, zD)
944      CALL icb_utl_zavg(zout, zin, ze3, zD, ikb)
945      WRITE(numout,*) 'INPUT  : zD = ',zD,' ze3 = ',ze3(1),' zin = ', zin, ' ikb = ',ikb
946      WRITE(numout,*) 'OUTPUT : zout = ',zout
947
948      zD = 80 ; ze3= 20.0 ; zin=1.0 ; zin(3:jpk) = 0.0
949      CALL icb_utl_getkb(ikb, ze3, zD)
950      ikb = 2
951      CALL icb_utl_zavg(zout, zin, ze3, zD, ikb)
952      WRITE(numout,*) 'INPUT  : zD = ',zD,' ze3 = ',ze3(1),' zin = ', zin, ' ikb = ',ikb
953      WRITE(numout,*) 'OUTPUT : zout = ',zout
954
955      CALL FLUSH(numout)
956
957   END SUBROUTINE test_icb_utl_getkb
958
959   !!======================================================================
960END MODULE icbutl
Note: See TracBrowser for help on using the repository browser.