New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P4Z/p4zfechem.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
7   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
8   !!----------------------------------------------------------------------
9   !!   p4z_fechem       : Compute remineralization/scavenging of iron
10   !!   p4z_fechem_init  : Initialisation of parameters for remineralisation
11   !!   p4z_fechem_alloc : Allocate remineralisation variables
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zche          ! chemical model
17   USE p4zbc           ! Boundary conditions from sediments
18   USE prtctl          ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_fechem        ! called in p4zbio.F90
25   PUBLIC   p4z_fechem_init   ! called in trcsms_pisces.F90
26
27   LOGICAL          ::   ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
28   REAL(wp), PUBLIC ::   xlam1        !: scavenging rate of Iron
29   REAL(wp), PUBLIC ::   xlamdust     !: scavenging rate of Iron by dust
30   REAL(wp), PUBLIC ::   ligand       !: ligand concentration in the ocean
31   REAL(wp), PUBLIC ::   kfep         !: rate constant for nanoparticle formation
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36#  include "single_precision_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE p4z_fechem( kt, knt, Kbb, Kmm, Krhs )
45      !!---------------------------------------------------------------------
46      !!                     ***  ROUTINE p4z_fechem  ***
47      !!
48      !! ** Purpose :   Compute remineralization/scavenging of iron
49      !!
50      !! ** Method  :   A simple chemistry model of iron from Aumont and Bopp (2006)
51      !!                based on one ligand and one inorganic form
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
54      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
55      !
56      INTEGER  ::   ji, jj, jk, jic, jn
57      REAL(wp) ::   zdep, zlam1a, zlam1b, zlamfac
58      REAL(wp) ::   zkeq, zfeequi, zfesatur, zfecoll, fe3sol
59      REAL(wp) ::   zdenom1, zscave, zaggdfea, zaggdfeb, zcoag
60      REAL(wp) ::   ztrc, zdust
61      REAL(wp) ::   zdenom2
62      REAL(wp) ::   zzFeL1, zzFeL2, zzFe2, zzFeP, zzFe3, zzstrn2
63      REAL(wp) ::   zrum, zcodel, zargu, zlight
64      REAL(wp) ::   zkox, zkph1, zkph2, zph, zionic, ztligand
65      REAL(wp) ::   za, zb, zc, zkappa1, zkappa2, za0, za1, za2
66      REAL(wp) ::   zxs, zfunc, zp, zq, zd, zr, zphi, zfff, zp3, zq2
67      REAL(wp) ::   ztfe, zoxy, zhplus, zxlam
68      REAL(wp) ::   zaggliga, zaggligb
69      REAL(wp) ::   dissol, zligco
70      REAL(wp) :: zrfact2
71      CHARACTER (len=25) :: charout
72      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zTL1, zFe3, ztotlig, precip, zFeL1
73      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zcoll3d, zscav3d, zlcoll3d
74      !!---------------------------------------------------------------------
75      !
76      IF( ln_timing )   CALL timing_start('p4z_fechem')
77      !
78      ! Total ligand concentration : Ligands can be chosen to be constant or variable
79      ! Parameterization from Tagliabue and Voelker (2011)
80      ! -------------------------------------------------
81      IF( ln_ligvar ) THEN
82         ztotlig(:,:,:) =  0.09 * tr(:,:,:,jpdoc,Kbb) * 1E6 + ligand * 1E9
83         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
84      ELSE
85        IF( ln_ligand ) THEN  ;   ztotlig(:,:,:) = tr(:,:,:,jplgw,Kbb) * 1E9
86        ELSE                  ;   ztotlig(:,:,:) = ligand * 1E9
87        ENDIF
88      ENDIF
89
90      ! ------------------------------------------------------------
91      !  from Aumont and Bopp (2006)
92      ! This model is based on one ligand and Fe'
93      ! Chemistry is supposed to be fast enough to be at equilibrium
94      ! ------------------------------------------------------------
95      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
96         zTL1(ji,jj,jk)  = ztotlig(ji,jj,jk)
97         zkeq            = fekeq(ji,jj,jk)
98         zfesatur        = zTL1(ji,jj,jk) * 1E-9
99         ztfe            = tr(ji,jj,jk,jpfer,Kbb) 
100         ! Fe' is the root of a 2nd order polynom
101         zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq - zkeq * ztfe )               &
102            &              + SQRT( ( 1. + zfesatur * zkeq - zkeq * ztfe )**2       &
103            &              + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
104         zFe3 (ji,jj,jk) = zFe3(ji,jj,jk) * 1E9
105         zFeL1(ji,jj,jk) = MAX( 0., tr(ji,jj,jk,jpfer,Kbb) * 1E9 - zFe3(ji,jj,jk) )
106      END_3D
107         !
108
109      zdust = 0.         ! if no dust available
110      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
111         ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
112         ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
113         ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
114         ! --------------------------------------------------------------------------------------
115         zhplus  = max( rtrn, hi(ji,jj,jk) )
116         fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
117         &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
118         &         + fesol(ji,jj,jk,5) / zhplus )
119         !
120         zfeequi = zFe3(ji,jj,jk) * 1E-9
121         zfecoll = 0.5 * zFeL1(ji,jj,jk) * 1E-9
122         ! precipitation of Fe3+, creation of nanoparticles
123         precip(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) * 1E-9 - fe3sol ) ) * kfep * xstep
124         !
125         ztrc   = ( tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + tr(ji,jj,jk,jpcal,Kbb) + tr(ji,jj,jk,jpgsi,Kbb) ) * 1.e6 
126         IF( ll_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk) &
127         &  * EXP( -gdept(ji,jj,jk,Kmm) / 540. )
128         IF (ln_ligand) THEN
129            zxlam  = xlam1 * MAX( 1.E-3, EXP(-2 * etot(ji,jj,jk) / 10. ) * (1. - EXP(-2 * tr(ji,jj,jk,jpoxy,Kbb) / 100.E-6 ) ))
130         ELSE
131            zxlam  = xlam1 * 1.0
132         ENDIF
133         zlam1b = 3.e-5 + xlamdust * zdust + zxlam * ztrc
134         zscave = zfeequi * zlam1b * xstep
135
136         ! Compute the different ratios for scavenging of iron
137         ! to later allocate scavenged iron to the different organic pools
138         ! ---------------------------------------------------------
139         zdenom1 = zxlam * tr(ji,jj,jk,jppoc,Kbb) / zlam1b
140         zdenom2 = zxlam * tr(ji,jj,jk,jpgoc,Kbb) / zlam1b
141
142         !  Increased scavenging for very high iron concentrations found near the coasts
143         !  due to increased lithogenic particles and let say it is unknown processes (precipitation, ...)
144         !  -----------------------------------------------------------
145         zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
146         zlamfac = MIN( 1.  , zlamfac )
147         zdep    = MIN( 1., 1000. / gdept(ji,jj,jk,Kmm) )
148         zcoag   = 1E-4 * ( 1. - zlamfac ) * zdep * xstep * tr(ji,jj,jk,jpfer,Kbb)
149
150         !  Compute the coagulation of colloidal iron. This parameterization
151         !  could be thought as an equivalent of colloidal pumping.
152         !  It requires certainly some more work as it is very poorly constrained.
153         !  ----------------------------------------------------------------
154         zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
155             &      + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
156         zaggdfea = zlam1a * xstep * zfecoll
157         !
158         zlam1b   = 3.53E3 * tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
159         zaggdfeb = zlam1b * xstep * zfecoll
160         !
161         tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zscave - zaggdfea - zaggdfeb &
162         &                     - zcoag - precip(ji,jj,jk)
163         tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zscave * zdenom1 + zaggdfea
164         tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zscave * zdenom2 + zaggdfeb
165         zscav3d(ji,jj,jk)   = zscave
166         zcoll3d(ji,jj,jk)   = zaggdfea + zaggdfeb
167         !
168      END_3D
169      !
170      !  Define the bioavailable fraction of iron
171      !  ----------------------------------------
172      biron(:,:,:) = tr(:,:,:,jpfer,Kbb) 
173      !
174      IF( ln_ligand ) THEN
175         !
176         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
177            zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
178                &    + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
179            !
180            zlam1b   = 3.53E3 *   tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
181            zligco   = 0.5 * tr(ji,jj,jk,jplgw,Kmm)
182            zaggliga = zlam1a * xstep * zligco
183            zaggligb = zlam1b * xstep * zligco
184            tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) - zaggliga - zaggligb
185            zlcoll3d(ji,jj,jk)  = zaggliga + zaggligb
186         END_3D
187         !
188         plig(:,:,:) =  MAX( 0., ( ( zFeL1(:,:,:) * 1E-9 ) / ( tr(:,:,:,jpfer,Kbb) +rtrn ) ) )
189         !
190      ENDIF
191      !  Output of some diagnostics variables
192      !     ---------------------------------
193      IF( lk_iomput ) THEN
194         IF( knt == nrdttrc ) THEN
195            zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
196            IF( iom_use("Fe3")  )  THEN
197               zFe3(:,:,jpk) = 0.  ;  CALL iom_put("Fe3" , zFe3(:,:,:) * tmask(:,:,:) )   ! Fe3+
198            ENDIF
199            IF( iom_use("FeL1") )  THEN
200              zFeL1(:,:,jpk) = 0.  ;  CALL iom_put("FeL1", zFeL1(:,:,:) * tmask(:,:,:) )   ! FeL1
201            ENDIF
202            IF( iom_use("TL1")  )  THEN
203              zTL1(:,:,jpk) = 0.   ;  CALL iom_put("TL1" , zTL1(:,:,:) * tmask(:,:,:) )   ! TL1
204            ENDIF
205            IF( iom_use("Totlig") )  CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
206            IF( iom_use("Biron")  )  CALL iom_put("Biron"  , biron  (:,:,:)  * 1e9 * tmask(:,:,:) )   ! biron
207            IF( iom_use("FESCAV") )  THEN
208               zscav3d (:,:,jpk) = 0.  ;  CALL iom_put("FESCAV" , zscav3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
209            ENDIF
210            IF( iom_use("FECOLL") ) THEN
211               zcoll3d (:,:,jpk) = 0.  ;   CALL iom_put("FECOLL" , zcoll3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
212            ENDIF
213            IF( iom_use("LGWCOLL")) THEN
214               zlcoll3d(:,:,jpk) = 0.  ;  CALL iom_put("LGWCOLL", zlcoll3d(:,:,:) * 1e9 * tmask(:,:,:) * zrfact2 )
215            ENDIF
216          ENDIF
217      ENDIF
218
219      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
220         WRITE(charout, FMT="('fechem')")
221         CALL prt_ctl_info( charout, cdcomp = 'top' )
222         CALL prt_ctl(tab4d_1=CASTWP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm)
223      ENDIF
224      !
225      IF( ln_timing )   CALL timing_stop('p4z_fechem')
226      !
227   END SUBROUTINE p4z_fechem
228
229
230   SUBROUTINE p4z_fechem_init
231      !!----------------------------------------------------------------------
232      !!                  ***  ROUTINE p4z_fechem_init  ***
233      !!
234      !! ** Purpose :   Initialization of iron chemistry parameters
235      !!
236      !! ** Method  :   Read the nampisfer namelist and check the parameters
237      !!      called at the first timestep
238      !!
239      !! ** input   :   Namelist nampisfer
240      !!
241      !!----------------------------------------------------------------------
242      INTEGER ::   ios   ! Local integer
243      !!
244      NAMELIST/nampisfer/ ln_ligvar, xlam1, xlamdust, ligand, kfep 
245      !!----------------------------------------------------------------------
246      !
247      IF(lwp) THEN
248         WRITE(numout,*)
249         WRITE(numout,*) 'p4z_rem_init : Initialization of iron chemistry parameters'
250         WRITE(numout,*) '~~~~~~~~~~~~'
251      ENDIF
252      !
253      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
254901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisfer in reference namelist' )
255      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
256902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisfer in configuration namelist' )
257      IF(lwm) WRITE( numonp, nampisfer )
258
259      IF(lwp) THEN                     ! control print
260         WRITE(numout,*) '   Namelist : nampisfer'
261         WRITE(numout,*) '      variable concentration of ligand          ln_ligvar    =', ln_ligvar
262         WRITE(numout,*) '      scavenging rate of Iron                   xlam1        =', xlam1
263         WRITE(numout,*) '      scavenging rate of Iron by dust           xlamdust     =', xlamdust
264         WRITE(numout,*) '      ligand concentration in the ocean         ligand       =', ligand
265         WRITE(numout,*) '      rate constant for nanoparticle formation  kfep         =', kfep
266      ENDIF
267      !
268   END SUBROUTINE p4z_fechem_init
269   
270   !!======================================================================
271END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.