source: trunk/UTILITAIRE/isadirectory.pro @ 2

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:isadirectory
;
; PURPOSE:check if a directory is in the !path variable or is the
; common. end it by '/' under Unix/Linux, ':' under Mac and '\' under
; Windows.
;
; CATEGORY: io
;
; CALLING SEQUENCE: directory=isadirectory()
; 
; INPUTS:none
;
; KEYWORD PARAMETERS:
;       IODIRECTORY:a proposed directory
;       TITLE: the title of the widget open if we need to choose a
;       directory.
;       /NOPATH:do not check if the directory is in the !path
;       variable.
;
; OUTPUTS: de directory name
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:while statement until we found a good directory...
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr)
;                      June 28, 2000
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
FUNCTION isadirectory, IODIRECTORY = iodirectory, NOPATH = nopath, TITLE = title

   cd, current = current
; if directory is undefine, we get the current directory.
   if  keyword_set(iodirectory) THEN directory = iodirectory ELSE directory = current 
;
   thisOS = strupcase(strmid(!version.os_family, 0, 3))
   CASE thisOS of
   'MAC':BEGIN & sep = ':' & pathsep = ',' & end
   'WIN':BEGIN & sep = '\' & pathsep = ';' & end
   ELSE: BEGIN & sep = '/' & pathsep = ':' & end
   ENDCASE
; si directory ou current ne finit pas par sep on le rajoute
   if rstrpos(current,sep) NE strlen(current)-1 then current = current+sep
   if rstrpos(directory, sep) NE strlen(directory)-1 then directory = directory+sep
   if keyword_set(nopath) then return, directory
; does directory is define in the !path variable or is it the current directory?
   possibledirectory = str_sep(!path, pathsep)
   if rstrpos(possibledirectory[0],sep) NE strlen(possibledirectory[0])-1 then $
    possibledirectory = possibledirectory+sep
   possibledirectory = [current, possibledirectory]
   while (where(possibledirectory EQ directory))[0] EQ -1 do begin
      directory = dialog_pickfile(/directory, title = title)
      if directory EQ '' then return, report('read_data canceled')
      if rstrpos(directory, sep) NE strlen(directory)-1 then directory = directory+sep
   endwhile

   return, directory
end