source: trunk/SRC/ToBeReviewed/WIDGET/COMPOUND_WIDGET/cw_specifie.pro @ 226

;*****************************************************
;+
; @file_comments
;
;
; @categories
; Compound widget
;
; @param ID
;
; @param VALUE
; It is the default tick mark value (a floating-point number).
;
; @returns
;
; @uses
;
; @restrictions
;
; @examples
;
; @history
;
; @version
; $Id$
;-
PRO cw_specifie_set_value, id, value
;
  compile_opt idl2, strictarrsubs
;
@cm_general
   if size(value, /type) NE 8 then return
   widget_control, widget_info(id,find_by_uname='min'), set_value = strtrim(value.min, 2)
   widget_control, widget_info(id,find_by_uname='max'), set_value = strtrim(value.max, 2)
   widget_control, widget_info(id,find_by_uname='int'), set_value = strtrim(value.inter, 2)
   widget_control, widget_info(id,find_by_uname='palnum'), set_value = strtrim(value.lct, 2)
   autres = extractstru(value, ['min', 'max', 'inter', 'lct', 'nothing', 'xindex', 'yindex'])
   if size(autres, /type) EQ 8 then BEGIN
      autresid = widget_info(id,find_by_uname='autres')
      widget_control, widget_info(id, find_by_uname = 'autres'), get_value = autresautres
      autresautres = autresautres[0]
      if strtrim(autresautres, 2) NE '' then begin
        autresautres = createfunc('get_extra(' + autresautres + ')' $
                                  , filename = myuniquetmpdir +'for_createfunc.pro')
        autres = mixstru(autres, autresautres)
      endif
      autres = strkeywd(autres)
      widget_control, widget_info(id,find_by_uname='autres'), set_value = autres
   endif
   return
end
;*****************************************************
;+
; @file_comments
;
;
; @categories
; Compound widget
;
; @param ID
;
; @returns
;
; @uses
;
; @restrictions
;
; @examples
;
; @history
;
; @version
; $Id$
;-
FUNCTION cw_specifie_get_value, id
;
  compile_opt idl2, strictarrsubs
;
@cm_general
   widget_control, widget_info(id,find_by_uname='min'), get_value = min
   min = float(min[0])
   widget_control, widget_info(id,find_by_uname='max'), get_value = max
   max = float(max[0])
   widget_control, widget_info(id,find_by_uname='int'), get_value = int
   int = float(int[0])
   widget_control, widget_info(id,find_by_uname='palnum'), get_value = palnum
   palnum = long(palnum[0])
   widget_control, widget_info(id,find_by_uname='autres'), get_value = autres
   autres = autres[0]
;
   exextra = {min:min, max:max, inter:int, lct:palnum}
   if strtrim(autres, 2) NE '' then $
      exextra = createfunc('get_extra('+autres+', _extra = exextra)' $
                           , kwdlist = 'exextra = exextra', exextra = exextra $
                           , filename = myuniquetmpdir +'for_createfunc.pro')
;
   return, exextra
end
;*****************************************************
;+
; @file_comments
;
;
; @categories
; Compound widget
;
; @param EVENT
;
; @returns
;
; @uses
;
; @restrictions
;
; @examples
;
; @history
;
; @version
; $Id$
;-
FUNCTION cw_specifie_event, event
;------------------------------------------------------------
; on recupere les ID des differents widgets
;------------------------------------------------------------
;------------------------------------------------------------
;
  compile_opt idl2, strictarrsubs
;
  widget_control, event.id, get_uvalue = uval
  widget_control, event.top, get_uvalue = top_uvalue
  smallin = extractatt(top_uvalue, 'smallin')
  numdessinin = smallin[2]-1
  smallout = extractatt(top_uvalue, 'smallout')
  numdessinout = smallout[2]-1
;------------------------------------------------------------
  case uval of
    'default':BEGIN
;---------------
; We find the name of the variable:
      vlstid = widget_info(event.top, find_by_uname = 'varlist')
      fieldname = widget_info(vlstid, /combobox_gettext)
;---------------
      exextra = definedefaultextra(fieldname)
      widget_control, widget_info(event.handler, find_by_uname = 'min'), set_value = strtrim(exextra.min, 1)
      widget_control, widget_info(event.handler, find_by_uname = 'max'), set_value = strtrim(exextra.max, 1)
      widget_control, widget_info(event.handler, find_by_uname = 'int'), set_value = strtrim(exextra.inter, 1)
      widget_control, widget_info(event.handler, find_by_uname = 'palnum'), set_value = strtrim(exextra.lct, 1)
      widget_control, widget_info(event.handler, find_by_uname = 'autres'), set_value = ''
    END
    'palcol':BEGIN
      ind = fix(strmid(event.value, 0, strpos(event.value, '-')))
      widget_control, widget_info(event.handler, find_by_uname = 'palnum'), set_value = strtrim(ind, 1)
    END
    ELSE:
  endcase
  return, {ID:event.handler, TOP:event.top, HANDLER:0L, OK:uval EQ 'ok'}
end
;*****************************************************
;*****************************************************
;+
; @file_comments
;
;
; @categories
; Compound widget
;
; @param PARENT {in}{required}
; The widget ID of the parent widget.
;
; @keyword COLUMN
; Buttons will be arranged in the number of columns
; specified by this keyword.
;
; @keyword ROW
; Buttons will be arranged in the number of rows
; specified by this keyword.
;
; @keyword UVALUE
; The user value to be associated with the widget.
;
; @keyword UNAME
; The user name to be associated with the widget.
;
; @keyword FRAME
;
; @keyword FORXXX
;
; @keyword _EXTRA
; Used to pass your keywords
;
; @returns
;
; @uses
;
; @restrictions
;
; @examples
;
; @history
;
; @version
; $Id$
;
; @todo
; seb: documenter
;
;-
FUNCTION cw_specifie, parent, ROW = row, COLUMN = column, UVALUE = uvalue, UNAME = uname, FRAME = frame, FORXXX = forxxx, _extra = ex
; checking exclusive keywords
;
  compile_opt idl2, strictarrsubs
;
   column = keyword_set(column)*(1-keyword_set(row))
   row = keyword_set(row)*(1-keyword_set(column)) +(keyword_set(row) EQ column)
;------------------------------------------------
   if NOT keyword_set(uvalue) then uvalue = ''
   if NOT keyword_set(uname) then uname = ''
   base = widget_base(parent, space = 0, /frame $
                      , EVENT_FUNC = 'cw_specifie_event' $
                      , FUNC_GET_VALUE='cw_specifie_get_value' $
                      , PRO_SET_VALUE='cw_specifie_set_value' $
                      , UVALUE = uvalue, UNAME = uname, _extra = ex)
; base1
   base1 = widget_base(base)
   rien = widget_label(base1, value = 'Min', xoffset =  85, yoffset = 15)
   rien = widget_label(base1, value = 'Max', xoffset = 145, yoffset = 15)
   rien = widget_label(base1, value = 'Int', xoffset = 210, yoffset = 15)
;
   lct, get_name = nomcouleur
   nbrligne = 30
   nbrlist = n_elements(nomcouleur)/nbrligne
   nomcouleur = strtrim(sindgen(n_elements(nomcouleur)), 1)+'- '+nomcouleur
   nomcouleur = '0\'+nomcouleur
   nomcouleur = ['1\Color', nomcouleur]
   if nbrlist GT 1 then for i = 1,nbrlist do $
    nomcouleur = [nomcouleur[0:nbrligne*i-1+i], '1\ ', nomcouleur[nbrligne*i+i:n_elements(nomcouleur)-1]]
   rien = cw_pdmenu(base1, nomcouleur, /RETURN_NAME , uvalue = 'palcol', uname = 'palcol', xoffset = 250, yoffset = 0)
; base2
   base2 = widget_base(base, column = 4+keyword_set(forxxx), yoffset = 30)
   if keyword_set(forxxx) then rien = widget_button(base2,value='Default', uvalue = 'default', /frame, tooltip = 'see '+(find('definedefaultextra'))[0])
   rien = widget_text(base2, value = '', /editable, xsize = 7, uname = 'min', uvalue = 'min')
   rien = widget_text(base2, value = '', /editable, xsize = 7, uname = 'max', uvalue = 'max')
   rien = widget_text(base2, value = '', /editable, xsize = 7, uname = 'int', uvalue = 'int')
   if keyword_set(forxxx) then colvalue = '' ELSE colvalue = '39'
   rien = widget_text(base2, value = colvalue, /editable, xsize = 2, uname = 'palnum', uvalue = 'palnum')



; widget text containing other keywords pass into top_uvalue.exextra
; Does it remain some? If yes, we have to put them as string

   rien = widget_text(base, value = '  ', /editable, uname = 'autres', uvalue = 'autres', xsize = 54, ysize = 3, yoffset = 65, /wrap, /no_newline)

    if keyword_set(forxxx) then cw_specifie_set_value, base, definedefaultextra('rien_du_tout')

;------------------------------------------------
   return, base
end