New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zfechem.F90 @ 14276

Last change on this file since 14276 was 14276, checked in by aumont, 3 years ago

numerous updates to PISCES, PISCES-QUOTA and the sediment module
  • Property svn:keywords set to Id
File size: 14.3 KB
Line 
1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
7   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
8   !!----------------------------------------------------------------------
9   !!   p4z_fechem       : Compute remineralization/scavenging of iron
10   !!   p4z_fechem_init  : Initialisation of parameters for remineralisation
11   !!   p4z_fechem_alloc : Allocate remineralisation variables
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zche          ! chemical model
17   USE p4zsbc          ! Boundary conditions from sediments
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_fechem        ! called in p4zbio.F90
25   PUBLIC   p4z_fechem_init   ! called in trcsms_pisces.F90
26
27   LOGICAL          ::   ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
28   REAL(wp), PUBLIC ::   xlam1        !: scavenging rate of Iron
29   REAL(wp), PUBLIC ::   xlamdust     !: scavenging rate of Iron by dust
30   REAL(wp), PUBLIC ::   ligand       !: ligand concentration in the ocean
31   REAL(wp), PUBLIC ::   kfep         !: rate constant for nanoparticle formation
32   REAL(wp), PUBLIC ::   scaveff      !: Fraction of scavenged iron that is considered as being subject to solubilization
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE p4z_fechem( kt, knt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE p4z_fechem  ***
44      !!
45      !! ** Purpose :   Compute remineralization/scavenging of iron
46      !!
47      !! ** Method  :   A simple chemistry model of iron from Aumont and Bopp (2006)
48      !!                based on one ligand and one inorganic form
49      !!---------------------------------------------------------------------
50      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
51      !
52      INTEGER  ::   ji, jj, jk, jic, jn
53      REAL(wp) ::   zlam1a, zlam1b
54      REAL(wp) ::   zkeq, zfesatur, zfecoll, fe3sol, zligco
55      REAL(wp) ::   zscave, zaggdfea, zaggdfeb, ztrc, zdust, zklight
56      REAL(wp) ::   ztfe, zhplus, zxlam, zaggliga, zaggligb
57      REAL(wp) ::   zrfact2
58      CHARACTER (len=25) :: charout
59      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zTL1, zFe3, ztotlig, precip, precipno3, zFeL1
60      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zcoll3d, zscav3d, zlcoll3d, zprecip3d
61      !!---------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('p4z_fechem')
64      !
65      zFe3 (:,:,:) = 0.   ;   zFeL1(:,:,:) = 0.
66      zTL1 (:,:,:) = 0.
67
68      ! Total ligand concentration : Ligands can be chosen to be constant or variable
69      ! Parameterization from Pham and Ito (2018)
70      ! -------------------------------------------------
71      IF( ln_ligvar ) THEN
72         ztotlig(:,:,:) =  0.09 * 0.667 * trb(:,:,:,jpdoc) * 1E6 + ligand * 1E9 + MAX(0., chemo2(:,:,:) - trb(:,:,:,jpoxy) ) / 400.E-6
73         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
74      ELSE
75        IF( ln_ligand ) THEN  ;   ztotlig(:,:,:) = trb(:,:,:,jplgw) * 1E9
76        ELSE                  ;   ztotlig(:,:,:) = ligand * 1E9 
77        ENDIF
78      ENDIF
79
80      ! ------------------------------------------------------------
81      !  from Aumont and Bopp (2006)
82      ! This model is based on one ligand, Fe2+ and Fe3+
83      ! Chemistry is supposed to be fast enough to be at equilibrium
84      ! ------------------------------------------------------------
85      DO jk = 1, jpkm1
86         DO jj = 1, jpj
87            DO ji = 1, jpi
88               zTL1(ji,jj,jk)  = ztotlig(ji,jj,jk)
89               zkeq            = fekeq(ji,jj,jk)
90               zklight         = 4.77E-7 * etot(ji,jj,jk) * 0.5 / 10**-6.3
91               zfesatur        = zTL1(ji,jj,jk) * 1E-9
92               ztfe            = (1.0 + zklight) * trb(ji,jj,jk,jpfer) 
93               ! Fe' is the root of a 2nd order polynom
94               zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq + zklight + consfe3(ji,jj,jk)/10**-6.3 - zkeq * trb(ji,jj,jk,jpfer) )               &
95                  &              + SQRT( ( 1. + zfesatur * zkeq + zklight + consfe3(ji,jj,jk)/10**-6.3 - zkeq * trb(ji,jj,jk,jpfer) )**2       &
96                  &              + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
97               zFeL1(ji,jj,jk) = MAX( 0., trb(ji,jj,jk,jpfer) - zFe3(ji,jj,jk) )
98           END DO
99         END DO
100      END DO
101      !
102      plig(:,:,:) =  MAX( 0., ( zFeL1(:,:,:) / ( trb(:,:,:,jpfer) + rtrn ) ) )
103      !
104      zdust = 0.         ! if no dust available
105      DO jk = 1, jpkm1
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
109               ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
110               ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
111               ! --------------------------------------------------------------------------------------
112               zhplus  = max( rtrn, hi(ji,jj,jk) )
113               fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
114               &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
115               &         + fesol(ji,jj,jk,5) / zhplus )
116               !
117               zfecoll = 0.5 * zFeL1(ji,jj,jk)
118               ! precipitation of Fe3+, creation of nanoparticles
119               precip(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) - fe3sol ) ) * kfep * xstep * ( 1.0 - nitrfac(ji,jj,jk) ) 
120               ! Precipitation of Fe2+ due to oxidation by NO3 (Croot et al., 2019)
121               ! This occurs in anoxic waters only
122               precipno3(ji,jj,jk) = 2.0 * 130.0 * trb(ji,jj,jk,jpno3) * nitrfac(ji,jj,jk) * xstep * zFe3(ji,jj,jk)
123               !
124               ztrc   = ( trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + trb(ji,jj,jk,jpcal) + trb(ji,jj,jk,jpgsi) ) * 1.e6 
125               ztrc = MAX( rtrn, ztrc )
126               IF( ln_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk)
127               zxlam  = MAX( 1.E-3, (1. - EXP(-2 * trb(ji,jj,jk,jpoxy) / 100.E-6 ) ))
128               zlam1b = 3.e-5 + ( xlamdust * zdust + xlam1 * ztrc ) * zxlam
129               zscave = zFe3(ji,jj,jk) * zlam1b * xstep
130
131               ! Compute the coagulation of colloidal iron. This parameterization
132               ! could be thought as an equivalent of colloidal pumping.
133               ! It requires certainly some more work as it is very poorly constrained.
134               ! ----------------------------------------------------------------
135               zlam1a   = ( 12.0  * 0.3 * trb(ji,jj,jk,jpdoc) + 9.05  * trb(ji,jj,jk,jppoc) ) * xdiss(ji,jj,jk)    &
136                   &    + ( 2.49  * trb(ji,jj,jk,jppoc) )     &
137                   &    + ( 127.8 * 0.3 * trb(ji,jj,jk,jpdoc) + 725.7 * trb(ji,jj,jk,jppoc) )
138               zaggdfea = zlam1a * xstep * zfecoll
139               !
140               zlam1b   = ( 1.94 * xdiss(ji,jj,jk) + 1.37 ) * trb(ji,jj,jk,jpgoc)
141               zaggdfeb = zlam1b * xstep * zfecoll
142               !
143               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zscave - zaggdfea - zaggdfeb &
144               &                     - precip(ji,jj,jk) - precipno3(ji,jj,jk)
145               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * scaveff * trb(ji,jj,jk,jppoc) / ztrc
146               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zscave * scaveff * trb(ji,jj,jk,jpgoc) / ztrc
147
148               ! Precipitated iron is supposed to be permanently lost.
149               ! Scavenged iron is supposed to be released back to seawater
150               ! when POM is solubilized. This is highly uncertain as probably
151               ! a significant part of it may be rescavenged back onto
152               ! the particles. An efficiency factor is applied that is read
153               ! in the namelist.
154               ! See for instance Tagliabue et al. (2019).
155               ! Aggregated FeL is considered as biogenic Fe as it
156               ! probably remains  complexed when the particle is solubilized.
157               ! -------------------------------------------------------------
158               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zaggdfea
159               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggdfeb
160               zscav3d(ji,jj,jk)   = zscave 
161               zcoll3d(ji,jj,jk)   = zaggdfea + zaggdfeb
162               zprecip3d(ji,jj,jk) = precip(ji,jj,jk) + precipno3(ji,jj,jk)
163               !
164            END DO
165         END DO
166      END DO
167      !
168      !  Define the bioavailable fraction of iron
169      !  ----------------------------------------
170      biron(:,:,:) = trb(:,:,:,jpfer) 
171      !
172      IF( ln_ligand ) THEN
173         !
174         DO jk = 1, jpkm1
175            DO jj = 1, jpj
176               DO ji = 1, jpi
177
178                  ! Coagulation of ligands due to various processes (Brownian, shear, diff. sedimentation
179                  ! Coefficients are taken from p4zagg
180                  ! -------------------------------------------------------------------------------------
181                  zlam1a   = ( 12.0  * 0.3 * trb(ji,jj,jk,jpdoc) + 9.05  * trb(ji,jj,jk,jppoc) ) * xdiss(ji,jj,jk)    &
182                      &    + ( 2.49  * trb(ji,jj,jk,jppoc) )     &
183                      &    + ( 127.8 * 0.3 * trb(ji,jj,jk,jpdoc) + 725.7 * trb(ji,jj,jk,jppoc) )
184                  !
185                  zlam1b   = ( 1.94 * xdiss(ji,jj,jk) + 1.37 ) * trb(ji,jj,jk,jpgoc)
186                  ! 50% of the ligands are supposed to be in the colloidal size fraction
187                  ! as for FeL
188                  zligco   = 0.5 * trb(ji,jj,jk,jplgw)
189                  zaggliga = zlam1a * xstep * zligco 
190                  zaggligb = zlam1b * xstep * zligco
191                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) - zaggliga - zaggligb
192                  zlcoll3d(ji,jj,jk)  = zaggliga + zaggligb
193               END DO
194            END DO
195         END DO
196         !
197      ENDIF
198      !  Output of some diagnostics variables
199      !     ---------------------------------
200      IF( lk_iomput .AND. knt == nrdttrc ) THEN
201         zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
202         IF( iom_use("Fe3")    )  CALL iom_put("Fe3"    , zFe3   (:,:,:)       * tmask(:,:,:) )   ! Fe3+
203         IF( iom_use("FeL1")   )  CALL iom_put("FeL1"   , zFeL1  (:,:,:)       * tmask(:,:,:) )   ! FeL1
204         IF( iom_use("TL1")    )  CALL iom_put("TL1"    , zTL1   (:,:,:)       * tmask(:,:,:) )   ! TL1
205         IF( iom_use("Totlig") )  CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
206         IF( iom_use("Biron")  )  CALL iom_put("Biron"  , biron  (:,:,:)  * 1e9 * tmask(:,:,:) )   ! biron
207         IF( iom_use("FESCAV") )  CALL iom_put("FESCAV" , zscav3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
208         IF( iom_use("FECOLL") )  CALL iom_put("FECOLL" , zcoll3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
209         IF( iom_use("FEPREC") )  CALL iom_put("FEPREC" , zprecip3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
210         IF( iom_use("LGWCOLL"))  CALL iom_put("LGWCOLL", zlcoll3d(:,:,:) * 1e9 * tmask(:,:,:) * zrfact2 )
211      ENDIF
212
213      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
214         WRITE(charout, FMT="('fechem')")
215         CALL prt_ctl_trc_info(charout)
216         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
217      ENDIF
218      !
219      IF( ln_timing )   CALL timing_stop('p4z_fechem')
220      !
221   END SUBROUTINE p4z_fechem
222
223
224   SUBROUTINE p4z_fechem_init
225      !!----------------------------------------------------------------------
226      !!                  ***  ROUTINE p4z_fechem_init  ***
227      !!
228      !! ** Purpose :   Initialization of iron chemistry parameters
229      !!
230      !! ** Method  :   Read the nampisfer namelist and check the parameters
231      !!      called at the first timestep
232      !!
233      !! ** input   :   Namelist nampisfer
234      !!
235      !!----------------------------------------------------------------------
236      INTEGER ::   ios   ! Local integer
237      !!
238      NAMELIST/nampisfer/ ln_ligvar, xlam1, xlamdust, ligand, kfep, scaveff 
239      !!----------------------------------------------------------------------
240      !
241      IF(lwp) THEN
242         WRITE(numout,*)
243         WRITE(numout,*) 'p4z_rem_init : Initialization of iron chemistry parameters'
244         WRITE(numout,*) '~~~~~~~~~~~~'
245      ENDIF
246      !
247      REWIND( numnatp_ref )            ! Namelist nampisfer in reference namelist : Pisces iron chemistry
248      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
249901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisfer in reference namelist' )
250      REWIND( numnatp_cfg )            ! Namelist nampisfer in configuration namelist : Pisces iron chemistry
251      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
252902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisfer in configuration namelist' )
253      IF(lwm) WRITE( numonp, nampisfer )
254
255      IF(lwp) THEN                     ! control print
256         WRITE(numout,*) '   Namelist : nampisfer'
257         WRITE(numout,*) '      variable concentration of ligand          ln_ligvar    =', ln_ligvar
258         WRITE(numout,*) '      scavenging rate of Iron                   xlam1        =', xlam1
259         WRITE(numout,*) '      scavenging rate of Iron by dust           xlamdust     =', xlamdust
260         WRITE(numout,*) '      ligand concentration in the ocean         ligand       =', ligand
261         WRITE(numout,*) '      rate constant for nanoparticle formation  kfep         =', kfep
262         WRITE(numout,*) '      Scavenged iron that is added to POFe      scaveff      =', scaveff
263      ENDIF
264      !
265   END SUBROUTINE p4z_fechem_init
266   
267   !!======================================================================
268END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.