New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zlys.F90 @ 14276

Last change on this file since 14276 was 14276, checked in by aumont, 3 years ago

numerous updates to PISCES, PISCES-QUOTA and the sediment module
  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   REAL(wp), PUBLIC ::   kdca   !: diss. rate constant calcite
32   REAL(wp), PUBLIC ::   nca    !: order of reaction for calcite dissolution
33
34   INTEGER  ::   rmtss              ! number of seconds per month
35   REAL(wp) ::   calcon = 1.03E-2   ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
36 
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE p4z_lys( kt, knt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_lys  ***
48      !!
49      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
50      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
51      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
52      !!
53      !! ** Method  : - pH is computed using the MOCSY module and dissolution
54      !!                is a function of the saturation state of CO3
55      !!---------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
57      !
58      INTEGER  ::   ji, jj, jk, jn
59      REAL(wp) ::   zdispot, zfact, zcalcon, zkd
60      REAL(wp) ::   zomegaca, zexcess, zexcess0
61      CHARACTER (len=25) ::   charout
62      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3, zcaldiss, zhinit, zhi, zco3sat
63      !!---------------------------------------------------------------------
64      !
65      IF( ln_timing )  CALL timing_start('p4z_lys')
66      !
67      zco3    (:,:,:) = 0._wp
68      zcaldiss(:,:,:) = 0._wp     ;     zco3sat(:,:,:) = 0._wp
69      zhinit  (:,:,:) = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
70      !
71      !     -------------------------------------------
72      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
73      !     -------------------------------------------
74      !     Call the carbonate chemistry subroutine to compute pH
75      !     This subroutine is in the p4zche module
76      CALL solve_at_general( zhinit, zhi )
77
78      DO jk = 1, jpkm1
79         DO jj = 1, jpj
80            DO ji = 1, jpi
81               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
82                  &             + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
83               hi  (ji,jj,jk) = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
84            END DO
85         END DO
86      END DO
87
88      !     ---------------------------------------------------------
89      !     CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
90      !     DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
91      !     MGCO3)
92      !     ---------------------------------------------------------
93
94      DO jk = 1, jpkm1
95         DO jj = 1, jpj
96            DO ji = 1, jpi
97
98               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
99               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
100               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
101               zfact    = rhop(ji,jj,jk) / 1000._wp
102               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
103               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
104
105               ! SET DEGREE OF UNDER-/SUPERSATURATION
106               excess(ji,jj,jk) = 1._wp - zomegaca
107               zexcess0 = MAX( 0., excess(ji,jj,jk) )
108               IF (zomegaca < 0.8) THEN
109                  zexcess  = zexcess0**nca
110                 ! AMOUNT CACO3 THAT RE-ENTERS SOLUTION
111                  zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
112               ELSE
113                  zkd = kdca * 0.1**(nca - 0.4)
114                  zexcess  = zexcess0**0.4
115                  zdispot = zkd * zexcess * trb(ji,jj,jk,jpcal)
116               ENDIF
117
118               ! CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
119               ! AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
120               zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
121               !
122               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
123               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
124               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
125            END DO
126         END DO
127      END DO
128
129      ! output of diagnostics
130      IF( lk_iomput .AND. knt == nrdttrc ) THEN
131         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( MAX( hi(:,:,:), rtrn ) ) * tmask(:,:,:) )
132         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)     * 1.e+3               * tmask(:,:,:) )
133         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:)  * 1.e+3               * tmask(:,:,:) )
134         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r     * tmask(:,:,:) )
135      ENDIF
136      !
137      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
138        WRITE(charout, FMT="('lys ')")
139        CALL prt_ctl_trc_info(charout)
140        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
141      ENDIF
142      !
143      IF( ln_timing )   CALL timing_stop('p4z_lys')
144      !
145   END SUBROUTINE p4z_lys
146
147
148   SUBROUTINE p4z_lys_init
149      !!----------------------------------------------------------------------
150      !!                  ***  ROUTINE p4z_lys_init  ***
151      !!
152      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
153      !!
154      !! ** Method  :   Read the nampiscal namelist and check the parameters
155      !!      called at the first timestep (nittrc000)
156      !!
157      !! ** input   :   Namelist nampiscal
158      !!
159      !!----------------------------------------------------------------------
160      INTEGER ::   ios   ! Local integer
161      !
162      NAMELIST/nampiscal/ kdca, nca
163      !!----------------------------------------------------------------------
164      IF(lwp) THEN
165         WRITE(numout,*)
166         WRITE(numout,*) 'p4z_lys_init : initialization of CaCO3 dissolution'
167         WRITE(numout,*) '~~~~~~~~~~~~'
168      ENDIF
169      !
170      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
171      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
172901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampiscal in reference namelist' )
173      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
174      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
175902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampiscal in configuration namelist' )
176      IF(lwm) WRITE( numonp, nampiscal )
177      !
178      IF(lwp) THEN                         ! control print
179         WRITE(numout,*) '   Namelist : nampiscal'
180         WRITE(numout,*) '      diss. rate constant calcite (per month)        kdca =', kdca
181         WRITE(numout,*) '      order of reaction for calcite dissolution      nca  =', nca
182      ENDIF
183      !
184      ! Number of seconds per month
185      rmtss =  nyear_len(1) * rday / raamo
186      !
187   END SUBROUTINE p4z_lys_init
188
189   !!======================================================================
190END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.