source: trunk/SRC/ToBeReviewed/PLOTS/DESSINE/pltz.pro @ 134

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:
;       PLTZ
;
; PURPOSE:
;       trace des graphes verticaux
;
; CATEGORY:
;       Graphics
;
; CALLING SEQUENCE:
;       pltz, champ [,min[, max]]
;
; INPUTS:
;       champ: le champ dont on veut faire la coupe verticale champ
;       peut etre de 2 types:
;         1) un tableau 2d ou 3d. 
;         Si le champ est 2d undiquer avec le mot cle boxzoom les
;         delimitations geographiques de la boxzoom. Si le chyamp est
;         3d, on extrait la section et on moyenne eventuellement avant
;         de faire le plot
;         2) une structure repondant aux critaire specifies par
;         litchamp.pro. cf. IDL> xhelp,'litchamp'. le tableau contenu
;         ds la structure doit etre 2 ou 3d cf cas 1) si dessus
;
; ces arguments ne sont pas obligatoires:
;  
;       MAX: valeur maximum que l'on veut prendre en compte dans le trace
; des contours. Par defaut on prend le max de tab1 (sur les pts mer)
;
;       MIN: valeur minimum que l'on veut prendre en compte dans le trace
; des contours. Par defaut on prend le min de tab1 (sur les pts mer)
;
; KEYWORD PARAMETERS:
;
;       BOXZOOM:vecteur indiquant la zone geographique sur laquelle doit etre
; faite la coupe. Si BOXZOOM a :
; 1 element : l''extraction est faite sur [lon1, lon2, lat1, lat2, 0.,boxzoom[0]]
; 2 elements: l''extraction est faite sur [lon1, lon2, lat1, lat2, boxzoom[0],boxzoom[1]]
; 4 elements: l''extraction est faite sur [Boxzoom, 0, 200]
; 5 elements: l''extraction est faite sur [Boxzoom[0:3], 0, Boxzoom[4]]
; 6 elements: l''extraction est faite sur Boxzoom
;
; Ou lon1, lon2,lat1,lat2 sont les variables globales
; definies lors du dernier domdef!
;
;      CB_TITLE: le titre de la colorbar
;
;      CB_SUBTITLE: le soustitre de la colorbar
;
;      CB_CHARSIZE: The character size of the color bar annotations
;
;       CONTINTERVALLE: lorsque CONTOUR est active, valeur d'un
; intervalle entre deux isolignes traces par un trait. Il peut ainsi
; etre different de celui specifie par INTERVALLE 
; qui, cas ce cas, ne controle que les isolignes coloriees en
; couleurs. Si aucun min n''est specifie, on choisit un contour min qui va
; bien avec l''intervalle specifie!. Si ce mot cle n''est pas
; specifie, on trace 20 isolignes du min au max. 
;
;       CONTLABEL: un entier n. lorsque CONTOUR est active, si n
; different de 0, choisit le type de label correspondant aux cas n
; pour les isolignes tracees par un trait. Pour specifier le type de
; label du contour en couleur, utiliser LABEL
;
;       CONTMAX: lorsque CONTOUR est active, valeur maximum que l''on
; veut prendre en compte dans le trace des isolignes traces par un
; trait. Par defaut on prend le max (sur les pts mer)
; du tableau passe ds le mot cle CONTOUR. 
;
;        COAST_COLOR: the color of the coastline.
;                     defaut value is 0 => black
;
;        COAST_THICK: the thickness of the coastline.
;                     defaut value is 1
;
;        /CONT_NOFILL: activer pour ne pas remplir les points masques
;        pour les laisser en transparent! 
;        Rq: on trace qd meme le contour du mask
;
;        CONT_COLOR: the color of the continent. defaut value is
;        (!d.n_colors - 1) < 255 => white
;
;       CONTMIN: lorsque CONTOUR est active, valeur minimum que l''on
; veut prendre en compte dans le trace des isolignes traces par un
; trait. Par defaut on prend le max (sur les pts mer)
; du tableau passe ds le mot cle CONTOUR. 
;
;       CONTNLEVEL: lorsque CONTOUR est active, nombre de contours
; trace par un trait a dessiner (actif si
; CONTLABEL=0) par defaut =20.
;
;       CONTOUR: si on veut tracer les contours d'un champ different que celui
; que l''on dessin en couleur (par ex E-P en couleur et QSR en
; contours). Doit etre un champ reponadnt aux meme caracteristiques
; que l''argument numero 1 de pltz
;
;       ENDPOINTS: mot clef specifiant que l'on veut faire une coupe
;       verticale en diagonale. les coordonnees des extremites de
;       celle-ci sont alors definies les 4 elements du vecteur
;       ENDPOINTS: [x1,y1,x2,y2] qui sont les coordonnees 
;
;       INTERVALLE: valeur d''un intervalle entre deux isolignes. Si
; aucun min n''est specifie, on choisit un contour min qui va bien
; avec l'intervalle specifie!. Si ce mot cle n''est pas specifie, on
; trace 20 isolignes du min au max. Rq: Qd CONTOUR est active
; INTERVALLE ne specifie que intervalle entre 2 isolignes coloriees en
; couleur. Pour specifier l''intervalle entre 2 isolignes traces par un trait
; utiliser CONTINTERVALLE.
;
;       /INV: inverse le vecteur couleur utilisee pour colorier le graphe
;             (sans toucher au noir, au blanc et a la palette utilisee)
;
;       ZRATIO: lorsque le dessin presente une partie zoomee, rapport de
; taille entre la partie zommee, hz (hauteur zoom), et le dessin entier, ht
; (hauteur total). Par defaut =2./3
;
;       LABEL: un entier n. si n different de 0, choisit le type de
; label correspondant aux cas n. cf label.pro
; Rq: Qd CONTOUR est active, ne specifie le type de label que pour les
; isolignes coloriees en couleur. Pour celles tracees par un trait
; utiliser CONTLABEL. 
;
;       /LANDSCAPE: oblige la feuille ou la fenetre a etre en position
;       "allongee"
;
;       LCT: entier designant le numero de la palette de couleur que
;       l''on veut utiliser pour le plot. 
;       
;       MAXIN: permet de specifier la valeur maximum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument max. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;
;       MININ: permet de specifier la valeur minimum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument min. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;       
;       NLEVEL: nombre de contours a dessiner. par defaut =20. actif si
; LABEL=0 ou n'est pas specifie.
;
;       /NOCOLORBAR: activer si on ne veut pas de colorbar
;
;       /NOCONTOUR: activer si on ne veut pas de contour mais juste
;       les couleurs
;
;       /NOFILL: activer si on veut juste les contours en noir et
;       blanc sur fond blanc
;
;       /NOERASE: activer pour faire un dessin a l''ecran sans creer
;       une nouvelle fenetre
;
;       /NOTRI: pour forcer a ne pas utiliser de triangulation.
;
;       OVERPLOT: pour faire un plt par dessus un autre. Rq:
;       contrairemnet a l''utilisation de CONTOUR,
;       l''utilisation de ce mot clef ne modifie pas la legende ou/et
;       la barre de couleur.
;
;       PETITDESSIN: vecteur de 3 ou 4 elements, applique pour faire un
; dessin sur une petite portion de feuille ou d''ecran. il delimite
; la zone ds laquelle va etre fait le dessin
; si il a 4 elements:
;       il est alors constitute des coordonnees -exprime en cm reperes par
;       rapport au coin en bas a gauche de la feuille ou de la fenetre
;       (en portrait comme en landscape)- du coin en bas a
;       gauche et du coin en haut a droite  de la zone de dessin.
; si il a 3 elements:
;       Ds ce cas, on divise la fenetre ou l''ecran en PETITDESSIN[0]
;       colonnes, en PETITDESSIN[1] lignes le dessin se faisant ds la
;       case numero PETITDESSIN[2].La numerotation commencant en haut
;       a gauche par le numero 1 et suivant apres dans le sens de
;       l''ecriture.
; Par defaut on fait un dessin occupant la plus grande place possible
; tout en concervant le rapport d''aspect (sauf qd REMPLI est active)
;
;       /PORTRAIT: oblige la feuille ou la fenetre a etre en position
;       "debout"
;
;       /POST: faire une sortie postscript. Ne marche que si on fait
;       un seul dessin sur la feuille. Si on fait plusieurs dessins,
;       utiliser @ps ou plein2dessins
;
;       /REMPLI:oblige le dessin a occuper l'espace maximum definit
;       par petitdessin
;
;       /SIN: activer ce mot cle si l''on veut que l'' axe des x soit
;       trace en sinus de la latitude qd on fait une coupe 'yz'
;
;       /STRICTFILL: activer ce mot clef pour que le remplissage des
;       contours ce fasse precisement entre le min et le max specifie
;       en laissant en banc les valeurs inferieurs au min specifie et
;       superieurs au max specifie.
;
;       STYLE: style de tracer a adopter pour dessiner les isolignes par
; defaut style=0. cf style.pro
;
;       /TRANS: fait un postscript (active /post automatiquement) et l'imprime
; -si on le desire- sur un transparant
;
;        UNLABSUR: entier n. specifant qu''on ne labelle qu''un
;        contour sur n. Par defaut unlabsur=2
;
;       /UNSUR2: si on veut tracer un countour sur deux. par  defaut trace
; tous les contours
;
;       WINDOW: nimero de la fenetre ou l'on veut faire le graphe (permet
; d'ouvrir plusieurs fenetres). par defaut on ouvre 'IDL0'
;
;       /WDEPTH: to specify that the field is at W depth instad of T 
;         depth (automatically activated if vargrid eq 'W')
;
;       /XZ: force a faire une coupe xz
;
;       /YZ: force a faire une coupe yz
;
;       YXASPECT: rapport d'echelle entre y et x (par ex: =1 pour un repere
; presque orthonorme, =2 si l'axe des y est environ deux fois plus dilate
; que celui des x). Par defaut on adapte pour occupe une grande partie de
; la feuille en sortie postScript ou pour cree une fenetre pas trop etiree
; 
;         /WDEPTH: to specify that the field is at W depth instad of T 
;         depth (automatically activated if vargrid eq 'W')
;
;       ZOOM: profondeur jusqu'a laquelle on fait un zoom. par defaut 200m ou
; la profondeur maximale si elle est inf a 200
;
;       /ZEROMIDDLE: fo force the middle of the colorbar to be equal
;       to 0 (force max=max(abs([min,max])) and min=-max)
;
; OUTPUTS:
;
; COMMON BLOCKS:
;       common.pro      
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       7/1999
;                       Sebastien Masson 08/02/2000 checkfield and
;                       notri keyword.
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
pro pltz, tab, giventype, givenmin, givenmax, BOXZOOM = boxzoom, CONTOUR = contour $
          , ENDPOINTS = endpoints, INTERVALLE = intervalle, INV = inv, ZRATIO = zratio $
          , CONTINTERVALLE = contintervalle, LABEL = label, CONTLABEL = contlabel $
          , STYLE = style, CONTMAX = contmax, SIN = sin, TYPEIN = typein $
          , CONTMIN = contmin, NLEVEL = nlevel, CONTNLEVEL = contnlevel $
          , NOTRI = notri, USETRI = usetri, FILLXDIR = fillxdir $
          , ZOOM = zoom, XZ = xz, YZ = yz, MININ = minin, MAXIN = maxin $
          , STRICTFILL = strictfill, OVERPLOT = overplot, MASKFILL = maskfill $
          , WDEPTH = wdepth, REALSECTION = realsection $
          , _EXTRA = ex
;---------------------------------------------------------
; include common
;
  compile_opt idl2, strictarrsubs
;
@cm_4mesh
@cm_4data
@cm_4ps
  IF NOT keyword_set(key_forgetold) THEN BEGIN
@updatenew
@updatekwd
  ENDIF
;--------------------------------------------------------------
  tempsun = systime(1)          ; pour key_performance
;------------------------------------------------------------
;--------------------------------------------------------------
; 1ere partie: initialisation et petits calculs...
;--------------------------------------------------------------
;on ne reinitialise pas qd on rapelle pltz en boucle pour utiliser contour
  if n_elements(contour) ne 4 AND NOT keyword_set(overplot) then reinitplt
;
  if n_elements(contour) ne 4 THEN saveboxparam, 'boxparam4pltz.dat'
;--------------------------------------------------------------
; lecture du champ
;--------------------------------------------------------------
  if n_elements(giventype) NE 0 then type = giventype
  if n_elements(givenmin) NE 0 then min = givenmin
  if n_elements(givenmax) NE 0 then max = givenmax
  if n_elements(minin) NE 0 then min = minin
  if n_elements(maxin) NE 0 then max = maxin
  if n_elements(realsection) EQ 0 then realsection = 1
  IF n_elements(usetri) EQ 0 THEN BEGIN
    IF n_elements(notri) NE 0 THEN usetri = 2-notri ELSE usetri = 1
  ENDIF
; no need of triangulation
  IF usetri EQ 1 AND keyword_set(realsection) THEN usetri = 0
; did we specify the type ?
  if keyword_set(typein) then BEGIN 
    if size(type, /type) NE 7 AND size(type, /type) NE 0 then begin
      if n_elements(min) NE 0 then max = min
      min = type
    endif
    type = typein
  ENDIF
; 
  checktypeminmax, 'pltz', TYPE = type, MIN = min, MAX = max $
    , XZ = xz, YZ = yz, ENDPOINTS = endpoints, _extra = ex
;
  if keyword_set(endpoints) then begin
    section, tab, z2d, glam, gphi, ENDPOINTS = endpoints, TYPE = type $ 
    , BOXZOOM = boxzoom, DIREC = direc, WDEPTH = wdepth, _extra = ex
    if z2d[0] EQ -1 AND n_elements(contour) ne 4 then BEGIN 
      restoreboxparam, 'boxparam4pltz.dat'
      return
    ENDIF
    nx = n_elements(glam) 
    ny = nx
    if strupcase(vargrid) EQ 'W' then begin
      gdep = gdepw[firstzw:lastzw]
      nz = nzw
    ENDIF ELSE BEGIN
      gdep = gdept[firstzt:lastzt]
      nz = nzt
    ENDELSE
    mask = z2d LE valmask/10.
  ENDIF ELSE BEGIN
    z2d = checkfield(tab, 'pltz', TYPE = type, BOXZOOM = boxzoom $
                     , DIREC = direc, WDEPTH = wdepth, _extra = ex)
    if z2d[0] EQ -1 AND n_elements(contour) ne 4 then BEGIN 
      restoreboxparam, 'boxparam4pltz.dat'
      return
    ENDIF
    IF realsection EQ 1 THEN grille, mask, glam, gphi, gdep, nx, ny, nz, ifpltz = type, WDEPTH = wdepth $
    ELSE grille, mask, glam, gphi, gdep, nx, ny, nz, WDEPTH = wdepth
  ENDELSE
; stop
;---------------------------------------------------------------
  profmax = !y.range[0]
  profmin = !y.range[1]
  if not keyword_set(zoom) then zoom = 200
  zoom = zoom[0]
  IF zoom LT profmin THEN zoom = profmax
  if zoom GE vert2 then zoom = profmax
; construction of the mask and of the axis
  axis4pltz, type, mask, glam, gphi, gdep, XXAXIS = xxaxis, ZZAXIS = zzaxis, SIN = sin, ZRATIO = zratio, ZOOM = zoom, PROFMAX = profmax, PROFMIN = profmin, _extra = ex
; to draw from bottom to top (avoid using cell_fill)
  z2d = reverse(z2d, 2)
;-----------------------------------------------------------------------------
;   determination du mi:min et du ma:max de tab1 ainsi que de max: max et
;   min: min pour le dessin.
;-----------------------------------------------------------------------------
  nan = total(finite(z2d, /nan)) < 1
; faudra-t-il faire un autoscale ???
  autoscale = testvar(var = min) EQ testvar(var = max) AND NOT keyword_set(intervalle)
  determineminmax, z2d, mask, mi, ma, MININ = min, MAXIN = max, nan = nan, INTERVALLE = intervalle, _extra = ex
  if z2d[0] EQ -1 THEN GOTO, sortie
; on fait un autoscale si besoin
  if autoscale then autoscale, min, max, intervalle
;--------------------------------------------------------------
;--------------------------------------------------------------
; 2eme partie: dessin
;--------------------------------------------------------------
;--------------------------------------------------------------
  if n_elements(contour) NE 4 AND NOT keyword_set(overplot) THEN $
    placedessin, 'pltz', posfenetre, posbar, contour = contour, endpoints = endpoints $
    , direc = direc, _extra = ex
;------------------------------------------------------------
;--------------------------------------------------------------
; choix des labels
;-----------------------------------------------------------
  if keyword_set(intervalle) AND NOT keyword_set(label) then label = 1
  if keyword_set(label) eq 0 then cas = 0 else cas = label
  label, cas, min, max, ncontour, level_z2d, colnumb, NLEVEL = nlevel $
         , INTERVALLE = intervalle, strictfill = strictfill
;--------------------------------------------------------------
; choix de style
;-----------------------------------------------------------
  if not keyword_set(style) then style = 0
  style, style, level_z2d, linestyle, thick
  if keyword_set(inv) then colnumb = reverse(colnumb)
;-----------------------------------------------------------
;   definition des axes
;----------------------------------------------------------
  if NOT keyword_set(overplot) THEN axe, type, SIN = sin, _EXTRA = ex
  !y.range = [-1, 0]
;--------------------------------------------------------------
; extrapolation des donnees sur les terres et seuillage
;--------------------------------------------------------------
; define masknan
  if keyword_set(nan) then BEGIN
    masknan = finite(z2d)
    z2d[where(masknan EQ 0)] = max
  ENDIF ELSE masknan = 1
  IF n_elements(fillxdir) EQ 0  THEN fillxdir = 1
  IF keyword_set(fillxdir) THEN BEGIN
; filling the mask values only in the x direction.
    z2d = remplit(z2d, nite = nx*(1-(n_elements(maskfill) NE 0)) $
                  , mask = mask*masknan, /basique $
                  , /fillxdir, _extra = ex)
; if some lines contains no data (the bottom line for ex) it must be
; also filled with 8 neighbourg method
    IF (where(total(mask*masknan, 1) EQ 0))[0] NE -1 THEN $
      z2d = remplit(z2d, nite = 1-(n_elements(maskfill) NE 0) $
                    , mask = z2d LT valmask/10, /basique, _extra = ex)
  ENDIF ELSE BEGIN 
; filling the mask values with 8 neighbourg
    z2d = remplit(z2d, nite = (1+(vargrid NE 'T')+keyword_set(nan)) $
                  *(1-(n_elements(maskfill) NE 0)), mask = mask*masknan $
                  , /basique, _extra = ex)
  ENDELSE 
  if keyword_set(strictfill) EQ 0 AND n_elements(maskfill) EQ 0 $
    then z2d = min > z2d <  max
  if n_elements(maskfill) NE 0 then BEGIN
    z2d = z2d*mask*masknan
    if maskfill NE 0 then z2d = temporary(z2d) + maskfill*(1b-mask*masknan)
  ENDIF
;----------------------------------------------------------
; check the mask and the triangulation according to the grid type and 
; nan values. find the coordinates of the mask
;---------------------------------------------------------- 
;   if (where(mask EQ 0))[0] EQ -1 AND NOT keyword_set(nan) then notri = 1
;   if keyword_set(notri) then trifield = -1 $
;   ELSE trifield = triangule(mask,/basic)
  if (usetri GE 1 AND (vargrid EQ 'T' OR vargrid EQ 'W')) $
    OR (usetri EQ 2 AND (vargrid NE 'T' AND vargrid NE 'W')) THEN $
    trifield = triangule(mask, /basic)
;
  IF NOT keyword_set(endpoints)  THEN BEGIN
    if keyword_set(nan) then trinan = triangule(masknan, /basic, coinmonte = coinmontenan, coindescend = coindescendnan)
    decoupeterre, mask, glammsk, gphimsk, gdepmsk, type = type, WDEPTH = wdepth, REALSECTION = realsection
    axis4pltz, type, mask, glammsk, gphimsk, gdepmsk, XXAXIS = xmask, ZZAXIS = zmask, SIN = sin, ZRATIO = zratio, ZOOM = zoom, PROFMAX = profmax, PROFMIN = profmin, _extra = ex
  ENDIF ELSE BEGIN
    xmask = xxaxis
    zmask = zzaxis
  ENDELSE 
;
  if (usetri GE 1 AND (vargrid NE 'T' AND vargrid NE 'W')) THEN BEGIN 
    IF keyword_set(realsection) THEN trimsk = triangule(mask, /basic) $
    ELSE trimsk = triangule(mask, /basic, coinmonte = coinmontemask $
                            , coindescend = coindescendmask)
  ENDIF     
;------------------------------------------------------------
; dessin en lui meme
;------------------------------------------------------------
  pltbase, z2d, xxaxis, zzaxis, mask, xmask, zmask $
    , level_z2d, colnumb, overplot = overplot $
    , contour = contour, trichamp = trifield, trimsk = trimsk  $
    , c_linestyle = linestyle $
    , c_labels = 1-(indgen(n_elements(level_z2d)) MOD 2) $
    , c_thick = thick, unsur2 = unsur2 $
    , masknan = masknan, trinan = trinan $
    , coinmontenan = coinmontenan, coindescendnan = coindescendnan $
    , coinmontemask = coinmontemask, coindescendmask = coindescendmask $
    , REALSECTION = realsection, USETRI = usetri, _extra = ex
;------------------------------------------------------------
; rappelle de pltz en boucle qd contour est active
;------------------------------------------------------------
  if n_elements(contour) eq 4 then BEGIN ; c''est la 2eme fois que je passe ds pltt
    contour = {mietma:[mi, ma], unit:varunit, inter:intervalle} ; je renvoie le min, le max et l''unite
    return
  endif
  if keyword_set(contour) THEN BEGIN 
    pourlegende = [1, 1, 1, 1]
    oldattributs = saveatt()
    oldcolnumb = colnumb
    pltz, contour, contmin, contmax, CONTOUR = pourlegende, ZRATIO = zratio $
      , INTERVALLE = contintervalle, LABEL = contlabel, STYLE = style, /noerase  $
      , NLEVEL = contnlevel, ZOOM = zoom, BOXZOOM = boxzoom, ENDPOINTS = endpoints $
      , STRICTFILL = strictfill, REALSECTION = realsection, MASKFILL = maskfill $
      , USETRI = usetri, WDEPTH = wdepth, _extra = ex
    restoreatt, oldattributs
    colnumb = oldcolnumb
  ENDIF
;------------------------------------------------------------
;------------------------------------------------------------
; 3eme partie: dessin du cadre, legendes, colorbar...
;------------------------------------------------------------
  if keyword_set(overplot) then BEGIN 
    !y.range =  [zoom, profmin] ; on repasse en coordonees physiques!
    plot, [0], [0], /nodata, /noerase, title = '', subtitle = '', xstyle = 5, ystyle = 5
    GOTO, fini
  endif
;------------------------------------------------------------
; legendes + affichage de celles-ci
;------------------------------------------------------------
  legende, mi, ma, type, CONTOUR = pourlegende, INTERVALLE = intervalle, DIREC = direc, endpoints = endpoints, _EXTRA = ex
  if type eq 'yz' then xaxe = 'lataxe' else xaxe = 'lonaxe'
  if keyword_set(sin) OR NOT key_onearth then xaxe = ''
; cadre applique par defaut
  plot, [xxaxis[0], xxaxis[n_elements(xxaxis)-1]], [-zratio, -zratio], /noerase $
    , xstyle = 1+4*(keyword_set(endpoints) AND ((type EQ 'xz' AND lat1 NE lat2) OR (type EQ 'yz' AND lon1 NE lon2))) $
    , xtickformat = xaxe, _extra = ex
; ajout d'un axe ds le cas ou l'on utilise endpoints
  if keyword_set(endpoints) then addaxe, endpoints, type, posfenetre, _EXTRA = ex
;------------------------------------------------------------
; axe y en 1 ou 2 parties
;------------------------------------------------------------
  if n_elements(ex) NE 0 then BEGIN 
; pour ne plus mettre de titre
    if (where(tag_names(ex) EQ 'TITLE'))[0] NE -1 then ex.TITLE = ' '
; pour ne plus mettre de sous titre
    if (where(tag_names(ex) EQ 'SUBTITLE'))[0] NE -1 then ex.SUBTITLE = ' '
; pour n''avoir q''un ytitle
    if (where(tag_names(ex) EQ 'YTITLE'))[0] NE -1 then BEGIN 
      ytitle = ex.YTITLE
      ex.YTITLE = ' '
    endif
  ENDIF
  htotal = posfenetre[3]-posfenetre[1]
  hzoom = 1.*zratio*htotal
  if zoom LT profmax then $
    plot, [0], [0], /nodata, /noerase, ystyle = 1, yrange = [profmax, zoom+0.001] $
    , position = posfenetre+[0, 0, 0, -hzoom], _extra = ex, title = '', subtitle = '', ytitle = ''
;
  !y.range =  [zoom, profmin]   ; on repasse en coordonees physiques!
  plot, [0], [0], /nodata, /noerase, ystyle = 1, _extra = ex $
    , title = '', subtitle = '', ytitle = '', position = posfenetre+[0, htotal-hzoom, 0, 0]
;------------------------------------------------------------
; pour ecrire le ytitle...
;------------------------------------------------------------
  if !d.name EQ 'PS' then $
    xs = (max(page_size, min = mi)*(1-key_portrait) + mi*key_portrait)*!d.x_px_cm $
  ELSE xs = !d.x_size
  if n_elements(ytitle) NE 0 then !y.title = ytitle
  charsize = chkstru(ex, 'ycharsize', /extract)
  if charsize EQ -1 then charsize = !p.charsize
  IF chkstru(ex, 'charsize') THEN ex.charsize = charsize
  if chkstru(ex, 'ytitle', /extract) NE '' then $
    decalage = string(format = '(e10.3)', profmax)
  decalage = float(strmid(decalage, strpos(decalage, 'e')+1))
  posy = posfenetre[1]+1.*htotal/2
  posx = posfenetre[0]-(decalage+3)*!d.x_ch_size*charsize/xs
  xyouts, posx, posy, !y.title, /normal, orientation = 90, color = 0, ALIGNMENT = .5, charsize = charsize, _extra = ex

;------------------------------------------------------------
; barre de couleur
;------------------------------------------------------------
  colnumb = colnumb[0:ncontour-1-keyword_set(strictfill)]
  barrecouleur, colnumb, min,  max, (ncontour-keyword_set(strictfill))/2 $
                , position = posbar, _extra = ex
;------------------------------------------------------------
;------------------------------------------------------------
; 4eme partie: impression eventuelle
;------------------------------------------------------------
;------------------------------------------------------------
fini:
  terminedessin, _extra = ex
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
sortie:
  restoreboxparam, 'boxparam4pltz.dat'
;
  if keyword_set(key_performance) NE 0 THEN print, 'temps pltz', systime(1)-tempsun 
  return
end