New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z/p4zprod.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 21.9 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       : Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  : Initialization of the parameters for growth
12   !!   p4z_prod_alloc : Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! shared variables between ocean and passive tracers
15   USE trc             ! passive tracers common variables
16   USE sms_pisces      ! PISCES Source Minus Sink variables
17   USE p4zlim          ! Co-limitations of differents nutrients
18   USE prtctl          ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   REAL(wp), PUBLIC ::   pislopen     !:
29   REAL(wp), PUBLIC ::   pisloped     !:
30   REAL(wp), PUBLIC ::   xadap        !:
31   REAL(wp), PUBLIC ::   excretn      !:
32   REAL(wp), PUBLIC ::   excretd      !:
33   REAL(wp), PUBLIC ::   bresp        !:
34   REAL(wp), PUBLIC ::   chlcnm       !:
35   REAL(wp), PUBLIC ::   chlcdm       !:
36   REAL(wp), PUBLIC ::   chlcmin      !:
37   REAL(wp), PUBLIC ::   fecnm        !:
38   REAL(wp), PUBLIC ::   fecdm        !:
39   REAL(wp), PUBLIC ::   grosip       !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
43   
44   REAL(wp) ::   r1_rday    ! 1 / rday
45   REAL(wp) ::   texcretn   ! 1 - excretn
46   REAL(wp) ::   texcretd   ! 1 - excretd       
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51#  include "single_precision_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE p4z_prod( kt , knt, Kbb, Kmm, Krhs )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_prod  ***
62      !!
63      !! ** Purpose :   Compute the phytoplankton production depending on
64      !!              light, temperature and nutrient availability
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt, knt   !
69      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
70      !
71      INTEGER  ::   ji, jj, jk
72      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
73      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
74      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
75      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
76      REAL(wp) ::   zmxltst, zmxlday
77      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
78      REAL(wp) ::   zfact
79      CHARACTER (len=25) :: charout
80      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
81      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
82      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
88      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
89      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
90      !!---------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('p4z_prod')
93      !
94      !  Allocate temporary workspace
95      !
96      zprorcan  (:,:,:) = 0._wp ; zprorcad  (:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
97      zprofen   (:,:,:) = 0._wp ; zysopt    (:,:,:) = 0._wp
98      zpronewn  (:,:,:) = 0._wp ; zpronewd  (:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
99      zprbio    (:,:,:) = 0._wp ; zprdch    (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
100      zmxl_fac  (:,:,:) = 0._wp ; zmxl_chl  (:,:,:) = 0._wp 
101      zpligprod1(:,:,:) = 0._wp ; zpligprod2(:,:,:) = 0._wp 
102
103      ! Computation of the optimal production
104      zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
105      zprmaxd(:,:,:) = zprmaxn(:,:,:)
106
107      ! compute the day length depending on latitude and the day
108      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
109      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
110
111      ! day length in hours
112      zstrn(:,:) = 0.
113      DO_2D( 1, 1, 1, 1 )
114         zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
115         zargu = MAX( -1., MIN(  1., zargu ) )
116         zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
117      END_2D
118
119      ! Impact of the day duration and light intermittency on phytoplankton growth
120      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
121         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
122            zval = MAX( 1., zstrn(ji,jj) )
123            IF( gdept(ji,jj,jk,Kmm) <= hmld(ji,jj) ) THEN
124               zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
125            ENDIF
126            zmxl_chl(ji,jj,jk) = zval / 24.
127            zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
128         ENDIF
129      END_3D
130
131      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
132      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
133
134      ! Maximum light intensity
135      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
136
137      ! Computation of the P-I slope for nanos and diatoms
138      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
139         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
140            ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
141            zadap       = xadap * ztn / ( 2.+ ztn )
142            zconctemp   = MAX( 0.e0 , tr(ji,jj,jk,jpdia,Kbb) - xsizedia )
143            zconctemp2  = tr(ji,jj,jk,jpdia,Kbb) - zconctemp
144            !
145            zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
146            &                   * tr(ji,jj,jk,jpnch,Kbb) /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
147            !
148            zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )   &
149            &                   * tr(ji,jj,jk,jpdch,Kbb) /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
150         ENDIF
151      END_3D
152
153      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
154         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
155             ! Computation of production function for Carbon
156             !  ---------------------------------------------
157             zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
158             &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
159             zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
160             &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
161             zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
162             zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
163             !  Computation of production function for Chlorophyll
164             !--------------------------------------------------
165             zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
166             zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
167             zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
168             zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
169         ENDIF
170      END_3D
171
172      !  Computation of a proxy of the N/C ratio
173      !  ---------------------------------------
174      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
175          zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
176          &      * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
177          quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
178          zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
179          &      * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
180          quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
181      END_3D
182
183
184      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
185
186          IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
187             !    Si/C of diatoms
188             !    ------------------------
189             !    Si/C increases with iron stress and silicate availability
190             !    Si/C is arbitrariliy increased for very high Si concentrations
191             !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
192            zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
193            zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
194            zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
195            zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
196            IF (gphit(ji,jj) < -30 ) THEN
197              zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
198            ELSE
199              zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
200            ENDIF
201            zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
202        ENDIF
203      END_3D
204
205      !  Mixed-layer effect on production
206      !  Sea-ice effect on production
207
208      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
209         zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
210         zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
211      END_3D
212
213      ! Computation of the various production terms
214      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
215         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
216            !  production terms for nanophyto. (C)
217            zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
218            zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
219            !
220            zratio = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) * fecnm + rtrn )
221            zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
222            zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
223            &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
224            &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
225            &             * zmax * tr(ji,jj,jk,jpphy,Kbb) * rfact2
226            !  production terms for diatoms (C)
227            zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
228            zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
229            !
230            zratio = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) * fecdm + rtrn )
231            zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
232            zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
233            &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
234            &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
235            &             * zmax * tr(ji,jj,jk,jpdia,Kbb) * rfact2
236         ENDIF
237      END_3D
238
239      ! Computation of the chlorophyll production terms
240      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
241         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
242            !  production terms for nanophyto. ( chlorophyll )
243            znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
244            zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
245            zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
246            chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
247            zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
248                                  & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
249            !  production terms for diatoms ( chlorophyll )
250            zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
251            zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
252            zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
253            chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
254            zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
255                                  & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
256            !   Update the arrays TRA which contain the Chla sources and sinks
257            tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
258            tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
259         ENDIF
260      END_3D
261
262      !   Update the arrays TRA which contain the biological sources and sinks
263      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
264        IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
265           zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
266           zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
267           zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
268           tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
269           tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
270           tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zproreg - zproreg2
271           tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) + zprorcan(ji,jj,jk) * texcretn
272           tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
273           tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) + zprorcad(ji,jj,jk) * texcretd
274           tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
275           tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
276           tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zdocprod
277           tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + o2ut * ( zproreg + zproreg2) &
278           &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
279           !
280           zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
281           tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zfeup
282           tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
283           tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
284           tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
285           &                                         - rno3 * ( zproreg + zproreg2 )
286        ENDIF
287      END_3D
288     !
289     IF( ln_ligand ) THEN
290         zpligprod1(:,:,:) = 0._wp    ;    zpligprod2(:,:,:) = 0._wp
291         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
292           IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
293              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
294              zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
295              tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
296              zpligprod1(ji,jj,jk) = zdocprod * ldocp
297              zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
298           ENDIF
299         END_3D
300     ENDIF
301
302
303    ! Total primary production per year
304    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
305         & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
306
307    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
308       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
309       !
310       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
311       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
312       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
313       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
314       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
315       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
316       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
317       IF( ln_ligand ) THEN
318         CALL iom_put( "LPRODP"  , zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
319         CALL iom_put( "LDETP"   , zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
320       ENDIF
321       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
322       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
323       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
324       CALL iom_put( "LNlight" , zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
325       CALL iom_put( "LDlight" , zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
326       CALL iom_put( "TPP"     , ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
327       CALL iom_put( "TPNEW"   , ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
328       CALL iom_put( "TPBFE"   , ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
329       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
330     ENDIF
331
332     IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
333         WRITE(charout, FMT="('prod')")
334         CALL prt_ctl_info( charout, cdcomp = 'top' )
335         CALL prt_ctl(tab4d_1=CASTWP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm)
336     ENDIF
337      !
338      IF( ln_timing )  CALL timing_stop('p4z_prod')
339      !
340   END SUBROUTINE p4z_prod
341
342
343   SUBROUTINE p4z_prod_init
344      !!----------------------------------------------------------------------
345      !!                  ***  ROUTINE p4z_prod_init  ***
346      !!
347      !! ** Purpose :   Initialization of phytoplankton production parameters
348      !!
349      !! ** Method  :   Read the nampisprod namelist and check the parameters
350      !!      called at the first timestep (nittrc000)
351      !!
352      !! ** input   :   Namelist nampisprod
353      !!----------------------------------------------------------------------
354      INTEGER ::   ios   ! Local integer
355      !
356      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, bresp, excretn, excretd,  &
357         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
358      !!----------------------------------------------------------------------
359      !
360      IF(lwp) THEN                         ! control print
361         WRITE(numout,*)
362         WRITE(numout,*) 'p4z_prod_init : phytoplankton growth'
363         WRITE(numout,*) '~~~~~~~~~~~~~'
364      ENDIF
365      !
366      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
367901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zprod in reference namelist' )
368      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
369902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zprod in configuration namelist' )
370      IF(lwm) WRITE( numonp, namp4zprod )
371
372      IF(lwp) THEN                         ! control print
373         WRITE(numout,*) '   Namelist : namp4zprod'
374         WRITE(numout,*) '      mean Si/C ratio                           grosip       =', grosip
375         WRITE(numout,*) '      P-I slope                                 pislopen     =', pislopen
376         WRITE(numout,*) '      Acclimation factor to low light           xadap        =', xadap
377         WRITE(numout,*) '      excretion ratio of nanophytoplankton      excretn      =', excretn
378         WRITE(numout,*) '      excretion ratio of diatoms                excretd      =', excretd
379         WRITE(numout,*) '      basal respiration in phytoplankton        bresp        =', bresp
380         WRITE(numout,*) '      Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
381         WRITE(numout,*) '      P-I slope  for diatoms                    pisloped     =', pisloped
382         WRITE(numout,*) '      Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
383         WRITE(numout,*) '      Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
384         WRITE(numout,*) '      Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
385         WRITE(numout,*) '      Minimum Fe/C in diatoms                   fecdm        =', fecdm
386      ENDIF
387      !
388      r1_rday   = 1._wp / rday 
389      texcretn  = 1._wp - excretn
390      texcretd  = 1._wp - excretd
391      tpp       = 0._wp
392      !
393   END SUBROUTINE p4z_prod_init
394
395
396   INTEGER FUNCTION p4z_prod_alloc()
397      !!----------------------------------------------------------------------
398      !!                     ***  ROUTINE p4z_prod_alloc  ***
399      !!----------------------------------------------------------------------
400      ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
401      !
402      IF( p4z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_prod_alloc : failed to allocate arrays.' )
403      !
404   END FUNCTION p4z_prod_alloc
405
406   !!======================================================================
407END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.