New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/TRA/traadv_fct.F90 @ 14200

Last change on this file since 14200 was 14200, checked in by mcastril, 4 years ago

Merging r14117 through r14199 into dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final
  • Property svn:keywords set to Id
File size: 36.2 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
84      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
86      !
87      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
88      REAL(wp) ::   ztra                                     ! local scalar
89      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
90      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
91      REAL(wp), DIMENSION(A2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
93      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
94      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
95      !!----------------------------------------------------------------------
96      !
97      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
98         IF( kt == kit000 )  THEN
99            IF(lwp) WRITE(numout,*)
100            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
101            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
102         ENDIF
103         !
104         l_trd = .FALSE.            ! set local switches
105         l_hst = .FALSE.
106         l_ptr = .FALSE.
107         ll_zAimp = .FALSE.
108         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
109         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
110         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
111            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
112         !
113      ENDIF
114
115      !! -- init to 0
116      zwi(:,:,:) = 0._wp
117      zwx(:,:,:) = 0._wp
118      zwy(:,:,:) = 0._wp
119      zwz(:,:,:) = 0._wp
120      ztu(:,:,:) = 0._wp
121      ztv(:,:,:) = 0._wp
122      zltu(:,:,:) = 0._wp
123      zltv(:,:,:) = 0._wp
124      ztw(:,:,:) = 0._wp
125      !
126      IF( l_trd .OR. l_hst )  THEN
127         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
128         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
129      ENDIF
130      !
131      IF( l_ptr ) THEN
132         ALLOCATE( zptry(A2D(nn_hls),jpk) )
133         zptry(:,:,:) = 0._wp
134      ENDIF
135      !
136      ! If adaptive vertical advection, check if it is needed on this PE at this time
137      IF( ln_zad_Aimp ) THEN
138         IF( MAXVAL( ABS( wi(A2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
139      END IF
140      ! If active adaptive vertical advection, build tridiagonal matrix
141      IF( ll_zAimp ) THEN
142         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
143         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
144            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
145            &                               / e3t(ji,jj,jk,Krhs)
146            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
147            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
148         END_3D
149      END IF
150      !
151      DO jn = 1, kjpt            !==  loop over the tracers  ==!
152         !
153         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
154         !                    !* upstream tracer flux in the i and j direction
155         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
156            ! upstream scheme
157            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
158            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
159            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
160            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
161            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
162            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
163         END_3D
164         !                               !* upstream tracer flux in the k direction *!
165         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
166            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
167            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
168            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
169         END_3D
170         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
171            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
172               DO_2D( 1, 1, 1, 1 )
173                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
174               END_2D
175            ELSE                                        ! no cavities: only at the ocean surface
176               DO_2D( 1, 1, 1, 1 )
177                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
178               END_2D
179            ENDIF
180         ENDIF
181         !
182         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
183            !                               ! total intermediate advective trends
184            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
185               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
186               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
187            !                               ! update and guess with monotonic sheme
188            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
189               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
190            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
191               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
192         END_3D
193
194         IF ( ll_zAimp ) THEN
195            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
196            !
197            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
198            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
199               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
200               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
201               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
202               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
203            END_3D
204            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
205               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
206                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
207            END_3D
208            !
209         END IF
210         !
211         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
212            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
213         END IF
214         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
215         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:)
216         !
217         !        !==  anti-diffusive flux : high order minus low order  ==!
218         !
219         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
220         !
221         CASE(  2  )                   !- 2nd order centered
222            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
223               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
224               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
225            END_3D
226            !
227         CASE(  4  )                   !- 4th order centered
228            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
229            zltv(:,:,jpk) = 0._wp
230            DO jk = 1, jpkm1                 ! Laplacian
231               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
232                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
233                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
234               END_2D
235               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
236                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
237                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
238               END_2D
239            END DO
240            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
241            !
242            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
243               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
244               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
245               !                                                        ! C4 minus upstream advective fluxes
246               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
247               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
248            END_3D
249            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
250            !
251         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
252            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
253            ztv(:,:,jpk) = 0._wp
254            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
255               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
256               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
257            END_3D
258            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
259            !
260            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
261            !
262            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
263               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
264               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
265               !                                                  ! C4 interpolation of T at u- & v-points (x2)
266               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
267               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
268               !                                                  ! C4 minus upstream advective fluxes
269               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
270               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
271            END_3D
272            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
273            !
274         END SELECT
275         !
276         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
277         !
278         CASE(  2  )                   !- 2nd order centered
279            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
280               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
281                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
282            END_3D
283            !
284         CASE(  4  )                   !- 4th order COMPACT
285            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
286            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
287               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
288            END_3D
289            !
290         END SELECT
291         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
292            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
293         ENDIF
294         !
295         IF (nn_hls.EQ.1) THEN
296            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
297         ELSE
298            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
299         END IF
300         !
301         IF (nn_hls.EQ.1) THEN
302            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
303         ELSE
304            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
305         END IF
306         !
307         IF ( ll_zAimp ) THEN
308            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
309               !                                                ! total intermediate advective trends
310               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
311                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
312                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
313               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
314            END_3D
315            !
316            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
317            !
318            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
319               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
320               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
321               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
322            END_3D
323         END IF
324         !
325         !        !==  monotonicity algorithm  ==!
326         !
327         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
328         !
329         !        !==  final trend with corrected fluxes  ==!
330         !
331         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
332            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
333               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
334               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
335            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
336            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
337         END_3D
338         !
339         IF ( ll_zAimp ) THEN
340            !
341            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
342            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
343               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
344               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
345               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
346               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
347            END_3D
348            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
349               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
350                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
351            END_3D
352         END IF
353         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
354            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
355            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
356            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
357            !
358            IF( l_trd ) THEN              ! trend diagnostics
359               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
360               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
361               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
362            ENDIF
363            !                             ! heat/salt transport
364            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
365            !
366         ENDIF
367         IF( l_ptr ) THEN              ! "Poleward" transports
368            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
369            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
370         ENDIF
371         !
372      END DO                     ! end of tracer loop
373      !
374      IF ( ll_zAimp ) THEN
375         DEALLOCATE( zwdia, zwinf, zwsup )
376      ENDIF
377      IF( l_trd .OR. l_hst ) THEN
378         DEALLOCATE( ztrdx, ztrdy, ztrdz )
379      ENDIF
380      IF( l_ptr ) THEN
381         DEALLOCATE( zptry )
382      ENDIF
383      !
384   END SUBROUTINE tra_adv_fct
385
386
387   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
388      !!---------------------------------------------------------------------
389      !!                    ***  ROUTINE nonosc  ***
390      !!
391      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
392      !!       scheme and the before field by a nonoscillatory algorithm
393      !!
394      !! **  Method  :   ... ???
395      !!       warning : pbef and paft must be masked, but the boundaries
396      !!       conditions on the fluxes are not necessary zalezak (1979)
397      !!       drange (1995) multi-dimensional forward-in-time and upstream-
398      !!       in-space based differencing for fluid
399      !!----------------------------------------------------------------------
400      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
401      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
402      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
403      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
404      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
405      !
406      INTEGER  ::   ji, jj, jk   ! dummy loop indices
407      INTEGER  ::   ikm1         ! local integer
408      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
409      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
410      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
411      !!----------------------------------------------------------------------
412      !
413      zbig  = 1.e+40_dp
414      zrtrn = 1.e-15_dp
415      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
416
417      ! Search local extrema
418      ! --------------------
419      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
420      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
421         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
422            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
423         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
424            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
425      END_3D
426
427      DO jk = 1, jpkm1
428         ikm1 = MAX(jk-1,1)
429         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
430
431            ! search maximum in neighbourhood
432            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
433               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
434               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
435               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
436
437            ! search minimum in neighbourhood
438            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
439               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
440               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
441               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
442
443            ! positive part of the flux
444            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
445               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
446               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
447
448            ! negative part of the flux
449            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
450               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
451               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
452
453            ! up & down beta terms
454            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
455            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
456            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
457         END_2D
458      END DO
459      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
460
461      ! 3. monotonic flux in the i & j direction (paa & pbb)
462      ! ----------------------------------------
463      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
464         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
465         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
466         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
467         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
468
469         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
470         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
471         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
472         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
473
474      ! monotonic flux in the k direction, i.e. pcc
475      ! -------------------------------------------
476         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
477         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
478         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
479         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
480      END_3D
481      !
482   END SUBROUTINE nonosc
483
484
485   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
486      !!----------------------------------------------------------------------
487      !!                  ***  ROUTINE interp_4th_cpt_org  ***
488      !!
489      !! **  Purpose :   Compute the interpolation of tracer at w-point
490      !!
491      !! **  Method  :   4th order compact interpolation
492      !!----------------------------------------------------------------------
493      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
494      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
495      !
496      INTEGER :: ji, jj, jk   ! dummy loop integers
497      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
498      !!----------------------------------------------------------------------
499
500      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
501         zwd (ji,jj,jk) = 4._wp
502         zwi (ji,jj,jk) = 1._wp
503         zws (ji,jj,jk) = 1._wp
504         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
505         !
506         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
507            zwd (ji,jj,jk) = 1._wp
508            zwi (ji,jj,jk) = 0._wp
509            zws (ji,jj,jk) = 0._wp
510            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
511         ENDIF
512      END_3D
513      !
514      jk = 2                                    ! Switch to second order centered at top
515      DO_2D( 1, 1, 1, 1 )
516         zwd (ji,jj,jk) = 1._wp
517         zwi (ji,jj,jk) = 0._wp
518         zws (ji,jj,jk) = 0._wp
519         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
520      END_2D
521      !
522      !                       !==  tridiagonal solve  ==!
523      DO_2D( 1, 1, 1, 1 )           ! first recurrence
524         zwt(ji,jj,2) = zwd(ji,jj,2)
525      END_2D
526      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
527         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
528      END_3D
529      !
530      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
531         pt_out(ji,jj,2) = zwrm(ji,jj,2)
532      END_2D
533      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
534         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
535      END_3D
536
537      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
538         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
539      END_2D
540      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
541         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
542      END_3D
543      !
544   END SUBROUTINE interp_4th_cpt_org
545
546
547   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
548      !!----------------------------------------------------------------------
549      !!                  ***  ROUTINE interp_4th_cpt  ***
550      !!
551      !! **  Purpose :   Compute the interpolation of tracer at w-point
552      !!
553      !! **  Method  :   4th order compact interpolation
554      !!----------------------------------------------------------------------
555      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
556      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
557      !
558      INTEGER ::   ji, jj, jk   ! dummy loop integers
559      INTEGER ::   ikt, ikb     ! local integers
560      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
561      !!----------------------------------------------------------------------
562      !
563      !                      !==  build the three diagonal matrix & the RHS  ==!
564      !
565      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
566         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
567         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
568         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
569         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
570            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
571      END_3D
572      !
573!!gm
574!      SELECT CASE( kbc )               !* boundary condition
575!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
576!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
577!      END SELECT
578!!gm
579      !
580      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
581         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
582      END IF
583      !
584      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
585         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
586         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
587         !
588         zwd (ji,jj,ikt) = 1._wp          ! top
589         zwi (ji,jj,ikt) = 0._wp
590         zws (ji,jj,ikt) = 0._wp
591         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
592         !
593         zwd (ji,jj,ikb) = 1._wp          ! bottom
594         zwi (ji,jj,ikb) = 0._wp
595         zws (ji,jj,ikb) = 0._wp
596         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )
597      END_2D
598      !
599      !                       !==  tridiagonal solver  ==!
600      !
601      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
602         zwt(ji,jj,2) = zwd(ji,jj,2)
603      END_2D
604      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
605         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
606      END_3D
607      !
608      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
609         pt_out(ji,jj,2) = zwrm(ji,jj,2)
610      END_2D
611      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
612         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
613      END_3D
614
615      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
616         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
617      END_2D
618      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
619         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
620      END_3D
621      !
622   END SUBROUTINE interp_4th_cpt
623
624
625   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
626      !!----------------------------------------------------------------------
627      !!                  ***  ROUTINE tridia_solver  ***
628      !!
629      !! **  Purpose :   solve a symmetric 3diagonal system
630      !!
631      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
632      !!
633      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
634      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
635      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
636      !!             (        ...          )( ... )   ( ...  )
637      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
638      !!
639      !!        M is decomposed in the product of an upper and lower triangular matrix.
640      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
641      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
642      !!        The solution is pta.
643      !!        The 3d array zwt is used as a work space array.
644      !!----------------------------------------------------------------------
645      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
646      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
647      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
648      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
649      !                                                             ! =0 pt at t-level
650      INTEGER ::   ji, jj, jk   ! dummy loop integers
651      INTEGER ::   kstart       ! local indices
652      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
653      !!----------------------------------------------------------------------
654      !
655      kstart =  1  + klev
656      !
657      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
658         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
659      END_2D
660      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
661         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
662      END_3D
663      !
664      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
665         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
666      END_2D
667      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
668         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
669      END_3D
670
671      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
672         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
673      END_2D
674      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
675         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
676      END_3D
677      !
678   END SUBROUTINE tridia_solver
679
680   !!======================================================================
681END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.