New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfdrg.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/ZDF – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/ZDF/zdfdrg.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE zdfdrg
2   !!======================================================================
3   !!                       ***  MODULE  zdfdrg  ***
4   !! Ocean physics: top and/or Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!            4.0  ! 2017-05  (G. Madec) zdfbfr becomes zdfdrg + variable names change
13   !!                                     + drag defined at t-point + new user interface + top drag (ocean cavities)
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   zdf_drg       : update bottom friction coefficient (non-linear bottom friction only)
18   !!   zdf_drg_exp   : compute the top & bottom friction in explicit case
19   !!   zdf_drg_init  : read in namdrg namelist and control the bottom friction parameters.
20   !!       drg_init  :
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and tracers variables
23   USE phycst  , ONLY : vkarmn
24   USE dom_oce        ! ocean space and time domain variables
25   USE zdf_oce        ! ocean vertical physics variables
26   USE trd_oce        ! trends: ocean variables
27   USE trddyn         ! trend manager: dynamics
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O module
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE lib_mpp        ! distributed memory computing
33   USE prtctl         ! Print control
34   USE sbc_oce , ONLY : nn_ice 
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   zdf_drg         ! called by zdf_phy
40   PUBLIC   zdf_drg_exp     ! called by dyn_zdf
41   PUBLIC   zdf_drg_init    ! called by zdf_phy_init
42
43   !                                 !!* Namelist namdrg: nature of drag coefficient namelist *
44   LOGICAL , PUBLIC ::   ln_drg_OFF   ! free-slip       : Cd = 0
45   LOGICAL          ::   ln_lin       !     linear  drag: Cd = Cd0_lin
46   LOGICAL          ::   ln_non_lin   ! non-linear  drag: Cd = Cd0_nl |U|
47   LOGICAL          ::   ln_loglayer  ! logarithmic drag: Cd = vkarmn/log(z/z0)
48   LOGICAL , PUBLIC ::   ln_drgimp    ! implicit top/bottom friction flag
49   LOGICAL , PUBLIC ::   ln_drgice_imp ! implicit ice-ocean drag
50   !                                 !!* Namelist namdrg_top & _bot: TOP or BOTTOM coefficient namelist *
51   REAL(wp)         ::   rn_Cd0       !: drag coefficient                                           [ - ]
52   REAL(wp)         ::   rn_Uc0       !: characteristic velocity (linear case: tau=rho*Cd0*Uc0*u)   [m/s]
53   REAL(wp)         ::   rn_Cdmax     !: drag value maximum (ln_loglayer=T)                         [ - ]
54   REAL(wp)         ::   rn_z0        !: roughness          (ln_loglayer=T)                         [ m ]
55   REAL(wp)         ::   rn_ke0       !: background kinetic energy (non-linear case)                [m2/s2]
56   LOGICAL          ::   ln_boost     !: =T regional boost of Cd0 ; =F Cd0 horizontally uniform
57   REAL(wp)         ::   rn_boost     !: local boost factor                                         [ - ]
58
59   REAL(wp), PUBLIC ::   r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top   ! set from namdrg_top namelist values
60   REAL(wp), PUBLIC ::   r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot   !  -    -  namdrg_bot    -       -
61
62   INTEGER ::              ndrg       ! choice of the type of drag coefficient
63   !                                  ! associated indices:
64   INTEGER, PARAMETER ::   np_OFF      = 0   ! free-slip: drag set to zero
65   INTEGER, PARAMETER ::   np_lin      = 1   !     linear drag: Cd = Cd0_lin
66   INTEGER, PARAMETER ::   np_non_lin  = 2   ! non-linear drag: Cd = Cd0_nl |U|
67   INTEGER, PARAMETER ::   np_loglayer = 3   ! non linear drag (logarithmic formulation): Cd = vkarmn/log(z/z0)
68
69   LOGICAL , PUBLIC ::   l_zdfdrg           !: flag to update at each time step the top/bottom Cd
70   LOGICAL          ::   l_log_not_linssh   !: flag to update at each time step the position ot the velocity point
71   !
72   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCd0_top, rCd0_bot   !: precomputed top/bottom drag coeff. at t-point (>0)
73   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCdU_top, rCdU_bot   !: top/bottom drag coeff. at t-point (<0)  [m/s]
74
75   !! * Substitutions
76#  include "do_loop_substitute.h90"
77#  include "domzgr_substitute.h90"
78#  include "single_precision_substitute.h90"
79   !!----------------------------------------------------------------------
80   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
81   !! $Id$
82   !! Software governed by the CeCILL license (see ./LICENSE)
83   !!----------------------------------------------------------------------
84CONTAINS
85
86   SUBROUTINE zdf_drg( kt, Kmm, k_mk, pCdmin, pCdmax, pz0, pke0, pCd0,   &   ! <<== in
87      &                                                     pCdU )      ! ==>> out : bottom drag [m/s]
88      !!----------------------------------------------------------------------
89      !!                   ***  ROUTINE zdf_drg  ***
90      !!
91      !! ** Purpose :   update the top/bottom drag coefficient (non-linear case only)
92      !!
93      !! ** Method  :   In non linear friction case, the drag coeficient is
94      !!              a function of the velocity:
95      !!                          Cd = cd0 * |U+Ut|   
96      !!              where U is the top or bottom velocity and
97      !!                    Ut a tidal velocity (Ut^2 = Tidal kinetic energy
98      !!                       assumed here here to be constant)
99      !!              Depending on the input variable, the top- or bottom drag is compted
100      !!
101      !! ** Action  :   p_Cd   drag coefficient at t-point
102      !!----------------------------------------------------------------------
103      INTEGER                 , INTENT(in   ) ::   kt       ! ocean time-step index
104      INTEGER                 , INTENT(in   ) ::   Kmm      ! ocean time level index
105      !                       !               !!         !==  top or bottom variables  ==!
106      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk     ! wet level (1st or last)
107      REAL(wp)                , INTENT(in   ) ::   pCdmin   ! min drag value
108      REAL(wp)                , INTENT(in   ) ::   pCdmax   ! max drag value
109      REAL(wp)                , INTENT(in   ) ::   pz0      ! roughness
110      REAL(wp)                , INTENT(in   ) ::   pke0     ! background tidal KE
111      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   pCd0     ! masked precomputed part of Cd0
112      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU     ! = - Cd*|U|   (t-points) [m/s]
113      !!
114      INTEGER ::   ji, jj   ! dummy loop indices
115      INTEGER ::   imk      ! local integers
116      REAL(wp)::   zzz, zut, zvt, zcd   ! local scalars
117      !!----------------------------------------------------------------------
118      !
119      IF( l_log_not_linssh ) THEN     !==  "log layer"  ==!   compute Cd and -Cd*|U|
120         DO_2D( 0, 0, 0, 0 )
121            imk = k_mk(ji,jj)          ! ocean bottom level at t-points
122            zut = uu(ji,jj,imk,Kmm) + uu(ji-1,jj,imk,Kmm)     ! 2 x velocity at t-point
123            zvt = vv(ji,jj,imk,Kmm) + vv(ji,jj-1,imk,Kmm)
124            zzz = 0.5_wp * e3t(ji,jj,imk,Kmm)           ! altitude below/above (top/bottom) the boundary
125            !
126!!JC: possible WAD implementation should modify line below if layers vanish
127            zcd = (  vkarmn / LOG( zzz / pz0 )  )**2
128            zcd = pCd0(ji,jj) * MIN(  MAX( pCdmin , zcd ) , pCdmax  )   ! here pCd0 = mask*boost
129            pCdU(ji,jj) = - zcd * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
130         END_2D
131      ELSE                                            !==  standard Cd  ==!
132         DO_2D( 0, 0, 0, 0 )
133            imk = k_mk(ji,jj)    ! ocean bottom level at t-points
134            zut = uu(ji,jj,imk,Kmm) + uu(ji-1,jj,imk,Kmm)     ! 2 x velocity at t-point
135            zvt = vv(ji,jj,imk,Kmm) + vv(ji,jj-1,imk,Kmm)
136            !                                                           ! here pCd0 = mask*boost * drag
137            pCdU(ji,jj) = - pCd0(ji,jj) * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
138         END_2D
139      ENDIF
140      !
141      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=pCdU, clinfo1=' Cd*U ')
142      !
143   END SUBROUTINE zdf_drg
144
145
146   SUBROUTINE zdf_drg_exp( kt, Kmm, pub, pvb, pua, pva )
147      !!----------------------------------------------------------------------
148      !!                  ***  ROUTINE zdf_drg_exp  ***
149      !!
150      !! ** Purpose :   compute and add the explicit top and bottom frictions.
151      !!
152      !! ** Method  :   in explicit case,
153      !!
154      !!              NB: in implicit case the calculation is performed in dynzdf.F90
155      !!
156      !! ** Action  :   (pua,pva)   momentum trend increased by top & bottom friction trend
157      !!---------------------------------------------------------------------
158      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
159      INTEGER                         , INTENT(in   ) ::   Kmm        ! time level indices
160      REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pub, pvb   ! the two components of the before velocity
161      REAL(dp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! the two components of the velocity tendency
162      !!
163      INTEGER  ::   ji, jj       ! dummy loop indexes
164      INTEGER  ::   ikbu, ikbv   ! local integers
165      REAL(wp) ::   zm1_2dt      ! local scalar
166      REAL(wp) ::   zCdu, zCdv   !   -      -
167      REAL(dp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
168      !!---------------------------------------------------------------------
169      !
170!!gm bug : time step is only rn_Dt (not 2 rn_Dt if euler start !)
171      zm1_2dt = - 1._wp / ( 2._wp * rn_Dt )
172
173      IF( l_trddyn ) THEN      ! trends: store the input trends
174         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
175         ztrdu(:,:,:) = pua(:,:,:)
176         ztrdv(:,:,:) = pva(:,:,:)
177      ENDIF
178
179      DO_2D( 0, 0, 0, 0 )
180         ikbu = mbku(ji,jj)          ! deepest wet ocean u- & v-levels
181         ikbv = mbkv(ji,jj)
182         !
183         ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
184         zCdu = 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / e3u(ji,jj,ikbu,Kmm)
185         zCdv = 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / e3v(ji,jj,ikbv,Kmm)
186         !
187         pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
188         pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
189      END_2D
190      !
191      IF( ln_isfcav ) THEN        ! ocean cavities
192         DO_2D( 0, 0, 0, 0 )
193            ikbu = miku(ji,jj)          ! first wet ocean u- & v-levels
194            ikbv = mikv(ji,jj)
195            !
196            ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
197            zCdu = 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / e3u(ji,jj,ikbu,Kmm)    ! NB: Cdtop masked
198            zCdv = 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / e3v(ji,jj,ikbv,Kmm)
199            !
200            pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
201            pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
202         END_2D
203      ENDIF
204      !
205      IF( l_trddyn ) THEN      ! trends: send trends to trddyn for further diagnostics
206         ztrdu(:,:,:) = pua(:,:,:) - ztrdu(:,:,:)
207         ztrdv(:,:,:) = pva(:,:,:) - ztrdv(:,:,:)
208         CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt, Kmm )
209         DEALLOCATE( ztrdu, ztrdv )
210      ENDIF
211      !                                          ! print mean trends (used for debugging)
212      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(pua), clinfo1=' bfr  - Ua: ', mask1=umask,               &
213         &                                  tab3d_2=CASTWP(pva), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
214      !
215   END SUBROUTINE zdf_drg_exp
216
217
218   SUBROUTINE zdf_drg_init
219      !!----------------------------------------------------------------------
220      !!                  ***  ROUTINE zdf_brg_init  ***
221      !!
222      !! ** Purpose :   Initialization of the bottom friction
223      !!
224      !! ** Method  :   Read the namdrg namelist and check their consistency
225      !!                called at the first timestep (nit000)
226      !!----------------------------------------------------------------------
227      INTEGER   ::   ji, jj      ! dummy loop indexes
228      INTEGER   ::   ios, ioptio   ! local integers
229      !!
230      NAMELIST/namdrg/ ln_drg_OFF, ln_lin, ln_non_lin, ln_loglayer, ln_drgimp, ln_drgice_imp
231      !!----------------------------------------------------------------------
232      !
233      !                     !==  drag nature  ==!
234      !
235      READ  ( numnam_ref, namdrg, IOSTAT = ios, ERR = 901)
236901   IF( ios /= 0 )   CALL ctl_nam( ios , 'namdrg in reference namelist' )
237      READ  ( numnam_cfg, namdrg, IOSTAT = ios, ERR = 902 )
238902   IF( ios >  0 )   CALL ctl_nam( ios , 'namdrg in configuration namelist' )
239      IF(lwm) WRITE ( numond, namdrg )
240      !
241      IF ( ln_drgice_imp .AND.   nn_ice /= 2  )   ln_drgice_imp = .FALSE.
242      !
243      IF(lwp) THEN
244         WRITE(numout,*)
245         WRITE(numout,*) 'zdf_drg_init : top and/or bottom drag setting'
246         WRITE(numout,*) '~~~~~~~~~~~~'
247         WRITE(numout,*) '   Namelist namdrg : top/bottom friction choices'
248         WRITE(numout,*) '      free-slip       : Cd = 0                  ln_drg_OFF  = ', ln_drg_OFF 
249         WRITE(numout,*) '      linear  drag    : Cd = Cd0                ln_lin      = ', ln_lin
250         WRITE(numout,*) '      non-linear  drag: Cd = Cd0_nl |U|         ln_non_lin  = ', ln_non_lin
251         WRITE(numout,*) '      logarithmic drag: Cd = vkarmn/log(z/z0)   ln_loglayer = ', ln_loglayer
252         WRITE(numout,*) '      implicit friction                         ln_drgimp   = ', ln_drgimp
253         WRITE(numout,*) '      implicit ice-ocean drag                   ln_drgice_imp  =', ln_drgice_imp
254      ENDIF
255      !
256      ioptio = 0                       ! set ndrg and control check
257      IF( ln_drg_OFF  ) THEN   ;   ndrg = np_OFF        ;   ioptio = ioptio + 1   ;   ENDIF
258      IF( ln_lin      ) THEN   ;   ndrg = np_lin        ;   ioptio = ioptio + 1   ;   ENDIF
259      IF( ln_non_lin  ) THEN   ;   ndrg = np_non_lin    ;   ioptio = ioptio + 1   ;   ENDIF
260      IF( ln_loglayer ) THEN   ;   ndrg = np_loglayer   ;   ioptio = ioptio + 1   ;   ENDIF
261      !
262      IF( ioptio /= 1 )   CALL ctl_stop( 'zdf_drg_init: Choose ONE type of drag coef in namdrg' )
263      !
264      IF ( ln_drgice_imp.AND.(.NOT.ln_drgimp) ) & 
265         &                CALL ctl_stop( 'zdf_drg_init: ln_drgice_imp=T requires ln_drgimp=T' )
266      !
267      !                     !==  BOTTOM drag setting  ==!   (applied at seafloor)
268      !
269      ALLOCATE( rCd0_bot(jpi,jpj), rCdU_bot(jpi,jpj) )
270      CALL drg_init( 'BOTTOM'   , mbkt       ,                                         &   ! <== in
271         &           r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot, rCd0_bot, rCdU_bot )   ! ==> out
272      !
273      !                     !==  TOP drag setting  ==!   (applied at the top of ocean cavities)
274      !
275      IF( ln_isfcav.OR.ln_drgice_imp ) THEN              ! Ocean cavities: top friction setting
276         ALLOCATE( rCdU_top(jpi,jpj) )
277      ENDIF
278      !
279      IF( ln_isfcav ) THEN
280         ALLOCATE( rCd0_top(jpi,jpj))
281         CALL drg_init( 'TOP   '   , mikt       ,                                         &   ! <== in
282            &           r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top, rCd0_top, rCdU_top )   ! ==> out
283      ENDIF
284      !
285   END SUBROUTINE zdf_drg_init
286
287
288   SUBROUTINE drg_init( cd_topbot, k_mk,  &
289      &                 pCdmin, pCdmax, pz0, pke0, pCd0, pCdU ) 
290      !!----------------------------------------------------------------------
291      !!                  ***  ROUTINE drg_init  ***
292      !!
293      !! ** Purpose :   Initialization of the top/bottom friction CdO and Cd
294      !!              from namelist parameters
295      !!----------------------------------------------------------------------
296      CHARACTER(len=6)        , INTENT(in   ) ::   cd_topbot       ! top/ bot indicator
297      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk            ! 1st/last  wet level
298      REAL(wp)                , INTENT(  out) ::   pCdmin, pCdmax  ! min and max drag coef. [-]
299      REAL(wp)                , INTENT(  out) ::   pz0             ! roughness              [m]
300      REAL(wp)                , INTENT(  out) ::   pke0            ! background KE          [m2/s2]
301      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCd0            ! masked precomputed part of the non-linear drag coefficient
302      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU            ! minus linear drag*|U| at t-points  [m/s]
303      !!
304      CHARACTER(len=40) ::   cl_namdrg, cl_file, cl_varname, cl_namref, cl_namcfg  ! local names
305      INTEGER ::   ji, jj              ! dummy loop indexes
306      LOGICAL ::   ll_top, ll_bot      ! local logical
307      INTEGER ::   ios, inum, imk      ! local integers
308      REAL(wp)::   zmsk, zzz, zcd      ! local scalars
309      REAL(wp), DIMENSION(jpi,jpj) ::   zmsk_boost   ! 2D workspace
310      !!
311      NAMELIST/namdrg_top/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
312      NAMELIST/namdrg_bot/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
313      !!----------------------------------------------------------------------
314      !
315      !                          !==  set TOP / BOTTOM specificities  ==!
316      ll_top = .FALSE.
317      ll_bot = .FALSE.
318      !
319      SELECT CASE (cd_topbot)
320      CASE( 'TOP   ' )
321         ll_top = .TRUE.
322         cl_namdrg  = 'namdrg_top'
323         cl_namref  = 'namdrg_top in reference     namelist'
324         cl_namcfg  = 'namdrg_top in configuration namelist'
325         cl_file    = 'tfr_coef.nc'
326         cl_varname = 'tfr_coef'
327      CASE( 'BOTTOM' )
328         ll_bot = .TRUE.
329         cl_namdrg  = 'namdrg_bot'
330         cl_namref  = 'namdrg_bot  in reference     namelist'
331         cl_namcfg  = 'namdrg_bot  in configuration namelist'
332         cl_file    = 'bfr_coef.nc'
333         cl_varname = 'bfr_coef'
334      CASE DEFAULT
335         CALL ctl_stop( 'drg_init: bad value for cd_topbot ' )
336      END SELECT
337      !
338      !                          !==  read namlist  ==!
339      !
340      IF(ll_top)   READ  ( numnam_ref, namdrg_top, IOSTAT = ios, ERR = 901)
341      IF(ll_bot)   READ  ( numnam_ref, namdrg_bot, IOSTAT = ios, ERR = 901)
342901   IF( ios /= 0 )   CALL ctl_nam( ios , TRIM(cl_namref) )
343      IF(ll_top)   READ  ( numnam_cfg, namdrg_top, IOSTAT = ios, ERR = 902 )
344      IF(ll_bot)   READ  ( numnam_cfg, namdrg_bot, IOSTAT = ios, ERR = 902 )
345902   IF( ios >  0 )   CALL ctl_nam( ios , TRIM(cl_namcfg) )
346      IF(lwm .AND. ll_top)   WRITE ( numond, namdrg_top )
347      IF(lwm .AND. ll_bot)   WRITE ( numond, namdrg_bot )
348      !
349      IF(lwp) THEN
350         WRITE(numout,*)
351         WRITE(numout,*) '   Namelist ',TRIM(cl_namdrg),' : set ',TRIM(cd_topbot),' friction parameters'
352         WRITE(numout,*) '      drag coefficient                        rn_Cd0   = ', rn_Cd0
353         WRITE(numout,*) '      characteristic velocity (linear case)   rn_Uc0   = ', rn_Uc0, ' m/s'
354         WRITE(numout,*) '      non-linear drag maximum                 rn_Cdmax = ', rn_Cdmax
355         WRITE(numout,*) '      background kinetic energy  (n-l case)   rn_ke0   = ', rn_ke0
356         WRITE(numout,*) '      bottom roughness           (n-l case)   rn_z0    = ', rn_z0
357         WRITE(numout,*) '      set a regional boost of Cd0             ln_boost = ', ln_boost
358         WRITE(numout,*) '         associated boost factor              rn_boost = ', rn_boost
359      ENDIF
360      !
361      !                          !==  return some namelist parametres  ==!   (used in non_lin and loglayer cases)
362      pCdmin = rn_Cd0
363      pCdmax = rn_Cdmax
364      pz0    = rn_z0
365      pke0   = rn_ke0
366      !
367      !                          !==  mask * boost factor  ==!
368      !
369      IF( ln_boost ) THEN           !* regional boost:   boost factor = 1 + regional boost
370         IF(lwp) WRITE(numout,*)
371         IF(lwp) WRITE(numout,*) '   ==>>>   use a regional boost read in ', TRIM(cl_file), ' file'
372         IF(lwp) WRITE(numout,*) '           using enhancement factor of ', rn_boost
373         ! cl_varname is a coefficient in [0,1] giving where to apply the regional boost
374         CALL iom_open ( TRIM(cl_file), inum )
375         CALL iom_get  ( inum, jpdom_global, TRIM(cl_varname), zmsk_boost, 1 )
376         CALL iom_close( inum)
377         zmsk_boost(:,:) = 1._wp + rn_boost * zmsk_boost(:,:)
378         !
379      ELSE                          !* no boost:   boost factor = 1
380         zmsk_boost(:,:) = 1._wp
381      ENDIF
382      !                             !* mask outside ocean cavities area (top) or land area (bot)
383      IF(ll_top)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:) * (1. - tmask(:,:,1) )  ! none zero in ocean cavities only
384      IF(ll_bot)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:)                         ! x seafloor mask
385      !
386      l_log_not_linssh = .FALSE.    ! default definition
387      !
388      SELECT CASE( ndrg )
389      !
390      CASE( np_OFF  )            !==  No top/bottom friction  ==!   (pCdU = 0)
391         IF(lwp) WRITE(numout,*)
392         IF(lwp) WRITE(numout,*) '   ==>>>   ',TRIM(cd_topbot),' free-slip, friction set to zero'
393         !
394         l_zdfdrg = .FALSE.         ! no time variation of the drag: set it one for all
395         !
396         pCdU(:,:) = 0._wp
397         pCd0(:,:) = 0._wp
398         !
399      CASE( np_lin )             !==  linear friction  ==!   (pCdU = Cd0 * Uc0)
400         IF(lwp) WRITE(numout,*)
401         IF(lwp) WRITE(numout,*) '   ==>>>   linear ',TRIM(cd_topbot),' friction (constant coef = Cd0*Uc0 = ', rn_Cd0*rn_Uc0, ')'
402         !
403         l_zdfdrg = .FALSE.         ! no time variation of the Cd*|U| : set it one for all
404         !                     
405         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time drag coefficient (= mask (and boost) Cd0)
406         pCdU(:,:) = - pCd0(:,:) * rn_Uc0      !  using a constant velocity
407         !
408      CASE( np_non_lin )         !== non-linear friction  ==!   (pCd0 = Cd0 )
409         IF(lwp) WRITE(numout,*)
410         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' friction (propotional to module of the velocity)'
411         IF(lwp) WRITE(numout,*) '   with    a drag coefficient Cd0 = ', rn_Cd0, ', and'
412         IF(lwp) WRITE(numout,*) '           a background velocity module of (rn_ke0)^1/2 = ', SQRT(rn_ke0), 'm/s)'
413         !
414         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
415         !
416         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time proportionality coefficient (= mask (and boost) Cd0)
417         pCdU(:,:) = 0._wp                     ! 
418         !
419      CASE( np_loglayer )       !== logarithmic layer formulation of friction  ==!   (CdU = (vkarman log(z/z0))^2 |U| )
420         IF(lwp) WRITE(numout,*)
421         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' drag (propotional to module of the velocity)'
422         IF(lwp) WRITE(numout,*) '   with   a logarithmic Cd0 formulation Cd0 = ( vkarman log(z/z0) )^2 ,'
423         IF(lwp) WRITE(numout,*) '          a background velocity module of (rn_ke0)^1/2 = ', SQRT(pke0), 'm/s), '
424         IF(lwp) WRITE(numout,*) '          a logarithmic formulation: a roughness of ', pz0, ' meters,   and '
425         IF(lwp) WRITE(numout,*) '          a proportionality factor bounded by min/max values of ', pCdmin, pCdmax
426         !
427         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
428         !
429         IF( ln_linssh ) THEN       !* pCd0 = (v log(z/z0))^2   as velocity points have a fixed z position
430            IF(lwp) WRITE(numout,*)
431            IF(lwp) WRITE(numout,*) '   N.B.   linear free surface case, Cd0 computed one for all'
432            !
433            l_log_not_linssh = .FALSE.    !- don't update Cd at each time step
434            !
435            DO_2D( 1, 1, 1, 1 )              ! pCd0 = mask (and boosted) logarithmic drag coef.
436               zzz =  0.5_wp * e3t_0(ji,jj,k_mk(ji,jj))
437               zcd = (  vkarmn / LOG( zzz / rn_z0 )  )**2
438               pCd0(ji,jj) = zmsk_boost(ji,jj) * MIN(  MAX( rn_Cd0 , zcd ) , rn_Cdmax  )  ! rn_Cd0 < Cd0 < rn_Cdmax
439            END_2D
440         ELSE                       !* Cd updated at each time-step ==> pCd0 = mask * boost
441            IF(lwp) WRITE(numout,*)
442            IF(lwp) WRITE(numout,*) '   N.B.   non-linear free surface case, Cd0 updated at each time-step '
443            !
444            l_log_not_linssh = .TRUE.     ! compute the drag coef. at each time-step
445            !
446            pCd0(:,:) = zmsk_boost(:,:)
447         ENDIF
448         pCdU(:,:) = 0._wp          ! initialisation to zero (will be updated at each time step)
449         !
450      CASE DEFAULT
451         CALL ctl_stop( 'drg_init: bad flag value for ndrg ' )
452      END SELECT
453      !
454   END SUBROUTINE drg_init
455
456   !!======================================================================
457END MODULE zdfdrg
Note: See TracBrowser for help on using the repository browser.