New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z/p4zsed.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zint          !  interpolation and computation of various fields
18   USE sed             !  Sediment module
19   USE iom             !  I/O manager
20   USE prtctl          !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sed 
26   PUBLIC   p4z_sed_init
27   PUBLIC   p4z_sed_alloc
28 
29   REAL(wp), PUBLIC ::   nitrfix      !: Nitrogen fixation rate
30   REAL(wp), PUBLIC ::   diazolight   !: Nitrogen fixation sensitivty to light
31   REAL(wp), PUBLIC ::   concfediaz   !: Fe half-saturation Cste for diazotrophs
32
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
35   !
36   REAL(wp), SAVE :: r1_rday         
37   REAL(wp), SAVE :: sedsilfrac, sedcalfrac
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42#  include "single_precision_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE p4z_sed( kt, knt, Kbb, Kmm, Krhs )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_sed  ***
53      !!
54      !! ** Purpose :   Compute loss of organic matter in the sediments. This
55      !!              is by no way a sediment model. The loss is simply
56      !!              computed to balance the inout from rivers and dust
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
63      INTEGER  ::  ji, jj, jk, ikt
64      REAL(wp) ::  zrivalk, zrivsil, zrivno3
65      REAL(wp) ::  zlim, zfact, zfactcal
66      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
67      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
68      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
69      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
70      REAL(wp) ::  xdiano3, xdianh4
71      !
72      CHARACTER (len=25) :: charout
73      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff, zwork
74      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4
75      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
76      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
78      !!---------------------------------------------------------------------
79      !
80      IF( ln_timing )  CALL timing_start('p4z_sed')
81      !
82
83      ! Allocate temporary workspace
84      ALLOCATE( ztrpo4(jpi,jpj,jpk) )
85      IF( ln_p5z )    ALLOCATE( ztrdop(jpi,jpj,jpk) )
86
87      zdenit2d(:,:) = 0.e0
88      zbureff (:,:) = 0.e0
89      zwork   (:,:) = 0.e0
90      zsedsi  (:,:) = 0.e0
91      zsedcal (:,:) = 0.e0
92      zsedc   (:,:) = 0.e0
93
94      IF( .NOT.lk_sed ) THEN
95         ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
96         ! --------------------------------------------------------------------
97         DO_2D( 1, 1, 1, 1 )
98            ikt  = mbkt(ji,jj)
99            zdep = e3t(ji,jj,ikt,Kmm) / xstep
100            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
101            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
102         END_2D
103
104         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
105         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
106         ! -------------------------------------------------------
107         DO_2D( 1, 1, 1, 1 )
108           IF( tmask(ji,jj,1) == 1 ) THEN
109              ikt = mbkt(ji,jj)
110              zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
111                &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
112              zflx  = LOG10( MAX( 1E-3, zflx ) )
113              zo2   = LOG10( MAX( 10. , tr(ji,jj,ikt,jpoxy,Kbb) * 1E6 ) )
114              zno3  = LOG10( MAX( 1.  , tr(ji,jj,ikt,jpno3,Kbb) * 1E6 * rno3 ) )
115              zdep  = LOG10( gdepw(ji,jj,ikt+1,Kmm) )
116              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
117                &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
118              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
119                !
120              zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
121                &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) ) * 1E6
122              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
123           ENDIF
124         END_2D
125         !
126      ENDIF
127
128      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
129      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
130      ! ------------------------------------------------------
131      IF( .NOT.lk_sed )  zrivsil = 1._wp - sedsilfrac
132
133      DO_2D( 1, 1, 1, 1 )
134         ikt  = mbkt(ji,jj)
135         zdep = xstep / e3t(ji,jj,ikt,Kmm) 
136         zwsc = zwsbio4(ji,jj) * zdep
137         zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
138         zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
139         !
140         tr(ji,jj,ikt,jpgsi,Krhs) = tr(ji,jj,ikt,jpgsi,Krhs) - zsiloss
141         tr(ji,jj,ikt,jpcal,Krhs) = tr(ji,jj,ikt,jpcal,Krhs) - zcaloss
142      END_2D
143      !
144      IF( .NOT.lk_sed ) THEN
145         DO_2D( 1, 1, 1, 1 )
146            ikt  = mbkt(ji,jj)
147            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
148            zwsc = zwsbio4(ji,jj) * zdep
149            zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
150            zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
151            tr(ji,jj,ikt,jpsil,Krhs) = tr(ji,jj,ikt,jpsil,Krhs) + zsiloss * zrivsil 
152            !
153            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
154            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
155            zrivalk  = sedcalfrac * zfactcal
156            tr(ji,jj,ikt,jptal,Krhs) =  tr(ji,jj,ikt,jptal,Krhs) + zcaloss * zrivalk * 2.0
157            tr(ji,jj,ikt,jpdic,Krhs) =  tr(ji,jj,ikt,jpdic,Krhs) + zcaloss * zrivalk
158            zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t(ji,jj,ikt,Kmm) 
159            zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t(ji,jj,ikt,Kmm) 
160         END_2D
161      ENDIF
162      !
163      DO_2D( 1, 1, 1, 1 )
164         ikt  = mbkt(ji,jj)
165         zdep = xstep / e3t(ji,jj,ikt,Kmm) 
166         zws4 = zwsbio4(ji,jj) * zdep
167         zws3 = zwsbio3(ji,jj) * zdep
168         tr(ji,jj,ikt,jpgoc,Krhs) = tr(ji,jj,ikt,jpgoc,Krhs) - tr(ji,jj,ikt,jpgoc,Kbb) * zws4 
169         tr(ji,jj,ikt,jppoc,Krhs) = tr(ji,jj,ikt,jppoc,Krhs) - tr(ji,jj,ikt,jppoc,Kbb) * zws3
170         tr(ji,jj,ikt,jpbfe,Krhs) = tr(ji,jj,ikt,jpbfe,Krhs) - tr(ji,jj,ikt,jpbfe,Kbb) * zws4
171         tr(ji,jj,ikt,jpsfe,Krhs) = tr(ji,jj,ikt,jpsfe,Krhs) - tr(ji,jj,ikt,jpsfe,Kbb) * zws3
172      END_2D
173      !
174      IF( ln_p5z ) THEN
175         DO_2D( 1, 1, 1, 1 )
176            ikt  = mbkt(ji,jj)
177            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
178            zws4 = zwsbio4(ji,jj) * zdep
179            zws3 = zwsbio3(ji,jj) * zdep
180            tr(ji,jj,ikt,jpgon,Krhs) = tr(ji,jj,ikt,jpgon,Krhs) - tr(ji,jj,ikt,jpgon,Kbb) * zws4
181            tr(ji,jj,ikt,jppon,Krhs) = tr(ji,jj,ikt,jppon,Krhs) - tr(ji,jj,ikt,jppon,Kbb) * zws3
182            tr(ji,jj,ikt,jpgop,Krhs) = tr(ji,jj,ikt,jpgop,Krhs) - tr(ji,jj,ikt,jpgop,Kbb) * zws4
183            tr(ji,jj,ikt,jppop,Krhs) = tr(ji,jj,ikt,jppop,Krhs) - tr(ji,jj,ikt,jppop,Kbb) * zws3
184         END_2D
185      ENDIF
186
187      IF( .NOT.lk_sed ) THEN
188         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
189         ! denitrification in the sediments. Not very clever, but simpliest option.
190         DO_2D( 1, 1, 1, 1 )
191            ikt  = mbkt(ji,jj)
192            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
193            zws4 = zwsbio4(ji,jj) * zdep
194            zws3 = zwsbio3(ji,jj) * zdep
195            zrivno3 = 1. - zbureff(ji,jj)
196            zwstpoc = tr(ji,jj,ikt,jpgoc,Kbb) * zws4 + tr(ji,jj,ikt,jppoc,Kbb) * zws3
197            zpdenit  = MIN( 0.5 * ( tr(ji,jj,ikt,jpno3,Kbb) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
198            z1pdenit = zwstpoc * zrivno3 - zpdenit
199            zolimit = MIN( ( tr(ji,jj,ikt,jpoxy,Kbb) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
200            tr(ji,jj,ikt,jpdoc,Krhs) = tr(ji,jj,ikt,jpdoc,Krhs) + z1pdenit - zolimit
201            tr(ji,jj,ikt,jppo4,Krhs) = tr(ji,jj,ikt,jppo4,Krhs) + zpdenit + zolimit
202            tr(ji,jj,ikt,jpnh4,Krhs) = tr(ji,jj,ikt,jpnh4,Krhs) + zpdenit + zolimit
203            tr(ji,jj,ikt,jpno3,Krhs) = tr(ji,jj,ikt,jpno3,Krhs) - rdenit * zpdenit
204            tr(ji,jj,ikt,jpoxy,Krhs) = tr(ji,jj,ikt,jpoxy,Krhs) - zolimit * o2ut
205            tr(ji,jj,ikt,jptal,Krhs) = tr(ji,jj,ikt,jptal,Krhs) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
206            tr(ji,jj,ikt,jpdic,Krhs) = tr(ji,jj,ikt,jpdic,Krhs) + zpdenit + zolimit 
207            sdenit(ji,jj) = rdenit * zpdenit * e3t(ji,jj,ikt,Kmm)
208            zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t(ji,jj,ikt,Kmm)
209            IF( ln_p5z ) THEN
210               zwstpop              = tr(ji,jj,ikt,jpgop,Kbb) * zws4 + tr(ji,jj,ikt,jppop,Kbb) * zws3
211               zwstpon              = tr(ji,jj,ikt,jpgon,Kbb) * zws4 + tr(ji,jj,ikt,jppon,Kbb) * zws3
212               tr(ji,jj,ikt,jpdon,Krhs) = tr(ji,jj,ikt,jpdon,Krhs) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
213               tr(ji,jj,ikt,jpdop,Krhs) = tr(ji,jj,ikt,jpdop,Krhs) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
214            ENDIF
215         END_2D
216       ENDIF
217
218
219      ! Nitrogen fixation process
220      ! Small source iron from particulate inorganic iron
221      !-----------------------------------
222      DO jk = 1, jpkm1
223         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
224         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
225      ENDDO
226      IF( ln_p4z ) THEN
227         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
228            !                      ! Potential nitrogen fixation dependant on temperature and iron
229            ztemp = ts(ji,jj,jk,jp_tem,Kmm)
230            zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
231            !       Potential nitrogen fixation dependant on temperature and iron
232            xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
233            xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
234            zlim = ( 1.- xdiano3 - xdianh4 )
235            IF( zlim <= 0.1 )   zlim = 0.01
236            zfact = zlim * rfact2
237            ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
238            ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
239            ztrdp = ztrpo4(ji,jj,jk)
240            nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
241         END_3D
242      ELSE       ! p5z
243         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
244            !                      ! Potential nitrogen fixation dependant on temperature and iron
245            ztemp = ts(ji,jj,jk,jp_tem,Kmm)
246            zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
247            !       Potential nitrogen fixation dependant on temperature and iron
248            xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
249            xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
250            zlim = ( 1.- xdiano3 - xdianh4 )
251            IF( zlim <= 0.1 )   zlim = 0.01
252            zfact = zlim * rfact2
253            ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
254            ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
255            ztrdop(ji,jj,jk) = tr(ji,jj,jk,jpdop,Kbb) / ( 1E-6 + tr(ji,jj,jk,jpdop,Kbb) ) * (1. - ztrpo4(ji,jj,jk))
256            ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
257            nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
258         END_3D
259      ENDIF
260
261      ! Nitrogen change due to nitrogen fixation
262      ! ----------------------------------------
263      IF( ln_p4z ) THEN
264         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
265            zfact = nitrpot(ji,jj,jk) * nitrfix
266            tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
267            tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
268            tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zfact * 2.0 / 3.0
269            tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
270            tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
271            tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
272            tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
273            tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0
274            tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
275            tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
276            tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
277            tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + concdnh4 / ( concdnh4 + tr(ji,jj,jk,jppo4,Kbb) ) &
278            &                     * 0.001 * tr(ji,jj,jk,jpdoc,Kbb) * xstep
279         END_3D
280      ELSE    ! p5z
281         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
282            zfact = nitrpot(ji,jj,jk) * nitrfix
283            tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
284            tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
285            tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
286            &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
287            tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zfact * 1.0 / 3.0
288            tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
289            tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + 16.0 / 46.0 * zfact / 3.0  &
290            &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
291            &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
292            tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
293            tr(ji,jj,jk,jppon,Krhs) = tr(ji,jj,jk,jppon,Krhs) + zfact * 1.0 / 3.0 * 2.0 /3.0
294            tr(ji,jj,jk,jppop,Krhs) = tr(ji,jj,jk,jppop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
295            tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
296            tr(ji,jj,jk,jpgon,Krhs) = tr(ji,jj,jk,jpgon,Krhs) + zfact * 1.0 / 3.0 * 1.0 /3.0
297            tr(ji,jj,jk,jpgop,Krhs) = tr(ji,jj,jk,jpgop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
298            tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
299            tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0 
300            tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
301            tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
302            tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
303         END_3D
304         !
305      ENDIF
306
307      IF( lk_iomput .AND. knt == nrdttrc ) THEN
308         zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
309         CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
310         CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
311         CALL iom_put( "SedSi" , zsedsi (:,:) * zfact )
312         CALL iom_put( "SedC"  , zsedc  (:,:) * zfact )
313         CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
314      ENDIF
315      !
316      IF(sn_cfctl%l_prttrc) THEN  ! print mean trneds (USEd for debugging)
317         WRITE(charout, fmt="('sed ')")
318         CALL prt_ctl_info( charout, cdcomp = 'top' )
319         CALL prt_ctl(tab4d_1=CASTWP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm)
320      ENDIF
321      !
322      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
323      !
324      IF( ln_timing )  CALL timing_stop('p4z_sed')
325      !
326   END SUBROUTINE p4z_sed
327
328   SUBROUTINE p4z_sed_init
329      !!----------------------------------------------------------------------
330      !!                  ***  routine p4z_sed_init  ***
331      !!
332      !! ** purpose :   initialization of some parameters
333      !!
334      !!----------------------------------------------------------------------
335      !!----------------------------------------------------------------------
336      INTEGER  :: ji, jj, jk, jm
337      INTEGER  :: ios                 ! Local integer output status for namelist read
338      !
339      !!
340      NAMELIST/nampissed/ nitrfix, diazolight, concfediaz
341      !!----------------------------------------------------------------------
342      !
343      IF(lwp) THEN
344         WRITE(numout,*)
345         WRITE(numout,*) 'p4z_sed_init : initialization of sediment mobilisation '
346         WRITE(numout,*) '~~~~~~~~~~~~ '
347      ENDIF
348      !                            !* set file information
349      READ  ( numnatp_ref, nampissed, IOSTAT = ios, ERR = 901)
350901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampissed in reference namelist' )
351      READ  ( numnatp_cfg, nampissed, IOSTAT = ios, ERR = 902 )
352902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampissed in configuration namelist' )
353      IF(lwm) WRITE ( numonp, nampissed )
354
355      IF(lwp) THEN
356         WRITE(numout,*) '   Namelist : nampissed '
357         WRITE(numout,*) '      nitrogen fixation rate                       nitrfix = ', nitrfix
358         WRITE(numout,*) '      nitrogen fixation sensitivty to light    diazolight  = ', diazolight
359         WRITE(numout,*) '      Fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
360      ENDIF
361      !
362      r1_rday  = 1. / rday
363      !
364      sedsilfrac = 0.03     ! percentage of silica loss in the sediments
365      sedcalfrac = 0.6      ! percentage of calcite loss in the sediments
366      !
367      lk_sed = ln_sediment .AND. ln_sed_2way 
368      !
369      nitrpot(:,:,jpk) = 0._wp   ! define last level for iom_put
370      !
371   END SUBROUTINE p4z_sed_init
372
373   INTEGER FUNCTION p4z_sed_alloc()
374      !!----------------------------------------------------------------------
375      !!                     ***  ROUTINE p4z_sed_alloc  ***
376      !!----------------------------------------------------------------------
377      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
378      !
379      IF( p4z_sed_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_alloc: failed to allocate arrays' )
380      !
381   END FUNCTION p4z_sed_alloc
382
383   !!======================================================================
384END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.