1 | ;+ |
---|
2 | ; |
---|
3 | ; @file_comments |
---|
4 | ; find the closest point of (P0) within a list of np1 points |
---|
5 | ; P1 which can be on a sphere |
---|
6 | ; |
---|
7 | ; @categories |
---|
8 | ; Maps |
---|
9 | ; |
---|
10 | ; @param p0lon {in}{required} {type=scalar} |
---|
11 | ; longitudes of point P0. |
---|
12 | ; |
---|
13 | ; @param p0lat {in}{required} {type=scalar} |
---|
14 | ; latitudes of point P0. |
---|
15 | ; |
---|
16 | ; @param neighlon {in}{optional} |
---|
17 | ; |
---|
18 | ; @param neighlat {in}{optional} |
---|
19 | ; |
---|
20 | ; @keyword RADIANS |
---|
21 | ; if set, inputs and angular outputs are in radians, otherwise degrees. |
---|
22 | ; |
---|
23 | ; @keyword DISTANCE |
---|
24 | ; dis, to get back the distances between P0 and the np1 points P1 in the |
---|
25 | ; variable dis. |
---|
26 | ; |
---|
27 | ; @keyword SPHERE |
---|
28 | ; to activate if points are located on a sphere. |
---|
29 | ; |
---|
30 | ; @returns |
---|
31 | ; index giving the P1[index] point that is the closest point of (P0) |
---|
32 | ; |
---|
33 | ; @examples |
---|
34 | ; |
---|
35 | ; IDL> print, neighbor(-105.15,40.02,[-0.07,100,50],[51.30,20,0], $ |
---|
36 | ; distance=dis) |
---|
37 | ; 0 |
---|
38 | ; IDL> print, dis |
---|
39 | ; 105.684 206.125 160.228 |
---|
40 | ; |
---|
41 | ; @history |
---|
42 | ; Sebastien Masson (smasson\@lodyc.jussieu.fr) |
---|
43 | ; October 2003 |
---|
44 | ; |
---|
45 | ; @version |
---|
46 | ; $Id$ |
---|
47 | ; |
---|
48 | ;- |
---|
49 | FUNCTION neighbor, p0lon, p0lat, neighlon, neighlat $ |
---|
50 | , SPHERE=sphere, DISTANCE=distance, RADIANS=radians |
---|
51 | ; |
---|
52 | compile_opt idl2, strictarrsubs |
---|
53 | ; |
---|
54 | ; some checks |
---|
55 | IF n_elements(p0lon) NE 1 THEN ras = report('Sorry p0lon must be a scalar') |
---|
56 | p0lon = p0lon[0] |
---|
57 | IF n_elements(p0lat) NE 1 THEN ras = report('Sorry p0lat must be a scalar') |
---|
58 | p0lat = p0lat[0] |
---|
59 | nneig = n_elements(neighlon) |
---|
60 | IF n_elements(neighlat) NE nneig THEN $ |
---|
61 | ras = report('neighlon and neighlat must have the same number of elements') |
---|
62 | ; distance between P0 and the others points |
---|
63 | IF keyword_set(sphere) THEN BEGIN |
---|
64 | IF sphere NE 1 THEN radius = sphere |
---|
65 | distance = Map_nPoints(p0lon, p0lat, neighlon, neighlat $ |
---|
66 | , radius = radius, radians = radians) |
---|
67 | ENDIF ELSE BEGIN |
---|
68 | distance = (neighlon-p0lon)^2+(neighlat-p0lat)^2 |
---|
69 | IF arg_present(distance) THEN distance = sqrt(distance) |
---|
70 | ENDELSE |
---|
71 | RETURN, where(distance EQ min(distance)) |
---|
72 | END |
---|