New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN/dynzdf.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!            4.0  !  2017-06  (G. Madec) remove the explicit time-stepping option + avm at t-point
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_zdf       : compute the after velocity through implicit calculation of vertical mixing
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain variables
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfdrg         ! vertical physics: top/bottom drag coef.
20   USE dynadv    ,ONLY: ln_dynadv_vec    ! dynamics: advection form
21   USE dynldf_iso,ONLY: akzu, akzv       ! dynamics: vertical component of rotated lateral mixing
22   USE ldfdyn         ! lateral diffusion: eddy viscosity coef. and type of operator
23   USE trd_oce        ! trends: ocean variables
24   USE trddyn         ! trend manager: dynamics
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf   !  routine called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "domzgr_substitute.h90"
41#  include "single_precision_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48   
49   SUBROUTINE dyn_zdf( kt, Kbb, Kmm, Krhs, puu, pvv, Kaa )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE dyn_zdf  ***
52      !!
53      !! ** Purpose :   compute the trend due to the vert. momentum diffusion
54      !!              together with the Leap-Frog time stepping using an
55      !!              implicit scheme.
56      !!
57      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
58      !!         u(after) =         u(before) + 2*dt *       u(rhs)                vector form or linear free surf.
59      !!         u(after) = ( e3u_b*u(before) + 2*dt * e3u_n*u(rhs) ) / e3u_after   otherwise
60      !!               - update the after velocity with the implicit vertical mixing.
61      !!      This requires to solver the following system:
62      !!         u(after) = u(after) + 1/e3u_after  dk+1[ mi(avm) / e3uw_after dk[ua] ]
63      !!      with the following surface/top/bottom boundary condition:
64      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
65      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfdrg.F90)
66      !!
67      !! ** Action :   (puu(:,:,:,Kaa),pvv(:,:,:,Kaa))   after velocity
68      !!---------------------------------------------------------------------
69      INTEGER                             , INTENT( in )  ::  kt                  ! ocean time-step index
70      INTEGER                             , INTENT( in )  ::  Kbb, Kmm, Krhs, Kaa ! ocean time level indices
71      REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv            ! ocean velocities and RHS of momentum equation
72      !
73      INTEGER  ::   ji, jj, jk         ! dummy loop indices
74      INTEGER  ::   iku, ikv           ! local integers
75      REAL(wp) ::   zzwi, ze3ua, zdt   ! local scalars
76      REAL(wp) ::   zzws, ze3va        !   -      -
77      REAL(wp) ::   z1_e3ua, z1_e3va   !   -      -
78      REAL(wp) ::   zWu , zWv          !   -      -
79      REAL(wp) ::   zWui, zWvi         !   -      -
80      REAL(wp) ::   zWus, zWvs         !   -      -
81      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::  zwi, zwd, zws   ! 3D workspace
82      REAL(dp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv   !  -      -
83      !!---------------------------------------------------------------------
84      !
85      IF( ln_timing )   CALL timing_start('dyn_zdf')
86      !
87      IF( kt == nit000 ) THEN       !* initialization
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
91         !
92         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
93         ELSE                   ;    r_vvl = 1._wp
94         ENDIF
95      ENDIF
96      !                             !* explicit top/bottom drag case
97      IF( .NOT.ln_drgimp )   CALL zdf_drg_exp( kt, Kmm, puu(:,:,:,Kbb), pvv(:,:,:,Kbb), puu(:,:,:,Krhs), pvv(:,:,:,Krhs) )  ! add top/bottom friction trend to (puu(Kaa),pvv(Kaa))
98      !
99      !
100      IF( l_trddyn )   THEN         !* temporary save of ta and sa trends
101         ALLOCATE( ztrdu(jpi,jpj,jpk), ztrdv(jpi,jpj,jpk) ) 
102         ztrdu(:,:,:) = puu(:,:,:,Krhs)
103         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
104      ENDIF
105      !
106      !              !==  RHS: Leap-Frog time stepping on all trends but the vertical mixing  ==!   (put in puu(:,:,:,Kaa),pvv(:,:,:,Kaa))
107      !
108      !                    ! time stepping except vertical diffusion
109      IF( ln_dynadv_vec .OR. ln_linssh ) THEN   ! applied on velocity
110         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
111            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kbb) + rDt * puu(ji,jj,jk,Krhs) ) * umask(ji,jj,jk)
112            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kbb) + rDt * pvv(ji,jj,jk,Krhs) ) * vmask(ji,jj,jk)
113         END_3D
114      ELSE                                      ! applied on thickness weighted velocity
115         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
116            puu(ji,jj,jk,Kaa) = (         e3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb )  &
117               &                  + rDt * e3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Krhs)  ) &
118               &                        / e3u(ji,jj,jk,Kaa) * umask(ji,jj,jk)
119            pvv(ji,jj,jk,Kaa) = (         e3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb )  &
120               &                  + rDt * e3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Krhs)  ) &
121               &                        / e3v(ji,jj,jk,Kaa) * vmask(ji,jj,jk)
122         END_3D
123      ENDIF
124      !                    ! add top/bottom friction
125      !     With split-explicit free surface, barotropic stress is treated explicitly Update velocities at the bottom.
126      !     J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
127      !                not lead to the effective stress seen over the whole barotropic loop.
128      !     G. Madec : in linear free surface, e3u(:,:,:,Kaa) = e3u(:,:,:,Kmm) = e3u_0, so systematic use of e3u(:,:,:,Kaa)
129      IF( ln_drgimp .AND. ln_dynspg_ts ) THEN
130         DO_3D( 0, 0, 0, 0, 1, jpkm1 )      ! remove barotropic velocities
131            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - uu_b(ji,jj,Kaa) ) * umask(ji,jj,jk)
132            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - vv_b(ji,jj,Kaa) ) * vmask(ji,jj,jk)
133         END_3D
134         DO_2D( 0, 0, 0, 0 )      ! Add bottom/top stress due to barotropic component only
135            iku = mbku(ji,jj)         ! ocean bottom level at u- and v-points
136            ikv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
137            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
138               &             + r_vvl   * e3u(ji,jj,iku,Kaa)
139            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
140               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
141            puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + rDt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
142            pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + rDt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
143         END_2D
144         IF( ln_isfcav.OR.ln_drgice_imp ) THEN    ! Ocean cavities (ISF)
145            DO_2D( 0, 0, 0, 0 )
146               iku = miku(ji,jj)         ! top ocean level at u- and v-points
147               ikv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
148               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
149                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)
150               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
151                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
152               puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + rDt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
153               pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + rDt * 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
154            END_2D
155         END IF
156      ENDIF
157      !
158      !              !==  Vertical diffusion on u  ==!
159      !
160      !                    !* Matrix construction
161      zdt = rDt * 0.5
162      IF( ln_zad_Aimp ) THEN   !!
163         SELECT CASE( nldf_dyn )
164         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
165            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
166               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
167                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
168               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
169                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
170               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
171                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
172               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
173               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
174               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWui, 0._wp ) 
175               zws(ji,jj,jk) = zzws - zdt * MAX( zWus, 0._wp )
176               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zdt * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
177            END_3D
178         CASE DEFAULT               ! iso-level lateral mixing
179            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
180               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &    ! after scale factor at U-point
181                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)
182               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )   &
183                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
184               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )   &
185                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
186               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
187               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
188               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWui, 0._wp )
189               zws(ji,jj,jk) = zzws - zdt * MAX( zWus, 0._wp )
190               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zdt * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
191            END_3D
192         END SELECT
193         DO_2D( 0, 0, 0, 0 )     !* Surface boundary conditions
194            zwi(ji,jj,1) = 0._wp
195            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
196               &             + r_vvl   * e3u(ji,jj,1,Kaa)
197            zzws = - zdt * ( avm(ji+1,jj,2) + avm(ji  ,jj,2) )   &
198               &         / ( ze3ua * e3uw(ji,jj,2,Kmm) ) * wumask(ji,jj,2)
199            zWus = ( wi(ji  ,jj,2) +  wi(ji+1,jj,2) ) / ze3ua
200            zws(ji,jj,1 ) = zzws - zdt * MAX( zWus, 0._wp )
201            zwd(ji,jj,1 ) = 1._wp - zzws - zdt * ( MIN( zWus, 0._wp ) )
202         END_2D
203      ELSE
204         SELECT CASE( nldf_dyn )
205         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
206            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
207               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
208                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
209               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
210                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
211               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
212                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
213               zwi(ji,jj,jk) = zzwi
214               zws(ji,jj,jk) = zzws
215               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
216            END_3D
217         CASE DEFAULT               ! iso-level lateral mixing
218            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
219               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
220                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
221               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )    &
222                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
223               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )    &
224                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
225               zwi(ji,jj,jk) = zzwi
226               zws(ji,jj,jk) = zzws
227               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
228            END_3D
229         END SELECT
230         DO_2D( 0, 0, 0, 0 )     !* Surface boundary conditions
231            zwi(ji,jj,1) = 0._wp
232            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
233         END_2D
234      ENDIF
235      !
236      !
237      !              !==  Apply semi-implicit bottom friction  ==!
238      !
239      !     Only needed for semi-implicit bottom friction setup. The explicit
240      !     bottom friction has been included in "u(v)a" which act as the R.H.S
241      !     column vector of the tri-diagonal matrix equation
242      !
243      IF ( ln_drgimp ) THEN      ! implicit bottom friction
244         DO_2D( 0, 0, 0, 0 )
245            iku = mbku(ji,jj)       ! ocean bottom level at u- and v-points
246            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
247               &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
248            zwd(ji,jj,iku) = zwd(ji,jj,iku) - rDt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / ze3ua
249         END_2D
250         IF ( ln_isfcav.OR.ln_drgice_imp ) THEN   ! top friction (always implicit)
251            DO_2D( 0, 0, 0, 0 )
252               !!gm   top Cd is masked (=0 outside cavities) no need of test on mik>=2  ==>> it has been suppressed
253               iku = miku(ji,jj)       ! ocean top level at u- and v-points
254               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
255                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
256               zwd(ji,jj,iku) = zwd(ji,jj,iku) - rDt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / ze3ua
257            END_2D
258         END IF
259      ENDIF
260      !
261      ! Matrix inversion starting from the first level
262      !-----------------------------------------------------------------------
263      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
264      !
265      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
266      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
267      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
268      !        (        ...               )( ...  ) ( ...  )
269      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
270      !
271      !   m is decomposed in the product of an upper and a lower triangular matrix
272      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
273      !   The solution (the after velocity) is in puu(:,:,:,Kaa)
274      !-----------------------------------------------------------------------
275      !
276      DO_3D( 0, 0, 0, 0, 2, jpkm1 )   !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
277         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
278      END_3D
279      !
280      DO_2D( 0, 0, 0, 0 )             !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
281         ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
282            &             + r_vvl   * e3u(ji,jj,1,Kaa) 
283         puu(ji,jj,1,Kaa) = puu(ji,jj,1,Kaa) + rDt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
284            &                                      / ( ze3ua * rho0 ) * umask(ji,jj,1) 
285      END_2D
286      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
287         puu(ji,jj,jk,Kaa) = puu(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * puu(ji,jj,jk-1,Kaa)
288      END_3D
289      !
290      DO_2D( 0, 0, 0, 0 )             !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
291         puu(ji,jj,jpkm1,Kaa) = puu(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
292      END_2D
293      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
294         puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - zws(ji,jj,jk) * puu(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
295      END_3D
296      !
297      !              !==  Vertical diffusion on v  ==!
298      !
299      !                       !* Matrix construction
300      zdt = rDt * 0.5
301      IF( ln_zad_Aimp ) THEN   !!
302         SELECT CASE( nldf_dyn )
303         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzv)
304            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
305               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
306                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
307               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
308                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
309               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
310                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
311               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
312               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
313               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWvi, 0._wp )
314               zws(ji,jj,jk) = zzws - zdt * MAX( zWvs, 0._wp )
315               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zdt * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
316            END_3D
317         CASE DEFAULT               ! iso-level lateral mixing
318            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
319               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
320                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
321               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
322                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
323               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
324                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
325               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
326               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
327               zwi(ji,jj,jk) = zzwi  + zdt * MIN( zWvi, 0._wp )
328               zws(ji,jj,jk) = zzws  - zdt * MAX( zWvs, 0._wp )
329               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zdt * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
330            END_3D
331         END SELECT
332         DO_2D( 0, 0, 0, 0 )   !* Surface boundary conditions
333            zwi(ji,jj,1) = 0._wp
334            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
335               &             + r_vvl   * e3v(ji,jj,1,Kaa)
336            zzws = - zdt * ( avm(ji,jj+1,2) + avm(ji,jj,2) )    &
337               &         / ( ze3va * e3vw(ji,jj,2,Kmm) ) * wvmask(ji,jj,2)
338            zWvs = ( wi(ji,jj  ,2) +  wi(ji,jj+1,2) ) / ze3va
339            zws(ji,jj,1 ) = zzws - zdt * MAX( zWvs, 0._wp )
340            zwd(ji,jj,1 ) = 1._wp - zzws - zdt * ( MIN( zWvs, 0._wp ) )
341         END_2D
342      ELSE
343         SELECT CASE( nldf_dyn )
344         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
345            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
346               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
347                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
348               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
349                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
350               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
351                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
352               zwi(ji,jj,jk) = zzwi
353               zws(ji,jj,jk) = zzws
354               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
355            END_3D
356         CASE DEFAULT               ! iso-level lateral mixing
357            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
358               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
359                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
360               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
361                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
362               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
363                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
364               zwi(ji,jj,jk) = zzwi
365               zws(ji,jj,jk) = zzws
366               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
367            END_3D
368         END SELECT
369         DO_2D( 0, 0, 0, 0 )        !* Surface boundary conditions
370            zwi(ji,jj,1) = 0._wp
371            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
372         END_2D
373      ENDIF
374      !
375      !              !==  Apply semi-implicit top/bottom friction  ==!
376      !
377      !     Only needed for semi-implicit bottom friction setup. The explicit
378      !     bottom friction has been included in "u(v)a" which act as the R.H.S
379      !     column vector of the tri-diagonal matrix equation
380      !
381      IF( ln_drgimp ) THEN
382         DO_2D( 0, 0, 0, 0 )
383            ikv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
384            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
385               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
386            zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - rDt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / ze3va           
387         END_2D
388         IF ( ln_isfcav.OR.ln_drgice_imp ) THEN
389            DO_2D( 0, 0, 0, 0 )
390               ikv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
391               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
392                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
393               zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - rDt * 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / ze3va
394            END_2D
395         ENDIF
396      ENDIF
397
398      ! Matrix inversion
399      !-----------------------------------------------------------------------
400      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
401      !
402      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
403      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
404      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
405      !        (        ...               )( ...  ) ( ...  )
406      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
407      !
408      !   m is decomposed in the product of an upper and lower triangular matrix
409      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
410      !   The solution (after velocity) is in 2d array va
411      !-----------------------------------------------------------------------
412      !
413      DO_3D( 0, 0, 0, 0, 2, jpkm1 )   !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
414         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
415      END_3D
416      !
417      DO_2D( 0, 0, 0, 0 )             !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
418         ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
419            &             + r_vvl   * e3v(ji,jj,1,Kaa) 
420         pvv(ji,jj,1,Kaa) = pvv(ji,jj,1,Kaa) + rDt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
421            &                                      / ( ze3va * rho0 ) * vmask(ji,jj,1) 
422      END_2D
423      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
424         pvv(ji,jj,jk,Kaa) = pvv(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * pvv(ji,jj,jk-1,Kaa)
425      END_3D
426      !
427      DO_2D( 0, 0, 0, 0 )             !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
428         pvv(ji,jj,jpkm1,Kaa) = pvv(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
429      END_2D
430      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
431         pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - zws(ji,jj,jk) * pvv(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
432      END_3D
433      !
434      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
435         ztrdu(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) ) / rDt - ztrdu(:,:,:)
436         ztrdv(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) ) / rDt - ztrdv(:,:,:)
437         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt, Kmm )
438         DEALLOCATE( ztrdu, ztrdv ) 
439      ENDIF
440      !                                          ! print mean trends (used for debugging)
441      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(puu(:,:,:,Kaa)), clinfo1=' zdf  - Ua: ', mask1=umask,               &
442         &                                  tab3d_2=CASTWP(pvv(:,:,:,Kaa)), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
443         !
444      IF( ln_timing )   CALL timing_stop('dyn_zdf')
445      !
446   END SUBROUTINE dyn_zdf
447
448   !!==============================================================================
449END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.