source: trunk/PLOTS/DESSINE/tvplus.pro @ 2

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME: tvplus
;
; PURPOSE: tvscl ameliore, permet de visualiser un tableau sans interpolation
;
; CATEGORY: pour regarder un tableau au point par point, chaque point
; etant represente par un carre de coefzoom pixels de cote. la couleur
; du carre, representant sa valeur, est une interpolation lineaire
; entre le min du tableau de couleur 0 et le max du tableau de couleur
; !d.n_colors-1 <255
;
; CALLING SEQUENCE:tvplus,z2d [,coefzoom]
;
; INPUTS: z2d le tableau 2d a visualiser
;
;         coefzoom : (optionnel) c''est la taille des cotes des carres
;         representant un point, mesure en pixel. si cet argument
;         n''est pas specifie, la taille des carres est calculee pour
;         que la fenetre soit au plus pres de 95% de la taille de l''ecran
;
; KEYWORD PARAMETERS:
;
;       BOTTOM: The lowest color index of the colors to be loaded in
;       the bar. default is 0.
;
;       C_NAN: c'est le numero de la couleur des points a
;       !values.f_nan. par defaut c''est !d.n_colors< 256 -1
;
;       C_MASK: c'est le numero de la couleur des points a
;       la valeur specifiee par MASK. par defaut c''est 0
;
;       OFFSET: c''est un vecteur de 2 elements donnant la valeur dont
;       il faut decaler la numerotation des points en x et en y.
;       Par ex:
;          tvplus,sst[x1:x2,y1:y2],offest=[x1,y1]
;
;       MASK: la valeur qui sert de mask a l''ecran. si abs(mask) lt
;       1e6 les points egaux a mask seronts en noir, dans le cas
;       contraire ce seront les points ge que abs(mask)/10. Ceci est
;       nessaire pour eviter les erreurs d''arrondi. 
;
;       MIN et MAX permet de borner z2d a un min ou a un max, les
;       points inferieurs a min etant de la couleur 0 (noir) et ceux
;       superieurs a max etant de la couleur (!d.n_colors-1) < 255 (blanc)
;
;       NCOLORS:  This is the number of colors in the color
;       bar. default is !d.n_colors<255 -1
;
;       NOINTERP: activer si on ne veut pas que les valeurs du tableau
;       soient interpoles entre 0 et !d.n_colors-1 < 255 pour obtenir
;       les correspondances avec les couleurs. Utile qd on travaille
;       avec des tableaux de type byte
;
;       WINDOW: numero de la fenetre ou l''on veut faire la visualisation (permet
;       d''ouvrir plusieurs fenetres). par defaut on ouvre 'IDL0'
;
; OUTPUTS: affichage de parametres selectionnes a la souris, cf. apres
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:
;       1) qd la fenetre qui doit etre ouverte a une dimension -imposee
;       par la presence de coefzoom- superieure a 75% de la taille de
;       l''ecran, c''est une fenetre avec un scrolling bar qui est
;       ouverte.
;
;       2) qd le dessin est realise ds une fenetre normale, le
;       programme s''arrete apres le trace pour faire des l'analyses au
;       point par point a l''aide de la souris:
;          Bouton de gauche: position du curseur et valeur du tableau en ce point
;          Bouton du milieu: zoom
;          Bouton de droite: quitter
;
; RESTRICTIONS: l''analyse a la souris ne marche pas ds les fenetres
; avec une scrolling bar...
;
; EXAMPLE:  IDL> tvplus,nlec('sst'),max=30
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       18/12/98
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
PRO tvplus, z2d, coefzoom, BOTTOM = bottom, C_MASK = c_mask, C_NAN = c_nan, WINDOW = window $
            , MIN = min, MAX = max, MASK = mask, OFFSET = offset, PASBLABLA = PASBLABLA $
            , NCOLORS = ncolors, NOINTERP = nointerp, _EXTRA = ex
;
   tab = float(z2d)
;------------------------------------------------------------
; on verifie la taille de tab
;------------------------------------------------------------
   if (size(tab))[0] NE 2 then begin
      ras = report('le tableau doit etre 2D')
      return
   endif
;------------------------------------------------------------
; on definit au besoin ncoulmax, bottom, topcoul et ncolors
;------------------------------------------------------------
   ncoulmax = !d.n_colors < 256
   IF N_ELEMENTS(bottom) EQ 0 THEN bottom = 0
   if NOT keyword_set(ncolors) then ncolors = ncoulmax-bottom
   topcoul = (bottom+ncolors-1) < (ncoulmax-1)
;------------------------------------------------------------
; on fait le menage
;------------------------------------------------------------
   xenvsauve = !x & yenvsauve = !y & penvsauve = !p
   reinitplt, /z, /invert
;------------------------------------------------------------
; le tableau contient des valeurs a !values.f_nan ???
;------------------------------------------------------------
   nan = total(finite(z2d,/nan)) < 1
   if keyword_set(nan) then begin
      nanindex = where(finite(z2d,/nan) EQ 1)
      tab[nanindex] = min(tab, /nan)
   endif
;------------------------------------------------------------
; on calcule coefzoom ou bien on verifit qu''il n''est pas trop grand
;------------------------------------------------------------
   dimensions = GET_SCREEN_SIZE()
   if n_elements(coefzoom) EQ 0 then BEGIN 
      coefzoom = min(floor(dimensions/(size(z2d))[1: 2]*.85))
   ENDIF ELSE $ 
; il faudra ouvrir une fenetre avec une scrolling barre
   if coefzoom GE min(floor(dimensions/(size(z2d))[1: 2]*.85)) then scrolling = 1
   if coefzoom LT 1 then begin
      coefzoom = 1
      scrolling = 1
   endif
;------------------------------------------------------------
; on met les valeurs masques au max (sur les points non masques) du tableau
;------------------------------------------------------------
   if n_elements(mask) then BEGIN 
      if abs(mask) LT 1e6 then BEGIN 
         terre = where(tab EQ mask)
         if terre[0] NE -1 then tab(terre) = min(tab(where(tab NE mask)))
      ENDIF ELSE BEGIN 
         terre = where(abs(tab) GE abs(mask)/10.)
         if terre[0] NE -1 then tab(terre) = min(tab(where(abs(tab) LT abs(mask)/10.)))
      ENDELSE
   ENDIF ELSE terre = -1
;------------------------------------------------------------
; on borne le tableau a min et max s''il sont declares
;------------------------------------------------------------
   if keyword_set(min) then BEGIN 
      tab = min > tab
      vraimin = min
   ENDIF ELSE vraimin = min(tab)
   if keyword_set(max) then BEGIN 
      tab = tab < max
      vraimax = max
   ENDIF ELSE vraimax = max(tab)
;------------------------------------------------------------
; on bidoulle tab 
;------------------------------------------------------------
   if NOT keyword_set(nointerp) then BEGIN
; on interpole tab entre bottom et bottom+ncolors-1
      m=1.*(ncolors-1)/(vraimax-vraimin)
      p=bottom-1.*vraimin*m
      tab=round(1.*m*tab+p) 
   endif
; on met les point nan a la couleur numero c_nan
   if keyword_set(nan) then begin
      if keyword_set(c_nan) THEN tab[nanindex] = c_nan <  (ncoulmax -1) $
      ELSE tab[nanindex] = topcoul
   endif
; on met les point terre a la couleur numero c_mask
   if keyword_set(c_mask) AND terre[0] NE -1 THEN $
    tab[terre] = c_mask < (ncoulmax -1)
; on passe le tableau en byte
   tab = byte(tab)
; on augmente la taille de tab pour pouvoir faire le tv
   tab = congridseb(tab, (size(tab))[1]*coefzoom,(size(tab))[2]*coefzoom)
;------------------------------------------------------------
; on ouvre une fenetre a la bonne taille et on dessine
;------------------------------------------------------------
   nx = (size(tab))[1]
   ny = (size(tab))[2]
; marges en pixel
   rapportaspect = 1.*nx/ny
   if rapportaspect GE 1 THEN margepix = 1.*[25, 25, 75, 25] ELSE margepix = 1.*[25, 100, 25, 25]
;
   if n_elements(scrolling) EQ 0 then BEGIN ; on ouvre une fenetre classique
      if NOT keyword_set(window) then window = 0
      window,window, xsize = nx+margepix[0]+margepix[1] $
       , ysize = ny+margepix[2]+margepix[3] ; ouverture de la fenetre
; qd on utilise des couleurs codees sur 24 bit, je n''arrive pas a stipuler la couleur du
; fond d''une fenetre a l'aide de !p.background, je suis oblige de faire cette bidouille!!!
      if !d.n_colors gt 256 then BEGIN ; alors  les couleurs sont codees sur 24 bit
         device, decomposed=1
         !p.background='ffffff'x
         plot,[0],[0], xstyle = 5, ystyle = 5
         device, decomposed=0
      endif
      tv, tab,margepix[0], margepix[2], _EXTRA = ex ; dessin de tab interpole entre 0 et !d.n_colors-1 < 255
;
; mise en place des axes et du cadre
;
; on recupere en coordonnees normalises la position du tv et donc
; cette du cadre
      poscadre = fltarr(4)
      poscadre[0] = margepix[0]/!d.x_size
      poscadre[2] = 1.-margepix[1]/!d.x_size
      poscadre[1] = margepix[2]/!d.y_size
      poscadre[3] = 1-margepix[3]/!d.y_size
;    on trace le cadre a l''aide d''un plot
      if NOT keyword_set(offset) then offset = [0, 0]
      plot, [0], [0],/noerase, position = poscadre, color = 0 $
       , xstyle = 1, ystyle = 1, xticklen = 1, yticklen = 1 $
       , xrange = 1.*[0, nx]/coefzoom-.5+offset[0], yrange = 1.*[0, ny]/coefzoom-.5+offset[1]
;
; mise en place de la colorbar
;
      if rapportaspect ge 1 then $
       posbar = [25./!d.x_size, 25./!d.y_size, 1-25./!d.x_size, 50./!d.y_size] $
      ELSE posbar = [1-75./!d.x_size, 25./!d.y_size, 1-50./!d.x_size, 1-25./!d.y_size]
   if keyword_set(nointerp) then BEGIN & vraimin = 0 & vraimax = ncoulmax & endif
      colorbar, min = vraimin, max = vraimax, division = 10, cb_color = 0, position = posbar $
       , vertical = rapportaspect lt 1, /right, BOTTOM = bottom, NCOLORS = ncolors, _EXTRA = ex
   ENDIF ELSE BEGIN 
;------------------------------------------------------------
; dessin ds une fenetre avec une scrolling barre
;------------------------------------------------------------
; qd on utilise des couleurs codees sur 24 bit, je n''arrive pas a stipuler la couleur du
; fond d''une fenetre a l'aide de !p.background, je suis oblige de faire cette bidouille!!!
      if !d.n_colors gt 256 then begin
         window, /pixmap
         device, decomposed=1
         !p.background='ffffff'x
         plot,[0],[0]
         device, decomposed=0
      endif
      slide_image, tab $        ; on le dessine ds une fenetre avec une scrolling bar
       , xsize = nx, ysize = ny $
       ,xvisible=round(.7*dimensions[0]) < (size(tab))[1] $
       ,yvisible=round(.7*dimensions[1]) < (size(tab))[2],/register,congrid=0,show_full=0
      return
   ENDELSE 
;------------------------------------------------------------
; on prend des infos a la souris
;------------------------------------------------------------
   if NOT keyword_set(pasblabla) then begin
      print, 'Bouton de gauche: position du curseur et valeur du tableau en ce point'
      print, 'Bouton du milieu: zoom'
      print, 'Bouton de droite: quitter'
   endif
   cursor,x,y,/device, /down
   while (!mouse.button ne 4) do BEGIN
      x = x-margepix[0] & x = 0 > floor(x/coefzoom) < ((size(tab))[1]-1)
      y = y-margepix[2] & y = 0 > floor(y/coefzoom) < ((size(tab))[2]-1)
      case !mouse.button of
         1:BEGIN                ; saisie d''une valeur
            if x LE nx/coefzoom AND y LE ny/coefzoom then begin
               print,'position: x='+strtrim(x+offset[0],1)+', y= '+strtrim(y+offset[1],1) $
                +' valeur: '+strtrim(float(z2d[x,y]), 1)
            ENDIF
            cursor,x,y,/device, /down
         END
         2:BEGIN                ; zoom
            cursor,x2,y2,/device, /down
            x2 = x2-margepix[0] & x2 =  0 > floor(x2/coefzoom) < ((size(tab))[1]-1)
            y2 = y2-margepix[2] & y2 =  0 > floor(y2/coefzoom) < ((size(tab))[2]-1)
            x =  [x, x2] & x =  x[sort(x)]
            y =  [y, y2] & y =  y[sort(y)]
            tvplus, z2d[x[0]:x[1],y[0]:y[1] ], WINDOW = window, MIN = min, MAX = max $
             , MASK = mask, C_MASK = c_mask, C_NAN = c_nan, /PASBLABLA, OFFSET = [x[0],y[0]] $
             , NCOLORS = ncolors, NOINTERP = nointerp, BOTTOM = bottom, _EXTRA = ex
            return
         END
      endcase
   ENDWHILE
;------------------------------------------------------------
   !x = xenvsauve & !y = yenvsauve & !p = penvsauve
;------------------------------------------------------------
   return
end