New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p5zprod.F90 @ 12537

Last change on this file since 12537 was 12537, checked in by aumont, 4 years ago

Comments in routines have been revised and significantly augmented
  • Property svn:keywords set to Id
File size: 39.3 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
12   !!   p5z_prod_init  :   Initialization of the parameters for growth
13   !!   p5z_prod_alloc :   Allocate variables for growth
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE p4zlim
19   USE p5zlim          !  Co-limitations of differents nutrients
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p5z_prod         ! called in p5zbio.F90
27   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
28   PUBLIC   p5z_prod_alloc
29
30   !! * Shared module variables
31   REAL(wp), PUBLIC ::  pislopen        !:
32   REAL(wp), PUBLIC ::  pislopep        !:
33   REAL(wp), PUBLIC ::  pisloped        !:
34   REAL(wp), PUBLIC ::  xadap           !:
35   REAL(wp), PUBLIC ::  excretn         !:
36   REAL(wp), PUBLIC ::  excretp         !:
37   REAL(wp), PUBLIC ::  excretd         !:
38   REAL(wp), PUBLIC ::  bresp           !:
39   REAL(wp), PUBLIC ::  thetanpm        !:
40   REAL(wp), PUBLIC ::  thetannm        !:
41   REAL(wp), PUBLIC ::  thetandm        !:
42   REAL(wp), PUBLIC ::  chlcmin         !:
43   REAL(wp), PUBLIC ::  grosip          !:
44
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excret
49   REAL(wp) :: texcretp               !: 1 - excretp
50   REAL(wp) :: texcretd               !: 1 - excret2       
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE p5z_prod( kt , knt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p5z_prod  ***
62      !!
63      !! ** Purpose :   Compute the phytoplankton production depending on
64      !!              light, temperature and nutrient availability
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      !
69      INTEGER, INTENT(in) :: kt, knt
70      !
71      INTEGER  ::   ji, jj, jk
72      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
73      REAL(wp) ::   zration, zratiop, zratiof, zmax, zsilim, ztn, zadap
74      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
75      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
76      REAL(wp) ::   zprnutmax, zdocprod, zprochln, zprochld, zprochlp
77      REAL(wp) ::   zpislopen, zpislopep, zpisloped
78      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
79      REAL(wp) ::   zfact, zrfact2, zmaxsi, zratiosi, zsizetmp, zlimfac
80      CHARACTER (len=25) :: charout
81      REAL(wp), DIMENSION(jpi,jpj    ) :: zmixnano, zmixpico, zmixdiat, zstrn
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadp, zpislopeadd
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprnut, zprnutp, zprmaxp, zprmaxn, zprmaxd
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprbio, zprpic, zprdia, zysopt
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprchln, zprchlp, zprchld
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcap, zprorcad 
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprofed, zprofep, zprofen
88      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewp, zpronewd
89      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zproregn, zproregp, zproregd
90      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpropo4n, zpropo4p, zpropo4d
91      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprodopn, zprodopp, zprodopd
92      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespn, zrespp, zrespd
93      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zcroissn, zcroissp, zcroissd
94      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
95      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
97      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zw2d
98      !!---------------------------------------------------------------------
99      !
100      IF( ln_timing )   CALL timing_start('p5z_prod')
101      !
102      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
103      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
104      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
105      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
106      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
107      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
108      zprodopn(:,:,:) = 0._wp ; zprodopp(:,:,:) = 0._wp ; zprodopd(:,:,:) = 0._wp
109      zysopt  (:,:,:) = 0._wp
110      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
111
112      ! Computation of the optimal production
113      zprnut (:,:,:) = 0.6_wp * (1.0 + zpsino3 * qnnmax ) * r1_rday * tgfunc(:,:,:)
114      zprnutp(:,:,:) =  0.6_wp * (1. + zpsino3 * qnpmax ) * r1_rday * tgfunc3(:,:,:)
115      zprmaxn(:,:,:) = ( 0.6_wp * (1. + zpsino3 * qnnmax ) ) * r1_rday * tgfunc(:,:,:)
116      zprmaxd(:,:,:) = ( 0.6_wp * (1. + zpsino3 * qndmax ) ) * r1_rday * tgfunc(:,:,:)
117      zprmaxp(:,:,:) = ( 0.4_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc3(:,:,:)
118
119      ! compute the day length depending on latitude and the day
120      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
121      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
122
123      ! day length in hours
124      zstrn(:,:) = 0.
125      DO jj = 1, jpj
126         DO ji = 1, jpi
127            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
128            zargu = MAX( -1., MIN(  1., zargu ) )
129            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
130         END DO
131      END DO
132
133         ! Impact of the day duration on phytoplankton growth
134      DO jk = 1, jpkm1
135         DO jj = 1 ,jpj
136            DO ji = 1, jpi
137               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
138                  zval = MAX( 1., zstrn(ji,jj) )
139                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
140                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
141                  ENDIF
142                  zmxl_chl(ji,jj,jk) = zval / 24.
143                  zmxl_fac(ji,jj,jk) = 1.0 - exp( -0.26 * zval )
144               ENDIF
145            END DO
146         END DO
147      END DO
148
149      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
150      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
151      zprpic(:,:,:) = zprmaxp(:,:,:) * zmxl_fac(:,:,:)
152
153
154      ! Maximum light intensity
155      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
156      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
157
158      DO jk = 1, jpkm1
159         DO jj = 1, jpj
160            DO ji = 1, jpi
161               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
162                  ! Computation of the P-I slope for nanos and diatoms
163                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
164                  zadap       = xadap * ztn / ( 2.+ ztn )
165                  !
166                  zpislopeadn(ji,jj,jk) = pislopen * trb(ji,jj,jk,jpnch)    &
167                  &                       /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
168                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
169                  &                       * trb(ji,jj,jk,jppch) /( trb(ji,jj,jk,jppic) * 12. + rtrn)
170                  zpislopeadd(ji,jj,jk) = pisloped * trb(ji,jj,jk,jpdch)    &
171                     &                    /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
172                  !
173                  zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
174                  zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
175                  zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
176
177                  ! Computation of production function for Carbon
178                  !  ---------------------------------------------
179                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) / zmxl_chl(ji,jj,jk) )  )
180                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) / zmxl_chl(ji,jj,jk))  )
181                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) / zmxl_chl(ji,jj,jk))  )
182
183                  ! Computation of production function for Chlorophyll
184                  !  -------------------------------------------------
185                  zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
186                  zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
187                  zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
188                  zprchln(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) )  )
189                  zprchlp(ji,jj,jk) = zprmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epicom(ji,jj,jk) )  )
190                  zprchld(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) )  )
191               ENDIF
192            END DO
193         END DO
194      END DO
195
196      DO jk = 1, jpkm1
197         DO jj = 1, jpj
198            DO ji = 1, jpi
199
200               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
201                  !    Si/C of diatoms
202                  !    ------------------------
203                  !    Si/C increases with iron stress and silicate availability
204                  !    Si/C is arbitrariliy increased for very high Si concentrations
205                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
206                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
207                  zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
208                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
209                  IF (gphit(ji,jj) < -30 ) THEN
210                    zsilfac2 = 1. + 1. * zsiborn / ( zsiborn + xksi2**3 )
211                  ELSE
212                    zsilfac2 = 1.
213                  ENDIF
214                  zratiosi = 1.0 - trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn ) / ( zsilfac2 * grosip * 3.0 + rtrn )
215                  zratiosi = MAX(0., MIN(1.0, zratiosi) )
216                  zmaxsi  = (1.0 + 0.1**4) * zratiosi**4 / ( zratiosi**4 + 0.1**4 )
217                  IF ( xlimsi(ji,jj,jk) /= xlimdia(ji,jj,jk) ) THEN
218                     zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zmaxsi
219                  ELSE
220                     zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zsilim**0.75 * zmaxsi
221                  ENDIF
222               ENDIF
223            END DO
224         END DO
225      END DO
226
227      !  Sea-ice effect on production                                                                               
228      DO jk = 1, jpkm1
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231               zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
232               zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
233               zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
234               zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
235               zprnutp(ji,jj,jk) = zprnutp(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
236            END DO
237         END DO
238      END DO
239
240      ! Computation of the various production and uptake terms of nanophytoplankton
241      ! Interactions between N and P are modeled according to the Chain Model
242      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
243      ! Droop kinetics. When the quota is approaching the maximum achievable
244      ! quota, uptake is downregulated according to a sigmoidal function
245      ! (power 2), as proposed by Flynn (2003)
246      ! ---------------------------------------------------------------------------
247      DO jk = 1, jpkm1
248         DO jj = 1, jpj
249            DO ji = 1, jpi
250               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
251                  !  production terms for nanophyto.
252                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
253
254                  ! Size computation
255                  ! Size is made a function of the limitation of of phytoplankton growth
256                  ! Strongly limited cells are supposed to be smaller. sizena is the
257                  ! size at time step t+1 and is thus updated at the end of the
258                  ! current time step
259                  ! --------------------------------------------------------------------
260                  zlimfac = xlimphys(ji,jj,jk) * zprchln(ji,jj,jk) / ( zprmaxn(ji,jj,jk) + rtrn )
261                  zsizetmp = 1.0 + 1.3 * ( xsizern - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
262                  sizena(ji,jj,jk) = min(xsizern, max( sizena(ji,jj,jk), zsizetmp ) )
263                  ! Maximum potential uptake rate
264                  zration = trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
265                  zratiop = trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn )
266                  zratiof = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
267                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpphy) * rfact2
268                  ! Uptake of nitrogen
269                  zrat = 1.0 - MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) )
270                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
271                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
272                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
273                  zpronewn(ji,jj,jk) = zpronmax * xnanono3(ji,jj,jk)
274                  zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
275                  ! Uptake of phosphorus and DOP
276                  zrat = 1.0 - MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
277                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
278                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk) * 16. / 10.
279                  zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
280                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
281                  ! Uptake of iron
282                  zrat = 1.0 - MIN( 1., zratiof / qfnmax )
283                  zmax = MAX(0., MIN(1., zrat**2/ (0.05**2 + zrat**2) ) )
284                  zprofmax = zprnutmax * qfnmax * zmax 
285                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk)    &
286                  &          * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
287                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
288               ENDIF
289            END DO
290         END DO
291      END DO
292
293      ! Computation of the various production and uptake terms of picophytoplankton
294      ! Interactions between N and P are modeled according to the Chain Model
295      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
296      ! Droop kinetics. When the quota is approaching the maximum achievable
297      ! quota, uptake is downregulated according to a sigmoidal function
298      ! (power 2), as proposed by Flynn (2003)
299      ! ---------------------------------------------------------------------------
300      DO jk = 1, jpkm1
301         DO jj = 1, jpj
302            DO ji = 1, jpi
303               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
304                  !  production terms for picophyto.
305                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trb(ji,jj,jk,jppic) * rfact2
306                  ! Size computation
307                  ! Size is made a function of the limitation of of phytoplankton growth
308                  ! Strongly limited cells are supposed to be smaller. sizepa is
309                  ! size at time step t+1 and is thus updated at the end of the
310                  ! current time step
311                  ! --------------------------------------------------------------------
312                  zlimfac = zprchlp(ji,jj,jk)  * xlimpics(ji,jj,jk) / ( zprmaxp(ji,jj,jk) + rtrn )
313                  zsizetmp = 1.0 + 1.3 * ( xsizerp - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
314                  sizepa(ji,jj,jk) = min(xsizerp, max( sizepa(ji,jj,jk), zsizetmp ) )
315                  ! Maximum potential uptake rate of nutrients
316                  zration = trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
317                  zratiop = trb(ji,jj,jk,jpppi) / ( trb(ji,jj,jk,jppic) + rtrn )
318                  zratiof = trb(ji,jj,jk,jppfe) / ( trb(ji,jj,jk,jppic) + rtrn )
319                  zprnutmax = zprnutp(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jppic) * rfact2
320                  ! Uptake of nitrogen
321                  zrat = 1.0 - MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
322                  zmax = MAX(0., MIN(1., zrat**2/ (0.05**2 + zrat**2) ) )
323                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
324                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
325                  zpronewp(ji,jj,jk) = zpronmax * xpicono3(ji,jj,jk) 
326                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
327                  ! Uptake of phosphorus
328                  zrat = 1.0 - MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
329                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
330                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk) * 16./10.
331                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
332                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
333                  ! Uptake of iron
334                  zrat = 1.0 - MIN( 1., zratiof / qfpmax )
335                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
336                  zprofmax = zprnutmax * qfpmax * zmax
337                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk)  &
338                  &          * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
339                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
340               ENDIF
341            END DO
342         END DO
343      END DO
344
345      ! Computation of the various production and uptake terms of diatoms
346      ! Interactions between N and P are modeled according to the Chain Model
347      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
348      ! Droop kinetics. When the quota is approaching the maximum achievable
349      ! quota, uptake is downregulated according to a sigmoidal function
350      ! (power 2), as proposed by Flynn (2003)
351      ! ---------------------------------------------------------------------------
352      DO jk = 1, jpkm1
353         DO jj = 1, jpj
354            DO ji = 1, jpi
355               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
356                  !  production terms for diatomees
357                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
358                  ! Size computation
359                  ! Size is made a function of the limitation of of phytoplankton growth
360                  ! Strongly limited cells are supposed to be smaller. sizeda is
361                  ! size at time step t+1 and is thus updated at the end of the
362                  ! current time step.
363                  ! --------------------------------------------------------------------
364                  zlimfac = zprchld(ji,jj,jk) * xlimdias(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn )
365                  zsizetmp = 1.0 + 1.3 * ( xsizerd - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
366                  sizeda(ji,jj,jk) = min(xsizerd, max( sizeda(ji,jj,jk), zsizetmp ) )
367                  ! Maximum potential uptake rate of nutrients
368                  zration = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
369                  zratiop = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
370                  zratiof = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
371                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpdia) * rfact2
372                  ! Uptake of nitrogen
373                  zrat = 1.0 - MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
374                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
375                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
376                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimdfe(ji,jj,jk) ) )
377                  zpronewd(ji,jj,jk) = zpronmax * xdiatno3(ji,jj,jk)
378                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
379                  ! Uptake of phosphorus
380                  zrat = 1.0 - MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
381                  zmax = MAX(0., MIN(1., zrat**2/ (0.05**2 + zrat**2) ) )
382                  zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk) * 16./10.
383                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
384                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
385                  ! Uptake of iron
386                  zrat = 1.0 - MIN( 1., zratiof / qfdmax )
387                  zmax = MAX(0., MIN(1., zrat**2 / (0.05**2 + zrat**2) ) )
388                  zprofmax = zprnutmax * qfdmax * zmax
389                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk)    &
390                  &          * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
391                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
392               ENDIF
393            END DO
394         END DO
395      END DO
396
397      ! Production of Chlorophyll. The formulation proposed by Geider et al.
398      ! is adopted here.
399      ! --------------------------------------------------------------------
400      DO jk = 1, jpkm1
401         DO jj = 1, jpj
402            DO ji = 1, jpi
403               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
404                     !  production terms for nanophyto. ( chlorophyll )
405                  znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
406                  zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
407                  zprochln = thetannm * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
408                  zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
409                     !  production terms for picophyto. ( chlorophyll )
410                  zpicotot = epicom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
411                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
412                  zprochlp = thetanpm * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
413                  zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
414                  !  production terms for diatoms ( chlorophyll )
415                  zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
416                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
417                  zprochld = thetandm * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
418                  zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
419                  !   Update the arrays TRA which contain the Chla sources and sinks
420                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
421                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
422                  tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp * texcretp
423               ENDIF
424            END DO
425         END DO
426      END DO
427
428      !   Update the arrays TRA which contain the biological sources and sinks
429      DO jk = 1, jpkm1
430         DO jj = 1, jpj
431           DO ji =1 ,jpi
432              zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
433              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
434              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
435              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
436              &          + excretp * zprorcap(ji,jj,jk)
437              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
438              &                     - zpropo4p(ji,jj,jk)
439              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
440              &                     - zpronewp(ji,jj,jk)
441              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
442              &                     - zproregp(ji,jj,jk)
443              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn    &
444                 &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
445                 &                  - zrespn(ji,jj,jk) 
446              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trb(ji,jj,jk,jpphy) + rtrn)
447              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcretn
448              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4n(ji,jj,jk) * texcretn   &
449              &                     + zprodopn(ji,jj,jk) * texcretn
450              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
451              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
452                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
453                 &                  - zrespp(ji,jj,jk) 
454              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trb(ji,jj,jk,jppic) + rtrn)
455              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
456              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
457              &                     + zprodopp(ji,jj,jk) * texcretp
458              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
459              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd   &
460                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
461                 &                  - zrespd(ji,jj,jk) 
462              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trb(ji,jj,jk,jpdia) + rtrn)
463              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcretd
464              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcretd   &
465              &                     + zprodopd(ji,jj,jk) * texcretd
466              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
467              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprmaxd(ji,jj,jk) * zysopt(ji,jj,jk) * rfact2 * trb(ji,jj,jk,jpdia)
468              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
469              &                     + excretp * zprorcap(ji,jj,jk)
470              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excretd * zprodtot + excretn * zprontot   &
471              &                     + excretp * zproptot
472              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excretd * zpropo4d(ji,jj,jk) + excretn * zpropo4n(ji,jj,jk)   &
473              &    - texcretn * zprodopn(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
474              &    - texcretp * zprodopp(ji,jj,jk)
475              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
476                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
477                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
478                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
479              zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
480              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
481              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - zprmaxd(ji,jj,jk) * zysopt(ji,jj,jk) * rfact2 * trb(ji,jj,jk,jpdia)
482              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
483              &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
484              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
485              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
486              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
487              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
488              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
489              &                     + zproregp(ji,jj,jk) ) 
490          END DO
491        END DO
492     END DO
493     
494     ! Production and uptake of ligands by phytoplankton. This part is activated
495     ! when ln_ligand is set to .true. in the namelist. Ligand uptake is small
496     ! and based on the FeL model by Morel et al. (2008) and on the study of
497     ! Shaked and Lis (2012)
498     ! -------------------------------------------------------------------------
499     IF( ln_ligand ) THEN
500         zpligprod1(:,:,:) = 0._wp    ;    zpligprod2(:,:,:) = 0._wp
501         DO jk = 1, jpkm1
502            DO jj = 1, jpj
503              DO ji =1 ,jpi
504                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
505                 zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
506                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp    &
507                 &       - zfeup * plig(ji,jj,jk) / ( rtrn + plig(ji,jj,jk) + 2.E3 * (1.0 - plig(ji,jj,jk) ) ) * lthet
508                 zpligprod1(ji,jj,jk) = zdocprod * ldocp
509                 zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) / ( rtrn + plig(ji,jj,jk) &
510                 &                      + 2.E3 * (1.0 - plig(ji,jj,jk) ) ) * lthet
511              END DO
512           END DO
513        END DO
514     ENDIF
515
516    ! Total primary production per year
517    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
518      & tpp = glob_sum( 'p5zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
519
520    IF( lk_iomput ) THEN
521       IF( knt == nrdttrc ) THEN
522          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
523          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
524          !
525          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) .OR. iom_use( "PPPHYP" ) )  THEN
526              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
527              CALL iom_put( "PPPHYN"  , zw3d )
528              !
529              zw3d(:,:,:) = zprorcap(:,:,:) * zfact * tmask(:,:,:)  ! primary production by picophyto
530              CALL iom_put( "PPPHYP"  , zw3d )
531              !
532              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatoms
533              CALL iom_put( "PPPHYD"  , zw3d )
534          ENDIF
535          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) .OR. iom_use( "PPNEWP" ) )  THEN
536              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
537              CALL iom_put( "PPNEWN"  , zw3d )
538              !
539              zw3d(:,:,:) = zpronewp(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by picophyto
540              CALL iom_put( "PPNEWP"  , zw3d )
541              !
542              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatoms
543              CALL iom_put( "PPNEWD"  , zw3d )
544          ENDIF
545          IF( iom_use( "PBSi" ) )  THEN
546              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
547              CALL iom_put( "PBSi"  , zw3d )
548          ENDIF
549          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) .OR. iom_use( "PFeP" ) )  THEN
550              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron uptake by nanophyto
551              CALL iom_put( "PFeN"  , zw3d )
552              !
553              zw3d(:,:,:) = zprofep(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron uptake by picophyto
554              CALL iom_put( "PFeP"  , zw3d )
555              !
556              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron uptake by  diatoms
557              CALL iom_put( "PFeD"  , zw3d )
558          ENDIF
559          IF( iom_use( "LPRODP" ) )  THEN
560              zw3d(:,:,:) = zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:)
561              CALL iom_put( "LPRODP"  , zw3d )  ! Ligand production by phytoplankton
562          ENDIF
563          IF( iom_use( "LDETP" ) )  THEN
564              zw3d(:,:,:) = zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:)
565              CALL iom_put( "LDETP"  , zw3d )  ! Uptake of ligands by phytoplankton
566          ENDIF
567          IF( iom_use( "Mumax" ) )  THEN
568              zw3d(:,:,:) = zprmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
569              CALL iom_put( "Mumax"  , zw3d )
570          ENDIF
571          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) .OR. iom_use( "MuP" ) )  THEN
572              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
573              CALL iom_put( "MuN"  , zw3d )
574              !
575              zw3d(:,:,:) = zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:)  ! Realized growth rate for picophyto
576              CALL iom_put( "MuP"  , zw3d )
577              !
578              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
579              CALL iom_put( "MuD"  , zw3d )
580          ENDIF
581          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) .OR. iom_use( "LPlight" ) )  THEN
582              zw3d(:,:,:) = zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term of nanophytoplankton
583              CALL iom_put( "LNlight"  , zw3d )
584              !
585              zw3d(:,:,:) = zprpic (:,:,:) / (zprmaxp(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term of picophytoplankton
586              CALL iom_put( "LPlight"  , zw3d )
587              !
588              zw3d(:,:,:) =  zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term of diatoms
589              CALL iom_put( "LDlight"  , zw3d )
590          ENDIF
591          IF( iom_use( "MunetN" ) .OR. iom_use( "MunetD" ) .OR. iom_use( "MunetP" ) )  THEN
592              zw3d(:,:,:) = zcroissn(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for nanophyto
593              CALL iom_put( "MunetN"  , zw3d )
594              !
595              zw3d(:,:,:) = zcroissp(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for picophyto
596              CALL iom_put( "MunetP"  , zw3d )
597              !
598              zw3d(:,:,:) = zcroissd(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for diatoms
599              CALL iom_put( "MunetD"  , zw3d )
600              !
601          ENDIF
602
603          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
604          !
605          DEALLOCATE( zw2d, zw3d )
606       ENDIF
607     ENDIF
608
609      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
610         WRITE(charout, FMT="('prod')")
611         CALL prt_ctl_trc_info(charout)
612         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
613      ENDIF
614      !
615      IF( ln_timing )   CALL timing_stop('p5z_prod')
616      !
617   END SUBROUTINE p5z_prod
618
619
620   SUBROUTINE p5z_prod_init
621      !!----------------------------------------------------------------------
622      !!                  ***  ROUTINE p5z_prod_init  ***
623      !!
624      !! ** Purpose :   Initialization of phytoplankton production parameters
625      !!
626      !! ** Method  :   Read the namp5zprod namelist and check the parameters
627      !!      called at the first timestep (nittrc000)
628      !!
629      !! ** input   :   Namelist namp5zprod
630      !!----------------------------------------------------------------------
631      INTEGER :: ios    ! Local integer output status for namelist read
632      !!
633      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
634         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
635      !!----------------------------------------------------------------------
636
637      REWIND( numnatp_ref )              ! Namelist namp5zprod in reference namelist : Pisces phytoplankton production
638      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
639901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist' )
640
641      REWIND( numnatp_cfg )              ! Namelist namp5zprod in configuration namelist : Pisces phytoplankton production
642      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
643902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist' )
644      IF(lwm) WRITE ( numonp, namp5zprod )
645
646      IF(lwp) THEN                         ! control print
647         WRITE(numout,*) ' '
648         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
649         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
650         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
651         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
652         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
653         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
654         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
655         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
656         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
657         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
658         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
659         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
660         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
661         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
662         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
663      ENDIF
664      !
665      r1_rday   = 1._wp / rday 
666      texcretn  = 1._wp - excretn
667      texcretp  = 1._wp - excretp
668      texcretd  = 1._wp - excretd
669      tpp       = 0._wp
670      !
671   END SUBROUTINE p5z_prod_init
672
673
674   INTEGER FUNCTION p5z_prod_alloc()
675      !!----------------------------------------------------------------------
676      !!                     ***  ROUTINE p5z_prod_alloc  ***
677      !!----------------------------------------------------------------------
678      ALLOCATE( zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
679      !
680      IF( p5z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p5z_prod_alloc : failed to allocate arrays.' )
681      !
682   END FUNCTION p5z_prod_alloc
683   !!======================================================================
684END MODULE p5zprod
Note: See TracBrowser for help on using the repository browser.