source: trunk/SRC/Calendar/date2jul.pro @ 175

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
;
; @file_comments 
; gives Julian day equivalent of a date in yyyymmdd format
;
; @categories
; Calendar
;
; @param date {in}{required} 
; date in yyyymmdd format
;
; @keyword GRADS
; if  1 <= year <= 49 --> year = 2000 + year
; if 50 <= year <= 99 --> year = 1900 + year
;
; @returns 
; date in Julian day
;
; @examples
;
; IDL> jday = juldate(19930124)
; IDL> print, date2jul(19931205) EQ julday(12,5,1993)
;       1
; IDL> print, date2jul(931205,/grads) EQ julday(12,5,1993)
;       1
;
; @history 
; Sebastien Masson (smasson\@lodyc.jussieu.fr) June 2005
;
; @version $Id$
;
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
function date2jul, date, GRADS = grads
;------------------------------------------------------------
;
  compile_opt idl2, strictarrsubs
;
   year = long(date) / 10000
   month = long(abs(date)/100) MOD 100
   day = long(abs(date)) MOD 100
;------------------------------------------------------------
   if keyword_set(grads) then year = year $
     + 1900 * (year GE 50 AND year LE 99) $
     + 2000 * (year GE  1 AND year LE 49)
;------------------------------------------------------------
   return, julday(month, day, year)
end