New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tradmp.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA/tradmp.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE tradmp
2   !!======================================================================
3   !!                       ***  MODULE  tradmp  ***
4   !! Ocean physics: internal restoring trend on active tracers (T and S)
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (O. Marti, G. Madec)  Original code
7   !!                 ! 1992-06  (M. Imbard)  doctor norme
8   !!                 ! 1998-07  (M. Imbard, G. Madec) ORCA version
9   !!            7.0  ! 2001-02  (M. Imbard)  add distance to coast, Original code
10   !!            8.1  ! 2001-02  (G. Madec, E. Durand)  cleaning
11   !!  NEMO      1.0  ! 2002-08  (G. Madec, E. Durand)  free form + modules
12   !!            3.2  ! 2009-08  (G. Madec, C. Talandier)  DOCTOR norm for namelist parameter
13   !!            3.3  ! 2010-06  (C. Ethe, G. Madec) merge TRA-TRC
14   !!            3.4  ! 2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
15   !!            3.6  ! 2015-06  (T. Graham)  read restoring coefficient in a file
16   !!            3.7  ! 2015-10  (G. Madec)  remove useless trends arrays
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   tra_dmp_alloc : allocate tradmp arrays
21   !!   tra_dmp       : update the tracer trend with the internal damping
22   !!   tra_dmp_init  : initialization, namlist read, parameters control
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean: variables
25   USE dom_oce        ! ocean: domain variables
26   USE c1d            ! 1D vertical configuration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   USE zdf_oce        ! ocean: vertical physics
30   USE phycst         ! physical constants
31   USE dtatsd         ! data: temperature & salinity
32   USE zdfmxl         ! vertical physics: mixed layer depth
33   !
34   USE in_out_manager ! I/O manager
35   USE iom            ! XIOS
36   USE lib_mpp        ! MPP library
37   USE prtctl         ! Print control
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   tra_dmp        ! called by step.F90
44   PUBLIC   tra_dmp_init   ! called by nemogcm.F90
45
46   !                                           !!* Namelist namtra_dmp : T & S newtonian damping *
47   LOGICAL            , PUBLIC ::   ln_tradmp   !: internal damping flag
48   INTEGER            , PUBLIC ::   nn_zdmp     !: = 0/1/2 flag for damping in the mixed layer
49   CHARACTER(LEN=200) , PUBLIC ::   cn_resto    !: name of netcdf file containing restoration coefficient field
50   !
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   resto    !: restoring coeff. on T and S (s-1)
52
53   !! * Substitutions
54#  include "do_loop_substitute.h90"
55#  include "single_precision_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
58   !! $Id$
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   INTEGER FUNCTION tra_dmp_alloc()
64      !!----------------------------------------------------------------------
65      !!                ***  FUNCTION tra_dmp_alloc  ***
66      !!----------------------------------------------------------------------
67      ALLOCATE( resto(jpi,jpj,jpk), STAT= tra_dmp_alloc )
68      !
69      CALL mpp_sum ( 'tradmp', tra_dmp_alloc )
70      IF( tra_dmp_alloc > 0 )   CALL ctl_warn('tra_dmp_alloc: allocation of arrays failed')
71      !
72   END FUNCTION tra_dmp_alloc
73
74
75   SUBROUTINE tra_dmp( kt, Kbb, Kmm, pts, Krhs )
76      !!----------------------------------------------------------------------
77      !!                   ***  ROUTINE tra_dmp  ***
78      !!
79      !! ** Purpose :   Compute the tracer trend due to a newtonian damping
80      !!      of the tracer field towards given data field and add it to the
81      !!      general tracer trends.
82      !!
83      !! ** Method  :   Newtonian damping towards t_dta and s_dta computed
84      !!      and add to the general tracer trends:
85      !!                     ta = ta + resto * (t_dta - tb)
86      !!                     sa = sa + resto * (s_dta - sb)
87      !!         The trend is computed either throughout the water column
88      !!      (nlmdmp=0) or in area of weak vertical mixing (nlmdmp=1) or
89      !!      below the well mixed layer (nlmdmp=2)
90      !!
91      !! ** Action  : - tsa: tracer trends updated with the damping trend
92      !!----------------------------------------------------------------------
93      INTEGER,                                   INTENT(in   ) :: kt              ! ocean time-step index
94      INTEGER,                                   INTENT(in   ) :: Kbb, Kmm, Krhs  ! time level indices
95      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts             ! active tracers and RHS of tracer equation
96      !
97      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
98      REAL(dp), DIMENSION(A2D(nn_hls),jpk,jpts)     ::  zts_dta
99      REAL(wp), DIMENSION(:,:,:,:), ALLOCATABLE ::  ztrdts
100      !!----------------------------------------------------------------------
101      !
102      IF( ln_timing )   CALL timing_start('tra_dmp')
103      !
104      IF( l_trdtra )   THEN                    !* Save ta and sa trends
105         ALLOCATE( ztrdts(jpi,jpj,jpk,jpts) )
106         ztrdts(:,:,:,:) = pts(:,:,:,:,Krhs)
107      ENDIF
108      !                           !==  input T-S data at kt  ==!
109      CALL dta_tsd( kt, zts_dta )            ! read and interpolates T-S data at kt
110      !
111      SELECT CASE ( nn_zdmp )     !==  type of damping  ==!
112      !
113      CASE( 0 )                        !*  newtonian damping throughout the water column  *!
114         DO jn = 1, jpts
115            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
116               pts(ji,jj,jk,jn,Krhs) = pts(ji,jj,jk,jn,Krhs)           &
117                  &                  + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jn) - pts(ji,jj,jk,jn,Kbb) )
118            END_3D
119         END DO
120         !
121      CASE ( 1 )                       !*  no damping in the turbocline (avt > 5 cm2/s)  *!
122         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
123            IF( avt(ji,jj,jk) <= avt_c ) THEN
124               pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)   &
125                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - pts(ji,jj,jk,jp_tem,Kbb) )
126               pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)   &
127                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - pts(ji,jj,jk,jp_sal,Kbb) )
128            ENDIF
129         END_3D
130         !
131      CASE ( 2 )                       !*  no damping in the mixed layer   *!
132         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
133            IF( gdept(ji,jj,jk,Kmm) >= hmlp (ji,jj) ) THEN
134               pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)   &
135                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_tem) - pts(ji,jj,jk,jp_tem,Kbb) )
136               pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)   &
137                  &                      + resto(ji,jj,jk) * ( zts_dta(ji,jj,jk,jp_sal) - pts(ji,jj,jk,jp_sal,Kbb) )
138            ENDIF
139         END_3D
140         !
141      END SELECT
142      !
143      IF( l_trdtra )   THEN       ! trend diagnostic
144         ztrdts(:,:,:,:) = pts(:,:,:,:,Krhs) - ztrdts(:,:,:,:)
145         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_dmp, ztrdts(:,:,:,jp_tem) )
146         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_dmp, ztrdts(:,:,:,jp_sal) )
147         DEALLOCATE( ztrdts )
148      ENDIF
149      !                           ! Control print
150IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(pts(:,:,:,jp_tem,Krhs)), clinfo1=' dmp  - Ta: ', mask1=tmask, tab3d_2=REAL(pts(:,:,:,jp_sal,Krhs), wp), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
151
152      !
153      IF( ln_timing )   CALL timing_stop('tra_dmp')
154      !
155   END SUBROUTINE tra_dmp
156
157
158   SUBROUTINE tra_dmp_init
159      !!----------------------------------------------------------------------
160      !!                  ***  ROUTINE tra_dmp_init  ***
161      !!
162      !! ** Purpose :   Initialization for the newtonian damping
163      !!
164      !! ** Method  :   read the namtra_dmp namelist and check the parameters
165      !!----------------------------------------------------------------------
166      INTEGER ::   ios, imask   ! local integers
167      !
168      NAMELIST/namtra_dmp/ ln_tradmp, nn_zdmp, cn_resto
169      !!----------------------------------------------------------------------
170      !
171      READ  ( numnam_ref, namtra_dmp, IOSTAT = ios, ERR = 901)
172901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_dmp in reference namelist' )
173      !
174      READ  ( numnam_cfg, namtra_dmp, IOSTAT = ios, ERR = 902 )
175902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_dmp in configuration namelist' )
176      IF(lwm) WRITE ( numond, namtra_dmp )
177      !
178      IF(lwp) THEN                  ! Namelist print
179         WRITE(numout,*)
180         WRITE(numout,*) 'tra_dmp_init : T and S newtonian relaxation'
181         WRITE(numout,*) '~~~~~~~~~~~~'
182         WRITE(numout,*) '   Namelist namtra_dmp : set relaxation parameters'
183         WRITE(numout,*) '      Apply relaxation   or not       ln_tradmp   = ', ln_tradmp
184         WRITE(numout,*) '         mixed layer damping option      nn_zdmp  = ', nn_zdmp
185         WRITE(numout,*) '         Damping file name               cn_resto = ', cn_resto
186         WRITE(numout,*)
187      ENDIF
188      !
189      IF( ln_tradmp ) THEN
190         !                          ! Allocate arrays
191         IF( tra_dmp_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'tra_dmp_init: unable to allocate arrays' )
192         !
193         SELECT CASE (nn_zdmp)      ! Check values of nn_zdmp
194         CASE ( 0 )   ;   IF(lwp) WRITE(numout,*) '   tracer damping as specified by mask'
195         CASE ( 1 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the mixing layer (kz > 5 cm2/s)'
196         CASE ( 2 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the mixed  layer'
197         CASE DEFAULT
198            CALL ctl_stop('tra_dmp_init : wrong value of nn_zdmp')
199         END SELECT
200         !
201         !!TG: Initialisation of dtatsd - Would it be better to have dmpdta routine
202         !    so can damp to something other than intitial conditions files?
203         !!gm: In principle yes. Nevertheless, we can't anticipate demands that have never been formulated.
204         IF( .NOT.ln_tsd_dmp ) THEN
205            IF(lwp) WRITE(numout,*)
206            IF(lwp) WRITE(numout, *)  '   read T-S data not initialized, we force ln_tsd_dmp=T'
207            CALL dta_tsd_init( ld_tradmp=ln_tradmp )        ! forces the initialisation of T-S data
208         ENDIF
209         !                          ! Read in mask from file
210         CALL iom_open ( cn_resto, imask)
211         CALL iom_get  ( imask, jpdom_auto, 'resto', resto )
212         CALL iom_close( imask )
213      ENDIF
214      !
215   END SUBROUTINE tra_dmp_init
216
217   !!======================================================================
218END MODULE tradmp
Note: See TracBrowser for help on using the repository browser.