| 1 | ;------------------------------------------------------------ |
|---|
| 2 | ;------------------------------------------------------------ |
|---|
| 3 | ;------------------------------------------------------------ |
|---|
| 4 | ;+ |
|---|
| 5 | ; NAME:xxx |
|---|
| 6 | ; |
|---|
| 7 | ; PURPOSE:un maximum de possibilites avec un minimum de clics |
|---|
| 8 | ; |
|---|
| 9 | ; CATEGORY:super widget |
|---|
| 10 | ; |
|---|
| 11 | ; CALLING SEQUENCE:xxx |
|---|
| 12 | ; |
|---|
| 13 | ; INPUTS:none |
|---|
| 14 | ; |
|---|
| 15 | ; KEYWORD PARAMETERS: |
|---|
| 16 | ; |
|---|
| 17 | ; /SEPARATE: pour separer la partie boutons de la partie dessin |
|---|
| 18 | ; en 2 fenetres. Utile pour les petits ecrans, mais attention |
|---|
| 19 | ; peut saturer la memoire video de certains Tx un peu vetustes. |
|---|
| 20 | ; |
|---|
| 21 | ; RESTORE='toto.dat' ou toto.dat est un fichier cree lors d''une |
|---|
| 22 | ; precedente utilisation de xxx grace a la commande "Widget" du |
|---|
| 23 | ; menu "save as". |
|---|
| 24 | ; |
|---|
| 25 | ; OUTPUTS: |
|---|
| 26 | ; |
|---|
| 27 | ; COMMON BLOCKS:common.pro |
|---|
| 28 | ; |
|---|
| 29 | ; SIDE EFFECTS: |
|---|
| 30 | ; |
|---|
| 31 | ; RESTRICTIONS: |
|---|
| 32 | ; |
|---|
| 33 | ; EXAMPLE: |
|---|
| 34 | ; |
|---|
| 35 | ; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr) |
|---|
| 36 | ; |
|---|
| 37 | ;- |
|---|
| 38 | ;------------------------------------------------------------ |
|---|
| 39 | ;------------------------------------------------------------ |
|---|
| 40 | ;------------------------------------------------------------ |
|---|
| 41 | |
|---|
| 42 | PRO xxx_event, event |
|---|
| 43 | ;------------------------------------------------------------ |
|---|
| 44 | ; |
|---|
| 45 | compile_opt idl2, strictarrsubs |
|---|
| 46 | ; |
|---|
| 47 | @common |
|---|
| 48 | ;------------------------------------------------------------ |
|---|
| 49 | ; = widget_info(event.top,find_by_uname = '') |
|---|
| 50 | ; quel est le type d''evenement? |
|---|
| 51 | ; if event.id EQ 622 then help, event, /struct |
|---|
| 52 | widget_control, event.id, get_uvalue=uval |
|---|
| 53 | if (tag_names(event, /structure_name))[0] EQ 'WIDGET_TRACKING' then uval = {name:'ActiverFenetre'} |
|---|
| 54 | if keyword_set(uval) EQ 0 then return |
|---|
| 55 | ;help, event, /struct |
|---|
| 56 | ;help, uval , /struct |
|---|
| 57 | ; case sur le type d''evenement |
|---|
| 58 | widget_control, event.top, get_uvalue = top_uvalue |
|---|
| 59 | ; si on a active le mot cles separate a l''appelle de xxx |
|---|
| 60 | if size(top_uvalue, /type) EQ 3 then begin |
|---|
| 61 | event.top = top_uvalue |
|---|
| 62 | widget_control, event.top, get_uvalue = top_uvalue |
|---|
| 63 | endif |
|---|
| 64 | ; on tue le petit widget cree par notice.pro si il existe |
|---|
| 65 | noticebase = extractatt(top_uvalue, 'noticebase') |
|---|
| 66 | if noticebase NE 0 then BEGIN |
|---|
| 67 | widget_control, noticebase, /destroy |
|---|
| 68 | *top_uvalue[1, findline(top_uvalue, 'noticebase')] = 0l |
|---|
| 69 | endif |
|---|
| 70 | ; |
|---|
| 71 | options = extractatt(top_uvalue, 'options') |
|---|
| 72 | case uval.name OF |
|---|
| 73 | 'menubar':xxxmenubar_event, event |
|---|
| 74 | 'ok':nouveaudessin = 1 |
|---|
| 75 | 'specifie': |
|---|
| 76 | 'action': |
|---|
| 77 | 'calendar1':BEGIN |
|---|
| 78 | date2id = widget_info(event.top, find_by_uname = 'calendar2') |
|---|
| 79 | widget_control, date2id, get_value = date2 |
|---|
| 80 | if event.value GT date2 then widget_control, date2id, set_value = event.value |
|---|
| 81 | END |
|---|
| 82 | 'calendar2':BEGIN |
|---|
| 83 | date1id = widget_info(event.top, find_by_uname = 'calendar1') |
|---|
| 84 | widget_control, date1id, get_value = date1 |
|---|
| 85 | if event.value LT date1 then widget_control, date1id, set_value = event.value |
|---|
| 86 | END |
|---|
| 87 | 'domain': |
|---|
| 88 | 'varlist':BEGIN |
|---|
| 89 | currentfile = extractatt(top_uvalue, 'currentfile') |
|---|
| 90 | listvar = (*(extractatt(top_uvalue, 'fileparameters'))[currentfile]).listvar |
|---|
| 91 | name = listvar[event.index] |
|---|
| 92 | changefield, event.top, name |
|---|
| 93 | END |
|---|
| 94 | 'txtcmd': |
|---|
| 95 | 'filelist':BEGIN |
|---|
| 96 | changefile, event.top, event.index |
|---|
| 97 | END |
|---|
| 98 | 'ActiverFenetre':BEGIN |
|---|
| 99 | if event.enter EQ 1 AND !d.name NE 'PS' then BEGIN |
|---|
| 100 | ; graphid = widget_info(event.top,find_by_uname = 'graph') |
|---|
| 101 | graphid = extractatt(top_uvalue, 'graphid') |
|---|
| 102 | widget_control,graphid,get_value=win |
|---|
| 103 | wset, win |
|---|
| 104 | widget_control,event.top,get_uvalue=top_uvalue |
|---|
| 105 | numdessinin = (extractatt(top_uvalue, 'smallin'))[2]-1 |
|---|
| 106 | !p = (extractatt(top_uvalue, 'penvs'))[numdessinin] |
|---|
| 107 | !x = (extractatt(top_uvalue, 'xenvs'))[numdessinin] |
|---|
| 108 | !y = (extractatt(top_uvalue, 'yenvs'))[numdessinin] |
|---|
| 109 | endif |
|---|
| 110 | END |
|---|
| 111 | 'graph':BEGIN |
|---|
| 112 | quelclick = identifyclick(event) |
|---|
| 113 | case quelclick.type of |
|---|
| 114 | 'inutile':return |
|---|
| 115 | 'long':longclickaction, event |
|---|
| 116 | 'single':singleclickaction, event |
|---|
| 117 | 'double':doubleclickaction, event |
|---|
| 118 | endcase |
|---|
| 119 | END |
|---|
| 120 | endcase |
|---|
| 121 | if keyword_set(nouveaudessin) then letsdraw, event.top |
|---|
| 122 | return |
|---|
| 123 | end |
|---|
| 124 | ;------------------------------------------------------------ |
|---|
| 125 | ;------------------------------------------------------------ |
|---|
| 126 | ;------------------------------------------------------------ |
|---|
| 127 | ;------------------------------------------------------------ |
|---|
| 128 | ;------------------------------------------------------------ |
|---|
| 129 | ;------------------------------------------------------------ |
|---|
| 130 | PRO xxx, datafilename, idlfile, argspro, CALLERWIDID = CallerWidId $ |
|---|
| 131 | , REDRAW = redraw, SEPARATE = separate, UVALUE = uvalue $ |
|---|
| 132 | , RESTORE = restore, _EXTRA = ex |
|---|
| 133 | ;------------------------------------------------------------ |
|---|
| 134 | ; |
|---|
| 135 | compile_opt idl2, strictarrsubs |
|---|
| 136 | ; |
|---|
| 137 | @all_cm |
|---|
| 138 | ;------------------------------------------------------------ |
|---|
| 139 | ; reinitialize the !p, !x, !y, !z variables |
|---|
| 140 | ;------------------------------------------------------------ |
|---|
| 141 | reinitplt |
|---|
| 142 | ;------------------------------------------------------------ |
|---|
| 143 | ; we get back the uvalue of the widget that called xxx to create a new widget |
|---|
| 144 | if keyword_set(restore) then BEGIN |
|---|
| 145 | restore = isafile(filename = restore, iodir = homedir, _extra = ex) |
|---|
| 146 | if size(restore, /type) NE 7 then restore = 0 ELSE BEGIN |
|---|
| 147 | restore, isafile(file = restore, iodir = homedir, _extra = ex) |
|---|
| 148 | newgrid = *(extractatt(uvalue, 'meshparameters'))[0] |
|---|
| 149 | change = changegrid(newgrid) |
|---|
| 150 | ENDELSE |
|---|
| 151 | endif |
|---|
| 152 | if n_elements(CallerWidId) NE 0 THEN $ |
|---|
| 153 | widget_control, CallerWidId, get_uvalue = uvalue ELSE CallerWidId = 0 |
|---|
| 154 | ;------------------------------------------------------------ |
|---|
| 155 | ;------------------------------------------------------------ |
|---|
| 156 | ; liste des fichiers que l''on veut regarder |
|---|
| 157 | ; |
|---|
| 158 | if keyword_set(uvalue) then BEGIN |
|---|
| 159 | currentfile = extractatt(uvalue, 'currentfile') |
|---|
| 160 | filelist = extractatt(uvalue, 'filelist') |
|---|
| 161 | fileparameters = extractatt(uvalue, 'fileparameters') |
|---|
| 162 | readparameters = extractatt(uvalue, 'readparameters') |
|---|
| 163 | meshparameters = extractatt(uvalue, 'meshparameters') |
|---|
| 164 | ENDIF ELSE BEGIN |
|---|
| 165 | newfile = selectfile(datafilename, idlfile, argspro, _extra = ex) |
|---|
| 166 | if size(newfile, /type) NE 8 then return |
|---|
| 167 | fileparameters = ptrarr(1, /allocate_heap) |
|---|
| 168 | *fileparameters[0] = newfile.fileparameters |
|---|
| 169 | readparameters = ptrarr(1, /allocate_heap) |
|---|
| 170 | *readparameters[0] = newfile.readparameters |
|---|
| 171 | meshparameters = ptrarr(1, /allocate_heap) |
|---|
| 172 | *meshparameters[0] = newfile.meshparameters |
|---|
| 173 | currentfile = 0 |
|---|
| 174 | filelist = newfile.fileparameters.filename |
|---|
| 175 | ENDELSE |
|---|
| 176 | ; |
|---|
| 177 | if keyword_set(uvalue) THEN BEGIN |
|---|
| 178 | smallin = extractatt(uvalue, 'smallin') |
|---|
| 179 | smallout = extractatt(uvalue, 'smallout') |
|---|
| 180 | ENDIF ELSE BEGIN |
|---|
| 181 | smallin = [1, 1, 1] |
|---|
| 182 | smallout = [1, 1, 1] |
|---|
| 183 | ENDELSE |
|---|
| 184 | nbredessin = smallin[0]*smallin[1] |
|---|
| 185 | numdessinin = smallin[2]-1 |
|---|
| 186 | ; warning flg definition must be consistent with cw_pdmenu argument |
|---|
| 187 | ; see also flag definition in cw_pagelayout |
|---|
| 188 | if keyword_set(uvalue) then BEGIN |
|---|
| 189 | flag = extractatt(uvalue, 'optionsflag') |
|---|
| 190 | key_portrait = flag[0, numdessinin] |
|---|
| 191 | ENDIF ELSE flag = [key_portrait, 0, 0, 0, 0]#replicate(1, nbredessin) |
|---|
| 192 | |
|---|
| 193 | ;------------------------------------------------------------ |
|---|
| 194 | ;------------------------------------------------------------ |
|---|
| 195 | ; We start the widget definition |
|---|
| 196 | ;------------------------------------------------------------ |
|---|
| 197 | ;------------------------------------------------------------ |
|---|
| 198 | ; |
|---|
| 199 | ; widget and screen size |
|---|
| 200 | scrsize = get_screen_size()*0.95 |
|---|
| 201 | windsize = givewindowsize() |
|---|
| 202 | xxxsize = [windsize[0] * (1-keyword_set(separate)) + 350, windsize[1]] |
|---|
| 203 | ; |
|---|
| 204 | ;------------------------------------------------------------ |
|---|
| 205 | ; The top base |
|---|
| 206 | ;------------------------------------------------------------ |
|---|
| 207 | IF xxxsize[0] LE scrsize[0] AND xxxsize[1] LE scrsize[1] THEN BEGIN |
|---|
| 208 | base = widget_base(title = 'xxx', GROUP_LEADER = group, /tracking_events $ |
|---|
| 209 | , uname = 'base', space = 0) |
|---|
| 210 | ENDIF ELSE BEGIN |
|---|
| 211 | base = widget_base(title = 'xxx', GROUP_LEADER = group, /tracking_events $ |
|---|
| 212 | , uname = 'base', space = 0 $ |
|---|
| 213 | , xsize = xxxsize[0], ysize = xxxsize[1] $ |
|---|
| 214 | , x_scroll_size = (xxxsize[0] < scrsize[0]) $ |
|---|
| 215 | , y_scroll_size = (xxxsize[1] < scrsize[1])) |
|---|
| 216 | ENDELSE |
|---|
| 217 | |
|---|
| 218 | ;------------------------------------------------------------ |
|---|
| 219 | ; combobox for plots choice |
|---|
| 220 | ;------------------------------------------------------------ |
|---|
| 221 | xoff = 0 |
|---|
| 222 | yoff = 0 |
|---|
| 223 | pltlst = ['plt' $ |
|---|
| 224 | , 'pltz', 'pltz diag up', 'pltz diag dn' $ |
|---|
| 225 | , 'pltt', 'pltt diag up', 'pltt diag dn' $ |
|---|
| 226 | , 'xy', 'xz', 'yz', 'xt', 'yt', 'zt' $ |
|---|
| 227 | , 'x', 'y', 'z', 't'] |
|---|
| 228 | actid = widget_combobox(base, value = pltlst, uname = 'action', uvalue = {name:'action'} $ |
|---|
| 229 | , xoffset = xoff+5, yoffset = yoff+4, xsize = 90) |
|---|
| 230 | if keyword_set(uvalue) then BEGIN |
|---|
| 231 | selectact = (extractatt(uvalue, 'types'))[numdessinin] |
|---|
| 232 | selectact = (where(pltlst EQ selectact))[0] |
|---|
| 233 | widget_control, actid, set_combobox_select = 0 > selectact |
|---|
| 234 | ENDIF ELSE selectfile = 0 |
|---|
| 235 | |
|---|
| 236 | ;------------------------------------------------------------ |
|---|
| 237 | ; menu/options |
|---|
| 238 | ;------------------------------------------------------------ |
|---|
| 239 | xoff = xoff + 110 |
|---|
| 240 | if keyword_set(uvalue) then begin |
|---|
| 241 | options = extractatt(uvalue, 'options') |
|---|
| 242 | ENDIF ELSE options = ['Portrait/Landscape', 'Overlay', 'Vecteur' $ |
|---|
| 243 | , 'Longitude / x index', 'Latitude / y index'] |
|---|
| 244 | |
|---|
| 245 | desc = [ '1\File', $ |
|---|
| 246 | '0\Open' , $ |
|---|
| 247 | '0\New xxx' , $ |
|---|
| 248 | '2\Quit', $ |
|---|
| 249 | '1\Save as' , $ |
|---|
| 250 | '0\PostScript' , $ |
|---|
| 251 | '0\Animated gif' , $ |
|---|
| 252 | '0\Gif' , $ |
|---|
| 253 | '0\IDL procedure', $ |
|---|
| 254 | '0\RESTORE kwd of xxx', $ |
|---|
| 255 | '2\Print to prompt', $ |
|---|
| 256 | '1\Flag options'] |
|---|
| 257 | descsuite = options |
|---|
| 258 | if n_elements(descsuite) GE 2 then $ |
|---|
| 259 | descsuite[0:n_elements(descsuite)-2] = '0\'+descsuite[0:n_elements(descsuite)-2] |
|---|
| 260 | descsuite[n_elements(descsuite)-1] = '2\'+descsuite[n_elements(descsuite)-1] |
|---|
| 261 | desc = [desc, descsuite] |
|---|
| 262 | ; |
|---|
| 263 | menu = cw_pdmenu(base, desc, /RETURN_NAME, uname = 'menubar', uvalue = {name:'menubar'} $ |
|---|
| 264 | , xoffset = xoff, yoffset = yoff) |
|---|
| 265 | |
|---|
| 266 | ;------------------------------------------------------------ |
|---|
| 267 | ; Ok button |
|---|
| 268 | ;------------------------------------------------------------ |
|---|
| 269 | yoff = yoff + 37 |
|---|
| 270 | xoff = 5 |
|---|
| 271 | ; boutton 'OK' |
|---|
| 272 | baseok = widget_button(base, value = ' OK ', uvalue = {name:'ok'}, uname = 'ok button' $ |
|---|
| 273 | , /frame, xoffset = xoff, yoffset = yoff) |
|---|
| 274 | |
|---|
| 275 | ;------------------------------------------------------------ |
|---|
| 276 | ; Page Layout |
|---|
| 277 | ;------------------------------------------------------------ |
|---|
| 278 | ; page layout |
|---|
| 279 | xoff = xoff + 65 |
|---|
| 280 | dummyid = cw_pagelayout(base, smallin, /row, /frame, xoffset = xoff, yoffset = yoff) |
|---|
| 281 | ; |
|---|
| 282 | ;------------------------------------------------------------ |
|---|
| 283 | ; List of Variables |
|---|
| 284 | ;------------------------------------------------------------ |
|---|
| 285 | xoff = xoff + 140 |
|---|
| 286 | currentlistvar = (*fileparameters[currentfile]).listvar |
|---|
| 287 | vlstid = widget_combobox(base, value = currentlistvar, uvalue = {name:'varlist'} $ |
|---|
| 288 | , uname = 'varlist', xoffset = xoff, yoffset = yoff+1) |
|---|
| 289 | if keyword_set(uvalue) then BEGIN |
|---|
| 290 | selectvar = (extractatt(uvalue, 'varinfo'))[1, numdessinin] |
|---|
| 291 | selectvar = (where(currentlistvar EQ selectvar))[0] |
|---|
| 292 | widget_control, vlstid, set_combobox_select = 0 > selectvar |
|---|
| 293 | ENDIF ELSE selectvar = 0 |
|---|
| 294 | ;------------------------------------------------------------ |
|---|
| 295 | ; List of files |
|---|
| 296 | ;------------------------------------------------------------ |
|---|
| 297 | yoff = yoff + 35 |
|---|
| 298 | flstid = widget_combobox(base, value = file_basename(filelist), uname = 'filelist' $ |
|---|
| 299 | , xsize = 345, yoffset = yoff, uvalue = {name:'filelist'}) |
|---|
| 300 | if keyword_set(uvalue) then BEGIN |
|---|
| 301 | selectfile = (extractatt(uvalue, 'varinfo'))[0, numdessinin] |
|---|
| 302 | selectfile = (where(file_basename(filelist) EQ selectfile))[0] |
|---|
| 303 | widget_control, flstid, set_combobox_select = 0 > selectfile |
|---|
| 304 | ENDIF ELSE selectfile = 0 |
|---|
| 305 | ;------------------------------------------------------------ |
|---|
| 306 | ; Text for computation |
|---|
| 307 | ;------------------------------------------------------------ |
|---|
| 308 | yoff = yoff + 32 |
|---|
| 309 | ; computation done on the files... |
|---|
| 310 | if keyword_set(uvalue) then txtvalue = (extractatt(uvalue, 'txtcmd'))[numdessinin] $ |
|---|
| 311 | ELSE txtvalue = varexp |
|---|
| 312 | dummyid = widget_text(base, value = txtvalue, uvalue = {name:'txtcmd'}, uname = 'txtcmd' $ |
|---|
| 313 | , /editable, yoffset = yoff, xsize = 54, /frame) |
|---|
| 314 | ;------------------------------------------------------------ |
|---|
| 315 | ; Calendar |
|---|
| 316 | ;------------------------------------------------------------ |
|---|
| 317 | yoff = yoff + 40 |
|---|
| 318 | currentcalendar = (*fileparameters[currentfile]).time_counter |
|---|
| 319 | key_caltype = (*fileparameters[currentfile]).caltype |
|---|
| 320 | fakecal = (*fileparameters[currentfile]).fakecal |
|---|
| 321 | if keyword_set(uvalue) then begin |
|---|
| 322 | dates = (extractatt(uvalue, 'dates'))[*, numdessinin] |
|---|
| 323 | date1 = date2jul(dates[0]) |
|---|
| 324 | date2 = date2jul(dates[1]) |
|---|
| 325 | ENDIF |
|---|
| 326 | basecalid = widget_base(base, column = 2, space = 0, yoffset = yoff, uname = 'basecal') |
|---|
| 327 | dummyid = cw_calendar(basecalid, currentcalendar, date1, FAKECAL = fakecal, uname = 'calendar1', uvalue = {name:'calendar1'}, /frame) |
|---|
| 328 | dummyid = cw_calendar(basecalid, currentcalendar, date2, FAKECAL = fakecal, uname = 'calendar2', uvalue = {name:'calendar2'}, /frame) |
|---|
| 329 | ;------------------------------------------------------------ |
|---|
| 330 | ; Domain |
|---|
| 331 | ;------------------------------------------------------------ |
|---|
| 332 | yoff = yoff + 60 |
|---|
| 333 | vargrid = strupcase((*fileparameters[currentfile]).listgrid[selectvar]) |
|---|
| 334 | IF vargrid EQ 'W' then zgrid = 'W' ELSE zgrid = 'T' |
|---|
| 335 | if keyword_set(uvalue) then boxzoom = (extractatt(uvalue, 'domaines'))[*, numdessinin] |
|---|
| 336 | dummyid = cw_domain(base, uname = 'domain', uvalue = {name:'domain'}, /unzoom, /frame $ |
|---|
| 337 | , boxzoom = boxzoom, yoffset = yoff, xoffset = 15) |
|---|
| 338 | ;------------------------------------------------------------ |
|---|
| 339 | ; Plots specifications |
|---|
| 340 | ;------------------------------------------------------------ |
|---|
| 341 | yoff = yoff + 230 |
|---|
| 342 | speid = cw_specifie(base, uname = 'specifie', uvalue = {name:'specifie'}, /frame, /column $ |
|---|
| 343 | , /forxxx, yoffset = yoff) |
|---|
| 344 | if keyword_set(uvalue) then BEGIN |
|---|
| 345 | exextra = *((extractatt(uvalue, 'exextra'))[numdessinin]) |
|---|
| 346 | IF n_elements(exextra) NE 0 THEN widget_control, speid, set_value = exextra |
|---|
| 347 | ENDIF |
|---|
| 348 | ;------------------------------------------------------------ |
|---|
| 349 | ; drawing part |
|---|
| 350 | ;------------------------------------------------------------ |
|---|
| 351 | if keyword_set(separate) then $ |
|---|
| 352 | basegraph = widget_base(title = 'xxx window', group_leader = base, uvalue = base) $ |
|---|
| 353 | ELSE basegraph = base |
|---|
| 354 | |
|---|
| 355 | graphid = widget_draw(basegraph, uname = 'graph', /button_events, retain = 2 $ |
|---|
| 356 | , uvalue = {name:'graph', press:0, click:0, x:[0., 0.], y:[0., 0.]} $ |
|---|
| 357 | , xoffset = 350*(1-keyword_set(separate)) $ |
|---|
| 358 | , xsize = windsize[0], ysize = windsize[1]); , tooltip = 'toto') |
|---|
| 359 | ;------------------------------------------------------------ |
|---|
| 360 | ; realize the widget |
|---|
| 361 | ;------------------------------------------------------------ |
|---|
| 362 | widget_control, base, /realize |
|---|
| 363 | if keyword_set(separate) then begin |
|---|
| 364 | widget_control, basegraph, /realize |
|---|
| 365 | xmanager, 'xxx', basegraph, /no_block |
|---|
| 366 | endif |
|---|
| 367 | |
|---|
| 368 | ;------------------------------------------------------------ |
|---|
| 369 | if keyword_set(uvalue) then BEGIN ; |
|---|
| 370 | ; on recopie le pointeur uvalue dans top_uvalue. |
|---|
| 371 | ; Attention, il faut completement redefinir top_uvalue a partir des |
|---|
| 372 | ; variables pointees par uvalue. Sinon si on fait simplement |
|---|
| 373 | ; top_uvalue = uvalue, qd on detruit par uvalue et les variables |
|---|
| 374 | ; surlesquelles il pointe on detruit aussi les variables sur |
|---|
| 375 | ; lesquelles pointent top_uvalue. |
|---|
| 376 | case 1 of |
|---|
| 377 | keyword_set(redraw):BEGIN |
|---|
| 378 | top_uvalue = uvalue |
|---|
| 379 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 380 | ; we find homedir |
|---|
| 381 | homedir = isadirectory(io = homedir, title = 'Bad definition of homedir') |
|---|
| 382 | ; on recupere la liste des instructions |
|---|
| 383 | globalcommand = extractatt(top_uvalue, 'globalcommand') |
|---|
| 384 | ; on complete par le premiere et les dernieres lignes du programme |
|---|
| 385 | createpro, globalcommand, filename = myuniquetmpdir + 'xxx2ps.pro' $ |
|---|
| 386 | , KWDLIST = ', NOERASE = noerase, POSTSCRIPT = postscript' $ |
|---|
| 387 | +', PORTRAIT = portrait, LANDSCAPE = landscape' $ |
|---|
| 388 | , /noerase |
|---|
| 389 | END |
|---|
| 390 | keyword_set(restore):begin |
|---|
| 391 | top_uvalue = uvalue |
|---|
| 392 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 393 | widget_control, graphid, get_value = win |
|---|
| 394 | wshow, win |
|---|
| 395 | wset, win |
|---|
| 396 | tv, image, /true |
|---|
| 397 | ; etat des widgets |
|---|
| 398 | updatewidget, base |
|---|
| 399 | ; menage |
|---|
| 400 | END |
|---|
| 401 | ELSE:BEGIN |
|---|
| 402 | top_uvalue = ptrarr(2, 29, /allocate_heap) |
|---|
| 403 | FOR i = 0, 28 do *top_uvalue[0, i] = *uvalue[0, i] |
|---|
| 404 | FOR i = 0, 14 do *top_uvalue[1, i] = *uvalue[1, i] |
|---|
| 405 | FOR i = 18, 27 do *top_uvalue[1, i] = *uvalue[1, i] |
|---|
| 406 | numfile = n_elements(extractatt(uvalue, 'filelist')) |
|---|
| 407 | *top_uvalue[1, 15] = ptrarr(numfile, /allocate_heap) |
|---|
| 408 | *top_uvalue[1, 16] = ptrarr(numfile, /allocate_heap) |
|---|
| 409 | *top_uvalue[1, 17] = ptrarr(numfile, /allocate_heap) |
|---|
| 410 | for i = 0, numfile-1 do begin |
|---|
| 411 | *(*top_uvalue[1, 15])[i] = *(*uvalue[1, 15])[i] |
|---|
| 412 | *(*top_uvalue[1, 16])[i] = *(*uvalue[1, 16])[i] |
|---|
| 413 | *(*top_uvalue[1, 17])[i] = *(*uvalue[1, 17])[i] |
|---|
| 414 | endfor |
|---|
| 415 | *top_uvalue[1, 28] = ptrarr(nbredessin, /allocate_heap) |
|---|
| 416 | for i = 0, nbredessin-1 do *(*top_uvalue[1, 28])[i] = *(*uvalue[1, 28])[i] |
|---|
| 417 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 418 | ; copie l''ecran du widget de uvalue dans celui de top_uvalue |
|---|
| 419 | if keyword_set(CallerWidId) then begin |
|---|
| 420 | widget_control, extractatt(uvalue, 'graphid'), get_value = win |
|---|
| 421 | wshow, win |
|---|
| 422 | wset, win |
|---|
| 423 | image = tvrd(/true) |
|---|
| 424 | widget_control, graphid, get_value = win |
|---|
| 425 | wshow, win |
|---|
| 426 | wset, win |
|---|
| 427 | tv, image, /true |
|---|
| 428 | ENDIF |
|---|
| 429 | END |
|---|
| 430 | endcase |
|---|
| 431 | *top_uvalue[1, findline(top_uvalue, 'graphid')] = graphid |
|---|
| 432 | ; |
|---|
| 433 | ENDIF ELSE BEGIN |
|---|
| 434 | ; sinon on va definit tous les elements que l''on acroche au widget |
|---|
| 435 | ; grace a la top_uvalue qui est un tableau de pointeurs a 2 colonnes: |
|---|
| 436 | ; les noms et des variables |
|---|
| 437 | ; on initialie tous ces elements. |
|---|
| 438 | ; variables concernant le widget ds sa generalite |
|---|
| 439 | if NOT keyword_set(ex) then ex = {nothing:0} |
|---|
| 440 | ; variables se rapportant aux differents fichiers que l''on peut lire |
|---|
| 441 | ; variables specifiques a chaque dessin |
|---|
| 442 | ; |
|---|
| 443 | |
|---|
| 444 | ; creation du pointeur que l''on va attache au widget. |
|---|
| 445 | top_uvalue = ptrarr(2, 29, /allocate_heap) |
|---|
| 446 | ; variables se rapportant au widget en general |
|---|
| 447 | *top_uvalue[0, 0] = 'options' & *top_uvalue[1, 0] = options |
|---|
| 448 | *top_uvalue[0, 1] = 'smallin' & *top_uvalue[1, 1] = smallin |
|---|
| 449 | *top_uvalue[0, 2] = 'smallout' & *top_uvalue[1, 2] = smallout |
|---|
| 450 | *top_uvalue[0, 3] = 'graphid' & *top_uvalue[1, 3] = graphid |
|---|
| 451 | *top_uvalue[0, 4] = 'alreadyvector' & *top_uvalue[1, 4] = -1 |
|---|
| 452 | *top_uvalue[0, 5] = 'alreadyover' & *top_uvalue[1, 5] = -1 |
|---|
| 453 | *top_uvalue[0, 6] = 'alreadyread' & *top_uvalue[1, 6] = -1 |
|---|
| 454 | *top_uvalue[0, 7] = 'currentreadcmd' & *top_uvalue[1, 7] = '' |
|---|
| 455 | *top_uvalue[0, 8] = 'globalcommand' & *top_uvalue[1, 8] = '' |
|---|
| 456 | *top_uvalue[0, 9] = 'globaloldcommand' & *top_uvalue[1, 9] = '' |
|---|
| 457 | *top_uvalue[0, 10] = 'no more used' & *top_uvalue[1, 10] = 9999 |
|---|
| 458 | *top_uvalue[0, 11] = 'noticebase' & *top_uvalue[1, 11] = 0l |
|---|
| 459 | *top_uvalue[0, 12] = 'extra' & *top_uvalue[1, 12] = ex |
|---|
| 460 | ; variables se rapportant aux differents fichiers que l''on peut lire |
|---|
| 461 | *top_uvalue[0, 13] = 'currentfile' & *top_uvalue[1, 13] = currentfile |
|---|
| 462 | *top_uvalue[0, 14] = 'filelist' & *top_uvalue[1, 14] = filelist |
|---|
| 463 | *top_uvalue[0, 15] = 'fileparameters' & *top_uvalue[1, 15] = fileparameters |
|---|
| 464 | *top_uvalue[0, 16] = 'readparameters' & *top_uvalue[1, 16] = readparameters |
|---|
| 465 | *top_uvalue[0, 17] = 'meshparameters' & *top_uvalue[1, 17] = meshparameters |
|---|
| 466 | ; variables se rapportant aux differents dessins que l''on peut faire |
|---|
| 467 | *top_uvalue[0, 18] = 'penvs' & *top_uvalue[1, 18] = replicate(!p, nbredessin) |
|---|
| 468 | *top_uvalue[0, 19] = 'xenvs' & *top_uvalue[1, 19] = replicate(!x, nbredessin) |
|---|
| 469 | *top_uvalue[0, 20] = 'yenvs' & *top_uvalue[1, 20] = replicate(!y, nbredessin) |
|---|
| 470 | *top_uvalue[0, 21] = 'nameprocedures' & *top_uvalue[1, 21] = strarr(nbredessin) |
|---|
| 471 | *top_uvalue[0, 22] = 'types' & *top_uvalue[1, 22] = strarr(nbredessin) |
|---|
| 472 | *top_uvalue[0, 23] = 'varinfo' & *top_uvalue[1, 23] = strarr(2, nbredessin) |
|---|
| 473 | *top_uvalue[0, 24] = 'domaines' & *top_uvalue[1, 24] = fltarr(6, nbredessin) |
|---|
| 474 | *top_uvalue[0, 25] = 'dates' & *top_uvalue[1, 25] = lonarr(2, nbredessin) |
|---|
| 475 | *top_uvalue[0, 26] = 'txtcmd' & *top_uvalue[1, 26] = strarr(nbredessin) |
|---|
| 476 | *top_uvalue[0, 27] = 'optionsflag' & *top_uvalue[1, 27] = flag |
|---|
| 477 | *top_uvalue[0, 28] = 'exextra' & *top_uvalue[1, 28] = ptrarr(nbredessin, /allocate_heap) |
|---|
| 478 | ; |
|---|
| 479 | widget_control, base, set_uvalue = top_uvalue |
|---|
| 480 | createhistory, base, smallin |
|---|
| 481 | ; |
|---|
| 482 | ENDELSE |
|---|
| 483 | ;------------------------------------------------------------ |
|---|
| 484 | xmanager, 'xxx', base, /no_block |
|---|
| 485 | ;------------------------------------------------------------ |
|---|
| 486 | ;------------------------------------------------------------ |
|---|
| 487 | return |
|---|
| 488 | end |
|---|
