| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
|---|
| 7 | !! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 8 | !! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 9 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! nemo_gcm : off-line: solve ocean tracer only |
|---|
| 14 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 15 | !! nemo_init : initialization of the NEMO system |
|---|
| 16 | !! nemo_ctl : initialisation of the contol print |
|---|
| 17 | !! nemo_closefile: close remaining open files |
|---|
| 18 | !! nemo_alloc : dynamical allocation |
|---|
| 19 | !! istate_init : simple initialization to zero of ocean fields |
|---|
| 20 | !! stp_ctl : reduced step control (no dynamics in off-line) |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE dom_oce ! ocean space domain variables |
|---|
| 23 | USE oce ! dynamics and tracers variables |
|---|
| 24 | USE trc_oce ! Shared ocean/passive tracers variables |
|---|
| 25 | USE c1d ! 1D configuration |
|---|
| 26 | USE domain ! domain initialization from coordinate & bathymetry (dom_init routine) |
|---|
| 27 | USE closea ! treatment of closed seas (for ln_closea) |
|---|
| 28 | USE usrdef_nam ! user defined configuration |
|---|
| 29 | USE eosbn2 ! equation of state (eos bn2 routine) |
|---|
| 30 | USE bdy_oce, ONLY : ln_bdy |
|---|
| 31 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
|---|
| 32 | ! ! ocean physics |
|---|
| 33 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
|---|
| 34 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
|---|
| 35 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
|---|
| 36 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
|---|
| 37 | USE traldf ! lateral physics (tra_ldf_init routine) |
|---|
| 38 | USE sbcmod ! surface boundary condition (sbc_init routine) |
|---|
| 39 | USE phycst ! physical constant (par_cst routine) |
|---|
| 40 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
|---|
| 41 | USE trcini ! Initilization of the passive tracers |
|---|
| 42 | USE daymod ! calendar (day routine) |
|---|
| 43 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 44 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
|---|
| 45 | ! ! Passive tracers needs |
|---|
| 46 | USE trc ! passive tracer : variables |
|---|
| 47 | USE trcnam ! passive tracer : namelist |
|---|
| 48 | USE trcrst ! passive tracer restart |
|---|
| 49 | USE diaptr ! Need to initialise this as some variables are used in if statements later |
|---|
| 50 | USE sbc_oce , ONLY : ln_rnf |
|---|
| 51 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 52 | ! ! I/O & MPP |
|---|
| 53 | USE iom ! I/O library |
|---|
| 54 | USE in_out_manager ! I/O manager |
|---|
| 55 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 56 | USE lib_mpp ! distributed memory computing |
|---|
| 57 | #if defined key_iomput |
|---|
| 58 | USE xios ! xIOserver |
|---|
| 59 | #endif |
|---|
| 60 | USE prtctl ! Print control (prt_ctl_init routine) |
|---|
| 61 | USE timing ! Timing |
|---|
| 62 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 63 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 64 | USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
|---|
| 65 | USE halo_mng |
|---|
| 66 | |
|---|
| 67 | IMPLICIT NONE |
|---|
| 68 | PRIVATE |
|---|
| 69 | |
|---|
| 70 | PUBLIC nemo_gcm ! called by nemo.F90 |
|---|
| 71 | |
|---|
| 72 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 73 | |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! NEMO/OFF 4.0 , NEMO Consortium (2018) |
|---|
| 76 | !! $Id$ |
|---|
| 77 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | CONTAINS |
|---|
| 80 | |
|---|
| 81 | SUBROUTINE nemo_gcm |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | !! *** ROUTINE nemo_gcm *** |
|---|
| 84 | !! |
|---|
| 85 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 86 | !! curvilinear mesh on the sphere. |
|---|
| 87 | !! |
|---|
| 88 | !! ** Method : - model general initialization |
|---|
| 89 | !! - launch the time-stepping (dta_dyn and trc_stp) |
|---|
| 90 | !! - finalize the run by closing files and communications |
|---|
| 91 | !! |
|---|
| 92 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 93 | !! Madec, 2008, internal report, IPSL. |
|---|
| 94 | !!---------------------------------------------------------------------- |
|---|
| 95 | INTEGER :: istp ! time step index |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | |
|---|
| 98 | CALL nemo_init ! Initializations |
|---|
| 99 | |
|---|
| 100 | ! check that all process are still there... If some process have an error, |
|---|
| 101 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 102 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 103 | |
|---|
| 104 | ! !-----------------------! |
|---|
| 105 | ! !== time stepping ==! |
|---|
| 106 | ! !-----------------------! |
|---|
| 107 | istp = nit000 |
|---|
| 108 | ! |
|---|
| 109 | IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization |
|---|
| 110 | ! |
|---|
| 111 | CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 112 | ! |
|---|
| 113 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==! |
|---|
| 114 | ! |
|---|
| 115 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 116 | CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp |
|---|
| 117 | #if defined key_sed_off |
|---|
| 118 | CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields |
|---|
| 119 | #else |
|---|
| 120 | CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields |
|---|
| 121 | #endif |
|---|
| 122 | CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 123 | #if ! defined key_sed_off |
|---|
| 124 | IF( .NOT.ln_linssh ) CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors |
|---|
| 125 | #endif |
|---|
| 126 | ! Swap time levels |
|---|
| 127 | Nrhs = Nbb |
|---|
| 128 | Nbb = Nnn |
|---|
| 129 | Nnn = Naa |
|---|
| 130 | Naa = Nrhs |
|---|
| 131 | ! |
|---|
| 132 | #if ! defined key_sed_off |
|---|
| 133 | IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters |
|---|
| 134 | #endif |
|---|
| 135 | CALL stp_ctl ( istp ) ! Time loop: control and print |
|---|
| 136 | istp = istp + 1 |
|---|
| 137 | END DO |
|---|
| 138 | ! |
|---|
| 139 | #if defined key_iomput |
|---|
| 140 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 141 | #endif |
|---|
| 142 | |
|---|
| 143 | ! !------------------------! |
|---|
| 144 | ! !== finalize the run ==! |
|---|
| 145 | ! !------------------------! |
|---|
| 146 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 147 | |
|---|
| 148 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 149 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 150 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 151 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | IF( ln_timing ) CALL timing_finalize |
|---|
| 155 | ! |
|---|
| 156 | CALL nemo_closefile |
|---|
| 157 | ! |
|---|
| 158 | #if defined key_iomput |
|---|
| 159 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 160 | #else |
|---|
| 161 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
|---|
| 162 | #endif |
|---|
| 163 | ! |
|---|
| 164 | IF(lwm) THEN |
|---|
| 165 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 166 | ELSE ; STOP 123 |
|---|
| 167 | ENDIF |
|---|
| 168 | ENDIF |
|---|
| 169 | ! |
|---|
| 170 | END SUBROUTINE nemo_gcm |
|---|
| 171 | |
|---|
| 172 | |
|---|
| 173 | SUBROUTINE nemo_init |
|---|
| 174 | !!---------------------------------------------------------------------- |
|---|
| 175 | !! *** ROUTINE nemo_init *** |
|---|
| 176 | !! |
|---|
| 177 | !! ** Purpose : initialization of the nemo model in off-line mode |
|---|
| 178 | !!---------------------------------------------------------------------- |
|---|
| 179 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 180 | !! |
|---|
| 181 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, & |
|---|
| 182 | & nn_isplt, nn_jsplt, nn_ictls, nn_ictle, nn_jctls, nn_jctle |
|---|
| 183 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 184 | !!---------------------------------------------------------------------- |
|---|
| 185 | ! |
|---|
| 186 | cxios_context = 'nemo' |
|---|
| 187 | nn_hls = 1 |
|---|
| 188 | ! |
|---|
| 189 | ! !-------------------------------------------------! |
|---|
| 190 | ! ! set communicator & select the local rank ! |
|---|
| 191 | ! ! must be done as soon as possible to get narea ! |
|---|
| 192 | ! !-------------------------------------------------! |
|---|
| 193 | ! |
|---|
| 194 | #if defined key_iomput |
|---|
| 195 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 196 | CALL mpp_start( ilocal_comm ) |
|---|
| 197 | #else |
|---|
| 198 | CALL mpp_start( ) |
|---|
| 199 | #endif |
|---|
| 200 | ! |
|---|
| 201 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 202 | lwm = (narea == 1) ! control of output namelists |
|---|
| 203 | ! |
|---|
| 204 | ! !---------------------------------------------------------------! |
|---|
| 205 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 206 | ! !---------------------------------------------------------------! |
|---|
| 207 | ! |
|---|
| 208 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 209 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 210 | ! open reference and configuration namelist files |
|---|
| 211 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 212 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 213 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 214 | ! open /dev/null file to be able to supress output write easily |
|---|
| 215 | IF( Agrif_Root() ) THEN |
|---|
| 216 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 217 | #ifdef key_agrif |
|---|
| 218 | ELSE |
|---|
| 219 | numnul = Agrif_Parent(numnul) |
|---|
| 220 | #endif |
|---|
| 221 | ENDIF |
|---|
| 222 | ! |
|---|
| 223 | ! !--------------------! |
|---|
| 224 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 225 | ! !--------------------! |
|---|
| 226 | ! |
|---|
| 227 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 228 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 229 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 230 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 231 | ! |
|---|
| 232 | ! finalize the definition of namctl variables |
|---|
| 233 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 234 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 235 | ! |
|---|
| 236 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 237 | ! |
|---|
| 238 | IF(lwp) THEN ! open listing units |
|---|
| 239 | ! |
|---|
| 240 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 241 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 242 | ! |
|---|
| 243 | WRITE(numout,*) |
|---|
| 244 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 245 | WRITE(numout,*) ' NEMO team' |
|---|
| 246 | WRITE(numout,*) ' Off-line TOP Model' |
|---|
| 247 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
|---|
| 248 | WRITE(numout,*) |
|---|
| 249 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 250 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 251 | WRITE(numout,*) |
|---|
| 252 | WRITE(numout,*) " o _, _, " |
|---|
| 253 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 254 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 255 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 256 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 257 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 258 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 259 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 260 | WRITE(numout,*) " ) ) ` ( ( " |
|---|
| 261 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 262 | WRITE(numout,*) |
|---|
| 263 | ! |
|---|
| 264 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 265 | ! |
|---|
| 266 | ENDIF |
|---|
| 267 | ! |
|---|
| 268 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 269 | ! |
|---|
| 270 | ! !------------------------------------! |
|---|
| 271 | ! ! Set global domain size parameters ! |
|---|
| 272 | ! !------------------------------------! |
|---|
| 273 | ! |
|---|
| 274 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 275 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 276 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 277 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 278 | ! |
|---|
| 279 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 280 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 281 | ELSE ! user-defined namelist |
|---|
| 282 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 283 | ENDIF |
|---|
| 284 | ! |
|---|
| 285 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 286 | l_offline = .true. ! passive tracers are run offline |
|---|
| 287 | ! |
|---|
| 288 | ! !-----------------------------------------! |
|---|
| 289 | ! ! mpp parameters and domain decomposition ! |
|---|
| 290 | ! !-----------------------------------------! |
|---|
| 291 | ! |
|---|
| 292 | CALL mpp_init |
|---|
| 293 | |
|---|
| 294 | CALL halo_mng_init() |
|---|
| 295 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 296 | CALL nemo_alloc() |
|---|
| 297 | |
|---|
| 298 | ! Initialise time level indices |
|---|
| 299 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
|---|
| 300 | |
|---|
| 301 | ! !-------------------------------! |
|---|
| 302 | ! ! NEMO general initialization ! |
|---|
| 303 | ! !-------------------------------! |
|---|
| 304 | |
|---|
| 305 | CALL nemo_ctl ! Control prints |
|---|
| 306 | ! |
|---|
| 307 | ! ! General initialization |
|---|
| 308 | IF( ln_timing ) CALL timing_init |
|---|
| 309 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 310 | ! |
|---|
| 311 | CALL phy_cst ! Physical constants |
|---|
| 312 | CALL eos_init ! Equation of state |
|---|
| 313 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 314 | CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain |
|---|
| 315 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 316 | & CALL prt_ctl_init ! Print control |
|---|
| 317 | |
|---|
| 318 | CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 319 | |
|---|
| 320 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 321 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 322 | |
|---|
| 323 | ! ! Tracer physics |
|---|
| 324 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 325 | CALL ldf_eiv_init ! Eddy induced velocity param |
|---|
| 326 | CALL tra_ldf_init ! lateral mixing |
|---|
| 327 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 328 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation |
|---|
| 329 | IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 330 | |
|---|
| 331 | ! ! Passive tracers |
|---|
| 332 | CALL trc_nam_run ! Needed to get restart parameters for passive tracers |
|---|
| 333 | CALL trc_rst_cal( nit000, 'READ' ) ! calendar |
|---|
| 334 | #if defined key_sed_off |
|---|
| 335 | CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics |
|---|
| 336 | #else |
|---|
| 337 | CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics |
|---|
| 338 | #endif |
|---|
| 339 | |
|---|
| 340 | CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization |
|---|
| 341 | CALL dia_ptr_init ! Poleward TRansports initialization |
|---|
| 342 | |
|---|
| 343 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 344 | ! |
|---|
| 345 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 346 | ! |
|---|
| 347 | END SUBROUTINE nemo_init |
|---|
| 348 | |
|---|
| 349 | |
|---|
| 350 | SUBROUTINE nemo_ctl |
|---|
| 351 | !!---------------------------------------------------------------------- |
|---|
| 352 | !! *** ROUTINE nemo_ctl *** |
|---|
| 353 | !! |
|---|
| 354 | !! ** Purpose : control print setting |
|---|
| 355 | !! |
|---|
| 356 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 357 | !!---------------------------------------------------------------------- |
|---|
| 358 | ! |
|---|
| 359 | IF(lwp) THEN ! control print |
|---|
| 360 | WRITE(numout,*) |
|---|
| 361 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 362 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 363 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 364 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 365 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 366 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 367 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 368 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 369 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 370 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 371 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 372 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 373 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 374 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 375 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 376 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 377 | ENDIF |
|---|
| 378 | |
|---|
| 379 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 380 | IF(lwp) THEN ! control print |
|---|
| 381 | WRITE(numout,*) |
|---|
| 382 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 383 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 384 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 385 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 386 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 387 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 388 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 389 | ENDIF |
|---|
| 390 | ! |
|---|
| 391 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 392 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 393 | ! |
|---|
| 394 | END SUBROUTINE nemo_ctl |
|---|
| 395 | |
|---|
| 396 | |
|---|
| 397 | SUBROUTINE nemo_closefile |
|---|
| 398 | !!---------------------------------------------------------------------- |
|---|
| 399 | !! *** ROUTINE nemo_closefile *** |
|---|
| 400 | !! |
|---|
| 401 | !! ** Purpose : Close the files |
|---|
| 402 | !!---------------------------------------------------------------------- |
|---|
| 403 | ! |
|---|
| 404 | IF( lk_mpp ) CALL mppsync |
|---|
| 405 | ! |
|---|
| 406 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 407 | ! |
|---|
| 408 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 409 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 410 | ! |
|---|
| 411 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 412 | ! |
|---|
| 413 | END SUBROUTINE nemo_closefile |
|---|
| 414 | |
|---|
| 415 | |
|---|
| 416 | SUBROUTINE nemo_alloc |
|---|
| 417 | !!---------------------------------------------------------------------- |
|---|
| 418 | !! *** ROUTINE nemo_alloc *** |
|---|
| 419 | !! |
|---|
| 420 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 421 | !! |
|---|
| 422 | !! ** Method : |
|---|
| 423 | !!---------------------------------------------------------------------- |
|---|
| 424 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 425 | USE dom_oce, ONLY : dom_oce_alloc |
|---|
| 426 | USE zdf_oce, ONLY : zdf_oce_alloc |
|---|
| 427 | USE trc_oce, ONLY : trc_oce_alloc |
|---|
| 428 | USE bdy_oce, ONLY : bdy_oce_alloc |
|---|
| 429 | ! |
|---|
| 430 | INTEGER :: ierr |
|---|
| 431 | !!---------------------------------------------------------------------- |
|---|
| 432 | ! |
|---|
| 433 | ierr = oce_alloc () ! ocean |
|---|
| 434 | ierr = ierr + dia_wri_alloc() |
|---|
| 435 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 436 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 437 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 438 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 439 | ! |
|---|
| 440 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 441 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 442 | ! |
|---|
| 443 | END SUBROUTINE nemo_alloc |
|---|
| 444 | |
|---|
| 445 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 446 | !!---------------------------------------------------------------------- |
|---|
| 447 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 448 | !! |
|---|
| 449 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 450 | !! |
|---|
| 451 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 452 | !! types of output for selected areas. |
|---|
| 453 | !!---------------------------------------------------------------------- |
|---|
| 454 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 455 | LOGICAL , INTENT(in ) :: setto |
|---|
| 456 | !!---------------------------------------------------------------------- |
|---|
| 457 | sn_cfctl%l_runstat = setto |
|---|
| 458 | sn_cfctl%l_trcstat = setto |
|---|
| 459 | sn_cfctl%l_oceout = setto |
|---|
| 460 | sn_cfctl%l_layout = setto |
|---|
| 461 | sn_cfctl%l_prtctl = setto |
|---|
| 462 | sn_cfctl%l_prttrc = setto |
|---|
| 463 | sn_cfctl%l_oasout = setto |
|---|
| 464 | END SUBROUTINE nemo_set_cfctl |
|---|
| 465 | |
|---|
| 466 | SUBROUTINE istate_init( Kmm, Kaa ) |
|---|
| 467 | !!---------------------------------------------------------------------- |
|---|
| 468 | !! *** ROUTINE istate_init *** |
|---|
| 469 | !! |
|---|
| 470 | !! ** Purpose : Initialization to zero of the dynamics and tracers. |
|---|
| 471 | !!---------------------------------------------------------------------- |
|---|
| 472 | INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices |
|---|
| 473 | ! |
|---|
| 474 | ! now fields ! after fields ! |
|---|
| 475 | uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp ! |
|---|
| 476 | vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp ! |
|---|
| 477 | ww (:,:,:) = 0._wp ! ! |
|---|
| 478 | hdiv (:,:,:) = 0._wp ! ! |
|---|
| 479 | ts (:,:,:,:,Kmm) = 0._wp ! ! |
|---|
| 480 | ! |
|---|
| 481 | rhd (:,:,:) = 0.e0 |
|---|
| 482 | rhop (:,:,:) = 0.e0 |
|---|
| 483 | rn2 (:,:,:) = 0.e0 |
|---|
| 484 | ! |
|---|
| 485 | END SUBROUTINE istate_init |
|---|
| 486 | |
|---|
| 487 | |
|---|
| 488 | SUBROUTINE stp_ctl( kt ) |
|---|
| 489 | !!---------------------------------------------------------------------- |
|---|
| 490 | !! *** ROUTINE stp_ctl *** |
|---|
| 491 | !! |
|---|
| 492 | !! ** Purpose : Control the run |
|---|
| 493 | !! |
|---|
| 494 | !! ** Method : - Save the time step in numstp |
|---|
| 495 | !! |
|---|
| 496 | !! ** Actions : 'time.step' file containing the last ocean time-step |
|---|
| 497 | !!---------------------------------------------------------------------- |
|---|
| 498 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
|---|
| 499 | !!---------------------------------------------------------------------- |
|---|
| 500 | ! |
|---|
| 501 | IF( kt == nit000 .AND. lwm ) THEN |
|---|
| 502 | WRITE(numout,*) |
|---|
| 503 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
|---|
| 504 | WRITE(numout,*) '~~~~~~~' |
|---|
| 505 | ! open time.step file |
|---|
| 506 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
|---|
| 507 | ENDIF |
|---|
| 508 | ! |
|---|
| 509 | IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp |
|---|
| 510 | IF(lwm) REWIND( numstp ) ! -------------------------- |
|---|
| 511 | ! |
|---|
| 512 | END SUBROUTINE stp_ctl |
|---|
| 513 | !!====================================================================== |
|---|
| 514 | END MODULE nemogcm |
|---|
