1 | MODULE traldf_lap_blp |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE traldf_lap_blp *** |
---|
4 | !! Ocean tracers: lateral diffusivity trend (laplacian and bilaplacian) |
---|
5 | !!============================================================================== |
---|
6 | !! History : 3.7 ! 2014-01 (G. Madec, S. Masson) Original code, re-entrant laplacian |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! tra_ldf_lap : tracer trend update with iso-level laplacian diffusive operator |
---|
11 | !! tra_ldf_blp : tracer trend update with iso-level or iso-neutral bilaplacian operator |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE oce ! ocean dynamics and active tracers |
---|
14 | USE dom_oce ! ocean space and time domain |
---|
15 | USE domutl, ONLY : is_tile |
---|
16 | USE ldftra ! lateral physics: eddy diffusivity |
---|
17 | USE traldf_iso ! iso-neutral lateral diffusion (standard operator) (tra_ldf_iso routine) |
---|
18 | USE traldf_triad ! iso-neutral lateral diffusion (triad operator) (tra_ldf_triad routine) |
---|
19 | USE diaptr ! poleward transport diagnostics |
---|
20 | USE diaar5 ! AR5 diagnostics |
---|
21 | USE trc_oce ! share passive tracers/Ocean variables |
---|
22 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
---|
23 | ! |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O library |
---|
26 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
27 | USE lib_mpp ! distribued memory computing library |
---|
28 | USE timing ! Timing |
---|
29 | |
---|
30 | IMPLICIT NONE |
---|
31 | PRIVATE |
---|
32 | |
---|
33 | PUBLIC tra_ldf_lap ! called by traldf.F90 |
---|
34 | PUBLIC tra_ldf_blp ! called by traldf.F90 |
---|
35 | |
---|
36 | LOGICAL :: l_ptr ! flag to compute poleward transport |
---|
37 | LOGICAL :: l_hst ! flag to compute heat transport |
---|
38 | |
---|
39 | !! * Substitutions |
---|
40 | # include "do_loop_substitute.h90" |
---|
41 | # include "domzgr_substitute.h90" |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
44 | !! $Id$ |
---|
45 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | CONTAINS |
---|
48 | |
---|
49 | SUBROUTINE tra_ldf_lap( kt, Kmm, kit000, cdtype, pahu, pahv, & |
---|
50 | & pgu , pgv , pgui, pgvi, & |
---|
51 | & pt, pt_rhs, kjpt, kpass ) |
---|
52 | !! |
---|
53 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
54 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
55 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
56 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
57 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
---|
58 | INTEGER , INTENT(in ) :: Kmm ! ocean time level index |
---|
59 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
---|
60 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
61 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
---|
62 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt ! before tracer fields |
---|
63 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pt_rhs ! tracer trend |
---|
64 | !! |
---|
65 | CALL tra_ldf_lap_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu), & |
---|
66 | & pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), & |
---|
67 | & pt, is_tile(pt), pt_rhs, is_tile(pt_rhs), kjpt, kpass ) |
---|
68 | END SUBROUTINE tra_ldf_lap |
---|
69 | |
---|
70 | |
---|
71 | SUBROUTINE tra_ldf_lap_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah, & |
---|
72 | & pgu , pgv , ktg , pgui, pgvi, ktgi, & |
---|
73 | & pt, ktt, pt_rhs, ktt_rhs, kjpt, kpass ) |
---|
74 | !!---------------------------------------------------------------------- |
---|
75 | !! *** ROUTINE tra_ldf_lap *** |
---|
76 | !! |
---|
77 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
78 | !! trend and add it to the general trend of tracer equation. |
---|
79 | !! |
---|
80 | !! ** Method : Second order diffusive operator evaluated using before |
---|
81 | !! fields (forward time scheme). The horizontal diffusive trends of |
---|
82 | !! the tracer is given by: |
---|
83 | !! difft = 1/(e1e2t*e3t) { di-1[ pahu e2u*e3u/e1u di(tb) ] |
---|
84 | !! + dj-1[ pahv e1v*e3v/e2v dj(tb) ] } |
---|
85 | !! Add this trend to the general tracer trend pt_rhs : |
---|
86 | !! pt_rhs = pt_rhs + difft |
---|
87 | !! |
---|
88 | !! ** Action : - Update pt_rhs arrays with the before iso-level |
---|
89 | !! harmonic mixing trend. |
---|
90 | !!---------------------------------------------------------------------- |
---|
91 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
92 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
93 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
94 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
95 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
---|
96 | INTEGER , INTENT(in ) :: Kmm ! ocean time level index |
---|
97 | INTEGER , INTENT(in ) :: ktah, ktg, ktgi, ktt, ktt_rhs |
---|
98 | REAL(wp), DIMENSION(ST_2DT(ktah), jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
---|
99 | REAL(wp), DIMENSION(ST_2DT(ktg), kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
100 | REAL(wp), DIMENSION(ST_2DT(ktgi), kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
---|
101 | REAL(wp), DIMENSION(ST_2DT(ktt), jpk,kjpt), INTENT(in ) :: pt ! before tracer fields |
---|
102 | REAL(wp), DIMENSION(ST_2DT(ktt_rhs),jpk,kjpt), INTENT(inout) :: pt_rhs ! tracer trend |
---|
103 | ! |
---|
104 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
105 | REAL(wp) :: zsign ! local scalars |
---|
106 | REAL(wp), DIMENSION(ST_2D(nn_hls),jpk) :: ztu, ztv, zaheeu, zaheev |
---|
107 | !!---------------------------------------------------------------------- |
---|
108 | ! |
---|
109 | IF( ntile == 0 .OR. ntile == 1 ) THEN ! Do only on the first tile |
---|
110 | IF( kt == nit000 .AND. lwp ) THEN |
---|
111 | WRITE(numout,*) |
---|
112 | WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass |
---|
113 | WRITE(numout,*) '~~~~~~~~~~~ ' |
---|
114 | ENDIF |
---|
115 | ! |
---|
116 | l_hst = .FALSE. |
---|
117 | l_ptr = .FALSE. |
---|
118 | IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf' ) ) ) l_ptr = .TRUE. |
---|
119 | IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
---|
120 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) ) l_hst = .TRUE. |
---|
121 | ENDIF |
---|
122 | ! |
---|
123 | ! !== Initialization of metric arrays used for all tracers ==! |
---|
124 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
---|
125 | ELSE ; zsign = -1._wp |
---|
126 | ENDIF |
---|
127 | DO_3D( 1, 0, 1, 0, 1, jpkm1 ) |
---|
128 | zaheeu(ji,jj,jk) = zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm) !!gm * umask(ji,jj,jk) pah masked! |
---|
129 | zaheev(ji,jj,jk) = zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm) !!gm * vmask(ji,jj,jk) |
---|
130 | END_3D |
---|
131 | ! |
---|
132 | ! ! =========== ! |
---|
133 | DO jn = 1, kjpt ! tracer loop ! |
---|
134 | ! ! =========== ! |
---|
135 | ! |
---|
136 | DO_3D( 1, 0, 1, 0, 1, jpkm1 ) |
---|
137 | ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( pt(ji+1,jj ,jk,jn) - pt(ji,jj,jk,jn) ) |
---|
138 | ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( pt(ji ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) |
---|
139 | END_3D |
---|
140 | ! TODO: NOT TESTED- requires zps |
---|
141 | IF( ln_zps ) THEN ! set gradient at bottom/top ocean level |
---|
142 | DO_2D( 1, 0, 1, 0 ) |
---|
143 | ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn) |
---|
144 | ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn) |
---|
145 | END_2D |
---|
146 | ! TODO: NOT TESTED- requires isf |
---|
147 | IF( ln_isfcav ) THEN ! top in ocean cavities only |
---|
148 | DO_2D( 1, 0, 1, 0 ) |
---|
149 | IF( miku(ji,jj) > 1 ) ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) |
---|
150 | IF( mikv(ji,jj) > 1 ) ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) |
---|
151 | END_2D |
---|
152 | ENDIF |
---|
153 | ENDIF |
---|
154 | ! |
---|
155 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) |
---|
156 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) & |
---|
157 | & + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) & |
---|
158 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
---|
159 | END_3D |
---|
160 | ! |
---|
161 | ! !== "Poleward" diffusive heat or salt transports ==! |
---|
162 | IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR. & !== first pass only ( laplacian) ==! |
---|
163 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass only (bilaplacian) ==! |
---|
164 | |
---|
165 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', -ztv(:,:,:) ) |
---|
166 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', -ztu(:,:,:), -ztv(:,:,:) ) |
---|
167 | ENDIF |
---|
168 | ! ! ================== |
---|
169 | END DO ! end of tracer loop |
---|
170 | ! ! ================== |
---|
171 | ! |
---|
172 | END SUBROUTINE tra_ldf_lap_t |
---|
173 | |
---|
174 | |
---|
175 | SUBROUTINE tra_ldf_blp( kt, Kmm, kit000, cdtype, pahu, pahv , & |
---|
176 | & pgu , pgv , pgui, pgvi, & |
---|
177 | & pt , pt_rhs, kjpt, kldf ) |
---|
178 | !!---------------------------------------------------------------------- |
---|
179 | !! *** ROUTINE tra_ldf_blp *** |
---|
180 | !! |
---|
181 | !! ** Purpose : Compute the before lateral tracer diffusive |
---|
182 | !! trend and add it to the general trend of tracer equation. |
---|
183 | !! |
---|
184 | !! ** Method : The lateral diffusive trends is provided by a bilaplacian |
---|
185 | !! operator applied to before field (forward in time). |
---|
186 | !! It is computed by two successive calls to laplacian routine |
---|
187 | !! |
---|
188 | !! ** Action : pta updated with the before rotated bilaplacian diffusion |
---|
189 | !!---------------------------------------------------------------------- |
---|
190 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
191 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
192 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
193 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
194 | INTEGER , INTENT(in ) :: kldf ! type of operator used |
---|
195 | INTEGER , INTENT(in ) :: Kmm ! ocean time level indices |
---|
196 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
---|
197 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
198 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
---|
199 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: pt ! before and now tracer fields |
---|
200 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pt_rhs ! tracer trend |
---|
201 | ! |
---|
202 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
203 | REAL(wp), DIMENSION(ST_2D(nn_hls),jpk,kjpt) :: zlap ! laplacian at t-point |
---|
204 | REAL(wp), DIMENSION(ST_2D(nn_hls), kjpt) :: zglu, zglv ! bottom GRADh of the laplacian (u- and v-points) |
---|
205 | REAL(wp), DIMENSION(ST_2D(nn_hls), kjpt) :: zgui, zgvi ! top GRADh of the laplacian (u- and v-points) |
---|
206 | !!--------------------------------------------------------------------- |
---|
207 | ! |
---|
208 | IF( ntile == 0 .OR. ntile == 1 ) THEN ! Do only on the first tile |
---|
209 | IF( kt == kit000 .AND. lwp ) THEN |
---|
210 | WRITE(numout,*) |
---|
211 | SELECT CASE ( kldf ) |
---|
212 | CASE ( np_blp ) ; WRITE(numout,*) 'tra_ldf_blp : iso-level bilaplacian operator on ', cdtype |
---|
213 | CASE ( np_blp_i ) ; WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (Standard)' |
---|
214 | CASE ( np_blp_it ) ; WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (triad)' |
---|
215 | END SELECT |
---|
216 | WRITE(numout,*) '~~~~~~~~~~~' |
---|
217 | ENDIF |
---|
218 | ENDIF |
---|
219 | |
---|
220 | zlap(:,:,:,:) = 0._wp |
---|
221 | ! |
---|
222 | SELECT CASE ( kldf ) !== 1st laplacian applied to pt (output in zlap) ==! |
---|
223 | ! |
---|
224 | CASE ( np_blp ) ! iso-level bilaplacian |
---|
225 | CALL tra_ldf_lap ( kt, Kmm, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt, zlap, kjpt, 1 ) |
---|
226 | CASE ( np_blp_i ) ! rotated bilaplacian : standard operator (Madec) |
---|
227 | CALL tra_ldf_iso ( kt, Kmm, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt, pt, zlap, kjpt, 1 ) |
---|
228 | CASE ( np_blp_it ) ! rotated bilaplacian : triad operator (griffies) |
---|
229 | CALL tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt, pt, zlap, kjpt, 1 ) |
---|
230 | END SELECT |
---|
231 | ! |
---|
232 | CALL lbc_lnk( 'traldf_lap_blp', zlap(:,:,:,:) , 'T', 1.0_wp ) ! Lateral boundary conditions (unchanged sign) |
---|
233 | ! ! Partial top/bottom cell: GRADh( zlap ) |
---|
234 | ! TODO: NOT TESTED- requires zps and isf |
---|
235 | IF( ln_isfcav .AND. ln_zps ) THEN ; CALL zps_hde_isf( kt, Kmm, kjpt, zlap, zglu, zglv, zgui, zgvi ) ! both top & bottom |
---|
236 | ELSEIF( ln_zps ) THEN ; CALL zps_hde ( kt, Kmm, kjpt, zlap, zglu, zglv ) ! only bottom |
---|
237 | ENDIF |
---|
238 | ! |
---|
239 | SELECT CASE ( kldf ) !== 2nd laplacian applied to zlap (output in pt_rhs) ==! |
---|
240 | ! |
---|
241 | CASE ( np_blp ) ! iso-level bilaplacian |
---|
242 | CALL tra_ldf_lap ( kt, Kmm, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt_rhs, kjpt, 2 ) |
---|
243 | CASE ( np_blp_i ) ! rotated bilaplacian : standard operator (Madec) |
---|
244 | CALL tra_ldf_iso ( kt, Kmm, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt , pt_rhs, kjpt, 2 ) |
---|
245 | CASE ( np_blp_it ) ! rotated bilaplacian : triad operator (griffies) |
---|
246 | CALL tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt , pt_rhs, kjpt, 2 ) |
---|
247 | END SELECT |
---|
248 | ! |
---|
249 | END SUBROUTINE tra_ldf_blp |
---|
250 | |
---|
251 | !!============================================================================== |
---|
252 | END MODULE traldf_lap_blp |
---|