1 | MODULE traadv_cen |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE traadv_cen *** |
---|
4 | !! Ocean tracers: advective trend (2nd/4th order centered) |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.7 ! 2014-05 (G. Madec) original code |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! tra_adv_cen : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order) |
---|
11 | !! NB: on the vertical it is actually a 4th order COMPACT scheme which is used |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE dom_oce ! ocean space and time domain |
---|
14 | USE eosbn2 ! equation of state |
---|
15 | USE traadv_fct ! acces to routine interp_4th_cpt |
---|
16 | USE trd_oce ! trends: ocean variables |
---|
17 | USE trdtra ! trends manager: tracers |
---|
18 | USE diaptr ! poleward transport diagnostics |
---|
19 | USE diaar5 ! AR5 diagnostics |
---|
20 | ! |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE iom ! IOM library |
---|
23 | USE trc_oce ! share passive tracers/Ocean variables |
---|
24 | USE lib_mpp ! MPP library |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC tra_adv_cen ! called by traadv.F90 |
---|
30 | |
---|
31 | REAL(wp) :: r1_6 = 1._wp / 6._wp ! =1/6 |
---|
32 | |
---|
33 | LOGICAL :: l_trd ! flag to compute trends |
---|
34 | LOGICAL :: l_ptr ! flag to compute poleward transport |
---|
35 | LOGICAL :: l_hst ! flag to compute heat/salt transport |
---|
36 | |
---|
37 | !! * Substitutions |
---|
38 | # include "do_loop_substitute.h90" |
---|
39 | # include "domzgr_substitute.h90" |
---|
40 | # include "single_precision_substitute.h90" |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
43 | !! $Id$ |
---|
44 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | CONTAINS |
---|
47 | |
---|
48 | SUBROUTINE tra_adv_cen( kt, kit000, cdtype, pU, pV, pW, & |
---|
49 | & Kmm, pt, kjpt, Krhs, kn_cen_h, kn_cen_v ) |
---|
50 | !!---------------------------------------------------------------------- |
---|
51 | !! *** ROUTINE tra_adv_cen *** |
---|
52 | !! |
---|
53 | !! ** Purpose : Compute the now trend due to the advection of tracers |
---|
54 | !! and add it to the general trend of passive tracer equations. |
---|
55 | !! |
---|
56 | !! ** Method : The advection is evaluated by a 2nd or 4th order scheme |
---|
57 | !! using now fields (leap-frog scheme). |
---|
58 | !! kn_cen_h = 2 ==>> 2nd order centered scheme on the horizontal |
---|
59 | !! = 4 ==>> 4th order - - - - |
---|
60 | !! kn_cen_v = 2 ==>> 2nd order centered scheme on the vertical |
---|
61 | !! = 4 ==>> 4th order COMPACT scheme - - |
---|
62 | !! |
---|
63 | !! ** Action : - update pt(:,:,:,:,Krhs) with the now advective tracer trends |
---|
64 | !! - send trends to trdtra module for further diagnostcs (l_trdtra=T) |
---|
65 | !! - poleward advective heat and salt transport (l_diaptr=T) |
---|
66 | !!---------------------------------------------------------------------- |
---|
67 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
68 | INTEGER , INTENT(in ) :: Kmm, Krhs ! ocean time level indices |
---|
69 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
70 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
71 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
72 | INTEGER , INTENT(in ) :: kn_cen_h ! =2/4 (2nd or 4th order scheme) |
---|
73 | INTEGER , INTENT(in ) :: kn_cen_v ! =2/4 (2nd or 4th order scheme) |
---|
74 | ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support) |
---|
75 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pU, pV, pW ! 3 ocean volume flux components |
---|
76 | REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! tracers and RHS of tracer equation |
---|
77 | ! |
---|
78 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
79 | INTEGER :: ierr ! local integer |
---|
80 | REAL(wp) :: zC2t_u, zC4t_u ! local scalars |
---|
81 | REAL(wp) :: zC2t_v, zC4t_v ! - - |
---|
82 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zwx, zwy, zwz, ztu, ztv, ztw |
---|
83 | !!---------------------------------------------------------------------- |
---|
84 | ! |
---|
85 | IF( ntile == 0 .OR. ntile == 1 ) THEN ! Do only on the first tile |
---|
86 | IF( kt == kit000 ) THEN |
---|
87 | IF(lwp) WRITE(numout,*) |
---|
88 | IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v |
---|
89 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ ' |
---|
90 | ENDIF |
---|
91 | ! ! set local switches |
---|
92 | l_trd = .FALSE. |
---|
93 | l_hst = .FALSE. |
---|
94 | l_ptr = .FALSE. |
---|
95 | IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE. |
---|
96 | IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) ) l_ptr = .TRUE. |
---|
97 | IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
---|
98 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) ) l_hst = .TRUE. |
---|
99 | ENDIF |
---|
100 | ! |
---|
101 | ! |
---|
102 | zwz(:,:, 1 ) = 0._wp ! surface & bottom vertical flux set to zero for all tracers |
---|
103 | zwz(:,:,jpk) = 0._wp |
---|
104 | ! |
---|
105 | DO jn = 1, kjpt !== loop over the tracers ==! |
---|
106 | ! |
---|
107 | SELECT CASE( kn_cen_h ) !-- Horizontal fluxes --! |
---|
108 | ! |
---|
109 | CASE( 2 ) !* 2nd order centered |
---|
110 | DO_3D( 1, 0, 1, 0, 1, jpkm1 ) |
---|
111 | zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj ,jk,jn,Kmm) ) |
---|
112 | zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji ,jj+1,jk,jn,Kmm) ) |
---|
113 | END_3D |
---|
114 | ! |
---|
115 | CASE( 4 ) !* 4th order centered |
---|
116 | ztu(:,:,jpk) = 0._wp ! Bottom value : flux set to zero |
---|
117 | ztv(:,:,jpk) = 0._wp |
---|
118 | DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 ) ! masked gradient |
---|
119 | ztu(ji,jj,jk) = ( pt(ji+1,jj ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk) |
---|
120 | ztv(ji,jj,jk) = ( pt(ji ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk) |
---|
121 | END_3D |
---|
122 | IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_cen', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp ) ! Lateral boundary cond. |
---|
123 | ! |
---|
124 | DO_3D( nn_hls-1, 0, nn_hls-1, 0, 1, jpkm1 ) ! Horizontal advective fluxes |
---|
125 | zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj ,jk,jn,Kmm) ! C2 interpolation of T at u- & v-points (x2) |
---|
126 | zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji ,jj+1,jk,jn,Kmm) |
---|
127 | ! ! C4 interpolation of T at u- & v-points (x2) |
---|
128 | zC4t_u = zC2t_u + r1_6 * ( ztu(ji-1,jj,jk) - ztu(ji+1,jj,jk) ) |
---|
129 | zC4t_v = zC2t_v + r1_6 * ( ztv(ji,jj-1,jk) - ztv(ji,jj+1,jk) ) |
---|
130 | ! ! C4 fluxes |
---|
131 | zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * zC4t_u |
---|
132 | zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * zC4t_v |
---|
133 | END_3D |
---|
134 | IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_cen', zwx, 'U', -1._wp , zwy, 'V', -1._wp ) |
---|
135 | ! |
---|
136 | CASE DEFAULT |
---|
137 | CALL ctl_stop( 'traadv_cen: wrong value for nn_cen' ) |
---|
138 | END SELECT |
---|
139 | ! |
---|
140 | SELECT CASE( kn_cen_v ) !-- Vertical fluxes --! (interior) |
---|
141 | ! |
---|
142 | CASE( 2 ) !* 2nd order centered |
---|
143 | DO_3D( 0, 0, 0, 0, 2, jpk ) |
---|
144 | zwz(ji,jj,jk) = 0.5 * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) ) * wmask(ji,jj,jk) |
---|
145 | END_3D |
---|
146 | ! |
---|
147 | CASE( 4 ) !* 4th order compact |
---|
148 | CALL interp_4th_cpt( CASTWP(pt(:,:,:,jn,Kmm)) , ztw ) ! ztw = interpolated value of T at w-point |
---|
149 | DO_3D( 0, 0, 0, 0, 2, jpkm1 ) |
---|
150 | zwz(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk) |
---|
151 | END_3D |
---|
152 | ! |
---|
153 | END SELECT |
---|
154 | ! |
---|
155 | IF( ln_linssh ) THEN !* top value (linear free surf. only as zwz is multiplied by wmask) |
---|
156 | IF( ln_isfcav ) THEN ! ice-shelf cavities (top of the ocean) |
---|
157 | DO_2D( 1, 1, 1, 1 ) |
---|
158 | zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kmm) |
---|
159 | END_2D |
---|
160 | ELSE ! no ice-shelf cavities (only ocean surface) |
---|
161 | DO_2D( 1, 1, 1, 1 ) |
---|
162 | zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kmm) |
---|
163 | END_2D |
---|
164 | ENDIF |
---|
165 | ENDIF |
---|
166 | ! |
---|
167 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) !-- Divergence of advective fluxes --! |
---|
168 | pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) & |
---|
169 | & - ( zwx(ji,jj,jk) - zwx(ji-1,jj ,jk ) & |
---|
170 | & + zwy(ji,jj,jk) - zwy(ji ,jj-1,jk ) & |
---|
171 | & + zwz(ji,jj,jk) - zwz(ji ,jj ,jk+1) ) & |
---|
172 | & * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm) |
---|
173 | END_3D |
---|
174 | ! ! trend diagnostics |
---|
175 | IF( l_trd ) THEN |
---|
176 | CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, CASTWP(pt(:,:,:,jn,Kmm)) ) |
---|
177 | CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, CASTWP(pt(:,:,:,jn,Kmm)) ) |
---|
178 | CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwz, pW, CASTWP(pt(:,:,:,jn,Kmm)) ) |
---|
179 | ENDIF |
---|
180 | ! ! "Poleward" heat and salt transports |
---|
181 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) ) |
---|
182 | ! ! heat and salt transport |
---|
183 | IF( l_hst ) CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) ) |
---|
184 | ! |
---|
185 | END DO |
---|
186 | ! |
---|
187 | END SUBROUTINE tra_adv_cen |
---|
188 | |
---|
189 | !!====================================================================== |
---|
190 | END MODULE traadv_cen |
---|
191 | |
---|