1 | ;+ |
---|
2 | ; |
---|
3 | ; @file_comments |
---|
4 | ; similar to <pro>extrapolate</pro> but could to the job in a better way |
---|
5 | ; because the extrapolated values are smoothed... |
---|
6 | ; takes more time than <pro>extrapolate</pro>. |
---|
7 | ; extrapolate data where mskin is equal 0 by filling |
---|
8 | ; step by step the coastline points with the mean value of the 8 neighbors. |
---|
9 | ; |
---|
10 | ; @categories |
---|
11 | ; Interpolation |
---|
12 | ; |
---|
13 | ; @param in {in}{required}{type=2d array} |
---|
14 | ; data to be extrapolate |
---|
15 | ; |
---|
16 | ; @param mskin {in}{required}{type=2d array or -1} |
---|
17 | ; a 2D array, the land-sea mask of the output data (1 on ocean, 0 on land) |
---|
18 | ; put -1 if input data are not masked |
---|
19 | ; |
---|
20 | ; @keyword MINVAL {type=scalar}{default=not used} |
---|
21 | ; to specify a minimum value to the extrapolated values |
---|
22 | ; |
---|
23 | ; @keyword MAXVAL {type=scalar}{default=not used} |
---|
24 | ; to specify a maximum value to the extrapolated values |
---|
25 | ; |
---|
26 | ; @keyword GE0 {type=scalar 0 or 1}{default=0} |
---|
27 | ; put 1 to force the extrapolated values to be larger than 0, same as using minval=0. |
---|
28 | ; |
---|
29 | ; @keyword |
---|
30 | ; _EXTRA to be able to call extrapsmooth with _extra keyword |
---|
31 | ; |
---|
32 | ; @returns |
---|
33 | ; the extrapolated array with no more masked values |
---|
34 | ; |
---|
35 | ; @restrictions |
---|
36 | ; You cannot specify the number of iterations done in the extrapolation process |
---|
37 | ; |
---|
38 | ; @examples |
---|
39 | ; IDL> a=extrapsmooth(dist(jpi,jpj),tmask[*,*,0],/x_periodic) |
---|
40 | ; IDL> tvplus, a |
---|
41 | ; compare to extrapolate result: |
---|
42 | ; IDL> b=extrapolate(dist(jpi,jpj),tmask[*,*,0],/x_periodic) |
---|
43 | ; IDL> tvplus, b, window = 1 |
---|
44 | ; |
---|
45 | ; @history |
---|
46 | ; January 2007: Sebastien Masson (smasson\@lodyc.jussieu.fr) |
---|
47 | ; |
---|
48 | ; @version |
---|
49 | ; $Id$ |
---|
50 | ;- |
---|
51 | FUNCTION extrapsmooth, in, mskin, X_PERIODIC=x_periodic $ |
---|
52 | , MINVAL=minval, MAXVAL=maxval, GE0=ge0, _EXTRA=ex |
---|
53 | ; |
---|
54 | compile_opt strictarr, strictarrsubs |
---|
55 | ; |
---|
56 | sz = size(reform(in)) |
---|
57 | IF sz[0] NE 2 THEN BEGIN |
---|
58 | ras = report('Input arrays must have 2 dimensions') |
---|
59 | return, -1 |
---|
60 | ENDIF |
---|
61 | nx = sz[1] |
---|
62 | ny = sz[2] |
---|
63 | IF n_elements(mskin) EQ 1 AND mskin[0] EQ -1 THEN mskin = replicate(1b, nx, ny) |
---|
64 | IF n_elements(mskin) NE nx*ny THEN BEGIN |
---|
65 | ras = report('input grid mask do not have the good size') |
---|
66 | return, -1 |
---|
67 | ENDIF |
---|
68 | ; |
---|
69 | out = reform(in) |
---|
70 | whmsk = where(mskin EQ 0, nbr) |
---|
71 | IF nbr NE 0 THEN out[temporary(whmsk)] = !values.f_nan |
---|
72 | ; add values on each side of the array to avoid boundary effects |
---|
73 | nx2 = nx/2 |
---|
74 | ny2 = ny/2 |
---|
75 | add = replicate(!values.f_nan, nx, ny2) |
---|
76 | out = [[add], [temporary(out)], [add]] |
---|
77 | IF keyword_set(x_periodic) THEN BEGIN |
---|
78 | add1 = out[0:nx2, *] |
---|
79 | add2 = out[nx-nx2:nx-1, *] |
---|
80 | out = [add2, [temporary(out)], add1] |
---|
81 | ENDIF ELSE BEGIN |
---|
82 | add = replicate(!values.f_nan, nx2, ny+2*ny2) |
---|
83 | out = [add, [temporary(out)], add] |
---|
84 | ENDELSE |
---|
85 | ; |
---|
86 | msk0 = where(finite(out) EQ 0) |
---|
87 | nnan = total(finite(out, /nan)) |
---|
88 | i = 1 |
---|
89 | WHILE nnan NE 0 DO BEGIN |
---|
90 | tmp = smooth(out, 2*i + 1, /nan) |
---|
91 | ; find only the changed values that where on land |
---|
92 | new = where(finite(out) EQ 0 AND finite(tmp) EQ 1, nnew) |
---|
93 | IF nnew EQ 0 then nnan = 0 ELSE BEGIN |
---|
94 | IF keyword_set(ge0) THEN tmp = 0. > temporary(tmp) |
---|
95 | IF n_elements(minval) NE 0 THEN tmp = minval > temporary(tmp) |
---|
96 | IF n_elements(maxval) NE 0 THEN tmp = temporary(tmp) < maxval |
---|
97 | out[new] = tmp[new] |
---|
98 | i = i+1 |
---|
99 | nnan = total(finite(out, /nan)) |
---|
100 | ENDELSE |
---|
101 | ENDWHILE |
---|
102 | ; a final smooth is needed |
---|
103 | out = smooth(temporary(out), 5, /nan) |
---|
104 | IF keyword_set(ge0) THEN out = 0. > temporary(out) |
---|
105 | IF n_elements(minval) NE 0 THEN out = minval > temporary(out) |
---|
106 | IF n_elements(maxval) NE 0 THEN out = temporary(out) < maxval |
---|
107 | ; get back to the original domain |
---|
108 | out = (temporary(out))[nx2:nx+nx2-1, ny2:ny+ny2-1] |
---|
109 | ; put back the non-maskqed values |
---|
110 | whmsk = where(mskin NE 0) |
---|
111 | out[whmsk] = in[whmsk] |
---|
112 | ; |
---|
113 | return, out |
---|
114 | END |
---|