source: trunk/SRC/ToBeReviewed/PLOTS/DIVERS/placedessin.pro @ 134

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:placedessin
;
; PURPOSE: mise en place du dessin / ouverture de la fenetre ou du PS
;
; CATEGORY: pour alleger les programmes plt, pltz, pltt.
;
; CALLING SEQUENCE: placedessin, typedessin,posfenetre, posbar
;
; INPUTS:
;   typedessin: une chaine de charactere specifiant quelle procedure
;   appelle placedessin: 'plt', 'pltz', 'pltt'
;
; KEYWORD PARAMETERS: pleins (ce de CALIBRE de WINDOW ...)
;
;       LCT: intier designant le numero de la palette de couleur que
;       l''on veut utiliser pour les plot. 
;       
; OUTPUTS:
;
;       posfenetre: un vecteur de 4 elements contenant la position de
;       cadre contenant les legendes + le graphe en coordonnes
;       normalises. Rq: pour positionner le dessin il faut apres
;       l''appelle de calibre faire !p.position=posfenetre
;
;       posbar: cf posfentre mais pour la barre de couleur. meme
;       remarque pour positionner la barre de couleur, !p.position=posbar
;
;
; COMMON BLOCKS:
;       common.pro
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       26/4/1999
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
PRO placedessin, typedessin, posfenetre, posbar, BARMARGES = barmarges $
                 , NOCOLORBAR = nocolorbar, NOFILL = nofill, COLOR_c = color_c $
                 , CONTOUR = contour $
                 , VECTEUR = vecteur, PORTRAIT = portrait, LANDSCAPE = landscape $
                 , SMALL = small, MARGES = marges, MAP = map $
                 , REMPLI = REMPLI, POST = post, WINDOW = window $
                 , ENDPOINTS = endpoints, TYPE = type, BASICMARGES = basicmarges $
                 , NOERASE = noerase, LCT = lct, DIREC = direc, CB_TITLE = cb_title, _extra = ex
;---------------------------------------------------------
; include common
;
  compile_opt idl2, strictarrsubs
;
@cm_4ps
@cm_4mesh
  IF NOT keyword_set(key_forgetold) THEN BEGIN
@updatekwd
  ENDIF
;-------------------------------------------------------------
; 1) determination de la taille des marges (unite=nbre de lignes ou colonnes)
; a gauche, a droite, en bas, en haut
; ATTENTION ds margebar le dernier element est le coint en haut a droite au
; lieu de la marge en haut
;-------------------------------------------------------------
  if n_elements(typedessin) EQ 0 then typedessin = 'autre'
  if keyword_set(basicmarges) then begin
    marge = 1.*[6, 2, 4, 3]
    if keyword_set(marges) THEN marge = marge+marges
    margebar = 1.*[marge[0]+1, marge[1]+1,  marge[2]-8,  marge[2]-6]
    if keyword_set(barmarges) then margebar = margebar+barmarges
  ENDIF ELSE BEGIN 
    nocolorbar = keyword_set(nocolorbar) + keyword_set(nofill) + keyword_set(color_c)  
    case typedessin of
      'plt':marge = 1.*[6, 2, 4, 3]
      'pltt':marge = 1.*[6+4*(type EQ 'xt'), 2, 4, 4]
      'pltz':marge = 1.*[6, 2, 4, 3]
      else:marge = 1.*[6, 2, 4, 3]
    ENDCASE
    if keyword_set(marges) THEN marge = marge+marges
    if NOT keyword_set(barmarges) then barmarges = replicate(0, 4)
    barmarges[3] = -barmarges[3]
    margebar = 1.*[marge[0]+1, marge[1]+1, 2, 4]+barmarges
    marge = marge+[0, 0, 4, 0]*keyword_set(cb_title)
    IF keyword_set(direc) THEN $
      marge = marge+[0, 0, 2, 0]*(strlowcase(direc) NE 't')
    marge = marge+[0, 0, 2, 0]*keyword_set(contour)
    marge = marge+[0, 0, 2, 0]*keyword_set(vecteur)
    if n_elements(lon1) NE 0 and n_elements(lon2) NE 0 $
      and n_elements(lat1) NE 0 and n_elements(lat2) NE 0 then begin
      if keyword_set(type) then $
        marge = marge+[0, 3*(type EQ 'yt' AND lon1 NE lon2), 0 $
                       , 2*(type NE 'yt' AND lat1 NE lat2)]*keyword_set(endpoints) $
      ELSE marge = marge+[0, 0, 0, 2*(lat1 NE lat2)]*keyword_set(endpoints)
    endif
    marge = marge+[0, 0, 2+margebar[3], 0]*(1-keyword_set(nocolorbar))
  ENDELSE
;--------------------------------------------------------------
; portrair ou landscape
;--------------------------------------------------------------
  IF NOT keyword_set(noerase) THEN BEGIN 
    CASE 1 OF
      n_elements(portrait) NE 0:key_portrait = portrait
      n_elements(landscape) NE 0:key_portrait = 1-landscape
      ELSE:
    ENDCASE
  ENDIF 
;--------------------------------------------------------------
; Quel type de rapport d''aspect (sera ecrase si YXASPECT existe)
;--------------------------------------------------------------
  case typedessin of
    'plt':yaspect = 1.*(lat2-lat1)/(lon2-lon1)
    'pltt':yaspect = 1.
    'pltz':yaspect = .5
    ELSE:yaspect = 1.
  endcase
;-------------------------------------------------------------
; 2) calcul de !p.position
; cf calibre.pro.
;------------------------------------------------------------
;
  IF NOT keyword_set(small) then small = [1, 1, 1]
;
  if keyword_set(map) then rempli = 1
;
  calibre, yaspect, marge, margebar, small, posfenetre, posbar, REMPLI = rempli, _extra = ex
;
  !p.position = posfenetre
;------------------------------------------------------------
; 3) ouverture de la fenetre graphique ou du postscript
;------------------------------------------------------------
  case 1 of
; cas du premier dessin sur un postcript
    keyword_set(post) AND !d.name ne 'PS':openps, _extra = ex
; cas du premier dessin sur un ecran
    keyword_set(post) EQ 0 AND keyword_set(noerase) EQ 0 $
      AND !d.name ne 'PS' AND !d.name ne 'Z':BEGIN
      if not keyword_set(window) then window = 0
; pour l''utilisation de @ps, @oups et de @vzoom
      if lmgr(/demo) EQ 0 then BEGIN ; on est en mode demo??
        if !journal NE 0 then journal ; on ferme le journal s''il est ouvert
        homedir = isadirectory(io = homedir, title = 'Bad definition of homedir')
        def_myuniquetmpdir
        journal, myuniquetmpdir+'idlsave.pro' ; on en ouvre un nouveau
        help, /recall_commands, output = listecommande ; on recupere la derniere commande
        listecommande = strmid(strcompress(listecommande[1]), 2)
        journal, listecommande ; on l''ecrit dans le journal
      ENDIF
      windsize = givewindowsize()
      window, window, xsize = windsize[0], ysize = windsize[1],  retain = 2, _extra = ex
; qd on utilise des couleurs codees sur 24 bit, je n''arrive pas a stipuler la couleur du
; fond d''une fenetre a l'aide de !p.background, je suis oblige de faire cette bidouille!!!
;          if !d.n_colors gt 256 then begin
;             device, decomposed=1
;             !p.background='ffffff'x
;             plot,[0],[0], /nodata, xstyle = 4, ystyle = 4
;             device, decomposed=0
;          endif
    END
    ELSE:
  endcase
;------------------------------------------------------------
  if n_elements(lct) NE 0 then lct, lct, _extra = ex
;------------------------------------------------------------

  return
end