;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME: saveboxparam
;
; PURPOSE: save all the zoom parameters (defined by calling domdef)
;          in a file (using save command) located in myuniquetmpdir
;          (common variable defined by def_myuniquetmpdir)
;
; CATEGORY:
;
; CALLING SEQUENCE: saveboxparam, filename
; 
; INPUTS: filename a scalar string defining the file name 
;
; KEYWORD PARAMETERS: none
;
; OUTPUTS:none
;
; COMMON BLOCKS: @cm_4mesh and @cm_demomode_used if we are in demo mode
;
; SIDE EFFECTS: call def_myuniquetmpdir, if myuniquetmpdir is undefined: 
;               => define, create and add it to !path
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr)
;                      June 2005
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
PRO saveboxparam, filename
@cm_4mesh
;
  def_myuniquetmpdir
;
  IF lmgr(/demo) EQ 1 THEN BEGIN
; if we are in demo mode, we cannot save the parameters in a temporary file...
@cm_demomode_used
;
      boxzoomparam = {bound:[lon1, lon2, lat1, lat2, vert1, vert2] $
       , indexes:[firstxt, lastxt, firstyt, lastyt $
       , firstxu, lastxu, firstyu, lastyu $
       , firstxv, lastxv, firstyv, lastyv $
       , firstxf, lastxf, firstyf, lastyf $
       , firstzt, lastzt, firstzw, lastzw $
       , nxt, nyt, nxu, nyu, nxv, nyv, nxf, nyf, nzt, nzw] $
       , key:key_irregular}
;
   ENDIF ELSE BEGIN
;
      save, lon1, lon2, lat1, lat2, vert1, vert2 $
       , firstxt, lastxt, firstyt, lastyt $
       , firstxu, lastxu, firstyu, lastyu $
       , firstxv, lastxv, firstyv, lastyv $
       , firstxf, lastxf, firstyf, lastyf $
       , firstzt, lastzt, firstzw, lastzw $
       , nxt, nyt, nxu, nyu, nxv, nyv, nxf, nyf, nzt, nzw $
       , key_irregular, filename = myuniquetmpdir + filename
;
   ENDELSE
;
  return
end