New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r14116_HPC-04_mcastril_Mixed_Precision_implementation_final/src/OCE/DYN/dynadv_cen2.F90 @ 14219

Last change on this file since 14219 was 14219, checked in by mcastril, 4 years ago

Add Mixed Precision support by Oriol Tintó
  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "do_loop_substitute.h90"
30#  include "domzgr_substitute.h90"
31#  include "single_precision_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE dyn_adv_cen2  ***
42      !!
43      !! ** Purpose :   Compute the now momentum advection trend in flux form
44      !!              and the general trend of the momentum equation.
45      !!
46      !! ** Method  :   Trend evaluated using now fields (centered in time)
47      !!
48      !! ** Action  :   (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) updated with the now vorticity term trend
49      !!----------------------------------------------------------------------
50      INTEGER                             , INTENT( in )  ::  kt           ! ocean time-step index
51      INTEGER                             , INTENT( in )  ::  Kmm, Krhs    ! ocean time level indices
52      REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv     ! ocean velocities and RHS of momentum equation
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zfu_t, zfu_uw
56      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfu_f, zfu
57      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zfv_t, zfv_vw
58      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zfv_f, zfv, zfw
59      !!----------------------------------------------------------------------
60      !
61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
64         WRITE(numout,*) '~~~~~~~~~~~~'
65      ENDIF
66      !
67      IF( l_trddyn ) THEN           ! trends: store the input trends
68         zfu_uw(:,:,:) = puu(:,:,:,Krhs)
69         zfv_vw(:,:,:) = pvv(:,:,:,Krhs)
70      ENDIF
71      !
72      !                             !==  Horizontal advection  ==!
73      !
74      DO jk = 1, jpkm1                    ! horizontal transport
75         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm)
76         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm)
77         DO_2D( 1, 0, 1, 0 )              ! horizontal momentum fluxes (at T- and F-point)
78            zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj  ,jk,Kmm) )
79            zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji  ,jj+1,jk,Kmm) )
80            zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj  ,jk,Kmm) )
81            zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji  ,jj+1,jk,Kmm) )
82         END_2D
83         DO_2D( 0, 0, 0, 0 )              ! divergence of horizontal momentum fluxes
84            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
85               &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj)   &
86               &                           / e3u(ji,jj,jk,Kmm)
87            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
88               &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj)   &
89               &                           / e3v(ji,jj,jk,Kmm)
90         END_2D
91      END DO
92      !
93      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
94         zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:)
95         zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:)
96         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm )
97         zfu_t(:,:,:) = puu(:,:,:,Krhs)
98         zfv_t(:,:,:) = pvv(:,:,:,Krhs)
99      ENDIF
100      !
101      !                             !==  Vertical advection  ==!
102      !
103      DO_2D( 0, 0, 0, 0 )                 ! surface/bottom advective fluxes set to zero
104         zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
105         zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
106      END_2D
107      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
108         DO_2D( 0, 0, 0, 0 )
109            zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji+1,jj) * ww(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
110            zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji,jj+1) * ww(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
111         END_2D
112      ENDIF
113      DO jk = 2, jpkm1                    ! interior advective fluxes
114         DO_2D( 0, 1, 0, 1 )                  ! 1/4 * Vertical transport
115            zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk)
116         END_2D
117         DO_2D( 0, 0, 0, 0 )
118            zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) )
119            zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) )
120         END_2D
121      END DO
122      DO_3D( 0, 0, 0, 0, 1, jpkm1 )       ! divergence of vertical momentum flux divergence
123         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
124            &                                      / e3u(ji,jj,jk,Kmm)
125         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
126            &                                      / e3v(ji,jj,jk,Kmm)
127      END_3D
128      !
129      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
130         zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:)
131         zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:)
132         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm )
133      ENDIF
134      !                                   ! Control print
135      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(puu(:,:,:,Krhs)), clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
136         &                                  tab3d_2=CASTWP(pvv(:,:,:,Krhs)), clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
137      !
138   END SUBROUTINE dyn_adv_cen2
139
140   !!==============================================================================
141END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.