New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zopt.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/TOP/PISCES/P2Z/p2zopt.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 9.0 KB
Line 
1MODULE p2zopt
2   !!======================================================================
3   !!                         ***  MODULE p2zopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   p2z_opt        :   Compute the light availability in the water column
16   !!----------------------------------------------------------------------
17   USE oce_trc         !
18   USE trc
19   USE sms_pisces
20   USE prtctl          ! Print control for debbuging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p2z_opt   !
26   PUBLIC   p2z_opt_init   !
27
28   REAL(wp), PUBLIC ::  xkr0      !: water coefficient absorption in red     
29   REAL(wp), PUBLIC ::  xkg0      !: water coefficient absorption in green   
30   REAL(wp), PUBLIC ::  xkrp      !: pigment coefficient absorption in red   
31   REAL(wp), PUBLIC ::  xkgp      !: pigment coefficient absorption in green 
32   REAL(wp), PUBLIC ::  xlr       !: exposant for pigment absorption in red 
33   REAL(wp), PUBLIC ::  xlg       !: exposant for pigment absorption in green
34   REAL(wp), PUBLIC ::  rpig      !: chla/chla+phea ratio   
35   !                 
36   REAL(wp), PUBLIC ::  rcchl     ! Carbone/Chlorophyl ratio [mgC.mgChla-1]
37   REAL(wp), PUBLIC ::  redf      ! redfield ratio (C:N) for phyto
38   REAL(wp), PUBLIC ::  reddom    ! redfield ratio (C:N) for DOM
39
40   !! * Substitutions
41#  include "do_loop_substitute.h90"
42#  include "domzgr_substitute.h90"
43#  include "single_precision_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p2z_opt( kt, Kmm )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p2z_opt  ***
54      !!
55      !! ** Purpose :   computes the light propagation in the water column
56      !!              and the euphotic layer depth
57      !!
58      !! ** Method  :   local par is computed in w layers using light propagation
59      !!              mean par in t layers are computed by integration
60      !!
61!!gm please remplace the '???' by true comments
62      !! ** Action  :   etot   ???
63      !!                neln   ???
64      !!---------------------------------------------------------------------
65      !!
66      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
67      INTEGER, INTENT( in ) ::   Kmm  ! time level index
68      !!
69      INTEGER  ::   ji, jj, jk          ! dummy loop indices
70      CHARACTER (len=25) ::   charout   ! temporary character
71      REAL(wp) ::   zpig                ! log of the total pigment
72      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
73      REAL(wp) ::   zcoef               ! temporary scalar
74      REAL(wp), DIMENSION(jpi,jpj    ) :: zpar100, zpar0m
75      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zparr, zparg
76      !!---------------------------------------------------------------------
77      !
78      IF( ln_timing )   CALL timing_start('p2z_opt')
79      !
80
81      IF( kt == nittrc000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) ' p2z_opt : LOBSTER optic-model'
84         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
85      ENDIF
86
87      !                                          ! surface irradiance
88      !                                          ! ------------------
89      IF( ln_dm2dc ) THEN   ;   zpar0m(:,:) = qsr_mean(:,:) * 0.43
90      ELSE                  ;   zpar0m(:,:) = qsr     (:,:) * 0.43
91      ENDIF
92      zpar100(:,:)   = zpar0m(:,:) * 0.01
93      zparr  (:,:,1) = zpar0m(:,:) * 0.5
94      zparg  (:,:,1) = zpar0m(:,:) * 0.5
95
96      !                                          ! Photosynthetically Available Radiation (PAR)
97      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
98      DO_3D( 1, 1, 1, 1, 2, jpk )                     ! local par at w-levels
99         zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk-1,jpphy,Kmm) ) * zcoef  )
100         zkr  = xkr0 + xkrp * EXP( xlr * zpig )
101         zkg  = xkg0 + xkgp * EXP( xlg * zpig )
102         zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * e3t(ji,jj,jk-1,Kmm) )
103         zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * e3t(ji,jj,jk-1,Kmm) )
104      END_3D
105      DO_3D( 1, 1, 1, 1, 1, jpkm1 )                   ! mean par at t-levels
106         zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk,jpphy,Kmm) ) * zcoef  )
107         zkr  = xkr0 + xkrp * EXP( xlr * zpig )
108         zkg  = xkg0 + xkgp * EXP( xlg * zpig )
109         zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkr * e3t(ji,jj,jk,Kmm) ) )
110         zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkg * e3t(ji,jj,jk,Kmm) ) )
111         etot (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
112      END_3D
113
114      !                                          ! Euphotic layer
115      !                                          ! --------------
116      neln(:,:) = 1                                   ! euphotic layer level
117      DO_3D( 1, 1, 1, 1, 1, jpkm1 )                   ! (i.e. 1rst T-level strictly below EL bottom)
118        IF( etot(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
119      END_3D
120      !                                               ! Euphotic layer depth
121      DO_2D( 1, 1, 1, 1 )
122         heup(ji,jj) = gdepw(ji,jj,neln(ji,jj),Kmm)
123      END_2D
124
125
126      IF(sn_cfctl%l_prttrc) THEN      ! print mean trends (used for debugging)
127         WRITE(charout, FMT="('opt')")
128         CALL prt_ctl_info( charout, cdcomp = 'top' )
129         CALL prt_ctl( tab4d_1=CASTWP(tr(:,:,:,:,Kmm)), mask1=tmask, clinfo=ctrcnm )
130      ENDIF
131      !
132      IF( ln_timing )   CALL timing_stop('p2z_opt')
133      !
134   END SUBROUTINE p2z_opt
135
136
137   SUBROUTINE p2z_opt_init
138      !!----------------------------------------------------------------------
139      !!                  ***  ROUTINE p2z_opt_init  ***
140      !!
141      !! ** Purpose :  optical parameters
142      !!
143      !! ** Method  :   Read the namlobopt namelist and check the parameters
144      !!
145      !!----------------------------------------------------------------------
146      INTEGER ::   ios   ! Local integer
147      !!
148      NAMELIST/namlobopt/ xkg0, xkr0, xkgp, xkrp, xlg, xlr, rpig
149      NAMELIST/namlobrat/ rcchl, redf, reddom
150      !!----------------------------------------------------------------------
151
152      READ  ( numnatp_ref, namlobopt, IOSTAT = ios, ERR = 901)
153901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobopt in reference namelist' )
154
155      READ  ( numnatp_cfg, namlobopt, IOSTAT = ios, ERR = 902 )
156902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobopt in configuration namelist' )
157      IF(lwm) WRITE ( numonp, namlobopt )
158
159      IF(lwp) THEN
160         WRITE(numout,*)
161         WRITE(numout,*) ' Namelist namlobopt'
162         WRITE(numout,*) '    green   water absorption coeff                       xkg0  = ', xkg0
163         WRITE(numout,*) '    red water absorption coeff                           xkr0  = ', xkr0
164         WRITE(numout,*) '    pigment red absorption coeff                         xkrp  = ', xkrp
165         WRITE(numout,*) '    pigment green absorption coeff                       xkgp  = ', xkgp
166         WRITE(numout,*) '    green chl exposant                                   xlg   = ', xlg
167         WRITE(numout,*) '    red   chl exposant                                   xlr   = ', xlr
168         WRITE(numout,*) '    chla/chla+phea ratio                                 rpig  = ', rpig
169         WRITE(numout,*) ' '
170      ENDIF
171      !
172      READ  ( numnatp_ref, namlobrat, IOSTAT = ios, ERR = 903)
173903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobrat in reference namelist' )
174
175      READ  ( numnatp_cfg, namlobrat, IOSTAT = ios, ERR = 904 )
176904   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobrat in configuration namelist' )
177      IF(lwm) WRITE ( numonp, namlobrat )
178
179      IF(lwp) THEN
180          WRITE(numout,*) ' Namelist namlobrat'
181         WRITE(numout,*) '     carbone/chlorophyl ratio                             rcchl = ', rcchl
182          WRITE(numout,*) '    redfield ratio  c:n for phyto                        redf      =', redf
183          WRITE(numout,*) '    redfield ratio  c:n for DOM                          reddom    =', reddom
184          WRITE(numout,*) ' '
185      ENDIF
186      !
187   END SUBROUTINE p2z_opt_init
188
189   !!======================================================================
190END MODULE p2zopt
Note: See TracBrowser for help on using the repository browser.