source: codes/icosagcm/trunk/src/advect_tracer.f90 @ 364

Last change on this file since 364 was 364, checked in by dubos, 9 years ago

Bugfix : memory leak in transfert_mpi / New : detect send_message not paired with wait_message
File size: 9.8 KB
Line 
1MODULE advect_tracer_mod
2  USE icosa
3  IMPLICIT NONE
4  PRIVATE
5
6  TYPE(t_field),SAVE,POINTER :: f_normal(:)
7  TYPE(t_field),SAVE,POINTER :: f_tangent(:)
8  TYPE(t_field),SAVE,POINTER :: f_gradq3d(:)
9  TYPE(t_field),SAVE,POINTER :: f_cc(:)  ! starting point of backward-trajectory (Miura approach)
10  TYPE(t_field),SAVE,POINTER :: f_sqrt_leng(:)
11
12  TYPE(t_message),SAVE :: req_u, req_cc, req_wfluxt, req_q, req_rhodz, req_gradq3d
13
14  REAL(rstd), PARAMETER :: pente_max=2.0 ! for vlz
15
16! temporary shared variable for vlz
17  TYPE(t_field),SAVE,POINTER :: f_dzqw(:)   ! vertical finite difference of q
18  TYPE(t_field),SAVE,POINTER :: f_adzqw(:)  ! abs(dzqw)
19  TYPE(t_field),SAVE,POINTER :: f_dzq(:)    ! limited slope of q
20  TYPE(t_field),SAVE,POINTER :: f_wq(:)     ! time-integrated flux of q
21
22  PUBLIC init_advect_tracer, advect_tracer
23
24CONTAINS
25
26  SUBROUTINE init_advect_tracer
27    USE advect_mod
28    USE omp_para
29    REAL(rstd),POINTER :: tangent(:,:)
30    REAL(rstd),POINTER :: normal(:,:)
31    REAL(rstd),POINTER :: sqrt_leng(:)
32    INTEGER :: ind
33
34    CALL allocate_field(f_normal,field_u,type_real,3, name='normal')
35    CALL allocate_field(f_tangent,field_u,type_real,3, name='tangent')
36    CALL allocate_field(f_gradq3d,field_t,type_real,llm,3, name='gradq3d')
37    CALL allocate_field(f_cc,field_u,type_real,llm,3, name='cc')
38    CALL allocate_field(f_sqrt_leng,field_t,type_real, name='sqrt_leng')
39    CALL allocate_field(f_dzqw, field_t, type_real, llm, name='dzqw')
40    CALL allocate_field(f_adzqw, field_t, type_real, llm, name='adzqw')
41    CALL allocate_field(f_dzq, field_t, type_real, llm, name='dzq')
42    CALL allocate_field(f_wq, field_t, type_real, llm+1, name='wq')
43   
44    DO ind=1,ndomain
45       IF (.NOT. assigned_domain(ind)) CYCLE
46       CALL swap_dimensions(ind)
47       CALL swap_geometry(ind)
48       normal=f_normal(ind)
49       tangent=f_tangent(ind)
50       sqrt_leng=f_sqrt_leng(ind)
51       IF (is_omp_level_master) CALL init_advect(normal,tangent,sqrt_leng)
52    END DO
53
54  END SUBROUTINE init_advect_tracer
55
56  SUBROUTINE advect_tracer(f_hfluxt, f_wfluxt,f_u, f_q,f_rhodz)
57    USE advect_mod
58    USE mpipara
59    USE trace
60    USE write_field_mod
61    IMPLICIT NONE
62   
63    TYPE(t_field),POINTER :: f_hfluxt(:)   ! time-integrated horizontal mass flux
64    TYPE(t_field),POINTER :: f_wfluxt(:)   ! time-integrated vertical mass flux
65    TYPE(t_field),POINTER :: f_u(:)        ! velocity (for back-trajectories)
66    TYPE(t_field),POINTER :: f_q(:)        ! tracer
67    TYPE(t_field),POINTER :: f_rhodz(:)    ! mass field at beginning of macro time step
68
69    REAL(rstd),POINTER :: q(:,:,:), normal(:,:), tangent(:,:), sqrt_leng(:), gradq3d(:,:,:), cc(:,:,:)
70    REAL(rstd),POINTER :: hfluxt(:,:), wfluxt(:,:)
71    REAL(rstd),POINTER :: rhodz(:,:), u(:,:) 
72! temporary shared variable for vlz
73    REAL(rstd),POINTER ::  dzqw(:,:)         ! vertical finite difference of q
74    REAL(rstd),POINTER ::  adzqw(:,:)        ! abs(dzqw)
75    REAL(rstd),POINTER ::  dzq(:,:)          ! limited slope of q
76    REAL(rstd),POINTER ::  wq(:,:)           ! time-integrated flux of q
77   
78     INTEGER :: ind,k
79    LOGICAL,SAVE :: first=.TRUE.
80!$OMP THREADPRIVATE(first)
81
82    IF (first) THEN
83      first=.FALSE.
84      CALL init_message(f_u,req_e1_vect,req_u, 'req_u')
85      CALL init_message(f_cc,req_e1_scal,req_cc, 'req_cc')
86      CALL init_message(f_wfluxt,req_i1,req_wfluxt, 'req_wfluxt')
87      CALL init_message(f_q,req_i1,req_q, 'req_q')
88      CALL init_message(f_rhodz,req_i1,req_rhodz, 'req_rhodz')
89      CALL init_message(f_gradq3d,req_i1,req_gradq3d, 'req_gradq3d')
90    ENDIF
91   
92!!$OMP BARRIER
93
94    IF(nqtot<1) RETURN
95    CALL trace_start("advect_tracer") 
96
97    CALL send_message(f_u,req_u)
98    CALL send_message(f_wfluxt,req_wfluxt)
99    CALL send_message(f_q,req_q)
100    CALL send_message(f_rhodz,req_rhodz)
101
102    CALL wait_message(req_u)
103    CALL wait_message(req_wfluxt)
104    CALL wait_message(req_q)
105    CALL wait_message(req_rhodz)
106   
107    ! 1/2 vertical transport + back-trajectories
108    DO ind=1,ndomain
109       IF (.NOT. assigned_domain(ind)) CYCLE
110       CALL swap_dimensions(ind)
111       CALL swap_geometry(ind)
112       normal  = f_normal(ind)
113       tangent = f_tangent(ind)
114       cc      = f_cc(ind)
115       u       = f_u(ind)
116       q       = f_q(ind)
117       rhodz   = f_rhodz(ind)
118       wfluxt  = f_wfluxt(ind) 
119       dzqw    = f_dzqw(ind)
120       adzqw   = f_adzqw(ind)
121       dzq     = f_dzq(ind)
122       wq      = f_wq(ind) 
123
124       DO k = 1, nqtot
125          CALL vlz(k==nqtot,0.5, wfluxt,rhodz,q(:,:,k),1,dzqw, adzqw, dzq, wq)
126       END DO
127
128       CALL compute_backward_traj(tangent,normal,u,0.5*dt*itau_adv, cc) 
129
130    END DO
131
132    CALL send_message(f_cc,req_cc)
133
134
135    ! horizontal transport - split in two to place transfer of gradq3d
136    DO k = 1, nqtot
137       DO ind=1,ndomain
138          IF (.NOT. assigned_domain(ind)) CYCLE
139          CALL swap_dimensions(ind)
140          CALL swap_geometry(ind)
141          q       = f_q(ind)
142          gradq3d = f_gradq3d(ind)
143          sqrt_leng=f_sqrt_leng(ind)
144          CALL compute_gradq3d(q(:,:,k),sqrt_leng,gradq3d,xyz_i,xyz_v)
145
146       END DO
147
148       CALL send_message(f_gradq3d,req_gradq3d)
149       CALL wait_message(req_cc)
150       CALL wait_message(req_gradq3d)
151
152
153       DO ind=1,ndomain
154          IF (.NOT. assigned_domain(ind)) CYCLE
155          CALL swap_dimensions(ind)
156          CALL swap_geometry(ind)
157          cc      = f_cc(ind)
158          q       = f_q(ind)
159          rhodz   = f_rhodz(ind)
160          hfluxt  = f_hfluxt(ind) 
161          gradq3d = f_gradq3d(ind)
162          CALL compute_advect_horiz(k==nqtot,hfluxt,cc,gradq3d, rhodz,q(:,:,k))
163       END DO
164    END DO 
165   
166    ! 1/2 vertical transport
167!!$OMP BARRIER
168
169    DO ind=1,ndomain
170       IF (.NOT. assigned_domain(ind)) CYCLE
171       CALL swap_dimensions(ind)
172       CALL swap_geometry(ind)
173       q       = f_q(ind)
174       rhodz   = f_rhodz(ind)
175       wfluxt  = f_wfluxt(ind) 
176       dzqw    = f_dzqw(ind)
177       adzqw   = f_adzqw(ind)
178       dzq     = f_dzq(ind)
179       wq      = f_wq(ind) 
180
181       DO k = 1,nqtot
182          CALL vlz(k==nqtot, 0.5,wfluxt,rhodz, q(:,:,k),0, dzqw, adzqw, dzq, wq)
183       END DO
184
185    END DO
186
187    CALL trace_end("advect_tracer")
188
189!!$OMP BARRIER
190
191  END SUBROUTINE advect_tracer
192
193  SUBROUTINE vlz(update_mass, fac,wfluxt,mass, q, halo, dzqw, adzqw, dzq, wq)
194    !
195    !     Auteurs:   P.Le Van, F.Hourdin, F.Forget, T. Dubos
196    !
197    !    ********************************************************************
198    !     Update tracers using vertical mass flux only
199    !     Van Leer scheme with minmod limiter
200    !     wfluxt >0 for upward transport
201    !    ********************************************************************
202    USE trace
203    USE omp_para
204    IMPLICIT NONE
205    LOGICAL, INTENT(IN)       :: update_mass
206    REAL(rstd), INTENT(IN)    :: fac, wfluxt(iim*jjm,llm+1) ! vertical mass flux
207    REAL(rstd), INTENT(INOUT) :: mass(iim*jjm,llm)
208    REAL(rstd), INTENT(INOUT) :: q(iim*jjm,llm)
209    INTEGER, INTENT(IN) :: halo
210
211! temporary shared variable
212    REAL(rstd),INTENT(INOUT) :: dzqw(iim*jjm,llm),        & ! vertical finite difference of q
213                                adzqw(iim*jjm,llm),       & ! abs(dzqw)
214                                dzq(iim*jjm,llm),         & ! limited slope of q
215                                wq(iim*jjm,llm+1)           ! time-integrated flux of q
216
217
218    REAL(rstd) :: dzqmax, newmass, sigw, qq, w
219    INTEGER :: i,ij,l,j,ijb,ije
220
221    CALL trace_start("vlz")
222     
223     ijb=((jj_begin-halo)-1)*iim+ii_begin-halo
224     ije = ((jj_end+halo)-1)*iim+ii_end+halo
225
226    ! finite difference of q
227
228     DO l=ll_beginp1,ll_end
229!$SIMD
230       DO ij=ijb,ije
231         dzqw(ij,l)=q(ij,l)-q(ij,l-1)
232         adzqw(ij,l)=abs(dzqw(ij,l))
233       ENDDO
234    ENDDO
235
236!--> flush dzqw, adzqw
237!$OMP BARRIER
238
239    ! minmod-limited slope of q
240    ! dzq = slope*dz, i.e. the reconstructed q varies by dzq inside level l
241
242     DO l=ll_beginp1,ll_endm1
243!$SIMD
244       DO ij=ijb,ije 
245         IF(dzqw(ij,l)*dzqw(ij,l+1).gt.0.) THEN
246             dzq(ij,l) = 0.5*( dzqw(ij,l)+dzqw(ij,l+1) )
247             dzqmax    = pente_max * min( adzqw(ij,l),adzqw(ij,l+1) )
248             dzq(ij,l) = sign( min(abs(dzq(ij,l)),dzqmax) , dzq(ij,l) )  ! NB : sign(a,b)=a*sign(b)
249          ELSE
250             dzq(ij,l)=0.
251          ENDIF
252       ENDDO
253    ENDDO
254
255
256    ! 0 slope in top and bottom layers
257    IF (is_omp_first_level) THEN
258      DO ij=ijb,ije
259           dzq(ij,1)=0.
260      ENDDO
261    ENDIF
262     
263    IF (is_omp_last_level) THEN
264      DO ij=ijb,ije
265          dzq(ij,llm)=0.
266      ENDDO
267    ENDIF
268
269!---> flush dzq
270!$OMP BARRIER 
271
272    ! sigw = fraction of mass that leaves level l/l+1
273    ! then amount of q leaving level l/l+1 = wq = w * qq
274     DO l=ll_beginp1,ll_end
275!$SIMD
276       DO ij=ijb,ije
277             w = fac*wfluxt(ij,l)
278             IF(w>0.) THEN  ! upward transport, upwind side is at level l
279                sigw       = w/mass(ij,l-1)
280                qq         = q(ij,l-1)+0.5*(1.-sigw)*dzq(ij,l-1) ! qq = q if sigw=1 , qq = q+dzq/2 if sigw=0
281             ELSE           ! downward transport, upwind side is at level l+1
282                sigw       = w/mass(ij,l)
283                qq         = q(ij,l)-0.5*(1.+sigw)*dzq(ij,l) ! qq = q if sigw=-1 , qq = q-dzq/2 if sigw=0               
284             ENDIF
285             wq(ij,l) = w*qq
286       ENDDO
287    END DO
288    ! wq = 0 at top and bottom
289    IF (is_omp_first_level) THEN
290       DO ij=ijb,ije
291            wq(ij,1)=0.
292      END DO
293    ENDIF
294   
295    IF (is_omp_last_level) THEN
296      DO ij=ijb,ije
297            wq(ij,llm+1)=0.
298      END DO
299    ENDIF
300
301! --> flush wq
302!$OMP BARRIER
303
304
305    ! update q, mass is updated only after all q's have been updated
306    DO l=ll_begin,ll_end
307!$SIMD
308       DO ij=ijb,ije
309             newmass = mass(ij,l) + fac*(wfluxt(ij,l)-wfluxt(ij,l+1))
310             q(ij,l) = ( q(ij,l)*mass(ij,l) + wq(ij,l)-wq(ij,l+1) ) / newmass
311             IF(update_mass) mass(ij,l)=newmass
312       ENDDO
313    END DO
314
315    CALL trace_end("vlz")
316
317  END SUBROUTINE vlz
318
319END MODULE advect_tracer_mod
Note: See TracBrowser for help on using the repository browser.