New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zrem.F90 @ 14276

Last change on this file since 14276 was 14276, checked in by aumont, 3 years ago

numerous updates to PISCES, PISCES-QUOTA and the sediment module
  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!         except for POC which is treated in p4zpoc.F90
6   !!         This module is common to both PISCES and PISCES-QUOTA
7   !!=========================================================================
8   !! History :   1.0  !  2004     (O. Aumont) Original code
9   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
10   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
11   !!----------------------------------------------------------------------
12   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
13   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
14   !!   p4z_rem_alloc :  Allocate remineralisation variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zche          !  chemical model
20   USE p4zprod         !  Growth rate of the 2 phyto groups
21   USE p4zlim          !  Nutrient limitation terms
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_rem         ! called in p4zbio.F90
30   PUBLIC   p4z_rem_init    ! called in trcini_pisces.F90
31   PUBLIC   p4z_rem_alloc   ! called in trcini_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC (p5z)
35   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON (p5z)
36   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP (p5z)
37   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
38   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of biogenic silica
39   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of BSi
40   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
41   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
42   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacterial Fe/C
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE p4z_rem( kt, knt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_rem  ***
56      !!
57      !! ** Purpose :   Compute remineralization/dissolution of organic compounds
58      !!                Computes also nitrification of ammonium
59      !!                The solubilization/remineralization of POC is treated
60      !!                in p4zpoc.F90. The dissolution of calcite is processed
61      !!                in p4zlys.F90.
62      !!
63      !! ** Method  : - Bacterial biomass is computed implicitely based on a
64      !!                parameterization developed from an explicit modeling
65      !!                of PISCES in an alternative version
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
68      !
69      INTEGER  ::   ji, jj, jk
70      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
71      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
72      REAL(wp) ::   zbactfer, zonitr
73      REAL(wp) ::   zammonic, zoxyremc, zosil, ztem, zdenitnh4, zolimic
74      CHARACTER (len=25) :: charout
75      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zfacsi, zfacsib, zdepeff, zfebact
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
77      !!---------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('p4z_rem')
80      !
81      ! Initialisation of arrays
82      zdepeff (:,:,:) = 0.3_wp
83      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
84      zfebact(:,:,:)  = 0._wp
85      zfacsi(:,:,:)   = xsilab
86
87      ! Computation of the mean bacterial concentration
88      ! this parameterization has been deduced from a model version
89      ! that was modeling explicitely bacteria. This is a very old param
90      ! that will be very soon updated based on results from a much more
91      ! recent version of PISCES with bacteria.
92      ! ----------------------------------------------------------------
93      DO jk = 1, jpkm1
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96               zdep = MAX( hmld(ji,jj), heup_01(ji,jj) )
97               zdepbac(ji,jj,jk) = 0.6 * ( MAX(0.0, trb(ji,jj,jk,jpzoo) + trb(ji,jj,jk,jpmes) ) * 1.0E6 )**0.6 * 1.E-6
98               IF( gdept_n(ji,jj,jk) >= zdep ) THEN
99                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
100                  zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3
101               ENDIF
102            END DO
103         END DO
104      END DO
105
106      DO jk = 1, jpkm1
107         DO jj = 1, jpj
108            DO ji = 1, jpi
109               ! DOC ammonification. Depends on a limitation term of the bacterial activity
110               ! and on the implicit bacteria concentration
111               ! --------------------------------------------------------------------------
112               zremik = xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
113               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
114               zremikc = xremikc * zremik
115
116               ! Ammonification in oxic waters with oxygen consumption
117               ! -----------------------------------------------------
118               zolimic = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc)
119               zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimic ) )
120               zolimi(ji,jj,jk) = zolimic
121
122               ! Ammonification in suboxic waters with denitrification
123               ! -----------------------------------------------------
124               zammonic = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
125               denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
126               denitr(ji,jj,jk)  = MAX(0., MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) ) )
127
128               ! Ammonification in waters depleted in O2 and NO3 based on
129               ! other redox processes
130               ! --------------------------------------------------------
131               zoxyremc          = MAX(0., zammonic - denitr(ji,jj,jk) )
132
133               ! Update of the TRA arrays
134               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
135               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - ( zolimic + denitr(ji,jj,jk) + zoxyremc )
136               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
137               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk) + zoxyremc
138               IF ( ln_p4z ) THEN ! PISCES-std
139                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimic + denitr(ji,jj,jk) + zoxyremc
140                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimic + denitr(ji,jj,jk) + zoxyremc
141                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimic + zoxyremc + ( rdenit + 1.) * denitr(ji,jj,jk) )
142               ELSE  ! PISCES-QUOTA (p5z)
143                  zremikn = xremikn / xremikc * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
144                  zremikp = xremikp / xremikc * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
145                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zremikp * ( zolimic + denitr(ji,jj,jk) + zoxyremc )
146                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zremikn * ( zolimic + denitr(ji,jj,jk) + zoxyremc )
147                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zremikn * ( zolimic + denitr(ji,jj,jk) + zoxyremc )
148                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zremikp * ( zolimic + denitr(ji,jj,jk) + zoxyremc )
149                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zremikn * ( zolimic + zoxyremc + ( rdenit + 1.) * denitr(ji,jj,jk) )
150               ENDIF
151            END DO
152         END DO
153      END DO
154
155      DO jk = 1, jpkm1
156         DO jj = 1, jpj
157            DO ji = 1, jpi
158               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
159               ! below 2 umol/L. Inhibited at strong light
160               ! ----------------------------------------------------------
161               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
162               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
163               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
164               zdenitnh4 = MAX(0., MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenita, zdenitnh4 ) ) 
165               ! Update of the tracers trends
166               ! ----------------------------
167               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
168               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
169               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
170               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
171            END DO
172         END DO
173      END DO
174
175       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
176         WRITE(charout, FMT="('rem1')")
177         CALL prt_ctl_trc_info(charout)
178         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
179       ENDIF
180
181      DO jk = 1, jpkm1
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184
185               ! Bacterial uptake of iron. No iron is available in DOC. So
186               ! Bacteria are obliged to take up iron from the water. Some
187               ! studies (especially at Papa) have shown this uptake to be significant
188               ! ---------------------------------------------------------------------
189               zbactfer = feratb * 0.6_wp * xstep * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk) * trb(ji,jj,jk,jpfer)    &
190                  &       / ( xkferb + trb(ji,jj,jk,jpfer) ) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
191
192               ! Only the transfer of iron from its dissolved form to particles
193               ! is treated here. The GGE of bacteria supposed to be equal to
194               ! 0.33. This is hard-coded.
195               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.18
196               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.15
197               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.03
198               zfebact(ji,jj,jk)   = zbactfer * 0.18
199               blim(ji,jj,jk)      = xlimbacl(ji,jj,jk)  * zdepbac(ji,jj,jk) / 1.e-6
200            END DO
201         END DO
202      END DO
203
204       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
205         WRITE(charout, FMT="('rem2')")
206         CALL prt_ctl_trc_info(charout)
207         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
208       ENDIF
209
210      ! Initialization of the array which contains the labile fraction
211      ! of bSi. Set to a constant in the upper ocean
212      ! ---------------------------------------------------------------
213      DO jk = 1, jpkm1
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216
217               ! Remineralization rate of BSi dependent on T and saturation
218               ! The parameterization is taken from Ridgwell et al. (2002)
219               ! ---------------------------------------------------------
220               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
221               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
222               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
223               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
224
225               ! Two fractions of bSi are considered : a labile one and a more
226               ! refractory one based on the commonly observed two step
227               ! dissolution of bSi (initial rapid dissolution followed by
228               ! more slowly dissolution).
229               ! Computation of the vertical evolution of the labile fraction
230               ! of bSi. This is computed assuming steady state.
231               ! --------------------------------------------------------------
232               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
233                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
234                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
235                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
236                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
237                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
238               ENDIF
239               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
240               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
241
242               ! Update of the TRA arrays
243               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
244               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
245            END DO
246         END DO
247      END DO
248
249      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
250         WRITE(charout, FMT="('rem3')")
251         CALL prt_ctl_trc_info(charout)
252         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
253       ENDIF
254
255      IF( knt == nrdttrc ) THEN
256          ALLOCATE( zw3d(jpi,jpj,jpk) )
257          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
258          !
259          IF( iom_use( "REMIN" ) )  THEN
260              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
261              CALL iom_put( "REMIN"  , zw3d )
262          ENDIF
263          IF( iom_use( "DENIT" ) )  THEN
264              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
265              CALL iom_put( "DENIT"  , zw3d )
266          ENDIF
267          IF( iom_use( "BACT" ) )  THEN
268               zw3d(:,:,:) = zdepbac(:,:,:) * 1.E6 * tmask(:,:,:)  ! Bacterial biomass
269               CALL iom_put( "BACT", zw3d )
270          ENDIF
271          IF( iom_use( "FEBACT" ) )  THEN
272               zw3d(:,:,:) = zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zfact   ! Bacterial iron consumption
273               CALL iom_put( "FEBACT" , zw3d )
274          ENDIF
275          !
276          DEALLOCATE( zw3d )
277       ENDIF
278      !
279      IF( ln_timing )   CALL timing_stop('p4z_rem')
280      !
281   END SUBROUTINE p4z_rem
282
283
284   SUBROUTINE p4z_rem_init
285      !!----------------------------------------------------------------------
286      !!                  ***  ROUTINE p4z_rem_init  ***
287      !!
288      !! ** Purpose :   Initialization of remineralization parameters
289      !!
290      !! ** Method  :   Read the nampisrem namelist and check the parameters
291      !!      called at the first timestep
292      !!
293      !! ** input   :   Namelist nampisrem
294      !!
295      !!----------------------------------------------------------------------
296      NAMELIST/nampisrem/ nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
297         &                xremikc, xremikn, xremikp
298      INTEGER :: ios                 ! Local integer output status for namelist read
299      !!----------------------------------------------------------------------
300      !
301      IF(lwp) THEN
302         WRITE(numout,*)
303         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
304         WRITE(numout,*) '~~~~~~~~~~~~'
305      ENDIF
306      !
307      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
308      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
309901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist' )
310      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
311      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
312902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist' )
313      IF(lwm) WRITE( numonp, nampisrem )
314
315      IF(lwp) THEN                         ! control print
316         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
317         IF( ln_p4z ) THEN
318            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
319         ELSE
320            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
321            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
322            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
323         ENDIF
324         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
325         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
326         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
327         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
328         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
329         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
330      ENDIF
331      !
332      denitr(:,:,:) = 0._wp
333      !
334   END SUBROUTINE p4z_rem_init
335
336
337   INTEGER FUNCTION p4z_rem_alloc()
338      !!----------------------------------------------------------------------
339      !!                     ***  ROUTINE p4z_rem_alloc  ***
340      !!----------------------------------------------------------------------
341      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
342      !
343      IF( p4z_rem_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' )
344      !
345   END FUNCTION p4z_rem_alloc
346
347   !!======================================================================
348END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.