source: codes/icosagcm/branches/SATURN_DYNAMICO/LMDZ.COMMON/libf/phystd/xios_output.F90 @ 1057

MODULE xios_output_mod


 INTEGER :: time_it
 CHARACTER(LEN=*), PARAMETER :: context_id= "lmdz_physics"
 
 PRIVATE :: time_it

 INTERFACE write_xios_field
    MODULE PROCEDURE write_xios_field_2d,write_xios_field_3d
  END INTERFACE
 

CONTAINS

  SUBROUTINE initialize_xios_output(time)
  USE comgeomphy
  USE xios
  USE dimphy
  USE mod_phys_lmdz_para
  USE mod_grid_phy_lmdz
  USE planete_mod, ONLY: ap,bp,preff
  
  IMPLICIT NONE
    INCLUDE "comcstfi.h" 
    INTEGER,INTENT(IN) :: time  
    TYPE(xios_context) :: ctx_hdl
    TYPE(xios_time)      :: dtime
    REAL :: lev_value(klev)

    REAL :: lon_mpi(klon_mpi)
    REAL :: lat_mpi(klon_mpi)
    REAL :: bounds_lon_mpi(klon_mpi,nvertex)
    REAL :: bounds_lat_mpi(klon_mpi,nvertex)
    INTEGER :: l
    REAL :: presnivs(klev)
    INTEGER :: time0
    CHARACTER(LEN=256) :: start_date
    INTEGER :: year,month,day,hour,minute,second

    CALL gather_omp(rlond,lon_mpi)
    CALL gather_omp(rlatd,lat_mpi)
    CALL gather_omp(rbounds_lon,bounds_lon_mpi)
    CALL gather_omp(rbounds_lat,bounds_lat_mpi)
    
!$OMP BARRIER    
!$OMP MASTER
    time0=time
    year=time0/(86400*360)
    time0=time0-year*(86400*360)
    month=time0/(86400*30)
    time0=time0-month*(86400*30)
    month=month+1
    day=time0/86400
    time0=time0-day*86400
    day=day+1
    hour=time0/3600
    time0=time0-hour*3600
    minute=time0/60
    time0=time0-minute*60
    second=time0
    write(start_date,'(i0.4,"-",i0.2,"-",i0.2," ",i0.2,":",i0.2,":",i0.2)'),year,month,day,hour,minute,second
    
    PRINT *,"time0  ",time," Start Date ",TRIM(start_date)
    CALL xios_context_initialize(context_id,comm_lmdz_phy)
    CALL xios_get_handle(context_id, ctx_hdl)
    CALL xios_set_current_context(ctx_hdl)
    CALL xios_set_attr(ctx_hdl,start_date=TRIM(start_date))
   
!    lev_value(:) = (/ (l,l=1,klev) /)     
!    CALL xios_set_axis_attr("altitude",size=klev ,value=lev_value)
    
    ! build presnivs "pseudo-pressure" at mid-layers
    DO l=1,klev
      presnivs(l)=0.5*(ap(l)+bp(l)*preff+ap(l+1)+bp(l+1)*preff)
    ENDDO
    CALL xios_set_axis_attr("presnivs",size=klev,value=presnivs,unit="Pa",positive="down")
  
    CALL xios_set_domain_attr("horiz_domain",ni_glo=klon_glo, ibegin=klon_mpi_begin, ni=klon_mpi)
    CALL xios_set_domain_attr("horiz_domain", data_dim=1, type='unstructured' , nvertex=6)
    CALL xios_set_domain_attr("horiz_domain", lonvalue=lon_mpi*180/Pi, latvalue=lat_mpi*180/Pi)
    CALL xios_set_domain_attr("horiz_domain", bounds_lon=reshape(bounds_lon_mpi,(/nvertex,klon_mpi/),order=(/2,1/))*180./Pi )
    CALL xios_set_domain_attr("horiz_domain", bounds_lat=reshape(bounds_lat_mpi,(/nvertex,klon_mpi/),order=(/2,1/))*180./Pi )
  
    dtime%second=dtphys
    CALL xios_set_timestep(dtime)
    time_it = 0  
    CALL xios_close_context_definition()
!$OMP END MASTER    
!$OMP BARRIER    
    
  END SUBROUTINE initialize_xios_output

  SUBROUTINE finalize_xios_output
  USE xios

!$OMP BARRIER    
!$OMP MASTER
    CALL xios_context_finalize
!$OMP END MASTER    
!$OMP BARRIER    
  
  END SUBROUTINE finalize_xios_output


  SUBROUTINE update_xios_timestep
  USE xios
  IMPLICIT NONE
    CALL set_xios_context
!$OMP MASTER
    time_it=time_it+1
    CALL xios_update_calendar(time_it)
!$OMP END MASTER    
  END SUBROUTINE update_xios_timestep


  SUBROUTINE set_xios_context
  USE XIOS
  IMPLICIT NONE
    TYPE(xios_context) :: ctx_hdl

!$OMP MASTER
    CALL xios_get_handle(context_id,ctx_hdl)
    CALL xios_set_current_context(ctx_hdl)
!$OMP END MASTER    
  END SUBROUTINE set_xios_context


  
  SUBROUTINE write_xios_field_2d(field_id,field)
  USE xios
  USE mod_phys_lmdz_para
  IMPLICIT NONE
    CHARACTER(LEN=*) :: field_id
    REAL,INTENT(IN)  :: field(:)
    REAL             :: field_mpi(klon_mpi)
  
    CALL gather_omp(field,field_mpi)

!$OMP MASTER
    CALL xios_send_field(field_id,field_mpi)
!$OMP END MASTER   
    
  END SUBROUTINE write_xios_field_2d

  SUBROUTINE write_xios_field_3d(field_id,field)
  USE xios
  USE mod_phys_lmdz_para
  IMPLICIT NONE
    CHARACTER(LEN=*) :: field_id
    REAL,INTENT(IN)  :: field(:,:)
    REAL             :: field_mpi(klon_mpi,SIZE(field,2))
  
    CALL gather_omp(field,field_mpi)

!$OMP MASTER
    CALL xios_send_field(field_id,field_mpi)
!$OMP END MASTER   
    
  END SUBROUTINE write_xios_field_3d
  
END MODULE xios_output_mod