MODULE time_mod
  use prec
  PRIVATE

  INTEGER,SAVE :: ncid
  INTEGER,SAVE :: time_counter_id
  INTEGER,SAVE :: it

  REAL(rstd),SAVE :: dt
  REAL(rstd),SAVE :: write_period
  INTEGER,SAVE :: itau_out
  INTEGER,SAVE :: itaumax
  
  PUBLIC create_time_counter_header, update_time_counter, close_time_counter, init_time



CONTAINS
  
  SUBROUTINE init_time
  USE earth_const
  USE ioipsl
  IMPLICIT NONE
  REAL(rstd) :: run_length
  
    dt=90.
    CALL getin('dt',dt)

    itaumax=100
    CALL getin('itaumax',itaumax)

    run_length=dt*itaumax
    CALL getin('run_length',run_length)
    itaumax=run_length/dt
    PRINT *,'itaumax=',itaumax
    dt=dt/scale_factor

    write_period=0
    CALL getin('write_period',write_period)
    write_period=write_period/scale_factor
    itau_out=FLOOR(.5+write_period/dt)
    PRINT *, 'Output frequency (scaled) set to ',write_period, ' : itau_out = ',itau_out
    
    CALL create_time_counter_header
    
  END SUBROUTINE init_time

  SUBROUTINE create_time_counter_header
  USE netcdf_mod
  USE prec
  USE ioipsl
  IMPLICIT NONE
  INTEGER :: status
  INTEGER :: timeid, dtid
  REAL(rstd) :: dt
  CHARACTER(LEN=255) :: time_frequency
  
    status = NF90_CREATE('time_counter.nc', NF90_CLOBBER, ncid)
    status = NF90_DEF_DIM(ncid,'time_counter',NF90_UNLIMITED,timeid)
    status = NF90_DEF_VAR(ncid,'time_counter',NF90_DOUBLE,(/ timeid /),time_counter_id)
    status = NF90_PUT_ATT(ncid,time_counter_id,"long_name","time")
    status = NF90_PUT_ATT(ncid,time_counter_id,"units","seconds since 2000-01-01 00:00:00")
    status = NF90_PUT_ATT(ncid,time_counter_id,"calendar","noleap")
    status = NF90_DEF_VAR(ncid,'mdt',NF90_DOUBLE,varid=dtid)

    WRITE(time_frequency,*) write_period
    PRINT*,TRIM(time_frequency)
    status = NF90_PUT_ATT(ncid,NF90_GLOBAL,"time_frequency",TRIM(time_frequency)//"s")

    status = NF90_ENDDEF(ncid) 

    CALL getin("dt",dt)
    status=NF90_PUT_VAR(ncid,dtid, dt)
    it=0

  END SUBROUTINE create_time_counter_header
  
  SUBROUTINE update_time_counter(time)
  USE netcdf_mod
  USE prec
  IMPLICIT NONE
  REAL(rstd),INTENT(IN) ::time
  INTEGER :: status
  REAL(rstd) ::time_array(1)
    time_array(1)=time
  
    it=it+1
    status=NF90_PUT_VAR(ncid,time_counter_id,time_array,start=(/ it /),count=(/ 1 /))
    status=NF90_SYNC(ncid)
  END SUBROUTINE update_time_counter    
  
  SUBROUTINE close_time_counter
  USE netcdf_mod
  IMPLICIT NONE
    INTEGER :: status
    
    status=NF90_CLOSE(ncid)
    
  END SUBROUTINE  close_time_counter 

END MODULE time_mod