New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/DIA/diaharm.F90 @ 12065

Last change on this file since 12065 was 12065, checked in by smueller, 5 years ago

Synchronizing with /NEMO/trunk@12055 (ticket #2194)
  • Property svn:keywords set to Id
File size: 18.6 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8   USE oce             ! ocean dynamics and tracers variables
9   USE dom_oce         ! ocean space and time domain
10   USE phycst
11   USE daymod
12   USE tide_mod
13   USE sbctide         ! Tidal forcing or not
14   !
15   USE in_out_manager  ! I/O units
16   USE iom             ! I/0 library
17   USE ioipsl          ! NetCDF IPSL library
18   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
19   USE timing          ! preformance summary
20   USE lib_mpp           ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24   
25   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
26   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
27
28   !                         !!** namelist variables **
29   LOGICAL, PUBLIC ::   ln_diaharm    ! Choose tidal harmonic output or not
30   INTEGER         ::   nit000_han    ! First time step used for harmonic analysis
31   INTEGER         ::   nitend_han    ! Last time step used for harmonic analysis
32   INTEGER         ::   nstep_han     ! Time step frequency for harmonic analysis
33   INTEGER         ::   nb_ana        ! Number of harmonics to analyse
34
35   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
37
38   INTEGER ::   ninco, nsparse
39   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
40   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
41   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
42   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
43   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
44   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
45
46   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
47
48   PUBLIC   dia_harm        ! routine called by step.F90
49   PUBLIC   dia_harm_init   ! routine called by nemogcm.F90
50
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE dia_harm_init 
59      !!----------------------------------------------------------------------
60      !!                 ***  ROUTINE dia_harm_init  ***
61      !!         
62      !! ** Purpose :   Initialization of tidal harmonic analysis
63      !!
64      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
65      !!
66      !!--------------------------------------------------------------------
67      INTEGER ::   jh, nhan, ji
68      INTEGER ::   ios                 ! Local integer output status for namelist read
69      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   tide_harmonics  ! Oscillation parameters of selected tidal components
70
71      NAMELIST/nam_diaharm/ ln_diaharm, nit000_han, nitend_han, nstep_han, tname
72      !!----------------------------------------------------------------------
73
74      IF(lwp) THEN
75         WRITE(numout,*)
76         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
77         WRITE(numout,*) '~~~~~~~ '
78      ENDIF
79      !
80      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
81      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
82901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist' )
83      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
84      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
85902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist' )
86      IF(lwm) WRITE ( numond, nam_diaharm )
87      !
88      IF(lwp) THEN
89         WRITE(numout,*) 'Tidal diagnostics = ', ln_diaharm
90         WRITE(numout,*) '   First time step used for analysis:         nit000_han= ', nit000_han
91         WRITE(numout,*) '   Last  time step used for analysis:         nitend_han= ', nitend_han
92         WRITE(numout,*) '   Time step frequency for harmonic analysis: nstep_han = ', nstep_han
93      ENDIF
94
95      IF( ln_diaharm .AND. .NOT.ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
96
97      IF( ln_diaharm ) THEN
98
99         !
100         ! Basic checks on harmonic analysis time window:
101         ! ----------------------------------------------
102         IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
103            &                                       ' restart capability not implemented' )
104         IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
105            &                                       'restart capability not implemented' )
106
107         IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
108            &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
109         !
110         ! Initialize oscillation parameters for tidal components that have been
111         ! selected for harmonic analysis
112         ! ---------------------------------------------------------------------
113         CALL tide_init_harmonics(tname, tide_harmonics)
114         ! Number of tidal components selected for harmonic analysis
115         nb_ana = size(tide_harmonics)
116         !
117         IF(lwp) THEN
118            WRITE(numout,*) '        Namelist nam_diaharm'
119            WRITE(numout,*) '        nb_ana    = ', nb_ana
120            CALL flush(numout)
121         ENDIF
122         !
123         IF (nb_ana > jpmax_harmo) THEN
124            WRITE(ctmp1,*) ' nb_ana must be lower than jpmax_harmo'
125            WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
126            CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
127         ENDIF
128
129         IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
130
131         DO jh = 1, nb_ana
132            IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',tide_harmonics(jh)%omega
133         END DO
134
135         ! Initialize temporary arrays:
136         ! ----------------------------
137         ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
138         ana_temp(:,:,:,:) = 0._wp
139
140      ENDIF
141
142   END SUBROUTINE dia_harm_init
143
144
145   SUBROUTINE dia_harm ( kt )
146      !!----------------------------------------------------------------------
147      !!                 ***  ROUTINE dia_harm  ***
148      !!         
149      !! ** Purpose :   Tidal harmonic analysis main routine
150      !!
151      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
152      !!
153      !!--------------------------------------------------------------------
154      INTEGER, INTENT( IN ) :: kt
155      !
156      INTEGER  :: ji, jj, jh, jc, nhc
157      REAL(wp) :: ztime, ztemp
158      !!--------------------------------------------------------------------
159      IF( ln_timing )   CALL timing_start('dia_harm')
160      !
161      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
162         !
163         ztime = (kt-nit000+1) * rdt 
164         !
165         nhc = 0
166         DO jh = 1, nb_ana
167            DO jc = 1, 2
168               nhc = nhc+1
169               ztemp =(     MOD(jc,2) * tide_harmonics(jh)%f *COS(tide_harmonics(jh)%omega*ztime + &
170                  &                                 tide_harmonics(jh)%v0 + tide_harmonics(jh)%u)  &
171                  &    +(1.-MOD(jc,2))* tide_harmonics(jh)%f *SIN(tide_harmonics(jh)%omega*ztime + &
172                  &                                 tide_harmonics(jh)%v0 + tide_harmonics(jh)%u))
173                  !
174               DO jj = 1,jpj
175                  DO ji = 1,jpi
176                     ! Elevation
177                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*ssmask (ji,jj)       
178                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*ssumask(ji,jj)
179                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*ssvmask(ji,jj)
180                  END DO
181               END DO
182               !
183            END DO
184         END DO
185         !       
186      END IF
187      !
188      IF( kt == nitend_han )   CALL dia_harm_end
189      !
190      IF( ln_timing )   CALL timing_stop('dia_harm')
191      !
192   END SUBROUTINE dia_harm
193
194
195   SUBROUTINE dia_harm_end
196      !!----------------------------------------------------------------------
197      !!                 ***  ROUTINE diaharm_end  ***
198      !!         
199      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
200      !!
201      !! ** Action  :  Decompose the signal on the harmonic constituents
202      !!
203      !!--------------------------------------------------------------------
204      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
205      INTEGER :: ksp, kun, keq
206      REAL(wp) :: ztime, ztime_ini, ztime_end
207      REAL(wp) :: X1, X2
208      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
209      !!--------------------------------------------------------------------
210      !
211      IF(lwp) WRITE(numout,*)
212      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
213      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
214
215      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
216      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
217      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
218
219      ninco = 2*nb_ana
220
221      ksp = 0
222      keq = 0       
223      DO jn = 1, nhan
224         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
225         keq = keq + 1
226         kun = 0
227         DO jh = 1, nb_ana
228            DO jc = 1, 2
229               kun = kun + 1
230               ksp = ksp + 1
231               nisparse(ksp) = keq
232               njsparse(ksp) = kun
233               valuesparse(ksp) = (   MOD(jc,2) * tide_harmonics(jh)%f * COS(tide_harmonics(jh)%omega*ztime &
234                  &                                          + tide_harmonics(jh)%v0 + tide_harmonics(jh)%u)   &
235                  &             + (1.-MOD(jc,2))* tide_harmonics(jh)%f * SIN(tide_harmonics(jh)%omega*ztime &
236                  &                                          + tide_harmonics(jh)%v0 + tide_harmonics(jh)%u) )
237            END DO
238         END DO
239      END DO
240
241      nsparse = ksp
242
243      ! Elevation:
244      DO jj = 1, jpj
245         DO ji = 1, jpi
246            ! Fill input array
247            kun = 0
248            DO jh = 1, nb_ana
249               DO jc = 1, 2
250                  kun = kun + 1
251                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
252               END DO
253            END DO
254
255            CALL SUR_DETERMINE(jj)
256
257            ! Fill output array
258            DO jh = 1, nb_ana
259               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
260               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
261            END DO
262         END DO
263      END DO
264
265      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
266         &      out_u  (jpi,jpj,2*nb_ana),   &
267         &      out_v  (jpi,jpj,2*nb_ana)  )
268
269      DO jj = 1, jpj
270         DO ji = 1, jpi
271            DO jh = 1, nb_ana 
272               X1 = ana_amp(ji,jj,jh,1)
273               X2 =-ana_amp(ji,jj,jh,2)
274               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
275               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
276            END DO
277         END DO
278      END DO
279
280      ! ubar:
281      DO jj = 1, jpj
282         DO ji = 1, jpi
283            ! Fill input array
284            kun=0
285            DO jh = 1,nb_ana
286               DO jc = 1,2
287                  kun = kun + 1
288                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
289               END DO
290            END DO
291
292            CALL SUR_DETERMINE(jj+1)
293
294            ! Fill output array
295            DO jh = 1, nb_ana
296               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
297               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
298            END DO
299
300         END DO
301      END DO
302
303      DO jj = 1, jpj
304         DO ji = 1, jpi
305            DO jh = 1, nb_ana 
306               X1= ana_amp(ji,jj,jh,1)
307               X2=-ana_amp(ji,jj,jh,2)
308               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
309               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
310            ENDDO
311         ENDDO
312      ENDDO
313
314      ! vbar:
315      DO jj = 1, jpj
316         DO ji = 1, jpi
317            ! Fill input array
318            kun=0
319            DO jh = 1,nb_ana
320               DO jc = 1,2
321                  kun = kun + 1
322                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
323               END DO
324            END DO
325
326            CALL SUR_DETERMINE(jj+1)
327
328            ! Fill output array
329            DO jh = 1, nb_ana
330               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
331               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
332            END DO
333
334         END DO
335      END DO
336
337      DO jj = 1, jpj
338         DO ji = 1, jpi
339            DO jh = 1, nb_ana 
340               X1=ana_amp(ji,jj,jh,1)
341               X2=-ana_amp(ji,jj,jh,2)
342               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
343               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
344            END DO
345         END DO
346      END DO
347      !
348      CALL dia_wri_harm ! Write results in files
349      !
350   END SUBROUTINE dia_harm_end
351
352
353   SUBROUTINE dia_wri_harm
354      !!--------------------------------------------------------------------
355      !!                 ***  ROUTINE dia_wri_harm  ***
356      !!         
357      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
358      !!--------------------------------------------------------------------
359      CHARACTER(LEN=lc) :: cltext
360      CHARACTER(LEN=lc) ::   &
361         cdfile_name_T   ,   & ! name of the file created (T-points)
362         cdfile_name_U   ,   & ! name of the file created (U-points)
363         cdfile_name_V         ! name of the file created (V-points)
364      INTEGER  ::   jh
365      !!----------------------------------------------------------------------
366
367      IF(lwp) WRITE(numout,*) '  '
368      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
369      IF(lwp) WRITE(numout,*) '  '
370
371      ! A) Elevation
372      !/////////////
373      !
374      DO jh = 1, nb_ana
375      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
376      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
377      END DO
378
379      ! B) ubar
380      !/////////
381      !
382      DO jh = 1, nb_ana
383      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
384      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
385      END DO
386
387      ! C) vbar
388      !/////////
389      !
390      DO jh = 1, nb_ana
391         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
392         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
393      END DO
394      !
395   END SUBROUTINE dia_wri_harm
396
397
398   SUBROUTINE SUR_DETERMINE(init)
399      !!---------------------------------------------------------------------------------
400      !!                      *** ROUTINE SUR_DETERMINE ***
401      !!   
402      !!   
403      !!       
404      !!---------------------------------------------------------------------------------
405      INTEGER, INTENT(in) ::   init 
406      !
407      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jh1_sd, jh2_sd
408      REAL(wp)                        :: zval1, zval2, zx1
409      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
410      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
411      !---------------------------------------------------------------------------------
412      !           
413      IF( init == 1 ) THEN
414         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
415         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
416         !
417         ztmp3(:,:) = 0._wp
418         !
419         DO jh1_sd = 1, nsparse
420            DO jh2_sd = 1, nsparse
421               nisparse(jh2_sd) = nisparse(jh2_sd)
422               njsparse(jh2_sd) = njsparse(jh2_sd)
423               IF( nisparse(jh2_sd) == nisparse(jh1_sd) ) THEN
424                  ztmp3(njsparse(jh1_sd),njsparse(jh2_sd)) = ztmp3(njsparse(jh1_sd),njsparse(jh2_sd))  &
425                     &                                     + valuesparse(jh1_sd)*valuesparse(jh2_sd)
426               ENDIF
427            END DO
428         END DO
429         !
430         DO jj_sd = 1 ,ninco
431            ipos1(jj_sd) = jj_sd
432            ipos2(jj_sd) = jj_sd
433         END DO
434         !
435         DO ji_sd = 1 , ninco
436            !
437            !find greatest non-zero pivot:
438            zval1 = ABS(ztmp3(ji_sd,ji_sd))
439            !
440            ipivot(ji_sd) = ji_sd
441            DO jj_sd = ji_sd, ninco
442               zval2 = ABS(ztmp3(ji_sd,jj_sd))
443               IF( zval2 >= zval1 )THEN
444                  ipivot(ji_sd) = jj_sd
445                  zval1         = zval2
446               ENDIF
447            END DO
448            !
449            DO ji1_sd = 1, ninco
450               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
451               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
452               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
453               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
454            END DO
455            !
456            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
457            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
458            ipos1(ji_sd)         = ipos2(ji_sd)
459            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
460            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
461            DO jj_sd = 1, ninco
462               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
463            END DO
464            !
465            DO ji2_sd = ji_sd+1, ninco
466               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
467               DO jj_sd=1,ninco
468                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
469               END DO
470            END DO
471            !
472         END DO
473         !
474      ENDIF ! End init==1
475
476      DO ji_sd = 1, ninco
477         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
478         DO ji2_sd = ji_sd+1, ninco
479            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
480         END DO
481      END DO
482
483      !system solving:
484      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
485      ji_sd = ninco
486      DO ji_sd = ninco-1, 1, -1
487         zx1 = 0._wp
488         DO jj_sd = ji_sd+1, ninco
489            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
490         END DO
491         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
492      END DO
493
494      DO jj_sd =1, ninco
495         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
496      END DO
497      !
498   END SUBROUTINE SUR_DETERMINE
499
500   !!======================================================================
501END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.