;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:level2mask
;
; PURPOSE: permet de passer d''un tableau 2d de niveau seuil au
; tableau 3d de mask avec des 1 ds les niveaux au dessus du
; niveau seuil et des 0 en dessous (et sur).
;
; CATEGORY: SANS BOUCLE
;
; CALLING SEQUENCE: res=level2mask(niveau)
;
; INPUTS: niveau tableau 2d de niveaux seuil (ou une structure repondant
; aux criteres de litchamp)
;
; KEYWORD PARAMETERS:
;
; OUTPUTS: un tableau 3d contenant le mask associe au tableau 2d de
; niveaux seuil
;
; COMMON BLOCKS:
;	common.pro
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       17/6/1999
; Setp 2004: boundary level have 0 values and not 1 (as it was
; explained before in the header). see:
; print, array_equal(niveau, total(level2mask(niveau),3))
;
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
FUNCTION level2mask, tab
;------------------------------------------------------------
   tempsun = systime(1)         ; pour key_performance
@common
;------------------------------------------------------------
; lecture du champ d''entree et recuperation de la taille du sous
; domaine utilise
;------------------------------------------------------------
   niveaux = litchamp(tab)
   grille,maskterre, -1, -1, -1,nx,ny,nz,firstx,firsty,firstz,lastx,lasty,lastz
;---------------------------------------------------------------
; verification de la coherence entre la taille du tableau et le domaine definit par domdef
;---------------------------------------------------------------
   IF ny EQ 1 THEN niveaux = reform(niveaux, nx, ny, /over)
   taille = size(niveaux)
   if taille[0] NE 2 then return, report('le champ en entree doit contenir un tableau 2d')
   case 1 of
      taille[1] eq jpi and taille[2] eq jpj:niveaux=niveaux[firstx:lastx, firsty:lasty]
      taille[1] eq  nx and taille[2] eq  ny:
      else:return, report('Probleme d''adequation entre les tailles du domaine et celle du champ.')
   endcase
;------------------------------------------------------------
;------------------------------------------------------------
; on transforme le tableau 2d de niveaux en tableau 3d de mask
;------------------------------------------------------------
   mask = reform( niveaux[*]#(1./(indgen(nz)+1)), nx, ny, nz )
   mask = floor(temporary(mask)) < 1
   mask = temporary(mask)*temporary(maskterre)
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
   if keyword_set(key_performance) THEN print, 'temps level2mask', systime(1)-tempsun 
   return, mask
end