source: trunk/SRC/ReadWrite/ncdf_getatt.pro @ 325

Last change on this file since 325 was 325, checked in by pinsard, 17 years ago

modification of some headers (+some corrections) to prepare usage of the new idldoc

  • Property svn:keywords set to Id
File size: 3.8 KB
Line 
1;+
2;
3; @file_comments
4; Get variable attibutes from a NetCDF file
5;
6; @categories
7; Read NetCDF file
8;
9; @param fileid {in}{required}{type=salar string or long}
10; if fileid is a scalar string then it is the name of the file (with
11; the full path) to be opened (in that case, the file will be opened
12; and closed within ncdf_getatt).
13; if fileid is a scalar long then it is the id of the file return by a call
14; to ncdf_open outside of ncdf_getatt (in that case, the file will
15; NOT be opened and closed within ncdf_getatt)
16;
17; @param varid {in}{required}{type=salar string or long}
18; The netCDF variable ID, returned from a previous call to NCDF_VARDEF
19; or NCDF_VARID, or the name of the variable.
20;
21; @keyword add_offset
22; Set this keyword to a named variable in which the value of
23; add_offset attribute is returned. Return 0. if this attribute
24; doesn't exist.
25;
26; @keyword scale_factor
27; Set this keyword to a named variable in which the value of
28; scale_factor attribute is returned. Return 0. if this attribute
29; doesn't exist.
30;
31; @keyword missing_value
32; Set this keyword to a named variable in which the value of
33; missing_value or _fillvalue attribute is returned. Return the scalar
34; 'no' if this attribute doesn't exist.
35;
36; @keyword units
37; Set this keyword to a named variable in which the value of
38; units attribute is returned. Return the empty string '' if this attribute
39; doesn't exist.
40;
41; @keyword calendar
42; Set this keyword to a named variable in which the value of
43; calendar attribute is returned. Return the string 'greg' if this attribute
44; doesn't exist.
45;
46; @examples
47; IDL> ncdf_getatt, cdfid, 'sst', add_offset = add_offset, scale_factor = scale_factor, units = units
48;
49; @history
50; August 2007: Sebastien Masson (smasson\@lodyc.jussieu.fr)
51;
52; @version
53; $Id$
54;
55;-
56PRO ncdf_getatt, fileid, varid, add_offset = add_offset, scale_factor = scale_factor, missing_value = missing_value, units = units, calendar = calendar
57;
58  compile_opt idl2, strictarrsubs
59;
60; should we open the file?
61  IF size(fileid, /type) EQ 7 THEN cdfid = ncdf_open(fileid) ELSE cdfid = fileid
62; default definitions
63  units = ''
64  add_offset = 0.
65  scale_factor = 1.
66  missing_value = 'no'
67  calendar = 'greg'
68;
69  varinq = ncdf_varinq(cdfid, varid)
70  IF varinq.natts GT 0 THEN BEGIN
71    FOR a = 0, varinq.natts-1 DO BEGIN
72      attname = ncdf_attname(cdfid, varid, a)
73      CASE strlowcase(attname) OF
74        'units':BEGIN
75          ncdf_attget, cdfid, varid, attname, tmp
76          units = strtrim(tmp, 2)
77        END
78        'calendar':BEGIN
79          ncdf_attget, cdfid, varid, attname, tmp
80          tmp = strtrim(tmp, 2)
81          CASE tmp OF
82            'noleap':calendar = 'noleap'
83            '360d':calendar = '360d'
84            'greg':IF n_elements(calendar) EQ 0 THEN calendar = 'greg'
85            ELSE:BEGIN
86;            notused = report('Unknown calendar: '+tmp+', we use greg calendar.')
87              calendar = 'greg'
88            END
89          ENDCASE
90        END
91        'add_offset':ncdf_attget, cdfid, varid, attname, add_offset
92        'scale_factor':ncdf_attget, cdfid, varid, attname, scale_factor
93        '_fillvalue':ncdf_attget, cdfid, varid, attname, missing_value
94        'missing_value':ncdf_attget, cdfid, varid, attname, missing_value
95        ELSE:
96      ENDCASE
97    ENDFOR
98  ENDIF
99;
100  IF size(missing_value, /type) EQ 1 THEN BEGIN
101    missing_value = strlowcase(string(missing_value))
102    IF strmid(missing_value, 0, 1, /reverse_offset) EQ 'f' THEN $
103       missing_value = strmid(missing_value, 0, strlen(missing_value)-1)
104    IF isnumber(string(missing_value), tmp) EQ 1 THEN BEGIN
105      missing_value = tmp
106    ENDIF ELSE BEGIN
107      ras = report('Warning: missing value is not a number: ' + missing_value)
108      missing_value = 'no'
109    ENDELSE
110  ENDIF
111
112  IF size(fileid, /type) EQ 7 THEN ncdf_close, cdfid
113 
114  return
115END
Note: See TracBrowser for help on using the repository browser.