New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn_rhg.F90 in NEMO/branches/2020/SI3_vp_rheology/src/ICE – NEMO

source: NEMO/branches/2020/SI3_vp_rheology/src/ICE/icedyn_rhg.F90 @ 13965

Last change on this file since 13965 was 13965, checked in by clem, 4 years ago

attempt to cleanup vp rheology so it can be merged (maybe). I put a stop to restrain from using it and I cleaned the namelists
  • Property svn:keywords set to Id
File size: 9.2 KB
Line 
1MODULE icedyn_rhg
2   !!======================================================================
3   !!                     ***  MODULE  icedyn_rhg  ***
4   !!   Sea-Ice dynamics : master routine for rheology
5   !!======================================================================
6   !! history :  4.0  !  2018     (C. Rousset)      Original code
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!    ice_dyn_rhg      : computes ice velocities
13   !!    ice_dyn_rhg_init : initialization and namelist read
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icedyn_rhg_evp ! sea-ice: EVP rheology
19   USE icedyn_rhg_vp  ! sea-ice: VP rheology
20   USE icectl         ! sea-ice: control prints
21   !
22   USE in_out_manager ! I/O manager
23   USE lib_mpp        ! MPP library
24   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
25   USE timing         ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   ice_dyn_rhg        ! called by icestp.F90
31   PUBLIC   ice_dyn_rhg_init   ! called by icestp.F90
32
33   INTEGER ::              nice_rhg   ! choice of the type of rheology
34   !                                        ! associated indices:
35   INTEGER, PARAMETER ::   np_rhgEVP = 1   ! EVP rheology
36!! INTEGER, PARAMETER ::   np_rhgEAP = 2   ! EAP rheology
37   INTEGER, PARAMETER ::   np_rhgVP  = 3   ! VP rheology
38
39   ! ** namelist (namrhg) **
40   LOGICAL ::   ln_rhg_EVP       ! EVP rheology
41   LOGICAL ::   ln_rhg_VP        ! EVP rheology
42   !
43   !!----------------------------------------------------------------------
44   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE ice_dyn_rhg( kt, Kmm )
51      !!-------------------------------------------------------------------
52      !!               ***  ROUTINE ice_dyn_rhg  ***
53      !!               
54      !! ** Purpose :   compute ice velocity
55      !!
56      !! ** Action  : comupte - ice velocity (u_ice, v_ice)
57      !!                      - 3 components of the stress tensor (stress1_i, stress2_i, stress12_i)
58      !!                      - shear, divergence and delta (shear_i, divu_i, delta_i)
59      !!--------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt     ! ice time step
61      INTEGER, INTENT(in) ::   Kmm    ! ocean time level index
62      !!--------------------------------------------------------------------
63      ! controls
64      IF( ln_timing    )   CALL timing_start('icedyn_rhg')                                                             ! timing
65      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icedyn_rhg', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
66      IF( ln_icediachk )   CALL ice_cons2D  (0, 'icedyn_rhg',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
67      !
68      IF( kt == nit000 .AND. lwp ) THEN
69         WRITE(numout,*)
70         WRITE(numout,*)'ice_dyn_rhg: sea-ice rheology'
71         WRITE(numout,*)'~~~~~~~~~~~'
72      ENDIF
73      !
74      !--------------!
75      !== Rheology ==!
76      !--------------!   
77      SELECT CASE( nice_rhg )
78      !                                !------------------------!
79      CASE( np_rhgEVP )                ! Elasto-Viscous-Plastic !
80         !                             !------------------------!
81         CALL ice_dyn_rhg_evp( kt, Kmm, stress1_i, stress2_i, stress12_i, shear_i, divu_i, delta_i )
82         !       
83         !                             !------------------------!
84      CASE( np_rhgVP  )                ! Viscous-Plastic        !
85         !                             !------------------------!
86         CALL ice_dyn_rhg_vp ( kt, shear_i, divu_i, delta_i )
87         !
88      END SELECT
89      !
90      IF( lrst_ice ) THEN                       !* write EVP fields in the restart file
91         IF( ln_rhg_EVP )   CALL rhg_evp_rst( 'WRITE', kt )
92         ! MV note: no restart needed for VP as there is no time equation for stress tensor
93      ENDIF
94      !
95      ! controls
96      IF( sn_cfctl%l_prtctl ) &
97         &                 CALL ice_prt3D   ('icedyn_rhg')                                                             ! prints
98      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icedyn_rhg', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
99      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icedyn_rhg',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
100      IF( ln_timing    )   CALL timing_stop ('icedyn_rhg')                                                             ! timing
101      !
102   END SUBROUTINE ice_dyn_rhg
103
104
105   SUBROUTINE ice_dyn_rhg_init
106      !!-------------------------------------------------------------------
107      !!                  ***  ROUTINE ice_dyn_rhg_init  ***
108      !!
109      !! ** Purpose : Physical constants and parameters linked to the ice
110      !!      dynamics
111      !!
112      !! ** Method  :  Read the namdyn_rhg namelist and check the ice-dynamic
113      !!       parameter values called at the first timestep (nit000)
114      !!
115      !! ** input   :   Namelist namdyn_rhg
116      !!-------------------------------------------------------------------
117      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
118      !!
119      NAMELIST/namdyn_rhg/  ln_rhg_EVP, ln_aEVP, rn_creepl, rn_ecc , nn_nevp, rn_relast, nn_rhg_chkcvg,   &    !-- evp
120    &                       ln_rhg_VP, nn_vp_nout, nn_vp_ninn, nn_vp_cvgchk                                    !-- vp
121      !!-------------------------------------------------------------------
122      !
123      READ  ( numnam_ice_ref, namdyn_rhg, IOSTAT = ios, ERR = 901)
124901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_rhg in reference namelist' )
125      READ  ( numnam_ice_cfg, namdyn_rhg, IOSTAT = ios, ERR = 902 )
126902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namdyn_rhg in configuration namelist' )
127      IF(lwm) WRITE ( numoni, namdyn_rhg )
128      !
129      IF(lwp) THEN                     ! control print
130         WRITE(numout,*)
131         WRITE(numout,*) 'ice_dyn_rhg_init: ice parameters for ice dynamics '
132         WRITE(numout,*) '~~~~~~~~~~~~~~~'
133         WRITE(numout,*) '   Namelist : namdyn_rhg:'
134         WRITE(numout,*) '      rheology EVP (icedyn_rhg_evp)                        ln_rhg_EVP    = ', ln_rhg_EVP
135         WRITE(numout,*) '         use adaptive EVP (aEVP)                           ln_aEVP       = ', ln_aEVP
136         WRITE(numout,*) '         creep limit                                       rn_creepl     = ', rn_creepl ! also used by vp
137         WRITE(numout,*) '         eccentricity of the elliptical yield curve        rn_ecc        = ', rn_ecc    ! also used by vp
138         WRITE(numout,*) '         number of iterations for subcycling               nn_nevp       = ', nn_nevp
139         WRITE(numout,*) '         ratio of elastic timescale over ice time step     rn_relast     = ', rn_relast
140         WRITE(numout,*) '         check convergence of rheology                     nn_rhg_chkcvg = ', nn_rhg_chkcvg
141         WRITE(numout,*) '      rheology VP   (icedyn_rhg_VP)                        ln_rhg_VP     = ', ln_rhg_VP
142         WRITE(numout,*) '         number of outer iterations                        nn_vp_nout    = ', nn_vp_nout
143         WRITE(numout,*) '         number of inner iterations                        nn_vp_ninn    = ', nn_vp_ninn
144         WRITE(numout,*) '         iteration step for convergence check              nn_vp_cvgchk  = ', nn_vp_cvgchk
145         IF( ln_rhg_EVP ) THEN
146            IF    ( nn_rhg_chkcvg == 0 ) THEN   ;   WRITE(numout,*) '         no check cvg'
147            ELSEIF( nn_rhg_chkcvg == 1 ) THEN   ;   WRITE(numout,*) '         check cvg at the main time step'
148            ELSEIF( nn_rhg_chkcvg == 2 ) THEN   ;   WRITE(numout,*) '         check cvg at both main and rheology time steps'
149            ENDIF
150         ENDIF
151      ENDIF
152      !
153      !                             !== set the choice of ice advection ==!
154      ioptio = 0 
155      IF( ln_rhg_EVP ) THEN   ;   ioptio = ioptio + 1   ;   nice_rhg = np_rhgEVP    ;   ENDIF
156!!    IF( ln_rhg_EAP ) THEN   ;   ioptio = ioptio + 1   ;   nice_rhg = np_rhgEAP    ;   ENDIF
157      IF( ln_rhg_VP  ) THEN   ;   ioptio = ioptio + 1   ;   nice_rhg = np_rhgVP     ;   ENDIF
158      IF( ioptio /= 1 )   CALL ctl_stop( 'ice_dyn_rhg_init: choose one and only one ice rheology' )
159      !
160      IF( ln_rhg_EVP  )   CALL rhg_evp_rst( 'READ' )  !* read or initialize all required files
161      ! no restart for VP as there is no explicit time dependency in the equation
162      !
163   END SUBROUTINE ice_dyn_rhg_init
164
165#else
166   !!----------------------------------------------------------------------
167   !!   Default option         Empty module           NO SI3 sea-ice model
168   !!----------------------------------------------------------------------
169#endif 
170
171   !!======================================================================
172END MODULE icedyn_rhg
Note: See TracBrowser for help on using the repository browser.