New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z/p4zlys.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl          !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   REAL(wp), PUBLIC ::   kdca   !: diss. rate constant calcite
32   REAL(wp), PUBLIC ::   nca    !: order of reaction for calcite dissolution
33
34   INTEGER  ::   rmtss              ! number of seconds per month
35   REAL(wp) ::   calcon = 1.03E-2   ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
36 
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39#  include "single_precision_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt, knt, Kbb, Krhs )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
59      INTEGER, INTENT(in)  ::  Kbb, Krhs ! time level indices
60      !
61      INTEGER  ::   ji, jj, jk, jn
62      REAL(wp) ::   zdispot, zfact, zcalcon
63      REAL(wp) ::   zomegaca, zexcess, zexcess0
64      CHARACTER (len=25) ::   charout
65      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3, zcaldiss, zhinit, zhi, zco3sat
66      !!---------------------------------------------------------------------
67      !
68      IF( ln_timing )  CALL timing_start('p4z_lys')
69      !
70      zhinit  (:,:,:) = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
71      !
72      !     -------------------------------------------
73      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
74      !     -------------------------------------------
75
76      CALL solve_at_general( zhinit, zhi, Kbb )
77
78      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
79         zco3(ji,jj,jk) = tr(ji,jj,jk,jpdic,Kbb) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
80            &             + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
81         hi  (ji,jj,jk) = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
82      END_3D
83
84      !     ---------------------------------------------------------
85      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
86      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
87      !        MGCO3)
88      !     ---------------------------------------------------------
89
90      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
91
92         ! DEVIATION OF [CO3--] FROM SATURATION VALUE
93         ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
94         zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
95         zfact    = rhop(ji,jj,jk) / 1000._wp
96         zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
97         zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
98
99         ! SET DEGREE OF UNDER-/SUPERSATURATION
100         excess(ji,jj,jk) = 1._wp - zomegaca
101         zexcess0 = MAX( 0., excess(ji,jj,jk) )
102         zexcess  = zexcess0**nca
103
104         ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
105         !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
106         !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
107         zdispot = kdca * zexcess * tr(ji,jj,jk,jpcal,Kbb)
108        !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
109        !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
110        zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
111        !
112        tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + 2. * zcaldiss(ji,jj,jk)
113        tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) -      zcaldiss(ji,jj,jk)
114        tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) +      zcaldiss(ji,jj,jk)
115      END_3D
116      !
117
118      IF( lk_iomput .AND. knt == nrdttrc ) THEN
119         CALL iom_put( "PH" , -1. * LOG10( MAX( hi(:,:,:), rtrn ) ) * tmask(:,:,:) )
120         IF( iom_use( "CO3" ) ) THEN
121            zco3(:,:,jpk) = 0.    ; CALL iom_put( "CO3"   , zco3(:,:,:)     * 1.e+3           * tmask(:,:,:) )
122         ENDIF
123         IF( iom_use( "CO3sat" ) ) THEN
124           zco3sat(:,:,jpk) = 0.  ; CALL iom_put( "CO3sat", zco3sat(:,:,:)  * 1.e+3           * tmask(:,:,:) )
125         ENDIF
126         IF( iom_use( "DCAL" ) ) THEN
127           zcaldiss(:,:,jpk) = 0. ; CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
128         ENDIF             
129      ENDIF
130      !
131      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
132        WRITE(charout, FMT="('lys ')")
133        CALL prt_ctl_info( charout, cdcomp = 'top' )
134        CALL prt_ctl(tab4d_1=CASTWP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm)
135      ENDIF
136      !
137      IF( ln_timing )   CALL timing_stop('p4z_lys')
138      !
139   END SUBROUTINE p4z_lys
140
141
142   SUBROUTINE p4z_lys_init
143      !!----------------------------------------------------------------------
144      !!                  ***  ROUTINE p4z_lys_init  ***
145      !!
146      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
147      !!
148      !! ** Method  :   Read the nampiscal namelist and check the parameters
149      !!      called at the first timestep (nittrc000)
150      !!
151      !! ** input   :   Namelist nampiscal
152      !!
153      !!----------------------------------------------------------------------
154      INTEGER ::   ios   ! Local integer
155      !
156      NAMELIST/nampiscal/ kdca, nca
157      !!----------------------------------------------------------------------
158      IF(lwp) THEN
159         WRITE(numout,*)
160         WRITE(numout,*) 'p4z_lys_init : initialization of CaCO3 dissolution'
161         WRITE(numout,*) '~~~~~~~~~~~~'
162      ENDIF
163      !
164      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
165901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampiscal in reference namelist' )
166      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
167902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampiscal in configuration namelist' )
168      IF(lwm) WRITE( numonp, nampiscal )
169      !
170      IF(lwp) THEN                         ! control print
171         WRITE(numout,*) '   Namelist : nampiscal'
172         WRITE(numout,*) '      diss. rate constant calcite (per month)        kdca =', kdca
173         WRITE(numout,*) '      order of reaction for calcite dissolution      nca  =', nca
174      ENDIF
175      !
176      ! Number of seconds per month
177      rmtss =  nyear_len(1) * rday / raamo
178      !
179   END SUBROUTINE p4z_lys_init
180
181   !!======================================================================
182END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.