1 | MODULE dynzad |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynzad *** |
---|
4 | !! Ocean dynamics : vertical advection trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1991-01 (G. Madec) Original code |
---|
7 | !! NEMO 0.5 ! 2002-07 (G. Madec) Free form, F90 |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! dyn_zad : vertical advection momentum trend |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE oce ! ocean dynamics and tracers |
---|
14 | USE dom_oce ! ocean space and time domain |
---|
15 | USE sbc_oce ! surface boundary condition: ocean |
---|
16 | USE trd_oce ! trends: ocean variables |
---|
17 | USE trddyn ! trend manager: dynamics |
---|
18 | ! |
---|
19 | USE in_out_manager ! I/O manager |
---|
20 | USE lib_mpp ! MPP library |
---|
21 | USE prtctl ! Print control |
---|
22 | USE timing ! Timing |
---|
23 | |
---|
24 | IMPLICIT NONE |
---|
25 | PRIVATE |
---|
26 | |
---|
27 | PUBLIC dyn_zad ! routine called by dynadv.F90 |
---|
28 | |
---|
29 | !! * Substitutions |
---|
30 | # include "vectopt_loop_substitute.h90" |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
33 | !! $Id$ |
---|
34 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | CONTAINS |
---|
37 | |
---|
38 | SUBROUTINE dyn_zad ( kt, Kmm, puu, pvv, Krhs ) |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! *** ROUTINE dynzad *** |
---|
41 | !! |
---|
42 | !! ** Purpose : Compute the now vertical momentum advection trend and |
---|
43 | !! add it to the general trend of momentum equation. |
---|
44 | !! |
---|
45 | !! ** Method : The now vertical advection of momentum is given by: |
---|
46 | !! w dz(u) = u(rhs) + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*ww) dk(u) ] |
---|
47 | !! w dz(v) = v(rhs) + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*ww) dk(v) ] |
---|
48 | !! Add this trend to the general trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)): |
---|
49 | !! (u(rhs),v(rhs)) = (u(rhs),v(rhs)) + w dz(u,v) |
---|
50 | !! |
---|
51 | !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the vert. momentum adv. trends |
---|
52 | !! - Send the trends to trddyn for diagnostics (l_trddyn=T) |
---|
53 | !!---------------------------------------------------------------------- |
---|
54 | INTEGER , INTENT( in ) :: kt ! ocean time-step inedx |
---|
55 | INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices |
---|
56 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
---|
57 | ! |
---|
58 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
59 | REAL(wp) :: zua, zva ! local scalars |
---|
60 | REAL(wp), DIMENSION(jpi,jpj) :: zww |
---|
61 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwuw, zwvw |
---|
62 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdu, ztrdv |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | ! |
---|
65 | IF( ln_timing ) CALL timing_start('dyn_zad') |
---|
66 | ! |
---|
67 | IF( kt == nit000 ) THEN |
---|
68 | IF(lwp) WRITE(numout,*) |
---|
69 | IF(lwp) WRITE(numout,*) 'dyn_zad : 2nd order vertical advection scheme' |
---|
70 | ENDIF |
---|
71 | |
---|
72 | IF( l_trddyn ) THEN ! Save puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends |
---|
73 | ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) |
---|
74 | ztrdu(:,:,:) = puu(:,:,:,Krhs) |
---|
75 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) |
---|
76 | ENDIF |
---|
77 | |
---|
78 | DO jk = 2, jpkm1 ! Vertical momentum advection at level w and u- and v- vertical |
---|
79 | DO jj = 2, jpj ! vertical fluxes |
---|
80 | DO ji = fs_2, jpi ! vector opt. |
---|
81 | zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk) |
---|
82 | END DO |
---|
83 | END DO |
---|
84 | DO jj = 2, jpjm1 ! vertical momentum advection at w-point |
---|
85 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
86 | zwuw(ji,jj,jk) = ( zww(ji+1,jj ) + zww(ji,jj) ) * ( puu(ji,jj,jk-1,Kmm) - puu(ji,jj,jk,Kmm) ) |
---|
87 | zwvw(ji,jj,jk) = ( zww(ji ,jj+1) + zww(ji,jj) ) * ( pvv(ji,jj,jk-1,Kmm) - pvv(ji,jj,jk,Kmm) ) |
---|
88 | END DO |
---|
89 | END DO |
---|
90 | END DO |
---|
91 | ! |
---|
92 | ! Surface and bottom advective fluxes set to zero |
---|
93 | DO jj = 2, jpjm1 |
---|
94 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
95 | zwuw(ji,jj, 1 ) = 0._wp |
---|
96 | zwvw(ji,jj, 1 ) = 0._wp |
---|
97 | zwuw(ji,jj,jpk) = 0._wp |
---|
98 | zwvw(ji,jj,jpk) = 0._wp |
---|
99 | END DO |
---|
100 | END DO |
---|
101 | ! |
---|
102 | DO jk = 1, jpkm1 ! Vertical momentum advection at u- and v-points |
---|
103 | DO jj = 2, jpjm1 |
---|
104 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
105 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm) |
---|
106 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm) |
---|
107 | END DO |
---|
108 | END DO |
---|
109 | END DO |
---|
110 | |
---|
111 | IF( l_trddyn ) THEN ! save the vertical advection trends for diagnostic |
---|
112 | ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:) |
---|
113 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:) |
---|
114 | CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt, Kmm ) |
---|
115 | DEALLOCATE( ztrdu, ztrdv ) |
---|
116 | ENDIF |
---|
117 | ! ! Control print |
---|
118 | IF(ln_ctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' zad - Ua: ', mask1=umask, & |
---|
119 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
---|
120 | ! |
---|
121 | IF( ln_timing ) CALL timing_stop('dyn_zad') |
---|
122 | ! |
---|
123 | END SUBROUTINE dyn_zad |
---|
124 | |
---|
125 | !!====================================================================== |
---|
126 | END MODULE dynzad |
---|