source: trunk/SRC/Utilities/createfunc.pro @ 119

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; @file_comments write an idl function, compile it and execute it.
; usefull to avoid the use of execute
;
; @param command {in}{required} a scalar string defining the result to be 
; given back by the function. (see examples)
;
; @keyword FILENAMEIN {in} name of the funccedure to be created.
;      'for_createfunc.pro' by default
;
; @keyword KWDLIST {in} a vector string. to specify a list of keywords that
;      must be included in the function definition. Warning: the string
;      must start with a ',' for example: KWDLIST = ', TOTO = toto'
;
; @keyword _EXTRA used to pass your keywords to the created function.
;
; @restrictions 
; - arguments can be given only through keywords;
; - ends the function name with '.pro' if needed.
;
; @examples
;      IDL> print, createfunc('3*2', filename='test')
;      IDL> print, createfunc('3*two', filename = 'test' $
;                                    , kwdlist ='two = two', two = 2)
;
; @history Sebastien Masson (smasson\@lodyc.jussieu.fr)
;                      May 2005
;
; @version $Id$
;
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
FUNCTION createfunc, command, FILENAMEIN = filenamein $
               , KWDLIST = kwdlist, _EXTRA = ex
;
  compile_opt idl2, hidden, strictarrsubs
;
  IF n_elements(command) NE 1 THEN stop
; define filename if needed
  if NOT keyword_set(filenamein) then filename = 'for_createfunc.pro' $
  ELSE filename = filenamein
; get the name of the function (not the name of the file containing the function)
   shortfilename =  file_basename(filename, '.pro')
; check if the directory exists
   dirname = isadirectory(file_dirname(filename) $
                          , title = 'Redefine '+shortfilename+'.pro directory')
   IF size(dirname, /type) NE 7 THEN return, -1
;
   filename = dirname + shortfilename + '.pro'
; create the file
   if NOT keyword_set(kwdlist) then kwdlist = ''
   kwdlist = kwdlist + ', _EXTRA = ex'
   IF strmid(kwdlist, 0, 1) NE ',' THEN kwdlist = ', ' +  kwdlist
   putfile, filename, ['function ' + shortfilename + kwdlist $
                       , 'compile_opt idl2, hidden, strictarrsubs' $
                       , 'res = ' + command $
                       , 'return, res' $
                       , 'end']
; go in dirname directory
   cd, dirname, current = old_dir
; compile it
   resolve_routine, shortfilename, /is_function
   cd, old_dir
; execute it
   res = call_function(shortfilename, _EXTRA = ex)
;
   return, res
end