| 1 | ;------------------------------------------------------------ |
|---|
| 2 | ;------------------------------------------------------------ |
|---|
| 3 | ;------------------------------------------------------------ |
|---|
| 4 | ;+ |
|---|
| 5 | ; NAME:xxx |
|---|
| 6 | ; |
|---|
| 7 | ; PURPOSE:un maximum de possibilites avec un minimum de clics |
|---|
| 8 | ; |
|---|
| 9 | ; CATEGORY:super widget |
|---|
| 10 | ; |
|---|
| 11 | ; CALLING SEQUENCE:xxx |
|---|
| 12 | ; |
|---|
| 13 | ; INPUTS:none |
|---|
| 14 | ; |
|---|
| 15 | ; KEYWORD PARAMETERS: |
|---|
| 16 | ; |
|---|
| 17 | ; /SEPARATE: pour separer la partie boutons de la partie dessin |
|---|
| 18 | ; en 2 fenetres. Utile pour les petits ecrans, mais attention |
|---|
| 19 | ; peut saturer la memoire video de certains Tx un peu vetustes. |
|---|
| 20 | ; |
|---|
| 21 | ; RESTORE='toto.dat' ou toto.dat est un fichier cree lors d''une |
|---|
| 22 | ; precedente utilisation de xxx grace a la commande "Widget" du |
|---|
| 23 | ; menu "save as". |
|---|
| 24 | ; |
|---|
| 25 | ; OUTPUTS: |
|---|
| 26 | ; |
|---|
| 27 | ; COMMON BLOCKS:common.pro |
|---|
| 28 | ; |
|---|
| 29 | ; SIDE EFFECTS: |
|---|
| 30 | ; |
|---|
| 31 | ; RESTRICTIONS: |
|---|
| 32 | ; |
|---|
| 33 | ; EXAMPLE: |
|---|
| 34 | ; |
|---|
| 35 | ; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr) |
|---|
| 36 | ; |
|---|
| 37 | ;- |
|---|
| 38 | ;------------------------------------------------------------ |
|---|
| 39 | ;------------------------------------------------------------ |
|---|
| 40 | ;------------------------------------------------------------ |
|---|
| 41 | |
|---|
| 42 | PRO xxx_event, event |
|---|
| 43 | ;------------------------------------------------------------ |
|---|
| 44 | @common |
|---|
| 45 | ;------------------------------------------------------------ |
|---|
| 46 | ; = widget_info(event.top,find_by_uname = '') |
|---|
| 47 | ; quel est le type d''evenement? |
|---|
| 48 | ; if event.id EQ 622 then help, event, /struct |
|---|
| 49 | widget_control, event.id, get_uvalue=uval |
|---|
| 50 | if (tag_names(event, /structure_name))[0] EQ 'WIDGET_TRACKING' then uval = {name:'ActiverFenetre'} |
|---|
| 51 | if keyword_set(uval) EQ 0 then return |
|---|
| 52 | ;help, event, /struct |
|---|
| 53 | ;help, uval , /struct |
|---|
| 54 | ; case sur le type d''evenement |
|---|
| 55 | widget_control, event.top, get_uvalue = top_uvalue |
|---|
| 56 | ; si on a active le mot cles separate a l''appelle de xxx |
|---|
| 57 | if size(top_uvalue, /type) EQ 3 then begin |
|---|
| 58 | event.top = top_uvalue |
|---|
| 59 | widget_control, event.top, get_uvalue = top_uvalue |
|---|
| 60 | endif |
|---|
| 61 | ; on tue le petit widget cree par notice.pro si il existe |
|---|
| 62 | noticebase = extractatt(top_uvalue, 'noticebase') |
|---|
| 63 | if noticebase NE 0 then BEGIN |
|---|
| 64 | widget_control, noticebase, /destroy |
|---|
| 65 | *top_uvalue[1, findline(top_uvalue, 'noticebase')] = 0l |
|---|
| 66 | endif |
|---|
| 67 | ; |
|---|
| 68 | options = extractatt(top_uvalue, 'options') |
|---|
| 69 | case uval.name OF |
|---|
| 70 | 'menubar':xxxmenubar_event, event |
|---|
| 71 | 'ok':nouveaudessin = 1 |
|---|
| 72 | 'specifie': |
|---|
| 73 | 'action': |
|---|
| 74 | 'calendar1':BEGIN |
|---|
| 75 | date2id = widget_info(event.top, find_by_uname = 'calendar2') |
|---|
| 76 | widget_control, date2id, get_value = date2 |
|---|
| 77 | if event.value GT date2 then widget_control, date2id, set_value = event.value |
|---|
| 78 | END |
|---|
| 79 | 'calendar2':BEGIN |
|---|
| 80 | date1id = widget_info(event.top, find_by_uname = 'calendar1') |
|---|
| 81 | widget_control, date1id, get_value = date1 |
|---|
| 82 | if event.value LT date1 then widget_control, date1id, set_value = event.value |
|---|
| 83 | END |
|---|
| 84 | 'domain': |
|---|
| 85 | 'varlist':BEGIN |
|---|
| 86 | currentfile = extractatt(top_uvalue, 'currentfile') |
|---|
| 87 | listvar = (*(extractatt(top_uvalue, 'fileparameters'))[currentfile]).listvar |
|---|
| 88 | name = listvar[event.index] |
|---|
| 89 | changefield, event.top, name |
|---|
| 90 | END |
|---|
| 91 | 'txtcmd': |
|---|
| 92 | 'filelist':BEGIN |
|---|
| 93 | changefile, event.top, event.index |
|---|
| 94 | END |
|---|
| 95 | 'ActiverFenetre':BEGIN |
|---|
| 96 | if event.enter EQ 1 AND !d.name NE 'PS' then BEGIN |
|---|
| 97 | ; graphid = widget_info(event.top,find_by_uname = 'graph') |
|---|
| 98 | graphid = extractatt(top_uvalue, 'graphid') |
|---|
| 99 | widget_control,graphid,get_value=win |
|---|
| 100 | wset, win |
|---|
| 101 | widget_control,event.top,get_uvalue=top_uvalue |
|---|
| 102 | numdessinin = (extractatt(top_uvalue, 'smallin'))[2]-1 |
|---|
| 103 | !p = (extractatt(top_uvalue, 'penvs'))[numdessinin] |
|---|
| 104 | !x = (extractatt(top_uvalue, 'xenvs'))[numdessinin] |
|---|
| 105 | !y = (extractatt(top_uvalue, 'yenvs'))[numdessinin] |
|---|
| 106 | endif |
|---|
| 107 | END |
|---|
| 108 | 'graph':BEGIN |
|---|
| 109 | quelclick = identifyclick(event) |
|---|
| 110 | case quelclick.type of |
|---|
| 111 | 'inutile':return |
|---|
| 112 | 'long':longclickaction, event |
|---|
| 113 | 'single':singleclickaction, event |
|---|
| 114 | 'double':doubleclickaction, event |
|---|
| 115 | endcase |
|---|
| 116 | END |
|---|
| 117 | endcase |
|---|
| 118 | if keyword_set(nouveaudessin) then letsdraw, event.top |
|---|
| 119 | return |
|---|
| 120 | end |
|---|
| 121 | ;------------------------------------------------------------ |
|---|
| 122 | ;------------------------------------------------------------ |
|---|
| 123 | ;------------------------------------------------------------ |
|---|
| 124 | ;------------------------------------------------------------ |
|---|
| 125 | ;------------------------------------------------------------ |
|---|
| 126 | ;------------------------------------------------------------ |
|---|
| 127 | PRO xxx, datafilename, idlfile, argspro, CALLERWIDID = CallerWidId $ |
|---|
| 128 | , REDRAW = redraw, SEPARATE = separate, UVALUE = uvalue $ |
|---|
| 129 | , RESTORE = restore, _EXTRA = ex |
|---|
| 130 | ;------------------------------------------------------------ |
|---|
| 131 | @all_cm |
|---|
| 132 | ;------------------------------------------------------------ |
|---|
| 133 | ; reinitialize the !p, !x, !y, !z variables |
|---|
| 134 | ;------------------------------------------------------------ |
|---|
| 135 | reinitplt |
|---|
| 136 | ;------------------------------------------------------------ |
|---|
| 137 | ; we get back the uvalue of the widget that called xxx to create a new widget |
|---|
| 138 | if keyword_set(restore) then BEGIN |
|---|
| 139 | restore = isafile(filename = restore, iodir = homedir, _extra = ex) |
|---|
| 140 | if size(restore, /type) NE 7 then restore = 0 ELSE BEGIN |
|---|
| 141 | restore, isafile(file = restore, iodir = homedir, _extra = ex) |
|---|
| 142 | newgrid = *(extractatt(uvalue, 'meshparameters'))[0] |
|---|
| 143 | change = changegrid(newgrid) |
|---|
| 144 | ENDELSE |
|---|
| 145 | endif |
|---|
| 146 | if n_elements(CallerWidId) NE 0 THEN $ |
|---|
| 147 | widget_control, CallerWidId, get_uvalue = uvalue ELSE CallerWidId = 0 |
|---|
| 148 | ;------------------------------------------------------------ |
|---|
| 149 | ;------------------------------------------------------------ |
|---|
| 150 | ; liste des fichiers que l''on veut regarder |
|---|
| 151 | ; |
|---|
| 152 | if keyword_set(uvalue) then BEGIN |
|---|
| 153 | currentfile = extractatt(uvalue, 'currentfile') |
|---|
| 154 | filelist = extractatt(uvalue, 'filelist') |
|---|
| 155 | fileparameters = extractatt(uvalue, 'fileparameters') |
|---|
| 156 | readparameters = extractatt(uvalue, 'readparameters') |
|---|
| 157 | meshparameters = extractatt(uvalue, 'meshparameters') |
|---|
| 158 | ENDIF ELSE BEGIN |
|---|
| 159 | newfile = selectfile(datafilename, idlfile, argspro, _extra = ex) |
|---|
| 160 | if size(newfile, /type) NE 8 then return |
|---|
| 161 | fileparameters = ptrarr(1, /allocate_heap) |
|---|
| 162 | *fileparameters[0] = newfile.fileparameters |
|---|
| 163 | readparameters = ptrarr(1, /allocate_heap) |
|---|
| 164 | *readparameters[0] = newfile.readparameters |
|---|
| 165 | meshparameters = ptrarr(1, /allocate_heap) |
|---|
| 166 | *meshparameters[0] = newfile.meshparameters |
|---|
| 167 | currentfile = 0 |
|---|
| 168 | filelist = newfile.fileparameters.filename |
|---|
| 169 | ENDELSE |
|---|
| 170 | ; |
|---|
| 171 | if keyword_set(uvalue) THEN BEGIN |
|---|
| 172 | smallin = extractatt(uvalue, 'smallin') |
|---|
| 173 | smallout = extractatt(uvalue, 'smallout') |
|---|
| 174 | ENDIF ELSE BEGIN |
|---|
| 175 | smallin = [1, 1, 1] |
|---|
| 176 | smallout = [1, 1, 1] |
|---|
| 177 | ENDELSE |
|---|
| 178 | nbredessin = smallin[0]*smallin[1] |
|---|
| 179 | numdessinin = smallin[2]-1 |
|---|
| 180 | ; warning flg definition must be consistent with cw_pdmenu argument |
|---|
| 181 | ; see also flag definition in cw_pagelayout |
|---|
| 182 | if keyword_set(uvalue) then BEGIN |
|---|
| 183 | flag = extractatt(uvalue, 'optionsflag') |
|---|
| 184 | key_portrait = flag[0, numdessinin] |
|---|
| 185 | ENDIF ELSE flag = [key_portrait, 0, 0, 0, 0]#replicate(1, nbredessin) |
|---|
| 186 | |
|---|
| 187 | ;------------------------------------------------------------ |
|---|
| 188 | ;------------------------------------------------------------ |
|---|
| 189 | ; We start the widget definition |
|---|
| 190 | ;------------------------------------------------------------ |
|---|
| 191 | ;------------------------------------------------------------ |
|---|
| 192 | ; |
|---|
| 193 | ; widget and screen size |
|---|
| 194 | scrsize = get_screen_size()*0.95 |
|---|
| 195 | windsize = givewindowsize() |
|---|
| 196 | xxxsize = [windsize[0] * (1-keyword_set(separate)) + 350, windsize[1]] |
|---|
| 197 | ; |
|---|
| 198 | ;------------------------------------------------------------ |
|---|
| 199 | ; The top base |
|---|
| 200 | ;------------------------------------------------------------ |
|---|
| 201 | IF xxxsize[0] LE scrsize[0] AND xxxsize[1] LE scrsize[1] THEN BEGIN |
|---|
| 202 | base = widget_base(title = 'xxx', GROUP_LEADER = group, /tracking_events $ |
|---|
| 203 | , uname = 'base', space = 0) |
|---|
| 204 | ENDIF ELSE BEGIN |
|---|
| 205 | base = widget_base(title = 'xxx', GROUP_LEADER = group, /tracking_events $ |
|---|
| 206 | , uname = 'base', space = 0 $ |
|---|
| 207 | , xsize = xxxsize[0], ysize = xxxsize[1] $ |
|---|
| 208 | , x_scroll_size = (xxxsize[0] < scrsize[0]) $ |
|---|
| 209 | , y_scroll_size = (xxxsize[1] < scrsize[1])) |
|---|
| 210 | ENDELSE |
|---|
| 211 | |
|---|
| 212 | ;------------------------------------------------------------ |
|---|
| 213 | ; combobox for plots choice |
|---|
| 214 | ;------------------------------------------------------------ |
|---|
| 215 | xoff = 0 |
|---|
| 216 | yoff = 0 |
|---|
| 217 | pltlst = ['plt' $ |
|---|
| 218 | , 'pltz', 'pltz diag up', 'pltz diag dn' $ |
|---|
| 219 | , 'pltt', 'pltt diag up', 'pltt diag dn' $ |
|---|
| 220 | , 'xy', 'xz', 'yz', 'xt', 'yt', 'zt' $ |
|---|
| 221 | , 'x', 'y', 'z', 't'] |
|---|
| 222 | actid = widget_combobox(base, value = pltlst, uname = 'action', uvalue = {name:'action'} $ |
|---|
| 223 | , xoffset = xoff+5, yoffset = yoff+4, xsize = 90) |
|---|
| 224 | if keyword_set(uvalue) then BEGIN |
|---|
| 225 | selectact = (extractatt(uvalue, 'types'))[numdessinin] |
|---|
| 226 | selectact = (where(pltlst EQ selectact))[0] |
|---|
| 227 | widget_control, actid, set_combobox_select = 0 > selectact |
|---|
| 228 | ENDIF ELSE selectfile = 0 |
|---|
| 229 | |
|---|
| 230 | ;------------------------------------------------------------ |
|---|
| 231 | ; menu/options |
|---|
| 232 | ;------------------------------------------------------------ |
|---|
| 233 | xoff = xoff + 110 |
|---|
| 234 | if keyword_set(uvalue) then begin |
|---|
| 235 | options = extractatt(uvalue, 'options') |
|---|
| 236 | ENDIF ELSE options = ['Portrait/Landscape', 'Overlay', 'Vecteur' $ |
|---|
| 237 | , 'Longitude / x index', 'Latitude / y index'] |
|---|
| 238 | |
|---|
| 239 | desc = [ '1\File', $ |
|---|
| 240 | '0\Open' , $ |
|---|
| 241 | '0\New xxx' , $ |
|---|
| 242 | '2\Quit', $ |
|---|
| 243 | '1\Save as' , $ |
|---|
| 244 | '0\PostScript' , $ |
|---|
| 245 | '0\Animated gif' , $ |
|---|
| 246 | '0\Gif' , $ |
|---|
| 247 | '0\IDL procedure', $ |
|---|
| 248 | '0\RESTORE kwd of xxx', $ |
|---|
| 249 | '2\Print to prompt', $ |
|---|
| 250 | '1\Flag options'] |
|---|
| 251 | descsuite = options |
|---|
| 252 | if n_elements(descsuite) GE 2 then $ |
|---|
| 253 | descsuite[0:n_elements(descsuite)-2] = '0\'+descsuite[0:n_elements(descsuite)-2] |
|---|
| 254 | descsuite[n_elements(descsuite)-1] = '2\'+descsuite[n_elements(descsuite)-1] |
|---|
| 255 | desc = [desc, descsuite] |
|---|
| 256 | ; |
|---|
| 257 | menu = cw_pdmenu(base, desc, /RETURN_NAME, uname = 'menubar', uvalue = {name:'menubar'} $ |
|---|
| 258 | , xoffset = xoff, yoffset = yoff) |
|---|
| 259 | |
|---|
| 260 | ;------------------------------------------------------------ |
|---|
| 261 | ; Ok button |
|---|
| 262 | ;------------------------------------------------------------ |
|---|
| 263 | yoff = yoff + 37 |
|---|
| 264 | xoff = 5 |
|---|
| 265 | ; boutton 'OK' |
|---|
| 266 | baseok = widget_button(base, value = ' OK ', uvalue = {name:'ok'}, uname = 'ok button' $ |
|---|
| 267 | , /frame, xoffset = xoff, yoffset = yoff) |
|---|
| 268 | |
|---|
| 269 | ;------------------------------------------------------------ |
|---|
| 270 | ; Page Layout |
|---|
| 271 | ;------------------------------------------------------------ |
|---|
| 272 | ; page layout |
|---|
| 273 | xoff = xoff + 65 |
|---|
| 274 | dummyid = cw_pagelayout(base, smallin, /row, /frame, xoffset = xoff, yoffset = yoff) |
|---|
| 275 | ; |
|---|
| 276 | ;------------------------------------------------------------ |
|---|
| 277 | ; List of Variables |
|---|
| 278 | ;------------------------------------------------------------ |
|---|
| 279 | xoff = xoff + 140 |
|---|
| 280 | currentlistvar = (*fileparameters[currentfile]).listvar |
|---|
| 281 | vlstid = widget_combobox(base, value = currentlistvar, uvalue = {name:'varlist'} $ |
|---|
| 282 | , uname = 'varlist', xoffset = xoff, yoffset = yoff+1) |
|---|
| 283 | if keyword_set(uvalue) then BEGIN |
|---|
| 284 | selectvar = (extractatt(uvalue, 'varinfo'))[1, numdessinin] |
|---|
| 285 | selectvar = (where(currentlistvar EQ selectvar))[0] |
|---|
| 286 | widget_control, vlstid, set_combobox_select = 0 > selectvar |
|---|
| 287 | ENDIF ELSE selectvar = 0 |
|---|
| 288 | ;------------------------------------------------------------ |
|---|
| 289 | ; List of files |
|---|
| 290 | ;------------------------------------------------------------ |
|---|
| 291 | yoff = yoff + 35 |
|---|
| 292 | flstid = widget_combobox(base, value = file_basename(filelist), uname = 'filelist' $ |
|---|
| 293 | , xsize = 345, yoffset = yoff, uvalue = {name:'filelist'}) |
|---|
| 294 | if keyword_set(uvalue) then BEGIN |
|---|
| 295 | selectfile = (extractatt(uvalue, 'varinfo'))[0, numdessinin] |
|---|
| 296 | selectfile = (where(file_basename(filelist) EQ selectfile))[0] |
|---|
| 297 | widget_control, flstid, set_combobox_select = 0 > selectfile |
|---|
| 298 | ENDIF ELSE selectfile = 0 |
|---|
| 299 | ;------------------------------------------------------------ |
|---|
| 300 | ; Text for computation |
|---|
| 301 | ;------------------------------------------------------------ |
|---|
| 302 | yoff = yoff + 32 |
|---|
| 303 | ; computation done on the files... |
|---|
| 304 | if keyword_set(uvalue) then txtvalue = (extractatt(uvalue, 'txtcmd'))[numdessinin] $ |
|---|
| 305 | ELSE txtvalue = varexp |
|---|
| 306 | dummyid = widget_text(base, value = txtvalue, uvalue = {name:'txtcmd'}, uname = 'txtcmd' $ |
|---|
| 307 | , /editable, yoffset = yoff, xsize = 54, /frame) |
|---|
| 308 | ;------------------------------------------------------------ |
|---|
| 309 | ; Calendar |
|---|
| 310 | ;------------------------------------------------------------ |
|---|
| 311 | yoff = yoff + 40 |
|---|
| 312 | currentcalendar = (*fileparameters[currentfile]).time_counter |
|---|
| 313 | key_caltype = (*fileparameters[currentfile]).caltype |
|---|
| 314 | fakecal = (*fileparameters[currentfile]).fakecal |
|---|
| 315 | if keyword_set(uvalue) then begin |
|---|
| 316 | dates = (extractatt(uvalue, 'dates'))[*, numdessinin] |
|---|
| 317 | date1 = date2jul(dates[0]) |
|---|
| 318 | date2 = date2jul(dates[1]) |
|---|
| 319 | ENDIF |
|---|
| 320 | basecalid = widget_base(base, column = 2, space = 0, yoffset = yoff, uname = 'basecal') |
|---|
| 321 | dummyid = cw_calendar(basecalid, currentcalendar, date1, FAKECAL = fakecal, uname = 'calendar1', uvalue = {name:'calendar1'}, /frame) |
|---|
| 322 | dummyid = cw_calendar(basecalid, currentcalendar, date2, FAKECAL = fakecal, uname = 'calendar2', uvalue = {name:'calendar2'}, /frame) |
|---|
| 323 | ;------------------------------------------------------------ |
|---|
| 324 | ; Domain |
|---|
| 325 | ;------------------------------------------------------------ |
|---|
| 326 | yoff = yoff + 60 |
|---|
| 327 | vargrid = strupcase((*fileparameters[currentfile]).listgrid[selectvar]) |
|---|
| 328 | IF vargrid EQ 'W' then zgrid = 'W' ELSE zgrid = 'T' |
|---|
| 329 | if keyword_set(uvalue) then boxzoom = (extractatt(uvalue, 'domaines'))[*, numdessinin] |
|---|
| 330 | dummyid = cw_domain(base, uname = 'domain', uvalue = {name:'domain'}, /unzoom, /frame $ |
|---|
| 331 | , boxzoom = boxzoom, yoffset = yoff, xoffset = 15) |
|---|
| 332 | ;------------------------------------------------------------ |
|---|
| 333 | ; Plots specifications |
|---|
| 334 | ;------------------------------------------------------------ |
|---|
| 335 | yoff = yoff + 230 |
|---|
| 336 | speid = cw_specifie(base, uname = 'specifie', uvalue = {name:'specifie'}, /frame, /column $ |
|---|
| 337 | , /forxxx, yoffset = yoff) |
|---|
| 338 | if keyword_set(uvalue) then BEGIN |
|---|
| 339 | exextra = *((extractatt(uvalue, 'exextra'))[numdessinin]) |
|---|
| 340 | IF n_elements(exextra) NE 0 THEN widget_control, speid, set_value = exextra |
|---|
| 341 | ENDIF |
|---|
| 342 | ;------------------------------------------------------------ |
|---|
| 343 | ; drawing part |
|---|
| 344 | ;------------------------------------------------------------ |
|---|
| 345 | if keyword_set(separate) then $ |
|---|
| 346 | basegraph = widget_base(title = 'xxx window', group_leader = base, uvalue = base) $ |
|---|
| 347 | ELSE basegraph = base |
|---|
| 348 | |
|---|
| 349 | graphid = widget_draw(basegraph, uname = 'graph', /button_events, retain = 2 $ |
|---|
| 350 | , uvalue = {name:'graph', press:0, click:0, x:[0., 0.], y:[0., 0.]} $ |
|---|
| 351 | , xoffset = 350*(1-keyword_set(separate)) $ |
|---|
| 352 | , xsize = windsize[0], ysize = windsize[1]); , tooltip = 'toto') |
|---|
| 353 | ;------------------------------------------------------------ |
|---|
| 354 | ; realize the widget |
|---|
| 355 | ;------------------------------------------------------------ |
|---|
| 356 | widget_control, base, /realize |
|---|
| 357 | if keyword_set(separate) then begin |
|---|
| 358 | widget_control, basegraph, /realize |
|---|
| 359 | xmanager, 'xxx', basegraph, /no_block |
|---|
| 360 | endif |
|---|
| 361 | |
|---|
| 362 | ;------------------------------------------------------------ |
|---|
| 363 | if keyword_set(uvalue) then BEGIN ; |
|---|
| 364 | ; on recopie le pointeur uvalue dans top_uvalue. |
|---|
| 365 | ; Attention, il faut completement redefinir top_uvalue a partir des |
|---|
| 366 | ; variables pointees par uvalue. Sinon si on fait simplement |
|---|
| 367 | ; top_uvalue = uvalue, qd on detruit par uvalue et les variables |
|---|
| 368 | ; surlesquelles il pointe on detruit aussi les variables sur |
|---|
| 369 | ; lesquelles pointent top_uvalue. |
|---|
| 370 | case 1 of |
|---|
| 371 | keyword_set(redraw):BEGIN |
|---|
| 372 | top_uvalue = uvalue |
|---|
| 373 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 374 | ; we find homedir |
|---|
| 375 | homedir = isadirectory(io = homedir, title = 'Bad definition of homedir') |
|---|
| 376 | ; on recupere la liste des instructions |
|---|
| 377 | globalcommand = extractatt(top_uvalue, 'globalcommand') |
|---|
| 378 | ; on complete par le premiere et les dernieres lignes du programme |
|---|
| 379 | createpro, globalcommand, filename = myuniquetmpdir + 'xxx2ps.pro' $ |
|---|
| 380 | , KWDLIST = ', NOERASE = noerase, POSTSCRIPT = postscript' $ |
|---|
| 381 | +', PORTRAIT = portrait, LANDSCAPE = landscape' $ |
|---|
| 382 | , /noerase |
|---|
| 383 | END |
|---|
| 384 | keyword_set(restore):begin |
|---|
| 385 | top_uvalue = uvalue |
|---|
| 386 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 387 | widget_control, graphid, get_value = win |
|---|
| 388 | wshow, win |
|---|
| 389 | wset, win |
|---|
| 390 | tv, image, /true |
|---|
| 391 | ; etat des widgets |
|---|
| 392 | updatewidget, base |
|---|
| 393 | ; menage |
|---|
| 394 | END |
|---|
| 395 | ELSE:BEGIN |
|---|
| 396 | top_uvalue = ptrarr(2, 29, /allocate_heap) |
|---|
| 397 | FOR i = 0, 28 do *top_uvalue[0, i] = *uvalue[0, i] |
|---|
| 398 | FOR i = 0, 14 do *top_uvalue[1, i] = *uvalue[1, i] |
|---|
| 399 | FOR i = 18, 27 do *top_uvalue[1, i] = *uvalue[1, i] |
|---|
| 400 | numfile = n_elements(extractatt(uvalue, 'filelist')) |
|---|
| 401 | *top_uvalue[1, 15] = ptrarr(numfile, /allocate_heap) |
|---|
| 402 | *top_uvalue[1, 16] = ptrarr(numfile, /allocate_heap) |
|---|
| 403 | *top_uvalue[1, 17] = ptrarr(numfile, /allocate_heap) |
|---|
| 404 | for i = 0, numfile-1 do begin |
|---|
| 405 | *(*top_uvalue[1, 15])[i] = *(*uvalue[1, 15])[i] |
|---|
| 406 | *(*top_uvalue[1, 16])[i] = *(*uvalue[1, 16])[i] |
|---|
| 407 | *(*top_uvalue[1, 17])[i] = *(*uvalue[1, 17])[i] |
|---|
| 408 | endfor |
|---|
| 409 | *top_uvalue[1, 28] = ptrarr(nbredessin, /allocate_heap) |
|---|
| 410 | for i = 0, nbredessin-1 do *(*top_uvalue[1, 28])[i] = *(*uvalue[1, 28])[i] |
|---|
| 411 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 412 | ; copie l''ecran du widget de uvalue dans celui de top_uvalue |
|---|
| 413 | if keyword_set(CallerWidId) then begin |
|---|
| 414 | widget_control, extractatt(uvalue, 'graphid'), get_value = win |
|---|
| 415 | wshow, win |
|---|
| 416 | wset, win |
|---|
| 417 | image = tvrd(/true) |
|---|
| 418 | widget_control, graphid, get_value = win |
|---|
| 419 | wshow, win |
|---|
| 420 | wset, win |
|---|
| 421 | tv, image, /true |
|---|
| 422 | ENDIF |
|---|
| 423 | END |
|---|
| 424 | endcase |
|---|
| 425 | *top_uvalue[1, findline(top_uvalue, 'graphid')] = graphid |
|---|
| 426 | ; |
|---|
| 427 | ENDIF ELSE BEGIN |
|---|
| 428 | ; sinon on va definit tous les elements que l''on acroche au widget |
|---|
| 429 | ; grace a la top_uvalue qui est un tableau de pointeurs a 2 colonnes: |
|---|
| 430 | ; les noms et des variables |
|---|
| 431 | ; on initialie tous ces elements. |
|---|
| 432 | ; variables concernant le widget ds sa generalite |
|---|
| 433 | if NOT keyword_set(ex) then ex = {nothing:0} |
|---|
| 434 | ; variables se rapportant aux differents fichiers que l''on peut lire |
|---|
| 435 | ; variables specifiques a chaque dessin |
|---|
| 436 | ; |
|---|
| 437 | |
|---|
| 438 | ; creation du pointeur que l''on va attache au widget. |
|---|
| 439 | top_uvalue = ptrarr(2, 29, /allocate_heap) |
|---|
| 440 | ; variables se rapportant au widget en general |
|---|
| 441 | *top_uvalue[0, 0] = 'options' & *top_uvalue[1, 0] = options |
|---|
| 442 | *top_uvalue[0, 1] = 'smallin' & *top_uvalue[1, 1] = smallin |
|---|
| 443 | *top_uvalue[0, 2] = 'smallout' & *top_uvalue[1, 2] = smallout |
|---|
| 444 | *top_uvalue[0, 3] = 'graphid' & *top_uvalue[1, 3] = graphid |
|---|
| 445 | *top_uvalue[0, 4] = 'alreadyvector' & *top_uvalue[1, 4] = -1 |
|---|
| 446 | *top_uvalue[0, 5] = 'alreadyover' & *top_uvalue[1, 5] = -1 |
|---|
| 447 | *top_uvalue[0, 6] = 'alreadyread' & *top_uvalue[1, 6] = -1 |
|---|
| 448 | *top_uvalue[0, 7] = 'currentreadcmd' & *top_uvalue[1, 7] = '' |
|---|
| 449 | *top_uvalue[0, 8] = 'globalcommand' & *top_uvalue[1, 8] = '' |
|---|
| 450 | *top_uvalue[0, 9] = 'globaloldcommand' & *top_uvalue[1, 9] = '' |
|---|
| 451 | *top_uvalue[0, 10] = 'no more used' & *top_uvalue[1, 10] = 9999 |
|---|
| 452 | *top_uvalue[0, 11] = 'noticebase' & *top_uvalue[1, 11] = 0l |
|---|
| 453 | *top_uvalue[0, 12] = 'extra' & *top_uvalue[1, 12] = ex |
|---|
| 454 | ; variables se rapportant aux differents fichiers que l''on peut lire |
|---|
| 455 | *top_uvalue[0, 13] = 'currentfile' & *top_uvalue[1, 13] = currentfile |
|---|
| 456 | *top_uvalue[0, 14] = 'filelist' & *top_uvalue[1, 14] = filelist |
|---|
| 457 | *top_uvalue[0, 15] = 'fileparameters' & *top_uvalue[1, 15] = fileparameters |
|---|
| 458 | *top_uvalue[0, 16] = 'readparameters' & *top_uvalue[1, 16] = readparameters |
|---|
| 459 | *top_uvalue[0, 17] = 'meshparameters' & *top_uvalue[1, 17] = meshparameters |
|---|
| 460 | ; variables se rapportant aux differents dessins que l''on peut faire |
|---|
| 461 | *top_uvalue[0, 18] = 'penvs' & *top_uvalue[1, 18] = replicate(!p, nbredessin) |
|---|
| 462 | *top_uvalue[0, 19] = 'xenvs' & *top_uvalue[1, 19] = replicate(!x, nbredessin) |
|---|
| 463 | *top_uvalue[0, 20] = 'yenvs' & *top_uvalue[1, 20] = replicate(!y, nbredessin) |
|---|
| 464 | *top_uvalue[0, 21] = 'nameprocedures' & *top_uvalue[1, 21] = strarr(nbredessin) |
|---|
| 465 | *top_uvalue[0, 22] = 'types' & *top_uvalue[1, 22] = strarr(nbredessin) |
|---|
| 466 | *top_uvalue[0, 23] = 'varinfo' & *top_uvalue[1, 23] = strarr(2, nbredessin) |
|---|
| 467 | *top_uvalue[0, 24] = 'domaines' & *top_uvalue[1, 24] = fltarr(6, nbredessin) |
|---|
| 468 | *top_uvalue[0, 25] = 'dates' & *top_uvalue[1, 25] = lonarr(2, nbredessin) |
|---|
| 469 | *top_uvalue[0, 26] = 'txtcmd' & *top_uvalue[1, 26] = strarr(nbredessin) |
|---|
| 470 | *top_uvalue[0, 27] = 'optionsflag' & *top_uvalue[1, 27] = flag |
|---|
| 471 | *top_uvalue[0, 28] = 'exextra' & *top_uvalue[1, 28] = ptrarr(nbredessin, /allocate_heap) |
|---|
| 472 | ; |
|---|
| 473 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 474 | createhistory, base, smallin |
|---|
| 475 | ; |
|---|
| 476 | ENDELSE |
|---|
| 477 | ;------------------------------------------------------------ |
|---|
| 478 | xmanager, 'xxx', base, /no_block |
|---|
| 479 | ;------------------------------------------------------------ |
|---|
| 480 | ;------------------------------------------------------------ |
|---|
| 481 | return |
|---|
| 482 | end |
|---|
