;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:t2v
;
; PURPOSE:permet de passer un champs se rapportant a la grille T sur
; la grille V, grace a la moyenne: res = 0.5*(res + shift(res, 0, -1))
;      
;
; CATEGORY:grille
;
; CALLING SEQUENCE:res=t2v(tab)
; 
; INPUTS:tab, un tableau 2, 3 ou 4d
;
; KEYWORD PARAMETERS:
;
; OUTPUTS:res, un tableau 2, 3 ou 4d
;
; COMMON BLOCKS:common.pro
;
; SIDE EFFECTS:force les parametres du zoom sur la grille V a etre
; les memes que ceux sur la grille T.
;
; RESTRICTIONS:les points qui ne peuvent etre calcules sont mis a la
; valeur NaN consacree par IDL: !values.f_nan
;
; EXAMPLE:
;
; MODIFICATION HISTORY:Marina Levy
;                      Sebastien Masson (smasson@lodyc.jussieu.fr):
;                      inspection des traveuax finis. 5/6/2000
;
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
FUNCTION t2v, temp
;---------------------------------------------------------
;
  compile_opt idl2, strictarrsubs
;
@cm_4mesh
@cm_4data
@cm_4cal
  IF NOT keyword_set(key_forgetold) THEN BEGIN
@updatenew
  ENDIF
;---------------------------------------------------------
   res = temp

;on force nxt=nxv, etc ...
   firstxv = firstxt
   lastxv = lastxt
   firstyv = firstyt
   lastyv = lastyt
   nxv = nxt
   nyv = nyt
   vargrid = 'V'
   if NOT keyword_set(valmask) then valmask = 1e20
   lat1 = gphit[0, firstyt]
   lat2 = gphiv[0, lastyv]

; cas sur la taille du tableau et application 
   taille = size(temp)
   CASE taille[0] OF 
      1: res = -1
      2: BEGIN 
         case 1 of
            taille[1] eq nxt and taille[2] eq nyt:
            taille[1] eq jpi and taille[2] eq jpj: $
             res=res[firstxt:lastxt, firstyt:lastyt]
            else: $
             return, report('Probleme d''adequation entre les tailles du domaine et de la boite.')
         endcase
         mask = tmask[firstxt:lastxt, firstyt:lastyt, 0]
         terre = where(mask EQ 0) 
         IF terre[0] NE -1 THEN res[terre] = !values.f_nan
         res = 0.5*(res + shift(res, 0, -1))
         res[*, nyt-1] = !values.f_nan
         mask = (vmask())[firstxt:lastxt, firstyt:lastyt, 0]
         terre = where(mask EQ 0) 
         IF terre[0] NE -1 THEN res[terre] = valmask
      END
      3: BEGIN 
         case 1 of
            taille[1] eq nxt and taille[2] eq nyt AND taille[3] EQ nzt:
            taille[1] eq nxt and taille[2] eq nyt AND taille[3] EQ jpk: $
             res=res[*, *, firstzt:lastzt]
            taille[1] eq nxt and taille[2] eq nyt AND taille[3] EQ jpt:
            taille[1] eq jpi and taille[2] eq jpj AND taille[3] EQ jpk: $
             res=res[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt]
            taille[1] eq jpi and taille[2] eq jpj AND taille[3] EQ jpt: $
             res=res[firstxt:lastxt, firstyt:lastyt, *]
            else: $
             return, report('Probleme d''adequation entre les tailles du domaine et de la boite.')
         ENDCASE
         if taille[3] EQ jpt then begin
            mask = tmask[firstxt:lastxt, firstyt:lastyt, lastzt*(nzt NE jpk)]
            mask = temporary(mask[*])#replicate(1, jpt)
            mask = reform(mask, nxt, nyt, jpt, /over)
         ENDIF ELSE mask = tmask[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt]
         terre = where(temporary(mask) EQ 0) 
         IF terre[0] NE -1 THEN res[temporary(terre)] = !values.f_nan
         res = 0.5*(res + shift(res, 0, -1, 0))
         res[*, nyt-1, *] = !values.f_nan
         if taille[3] EQ jpt then BEGIN
            mask = (vmask())[firstxt:lastxt, firstyt:lastyt, lastzt*(nzt NE jpk)]
            mask = temporary(mask[*])#replicate(1, jpt)
            mask = reform(mask, nxt, nyt, jpt, /over)
         ENDIF ELSE mask = (vmask())[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt]
         terre = where(temporary(mask) EQ 0) 
         IF terre[0] NE -1 THEN res[temporary(terre)] = valmask
      END
      4: BEGIN 
         case 1 of
            taille[1] eq nxt and taille[2] eq nyt AND taille[3] EQ nzt AND taille[4] EQ jpt:
            taille[1] eq nxt and taille[2] eq nyt AND taille[3] EQ jpk AND taille[4] EQ jpt: $
             res=res[*, *, firstzt:lastzt, *]
            taille[1] eq jpi and taille[2] eq jpj AND taille[3] EQ jpk AND taille[4] EQ jpt: $
             res=res[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt, *]
            else: $
             return, report('Probleme d''adequation entre les tailles du domaine et de la boite.')
         ENDCASE
         mask = tmask[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt]
         mask = temporary(mask[*])#replicate(1, jpt)
         mask = reform(mask, nxt, nyt, nzt, jpt, /over)
         terre = where(temporary(mask) EQ 0) 
         IF terre[0] NE -1 THEN res[temporary(terre)] = !values.f_nan
         res = 0.5*(res + shift(res, 0, -1, 0, 0))
         res[*, nyt-1, *, *] = !values.f_nan
         mask = (vmask())[firstxt:lastxt, firstyt:lastyt, firstzt:lastzt]
         mask = temporary(mask[*])#replicate(1, jpt)
         mask = reform(mask, nxt, nyt, nzt, jpt, /over)
         terre = where(temporary(mask) EQ 0) 
         IF terre[0] NE -1 THEN res[temporary(terre)] = valmask
      END
    ENDCASE

  IF NOT keyword_set(key_forgetold) THEN BEGIN
   @updateold
  ENDIF 

   return, res
END