source: trunk/SRC/ToBeReviewed/PLOTS/DESSINE/plt1d.pro @ 72

;------------------------------------------------------------
;+
; NAME:
;       PLT1D
;
; PURPOSE:
;       trace des graphes 1d
;
; CATEGORY:
;       Graphics, trace des graphes 1d: x,y,z (ou t mais ds ce cas, on
;       rapelle directement pltt)
;
; CALLING SEQUENCE:
;       plt1d, champ,type [,min[, max]]
;
; INPUTS:
;       champ: le champ dont on veut faire le hovmoller champ
;       peut etre de 2 types:
;       1) un tableu qui peut etre:
;          * 2d, 3d ou 4d:  tableau xy, xyz. xyt ou xyzt. dans ce cas,
;            le tableau va passer dans moyenne ou grossemoyenne pour
;            etre moyennee et devenir un tableau 1 1d. 
;          * 1d:type doit qd meme etre specifie pour qu''on sache de
;          quel trace il sagit. Pour avoir une legende correcte,
;          respecifier la zone d''extraction via BOXZOOM
;       2) une structure repondant aux critaires specifies par
;       litchamp.pro. cf. IDL> xhelp,'litchamp'. Le tableau contennu ds
;       la structure repondant aux criteres du cas 1) cf. ci-dessus
;
;       TYPE: un string: type de plot 1d que l''on veut faire:
;       trace suivant: 'x','y','z'  
;
; ces arguments ne sont pas obligatoires:
;  
;       MAX: valeur maximum que l'on veut prendre en compte dans le trace
; du plot. Par defaut on prend le max de tableau (sur les pts mer)
;
;       MIN: valeur minimum que l'on veut prendre en compte dans le trace
; du plot. Par defaut on prend le min de tableau (sur les pts mer)
;
; KEYWORD PARAMETERS:
;
;       BOXZOOM:vecteur indiquant la zone geographique (3d) sur laquelle doit
; etre fait l''extraction du champ pour faire le hovmoeller.
; Si BOXZOOM a :
; 1 element : l''extraction est faite sur [lon1, lon2, lat1, lat2, 0.,boxzoom[0]]
; 2 elements: l''extraction est faite sur [lon1, lon2, lat1, lat2, boxzoom[0],boxzoom[1]]
; 4 elements: l''extraction est faite sur [Boxzoom, vert1, vert2]
; 5 elements: l''extraction est faite sur [Boxzoom[0:3], 0, Boxzoom[4]]
; 6 elements: l''extraction est faite sur Boxzoom
;
; Ou lon1, lon2,lat1,lat2,vert1,vert2 sont les variables globales
; definies lors du dernier domdef!
;
;       COL1d: --OBSOLETE--numero de la couleur qd on fait un trace 1d
;       par defaut, 0. il faut mieux utiliser le mot cle COLOR utilise
;       par plot
;
;       ENDPOINTS: mot clef specifiant que l'on veut faire une coupe
;       verticale en diagonale. les coordonnees des extremites de
;       celle-ci sont alors definies les 4 elements du vecteur
;       ENDPOINTS: [x1,y1,x2,y2] qui sont les coordonnees 
;
;       /LANDSCAPE: oblige la feuille ou le fenetre a l''ecran a etre
;       en position "allongee".
;       
;       MAXIN: permet de specifier la valeur maximum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument max. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;
;       MININ: permet de specifier la valeur minimum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument min. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;
;       /NOERASE: activer pour faire un dessin a l''ecran sans creer
; une nouvelle fenetre. Rq: activer ds le cas d''un Postscript de
; plusieurs traces de type 't' pour ne pas faire un Postscript de
; plusieurs pages 
;
;       /OV1D:permet de surimprimer un courbe 1d a un precedent trace 1d.
;
;       PETITDESSIN: vecteur de 3 ou 4 elements, applique pour faire un
; dessin sur une petite portion de feuille ou d''ecran. il delimite
; la zone ds laquelle va etre fait le dessin
; si il a 4 elements:
;       il est alors constitute des coordonnees -exprime en cm reperes par
;       rapport au coin en bas a gauche de la feuille ou de la fenetre
;       (en portrait comme en landscape)- du coin en bas a
;       gauche et du coin en haut a droite  de la zone de dessin.
; si il a 3 elements:
;       Ds ce cas, on divise la fenetre ou l''ecran en PETITDESSIN[0]
;       colonnes, en PETITDESSIN[1] lignes le dessin se faisant ds la
;       case numero PETITDESSIN[2].La numerotation commencant en haut
;       a gauche par le numero 1 et suivant apres dans le sens de
;       l''ecriture.
; Par defaut on fait un dessin occupant la plus grande place possible
; tout en concervant le rapport d''aspect (sauf qd REMPLI est active)
;
;       /PORTRAIT: oblige la feuille ou la fenetre a etre en position "debout".
;
;       /POST: faire une sortie postscript. Ne marche que si on fait
;       un seul dessin sur la feuille. Si on fait plusieurs dessins,
;       utiliser @ps ou plein2dessins
;
;       /REMPLI:oblige le dessin a occuper l'espace maximum definit
;       par petitdessin
;
;       /REVERSE_X: pour inverser l''axe des x (et aussi le dessin)
;
;       /REVERSE_Y: pour inverser l''axe des y (et aussi le dessin)
;
;       /SIN: activer ce mot cle si l''on veut que l'' axe des x soit
;       trace en sinus de la latitude qd on fait un frace f(y)
;
;       STY1D: --OBSOLETE--numero du style utilise lors d'un trace
;       1d. Il faut mieux utiliser le mot cle LINESTYLE qui est celui
;       de plot. Attention ce mot cle est encore utile si on veut
;       faire des barres plutot qu'un courbe, mettre sty1d='bar'
;
;       /TRANS: fait un postscript (active /post automatiquement) et l'imprime
; -si on le desire- sur un transparant
;
;       WINDOW: nimero de la fenetre ou l'on veut faire le graphe (permet
; d'ouvrir plusieurs fenetres). par defaut on ouvre 'IDL0'
;
;       YXASPECT: rapport d'echelle entre y et x. Par defaut=1
; Par defaut on adapte pour occupe une grande partie de la feuille en sortie
; postScript ou pour cree une fenetre pas trop etiree
;
;       /ZEROMIDDLE: fo force the middle of the colorbar to be equal
;       to 0 (force max=max(abs([min,max])) and min=-max)
;
; COMMON BLOCKS:
;       common.pro
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY: creation 24/6/99 Eric Guilyardi 
;                       (a partir routine pltt de Sebastien Masson)
; 8/7/1999 Sebastien Masson (smasson@lodyc.jussieu.fr) 
; inspection des travaux finis
; 8/2/2000 Sebastien Masson: checkfield
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
pro plt1d, tab, giventype, givenmin, givenmax, BOXZOOM = boxzoom, SIN = sin $
           , MININ = minin, MAXIN = maxin, TYPEIN = typein, ENDPOINTS = endpoints $
           , COL1D = col1d, STY1D = sty1d, OV1D = ov1d, X = x, Y = y, Z = z, TT = tt $
           , REVERSE_X = reverse_x, REVERSE_Y = reverse_y, SWITCHXY = switchxy $
           , _extra = ex
;---------------------------------------------------------
; include common
@cm_4mesh
@cm_4data
  IF NOT keyword_set(key_forgetold) THEN BEGIN
@updatenew
@updatekwd
  ENDIF
;------------------------------------------------------------
  tempsun = systime(1)          ; pour key_performance
;--------------------------------------------------------------
; 1ere partie: initialisation et petits calculs...
;--------------------------------------------------------------
;--------------------------------------------------------------
;--------------------------------------------------------------
; verification de la valeur de type
;--------------------------------------------------------------
;
  if n_elements(giventype) NE 0 then type = giventype
  if n_elements(givenmin) NE 0 then min = givenmin
  if n_elements(givenmax) NE 0 then max = givenmax
  if n_elements(minin) NE 0 then min = minin
  if n_elements(maxin) NE 0 then max = maxin
  if keyword_set(tt) then typein = 't'
  if keyword_set(typein) then BEGIN 
    if size(type, /type) NE 7 AND size(type, /type) NE 0 then begin
      if n_elements(min) NE 0 then max = min
      min = type
    endif
    type = typein
  endif
;
  checktypeminmax, 'plt1d', TYPE = type, MIN = min, MAX = max, ENDPOINTS = endpoints $
    , XX = keyword_set(x), YY = keyword_set(y), ZZ = keyword_set(z) 
  if type EQ 't' then BEGIN
    pltt, tab, type, min, max, BOXZOOM = boxzoom, SIN = sin, TYPEIN = typein $
      , COL1D = col1d, STY1D = sty1d, OV1D = ov1d, ENDPOINTS = endpoints, _extra = ex
    return
  endif
;--------------------------------------------------------------
; I2) reinitialisation. !p.,!x.,!y.
; Rq: on ne reinitialise pas qd on rapelle plt1d
;--------------------------------------------------------------
  if NOT keyword_set(ov1d) then reinitplt
;--------------------------------------------------------------
; I1) lecture du champ
;--------------------------------------------------------------
   if (keyword_set(boxzoom) OR keyword_set(endpoints)) THEN BEGIN
     savedbox = 1b
     saveboxparam, 'boxparam4plt1d.dat'
   ENDIF
;
  if keyword_set(endpoints) then begin
    section, tab, z1d, glam, gphi, ENDPOINTS = endpoints, TYPE = type $
      , BOXZOOM = boxzoom, DIREC = direc
    nx = n_elements(glam) 
    ny = nx
    if strupcase(vargrid) EQ 'W' then begin
      z = gdepw[firstzw:lastzw]
      nz = nzw
    ENDIF ELSE BEGIN
      z = gdept[firstzt:lastzt]
      nz = nzt
    ENDELSE
  ENDIF ELSE BEGIN 
    z1d = checkfield(tab, 'plt1d', TYPE = type, BOXZOOM = boxzoom $
                     , direc = direc, _extra = ex)
    grille, mask, glam, gphi, gdep, nx, ny, nz
  ENDELSE
  if z1d[0] EQ -1 then BEGIN 
    IF keyword_set(savedbox) THEN restoreboxparam, 'boxparam4plt1d.dat'
    return
  endif
; on construit le mask pour cela le tableau doit etre masque (fait
; automatiquement a la valeure valmask si on passe ds moyenne ou grossemoyenne)
  mask = fltarr(n_elements(z1d))
  if n_elements(valmask) EQ 0 then valmask = 1e20
  nan = total(finite(z1d, /nan))  < 1
  if keyword_set(nan) then begin
    notanum = where(finite(z1d) EQ 0)
    z1d[notanum] = 0
    mask(where(z1d LT valmask/10)) = 1
    z1d[notanum] = !values.f_nan
  ENDIF ELSE mask(where(z1d LT valmask/10)) = 1
;-----------------------------------------------------------------------------
; determination du min et du max apres la moyenne
;-----------------------------------------------------------------------------
  nan = total(finite(z1d, /nan)) < 1
  determineminmax, z1d, mask, mi, ma, MININ = min, MAXIN = max, nan = nan, INTERVALLE = intervalle, _extra = ex
  if z1d[0] EQ -1 THEN return
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
  if NOT keyword_set(ov1d) THEN placedessin, 'autre', posfenetre, posbar, contour = contour, DIREC = direc, endpoints = endpoints, _extra = ex
;--------------------------------------------------------------
;--------------------------------------------------------------
; 2eme partie: dessin
;--------------------------------------------------------------
;-----------------------------------------------------------------------------
; definition des vecteurs abscisse et ordonee
; la triangulation est definie pour que le trace soit effectue du bas
; a gauche vers le haut a droite. il faut donc la matrice e contourer
; se presente de cette maniere, d''ou certains transpose et reverse
;-----------------------------------------------------------------------------
;-----------------------------------------------------------------------------
  case type of
    'y': begin
      yy = z1d
      if (size(gphi))[0] EQ 1 then xx = gphi ELSE xx = reform(gphi[0, *])
      if keyword_set(sin) then xx = sin(!pi/180.*xx)
      min0 = lat1 & max0 = lat2
    END
    'x':begin
      yy = z1d
      xx = glam[*, 0]
      min0 = lon1 & max0 = lon2
    END 
    'z':begin
      yy = reverse(gdep, 1)
      xx = reverse(z1d, 1)
      min0 = 0 & max0 = 0
      case n_elements(boxzoom) of
        0:!y.range = [vert1, vert2]
        1:!y.range = [0, boxzoom]
        2:!y.range = boxzoom
        4:!y.range = [vert1, vert2]
        5:!y.range = [0, boxzoom[4]]
        6:!y.range = boxzoom[4:5]
      endcase
      if NOT keyword_set(ov1d) then !y.range = reverse(!y.range)
    END 
  ENDCASE 
;-----------------------------------------------------------
;-----------------------------------------------------------
;   definition des axes
;----------------------------------------------------------
;    if keyword_set(integrationtps) then axe, type, time[0], time[jpt-1], SIN = sin, _extra = ex $
;    ELSE axe, type, SIN = sin
  if NOT keyword_set(ov1d) then axe, type, SIN = sin
;------------------------------------------------------------
;------------------------------------------------------------
; dessin
;------------------------------------------------------------
;------------------------------------------------------------
  if type EQ 'z' then begin
    idx = where(xx NE valmask)
    if NOT keyword_set(ov1d) then BEGIN 
      if min EQ mi then !x.range = [min-abs(max-min)/5., max+abs(max-min)/5.] $
      ELSE !x.range = [min, max]
    ENDIF
  ENDIF ELSE BEGIN 
    idx = where(yy NE valmask)
    if NOT keyword_set(ov1d) then BEGIN 
      if min EQ mi then !y.range = [min-abs(max-min)/5., max+abs(max-min)/5.] $
      ELSE !y.range = [min, max]
    ENDIF
  ENDELSE 
;
  if NOT keyword_set(ov1d) then BEGIN 
    legende, mi, ma, type, CONTOUR = contour, DIREC = direc, ENDPOINTS = endpoints, _EXTRA = ex
;
  ENDIF
  IF keyword_set(switchxy)  THEN BEGIN
    tmp = xx
    xx = yy
    yy = temporary(tmp)
    if NOT keyword_set(ov1d) then BEGIN 
      tmp = !x
      !x = !y
      !y = temporary(tmp)
    ENDIF
  ENDIF
  if NOT keyword_set(ov1d) then BEGIN 
    if keyword_set(reverse_x) then !x.range = reverse(!x.range)
    if keyword_set(reverse_y) then !y.range = reverse(!y.range)
  ENDIF
;
  xx = xx[idx]
  yy = yy[idx]
  if (not keyword_set(col1d)) then col1d = 0
  if keyword_set(sty1d) then BEGIN ;si on veut faire des barres
    IF strlowcase(strtrim(sty1d)) EQ 'bar' then begin
      !y.range = [!y.range[0]-(!y.range[1]-!y.range[0])*.05, !y.range[1]] 
      bar_plot, yy, background = (!d.n_colors-1) < 255,  $
        baselines = replicate(!y.range[0], n_elements(yy)), barnames = ['', ''], $
        colors    = replicate(col1d, n_elements(yy)), /outline
      if n_elements(ex) NE 0 then BEGIN 
; pour avoir un cadre de la couleur noire
        if (where(tag_names(ex) EQ 'COLOR'))[0] NE -1 then ex.COLOR = 0
      ENDIF
      plot, [0], [0], /noerase, /nodata, _extra = ex
      GOTO, fini
    ENDIF 
  ENDIF
;
  if NOT keyword_set(ov1d) then BEGIN 
;
    plot, xx, yy, color = col1d, linestyle = sty1d, thick = 2, title = '', subtitle = '', _extra = ex
    if n_elements(ex) NE 0 then BEGIN 
; pour avoir un cadre de la couleur 0 et trace une ligne a y=0
      if (where(tag_names(ex) EQ 'COLOR'))[0] NE -1 then ex.COLOR = 0
      if (where(tag_names(ex) EQ 'LINESTYLE'))[0] NE -1 then ex.LINESTYLE = 0
      if (where(tag_names(ex) EQ 'THICK'))[0] NE -1 then ex.THICK = 0
    ENDIF
    plot, !x.range, [0, 0], /noerase, /nodata $
      , xstyle = 1+4*(keyword_set(endpoints) AND $
                      ((type EQ 'x' AND lat1 NE lat2) OR (type EQ 'y' AND lon1 NE lon2))) $
      , ystyle = 1, _extra = ex
; ajout d'un axe ds le cas ou l'on utilise endpoints
    if keyword_set(endpoints) then addaxe, endpoints, type, posfenetre, _EXTRA = ex
; trace une ligne a x=0
    plot, [0, 0], !y.range, /noerase, /nodata, title = '', subtitle = '', _extra = ex
  ENDIF ELSE oplot, xx, yy, color = col1d, linestyle = sty1d, thick = 2, _extra = ex
;------------------------------------------------------------
;------------------------------------------------------------
; 3eme partie: impression eventuelle
;------------------------------------------------------------
;------------------------------------------------------------
fini:
  terminedessin, _extra = ex
  if keyword_set(savedbox) THEN restoreboxparam, 'boxparam4plt1d.dat'
;------------------------------------------------------------
  if n_elements(key_performance) NE 0 then $
    IF key_performance EQ 1 THEN print, 'temps plt1d', systime(1)-tempsun 
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
  return
end