1 | MODULE bdydyn |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE bdydyn *** |
---|
4 | !! Unstructured Open Boundary Cond. : Apply boundary conditions to velocities |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2005-02 (J. Chanut, A. Sellar) Original code |
---|
7 | !! - ! 2007-07 (D. Storkey) Move Flather implementation to separate routine. |
---|
8 | !! 3.0 ! 2008-04 (NEMO team) add in the reference version |
---|
9 | !! 3.2 ! 2008-04 (R. Benshila) consider velocity instead of transport |
---|
10 | !! 3.3 ! 2010-09 (E.O'Dea) modifications for Shelf configurations |
---|
11 | !! 3.3 ! 2010-09 (D.Storkey) add ice boundary conditions |
---|
12 | !! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! bdy_dyn : split velocities into barotropic and baroclinic parts |
---|
15 | !! and call bdy_dyn2d and bdy_dyn3d to apply boundary |
---|
16 | !! conditions |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE oce ! ocean dynamics and tracers |
---|
19 | USE dom_oce ! ocean space and time domain |
---|
20 | USE bdy_oce ! ocean open boundary conditions |
---|
21 | USE bdydyn2d ! open boundary conditions for barotropic solution |
---|
22 | USE bdydyn3d ! open boundary conditions for baroclinic velocities |
---|
23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
24 | USE in_out_manager ! |
---|
25 | USE domvvl ! variable volume |
---|
26 | |
---|
27 | IMPLICIT NONE |
---|
28 | PRIVATE |
---|
29 | |
---|
30 | PUBLIC bdy_dyn ! routine called in dyn_nxt |
---|
31 | |
---|
32 | !! * Substitutions |
---|
33 | # include "domzgr_substitute.h90" |
---|
34 | # include "single_precision_substitute.h90" |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
37 | !! $Id$ |
---|
38 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | CONTAINS |
---|
41 | |
---|
42 | SUBROUTINE bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only ) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | !! *** SUBROUTINE bdy_dyn *** |
---|
45 | !! |
---|
46 | !! ** Purpose : - Wrapper routine for bdy_dyn2d and bdy_dyn3d. |
---|
47 | !! |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | INTEGER , INTENT(in) :: kt ! Main time step counter |
---|
50 | INTEGER , INTENT(in) :: Kbb, Kaa ! Ocean time level indices |
---|
51 | REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! Ocean velocities (to be updated at open boundaries) |
---|
52 | LOGICAL, OPTIONAL , INTENT(in) :: dyn3d_only ! T => only update baroclinic velocities |
---|
53 | ! |
---|
54 | INTEGER :: jk, ii, ij, ib_bdy, ib, igrd ! Loop counter |
---|
55 | LOGICAL :: ll_dyn2d, ll_dyn3d, ll_orlanski |
---|
56 | REAL(wp), DIMENSION(jpi,jpj) :: zua2d, zva2d ! after barotropic velocities |
---|
57 | !!---------------------------------------------------------------------- |
---|
58 | ! |
---|
59 | ll_dyn2d = .true. |
---|
60 | ll_dyn3d = .true. |
---|
61 | ! |
---|
62 | IF( PRESENT(dyn3d_only) ) THEN |
---|
63 | IF( dyn3d_only ) ll_dyn2d = .false. |
---|
64 | ENDIF |
---|
65 | ! |
---|
66 | ll_orlanski = .false. |
---|
67 | DO ib_bdy = 1, nb_bdy |
---|
68 | IF ( cn_dyn2d(ib_bdy) == 'orlanski' .OR. cn_dyn2d(ib_bdy) == 'orlanski_npo' & |
---|
69 | & .OR. cn_dyn3d(ib_bdy) == 'orlanski' .OR. cn_dyn3d(ib_bdy) == 'orlanski_npo') ll_orlanski = .true. |
---|
70 | END DO |
---|
71 | |
---|
72 | !------------------------------------------------------- |
---|
73 | ! Split velocities into barotropic and baroclinic parts |
---|
74 | !------------------------------------------------------- |
---|
75 | |
---|
76 | ! ! "After" velocities: |
---|
77 | zua2d(:,:) = 0._wp |
---|
78 | zva2d(:,:) = 0._wp |
---|
79 | DO jk = 1, jpkm1 |
---|
80 | zua2d(:,:) = zua2d(:,:) + e3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk) |
---|
81 | zva2d(:,:) = zva2d(:,:) + e3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk) |
---|
82 | END DO |
---|
83 | zua2d(:,:) = zua2d(:,:) * r1_hu(:,:,Kaa) |
---|
84 | zva2d(:,:) = zva2d(:,:) * r1_hv(:,:,Kaa) |
---|
85 | |
---|
86 | DO jk = 1 , jpkm1 |
---|
87 | puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) - zua2d(:,:) ) * umask(:,:,jk) |
---|
88 | pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) - zva2d(:,:) ) * vmask(:,:,jk) |
---|
89 | END DO |
---|
90 | |
---|
91 | |
---|
92 | IF( ll_orlanski ) THEN ! "Before" velocities (Orlanski condition only) |
---|
93 | DO jk = 1 , jpkm1 |
---|
94 | puu(:,:,jk,Kbb) = ( puu(:,:,jk,Kbb) - uu_b(:,:,Kbb) ) * umask(:,:,jk) |
---|
95 | pvv(:,:,jk,Kbb) = ( pvv(:,:,jk,Kbb) - vv_b(:,:,Kbb) ) * vmask(:,:,jk) |
---|
96 | END DO |
---|
97 | ENDIF |
---|
98 | |
---|
99 | !------------------------------------------------------- |
---|
100 | ! Apply boundary conditions to barotropic and baroclinic |
---|
101 | ! parts separately |
---|
102 | !------------------------------------------------------- |
---|
103 | |
---|
104 | IF( ll_dyn2d ) CALL bdy_dyn2d( kt, zua2d, zva2d, uu_b(:,:,Kbb), vv_b(:,:,Kbb), r1_hu(:,:,Kaa), r1_hv(:,:,Kaa), CASTWP(ssh(:,:,Kaa)) ) |
---|
105 | |
---|
106 | IF( ll_dyn3d ) CALL bdy_dyn3d( kt, Kbb, puu, pvv, Kaa ) |
---|
107 | |
---|
108 | !------------------------------------------------------- |
---|
109 | ! Recombine velocities |
---|
110 | !------------------------------------------------------- |
---|
111 | ! |
---|
112 | DO jk = 1 , jpkm1 |
---|
113 | puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) + zua2d(:,:) ) * umask(:,:,jk) |
---|
114 | pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) + zva2d(:,:) ) * vmask(:,:,jk) |
---|
115 | END DO |
---|
116 | ! |
---|
117 | IF ( ll_orlanski ) THEN |
---|
118 | DO jk = 1 , jpkm1 |
---|
119 | puu(:,:,jk,Kbb) = ( puu(:,:,jk,Kbb) + uu_b(:,:,Kbb) ) * umask(:,:,jk) |
---|
120 | pvv(:,:,jk,Kbb) = ( pvv(:,:,jk,Kbb) + vv_b(:,:,Kbb) ) * vmask(:,:,jk) |
---|
121 | END DO |
---|
122 | END IF |
---|
123 | ! |
---|
124 | END SUBROUTINE bdy_dyn |
---|
125 | |
---|
126 | !!====================================================================== |
---|
127 | END MODULE bdydyn |
---|