;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:barrecouleur
;
; PURPOSE:surcouche de colorbar
;
; CATEGORY:delestage de l''ecriture de plt, pltz, pltt
;
; CALLING SEQUENCE:barrecouleur
;
; SIDE EFFECTS: passer tous les arguments que l''on veut grace a _extra
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       23/12/98
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
PRO barrecouleur, NOCOLORBAR = nocolorbar, CB_TITLE = cb_title, CB_SUBTITLE = cb_subtitle $
                  , POST = post, _extra = ex
@common
;------------------------------------------------------------
   ancienx = !x
   ancieny = !y
   ancienp = !p
   reinitplt
   !x.style = 1
   !y.style = 1
;------------------------------------------------------------
   if n_elements(ex) NE 0 then BEGIN 
      if (where(tag_names(ex) EQ 'MIN'))[0] NE -1 then colorbarinf=ex.MIN
      if (where(tag_names(ex) EQ 'MAX'))[0] NE -1 then colorbarsup=ex.MAX
      if (where(tag_names(ex) EQ 'DIVISIONS'))[0] NE -1 then colorbardiv=ex.DIVISIONS
      if (where(tag_names(ex) EQ 'NOCOULEUR'))[0] NE -1 then nocolorbar = 1
   ENDIF
   if not keyword_set(nocolorbar) then BEGIN 
      colorbar,cb_color=0, cb_charsize=ancienp.charsize, pscolor=keyword_set(post) $
       , cb_title = cb_title,_extra = ex
   ENDIF
   !x= ancienx
   !y= ancieny
   !p= ancienp
   return
end