source: trunk/PLOTS/DESSINE/pltz.pro @ 2

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:
;       PLTZ
;
; PURPOSE:
;       trace des graphes verticaux
;
; CATEGORY:
;       Graphics
;
; CALLING SEQUENCE:
;       pltz, champ [,min[, max]]
;
; INPUTS:
;       champ: le champ dont on veut faire la coupe verticale champ
;       peut etre de 2 types:
;         1) un tableau 2d ou 3d. 
;         Si le champ est 2d undiquer avec le mot cle boite les
;         delimitations geographiques de la boite. Si le chyamp est
;         3d, on extrait la section et on moyenne eventuellement avant
;         de faire le plot
;         2) une structure repondant aux critaire specifies par
;         litchamp.pro. cf. IDL> xhelp,'litchamp'. le tableau contenu
;         ds la structure doit etre 2 ou 3d cf cas 1) si dessus
;
; ces arguments ne sont pas obligatoires:
;  
;       MAX: valeur maximum que l'on veut prendre en compte dans le trace
; des contours. Par defaut on prend le max de tab1 (sur les pts mer)
;
;       MIN: valeur minimum que l'on veut prendre en compte dans le trace
; des contours. Par defaut on prend le min de tab1 (sur les pts mer)
;
; KEYWORD PARAMETERS:
;
;       BOITE:vecteur indiquant la zone geographique sur laquelle doit etre
; faite la coupe. Si BOITE a :
; 1 element : l''extraction est faite sur [lon1, lon2, lat1, lat2, 0.,boite[0]]
; 2 elements: l''extraction est faite sur [lon1, lon2, lat1, lat2, boite[0],boite[1]]
; 4 elements: l''extraction est faite sur [Boite, 0, 200]
; 5 elements: l''extraction est faite sur [Boite[0:3], 0, Boite[4]]
; 6 elements: l''extraction est faite sur Boite
;
; Ou lon1, lon2,lat1,lat2 sont les variables globales
; definies lors du dernier domdef!
;
;      CB_TITLE: le titre de la colorbar
;
;      CB_SUBTITLE: le soustitre de la colorbar
;
;      CB_CHARSIZE: The character size of the color bar annotations
;
;       CONTINTERVALLE: lorsque CONTOUR est active, valeur d'un
; intervalle entre deux isolignes traces par un trait ds la couleur
; c_lab. Il peut ainsi etre different de celui specifie par INTERVALLE
; qui, cas ce cas, ne controle que les isolignes coloriees en
; couleurs. Si aucun min n''est specifie, on choisit un contour min qui va
; bien avec l''intervalle specifie!. Si ce mot cle n''est pas
; specifie, on trace 20 isolignes du min au max. 
;
;       CONTLABEL: un entier n. lorsque CONTOUR est active, si n
; different de 0, choisit le type de label correspondant aux cas n
; pour les isolignes tracees par un trait. Pour specifier le type de
; label du contour en couleur, utiliser LABEL
;
;       CONTMAX: lorsque CONTOUR est active, valeur maximum que l''on
; veut prendre en compte dans le trace des isolignes traces par un
; trait de couleur c_lab. Par defaut on prend le max (sur les pts mer)
; du tableau passe ds le mot cle CONTOUR. 
;
;       CONTMIN: lorsque CONTOUR est active, valeur minimum que l''on
; veut prendre en compte dans le trace des isolignes traces par un
; trait de couleur c_lab. Par defaut on prend le max (sur les pts mer)
; du tableau passe ds le mot cle CONTOUR. 
;
;       CONTNLEVEL: lorsque CONTOUR est active, nombre de contours
; trace par un trait de couleur c_lab a dessiner (actif si
; CONTLABEL=0) par defaut =20.
;
;       CONTOUR: si on veut tracer les contours d'un champ different que celui
; que l''on dessin en couleur (par ex E-P en couleur et QSR en
; contours). Doit etre un champ reponadnt aux meme caracteristiques
; que l''argument numero 1 de pltz
;
;       ENDPOINTS: mot clef specifiant que l'on veut faire une coupe
;       verticale en diagonale. les coordonnees des extremites de
;       celle-ci sont alors definies les 4 elements du vecteur
;       ENDPOINTS: [x1,y1,x2,y2] qui sont les coordonnees 
;
;       INTERVALLE: valeur d''un intervalle entre deux isolignes. Si
; aucun min n''est specifie, on choisit un contour min qui va bien
; avec l'intervalle specifie!. Si ce mot cle n''est pas specifie, on
; trace 20 isolignes du min au max. Rq: Qd CONTOUR est active
; INTERVALLE ne specifie que intervalle entre 2 isolignes coloriees en
; couleur. Pour specifier l''intervalle entre 2 isolignes traces par un trait
; de couleur c_lab utiliser CONTINTERVALLE.
;
;       /INV: inverse le vecteur couleur utilisee pour colorier le graphe
;             (sans toucher au noir, au blanc et a la palette utilisee)
;
;       HZSURHT: lorsque le dessin presente une partie zoomee, rapport de
; taille entre la partie zommee, hz (hauteur zoom), et le dessin entier, ht
; (hauteur total). Par defaut =2./3
;
;       LABEL: un entier n. si n different de 0, choisit le type de
; label correspondant aux cas n. cf label.pro
; Rq: Qd CONTOUR est active, ne specifie le type de label que pour les
; isolignes coloriees en couleur. Pour celles tracees par un trait de
; couleur c_lab utiliser CONTLABEL.
;
;       /LANDSCAPE: oblige la feuille ou la fenetre a etre en position
;       "allongee"
;
;       LCT: entier designant le numero de la palette de couleur que
;       l''on veut utiliser pour le plot. 
;       
;       MAXIN: permet de specifier la valeur maximum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument max. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;
;       MININ: permet de specifier la valeur minimum que l''on veut
;       prendre en compte dans le trace des contours a l''aide d''un
;       mot cle plutot que par l''argument min. Si l''argument et le
;       mot cle sont specifies en meme temps, c''est la valeur
;       specifiee par le mot cle qui est retenue.
;       
;       NLEVEL: nombre de contours a dessiner. par defaut =20. actif si
; LABEL=0 ou n'est pas specifie.
;
;       /NOCOLORBAR: activer si on ne veut pas de colorbar
;
;       /NOCONTOUR: activer si on ne veut pas de contour mais juste
;       les couleurs
;
;       /NOCOULEUR: activer si on veut juste les contours en noir et
;       blanc sur fond blanc
;
;       /NOERASE: activer pour faire un dessin a l''ecran sans creer
;       une nouvelle fenetre
;
;       /NOTRI: pour forcer a ne pas utiliser de triangulation.
;
;       OVERPLOT: pour faire un plt par dessus un autre. Rq:
;       contrairemnet a l''utilisation de CONTOUR,
;       l''utilisation de ce mot clef ne modifie pas la legende ou/et
;       la barre de couleur.
;
;       PETITDESSIN: vecteur de 3 ou 4 elements, applique pour faire un
; dessin sur une petite portion de feuille ou d''ecran. il delimite
; la zone ds laquelle va etre fait le dessin
; si il a 4 elements:
;       il est alors constitute des coordonnees -exprime en cm reperes par
;       rapport au coin en bas a gauche de la feuille ou de la fenetre
;       (en portrait comme en landscape)- du coin en bas a
;       gauche et du coin en haut a droite  de la zone de dessin.
; si il a 3 elements:
;       Ds ce cas, on divise la fenetre ou l''ecran en PETITDESSIN[0]
;       colonnes, en PETITDESSIN[1] lignes le dessin se faisant ds la
;       case numero PETITDESSIN[2].La numerotation commencant en haut
;       a gauche par le numero 1 et suivant apres dans le sens de
;       l''ecriture.
; Par defaut on fait un dessin occupant la plus grande place possible
; tout en concervant le rapport d''aspect (sauf qd REMPLI est active)
;
;       /PORTRAIT: oblige la feuille ou la fenetre a etre en position
;       "debout"
;
;       /POST: faire une sortie postscript. Ne marche que si on fait
;       un seul dessin sur la feuille. Si on fait plusieurs dessins,
;       utiliser @ps ou plein2dessins
;
;       /REMPLI:oblige le dessin a occuper l'espace maximum definit
;       par petitdessin
;
;       /REVERSE_X: pour inverser l''axe des x (et aussi le dessin)
;
;       /REVERSE_Y: pour inverser l''axe des y (et aussi le dessin)
;
;       /SIN: activer ce mot cle si l''on veut que l'' axe des x soit
;       trace en sinus de la latitude qd on fait une coupe 'yz'
;
;       /STRICTFILL: activer ce mot clef pour que le remplissage des
;       contours ce fasse precisement entre le min et le max specifie
;       en laissant en banc les valeurs inferieurs au min specifie et
;       superieurs au max specifie.
;
;       STYLE: style de tracer a adopter pour dessiner les isolignes par
; defaut style=0. cf style.pro
;
;       /TRANS: fait un postscript (active /post automatiquement) et l'imprime
; -si on le desire- sur un transparant
;
;        UNLABSUR: entier n. specifant qu''on ne labelle qu''un
;        contour sur n. Par defaut unlabsur=2
;
;       /UNSUR2: si on veut tracer un countour sur deux. par  defaut trace
; tous les contours
;
;       WINDOW: nimero de la fenetre ou l'on veut faire le graphe (permet
; d'ouvrir plusieurs fenetres). par defaut on ouvre 'IDL0'
;
;       /XZ: force a faire une coupe xz
;
;       /YZ: force a faire une coupe yz
;
;       YSURX: rapport d'echelle entre y et x (par ex: =1 pour un repere
; presque orthonorme, =2 si l'axe des y est environ deux fois plus dilate
; que celui des x). Par defaut on adapte pour occupe une grande partie de
; la feuille en sortie postScript ou pour cree une fenetre pas trop etiree
;
;       ZOOM: profondeur jusqu'a laquelle on fait un zoom. par defaut 200m ou
; la profondeur maximale si elle est inf a 200
;
; OUTPUTS:
;
; COMMON BLOCKS:
;       common.pro      
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; EXAMPLE:
;
; MODIFICATION HISTORY: Sebastien Masson (smasson@lodyc.jussieu.fr)
;                       7/1999
;                       Sebastien Masson 08/02/2000 checkfield and
;                       notri keyword.
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
pro pltz,tab,giventype, givenmin,givenmax,BOITE=boite,CONTOUR=contour $
         ,ENDPOINTS=endpoints,INTERVALLE=intervalle,INV=inv,HZSURHT=hzsurht $
         ,CONTINTERVALLE=contintervalle,LABEL=label,CONTLABEL=contlabel $
         ,STYLE=style,CONTMAX=contmax, SIN = sin, TYPEIN = typein $
         ,CONTMIN=contmin,NLEVEL=nlevel,CONTNLEVEL=contnlevel, NOTRI = notri $
         ,ZOOM=zoom, XZ = xz, YZ = yz, MININ = minin, MAXIN = maxin $
         , STRICTFILL = strictfill, OVERPLOT = overplot, _EXTRA = ex
@common
   tempsun = systime(1)         ; pour key_performance
;------------------------------------------------------------
;--------------------------------------------------------------
; 1ere partie: initialisation et petits calculs...
;--------------------------------------------------------------
;on ne reinitialise pas qd on rapelle pltz en boucle pour utiliser contour
   if n_elements(contour) ne 4 AND NOT keyword_set(overplot) then reinitplt
;
   if keyword_set(boite) then oldboite = [lon1, lon2, lat1, lat2, prof1, prof2]
;--------------------------------------------------------------
; lecture du champ
;--------------------------------------------------------------
   if n_elements(giventype) NE 0 then type = giventype
   if n_elements(givenmin) NE 0 then min = givenmin
   if n_elements(givenmax) NE 0 then max = givenmax
   if n_elements(minin) NE 0 then min = minin
   if n_elements(maxin) NE 0 then max = maxin
   if keyword_set(typein) then BEGIN 
      if size(type, /type) NE 7 AND size(type, /type) NE 0 then begin
         if n_elements(min) NE 0 then max = min
         min = type
      endif
      type = typein
   endif
   if keyword_set(boite) then vraiboite = boite
   checktypeminmax, 'pltz', TYPE = type, MIN = min, MAX = max, XZ = xz, YZ = yz, ENDPOINTS=endpoints, BOITE = boite, _extra = ex
   coupe = type
   if keyword_set(endpoints) then begin
      section, tab, z2d, glam, gphi, ENDPOINTS = endpoints, TYPE = type, BOITE = boite, DIREC = direc
      nx = n_elements(glam) 
      ny = nx
      if strupcase(vargrid) EQ 'W' then begin
         z = gdepw[premierzw:dernierzw]
         nz = nzw
      ENDIF ELSE BEGIN
         z = gdept[premierzt:dernierzt]
         nz = nzt
      ENDELSE
   ENDIF ELSE BEGIN
      z2d = checkfield(tab, 'pltz', TYPE = type, BOITE = boite, DIREC = direc, _extra = ex)
      if z2d[0] EQ -1 then BEGIN 
         if keyword_set(boite) AND n_elements(oldboite) NE 0 then domdef, oldboite, GRILLE=vargrid
         return
      ENDIF
      grille,mask,glam,gphi,z,nx,ny,nz
   ENDELSE
;---------------------------------------------------------------
   profmax = !y.range[0]
   profmin = !y.range[1]
   if not keyword_set(zoom) then zoom=200
   zoom = zoom[0]
   if zoom GE prof2 then zoom=profmax
;--------------------------------------------------------------------
; construction du mask
;--------------------------------------------------------------------
   mask = fltarr((size(z2d))[1],(size(z2d))[2] )
   nan = total(finite(z2d,/nan))  < 1
   if keyword_set(nan) then begin
      notanum = where(finite(z2d) EQ 0)
      z2d[notanum] = 0
      mask(where(z2d LT valmask/10)) = 1
      z2d[notanum] = !values.f_nan
   ENDIF ELSE mask(where(z2d LT valmask/10)) = 1
   if (where(mask EQ 0))[0] EQ -1 AND NOT keyword_set(nan) then notri = 1
;-----------------------------------------------------------------------------
;   determination du mi:min et du ma:max de tab1 ainsi que de max: max et
;   min: min pour le dessin.
;-----------------------------------------------------------------------------
; faudra-t-il faire un autoscale ???
   autoscale = testvar(var = min) EQ testvar(var = max) AND NOT keyword_set(intervalle)
   determineminmax, z2d,mask, mi, ma, MININ = min, MAXIN = max, nan = nan,INTERVALLE=intervalle
   if z2d[0] EQ -1 THEN GOTO, sortie
; on fait un autoscale si besoin
   if autoscale then autoscale, min, max, intervalle
;--------------------------------------------------------------
   z2d=reverse(z2d,2)
   mask=reverse(mask,2)
;--------------------------------------------------------------
;--------------------------------------------------------------
; 2eme partie: dessin
;--------------------------------------------------------------
;--------------------------------------------------------------
   if n_elements(contour) NE 4 AND NOT keyword_set(overplot) THEN $
    placedessin, 'pltz',posfenetre, posbar, contour = contour, endpoints = endpoints $
    , direc = direc, _extra = ex
;------------------------------------------------------------
;--------------------------------------------------------------
; choix des labels
;-----------------------------------------------------------
   if keyword_set(intervalle) AND NOT keyword_set(label) then label=1
   if keyword_set(label) eq 0 then cas=0 else cas=label
   label,cas,min,max,ncontour,level_z2d,NLEVEL=nlevel,INTERVALLE=intervalle $
    , strictfill = strictfill
;--------------------------------------------------------------
; choix de style
;-----------------------------------------------------------
   if not keyword_set(style) then style=0
   style,style,level_z2d,linestyle,thick
   if keyword_set(inv) then couleur=reverse(couleur)
;-----------------------------------------------------------
;   definition des axes
;----------------------------------------------------------
   if NOT keyword_set(overplot) THEN axe, coupe, SIN = sin, _EXTRA = ex
   if keyword_set(reverse_y) then !y.range=[0, -1] ELSE !y.range = [-1, 0]
;----------------------------------------------------------
; on projette l''axe z dans [0,1]
;----------------------------------------------------------
   if not keyword_set(hzsurht) then hzsurht=2./3
   if zoom ge profmax then hzsurht=1.
   if zoom LT profmax then begin
      mp = projsegment([profmin, zoom], [0, hzsurht], /mp)
      z[where(z LE zoom)] = mp[0]*z[where(z LE zoom)]+mp[1]
      mp = projsegment([zoom, profmax], [hzsurht, 1], /mp)
      z[where(z GE zoom)] = mp[0]*z[where(z GE zoom)]+mp[1]
   ENDIF ELSE BEGIN
      mp = projsegment([profmin, profmax], [0, 1], /mp)
      z = mp[0]*z+mp[1]
   ENDELSE
   z=reverse(-z,1)
;----------------------------------------------------------
; on passe les axes en tableaux 2d pour pouvoir utiliser la
; trianguletion
;----------------------------------------------------------
   if coupe eq 'yz' then BEGIN 
      if (size(gphi))[0] EQ 2 then x=reform(gphi[0, *]) ELSE x=gphi 
      if keyword_set(sin) then x = sin(!pi/180.*x)
      x = x#replicate(1, nz)
      z = replicate(1, ny)#z
   ENDIF ELSE BEGIN 
      x = glam[*, 0]#replicate(1, nz)
      z = replicate(1, nx)#z
   ENDELSE 
;--------------------------------------------------------------
; extrapolation des donnees sur les terres et seuillage
;--------------------------------------------------------------
   if keyword_set(nan) then begin
      notanumber = where(finite(z2d, /nan) EQ 1)
      z2d[notanumber] = max
      if coupe eq 'yz' then masknan = replicate(1, ny, nz) ELSE masknan = replicate(1, nx, nz) 
      masknan[notanumber] = 0
   ENDIF ELSE masknan = 1
   z2d = remplit(z2d,nite=1+keyword_set(nan), mask = mask*masknan, /basique, _extra=ex)
   if NOT keyword_set(strictfill) then z2d = min > z2d <  max
   if keyword_set(notri) then triangulation = -1 ELSE $
    triangulation = triangule(mask*masknan,/regulier,coinmonte=coinmontemask,coindescend=coindescendmask)
;------------------------------------------------------------
; dessin en lui meme
;------------------------------------------------------------
   pltbase, z2d,x, z, mask,x, z, level_z2d,couleur, overplot = overplot $
    , contour = contour, trichamp = triangulation, trimsk = triangulation  $
    , c_linestyle=linestyle,c_labels=1-(indgen(n_elements(level_z2d)) MOD 2) $
    , c_thick=thick,unsur2 = unsur2 $
    , coinmontemask=-1,coindescendmask=-1, masknan = masknan $
    , _extra = ex
;------------------------------------------------------------
; rappelle de plt en boucle qd contour est active
;------------------------------------------------------------
   if n_elements(contour) eq 4 then BEGIN ; c''est la 2eme fois que je passe ds pltt
      contour = {mietma:[mi, ma], unit:varunit, inter:intervalle} ; je renvoie le min, le max et l''unite
      if keyword_set(vraiboite) then boite = vraiboite
      return
   endif
   if keyword_set(contour) THEN BEGIN 
      pourlegende = [1, 1, 1, 1]
      oldattributs = saveatt()
      oldcouleur = couleur
      pltz,contour,contmin,contmax,CONTOUR=pourlegende,HZSURHT=hzsurht $
       ,INTERVALLE=contintervalle,LABEL=contlabel,STYLE=style, /noerase, NOTRI = notri  $
       ,NLEVEL=contnlevel,ZOOM=zoom,BOITE=vraiboite,ENDPOINTS=endpoints, STRICTFILL = strictfill $
       , _extra = ex
      restoreatt, oldattributs
      couleur = oldcouleur
   ENDIF
;------------------------------------------------------------
;------------------------------------------------------------
; 3eme partie: dessin du cadre, legendes, colorbar...
;------------------------------------------------------------
   if keyword_set(overplot) then BEGIN 
      !y.range =  [zoom, profmin] ; on repasse en coordonees physiques!
      plot,[0], [0],/nodata, /noerase, title = '', subtitle = '', xstyle = 5, ystyle = 5
      GOTO, fini
   endif
;------------------------------------------------------------
; legendes + affichage de celles-ci
;------------------------------------------------------------
   legende,mi,ma,coupe, CONTOUR = pourlegende, INTERVALLE = intervalle, DIREC = direc, endpoints = endpoints, _EXTRA = ex
   if coupe eq 'yz' then xaxe='lataxe' else xaxe='lonaxe'
   if keyword_set(sin) then xaxe = ''
; cadre applique par defaut
   plot,[x[0], x[n_elements(x)-1]],[-hzsurht,-hzsurht],/noerase,color=c_cote $
    ,xstyle=1+4*(keyword_set(endpoints) AND ((type EQ 'xz' AND lat1 NE lat2) OR (type EQ 'yz' AND lon1 NE lon2))) $
    ,xtickformat=xaxe, _extra = ex
; ajout d'un axe ds le cas ou l'on utilise endpoints
   if keyword_set(endpoints) then addaxe, endpoints, type, posfenetre, _EXTRA = ex
;------------------------------------------------------------
; axe y en 1 ou 2 parties
;------------------------------------------------------------
   if n_elements(ex) NE 0 then BEGIN 
; pour ne plus mettre de titre
      if (where(tag_names(ex) EQ 'TITLE'))[0] NE -1 then ex.TITLE = ' '
; pour ne plus mettre de sous titre
      if (where(tag_names(ex) EQ 'SUBTITLE'))[0] NE -1 then ex.SUBTITLE = ' '
; pour n''avoir q''un ytitle
      if (where(tag_names(ex) EQ 'YTITLE'))[0] NE -1 then BEGIN 
         ytitle = ex.YTITLE
         ex.YTITLE = ' '
      endif
   ENDIF
   htotal=posfenetre[3]-posfenetre[1]
   hzoom=1.*hzsurht*htotal
   if zoom LT profmax then $
    plot,[0], [0],/noerase,color=c_cote,ystyle=1, yrange = [profmax, zoom+0.001] $
    , position=posfenetre+[0,0,0,-hzoom], _extra = ex, title = '', subtitle = '', ytitle = ''
;
   !y.range =  [zoom, profmin]  ; on repasse en coordonees physiques!
   plot,[0], [0],/noerase,color=c_cote,ystyle=1, _extra = ex $
    , title = '', subtitle = '', ytitle = '', position=posfenetre+[0,htotal-hzoom,0,0]
;------------------------------------------------------------
; pour ecrire le ytitle...
;------------------------------------------------------------
   if !d.name EQ 'PS' then $
    xs = (grandfeuille*(1-key_portrait)+petitfeuille*key_portrait)*!d.x_px_cm $
   ELSE xs = !d.x_size
   if n_elements(ytitle) NE 0 then !y.title = ytitle
   charsize = chkstru(ex, 'ycharsize', /extract)
   if charsize EQ -1 then charsize = !p.charsize
   IF chkstru(ex, 'charsize') THEN ex.charsize = charsize
   if chkstru(ex, 'ytitle', /extract) NE '' then $
   decalage = string(format='(e10.3)',profmax)
   decalage = float(strmid(decalage,strpos(decalage,'e')+1))
   posy=posfenetre[1]+1.*htotal/2
   posx=posfenetre[0]-(decalage+3)*!d.x_ch_size*charsize/xs
    xyouts,posx,posy,!y.title, /normal,orientation=90,color=0,ALIGNMENT = .5, charsize = charsize, _extra = ex

;------------------------------------------------------------
; barre de couleur
;------------------------------------------------------------
   couleur = couleur[0:ncontour-1-keyword_set(strictfill)]
   barrecouleur, position=posbar,divisions=(ncontour-keyword_set(strictfill))/2,min=min $
    , max=max,discret=couleur,_extra = ex
;------------------------------------------------------------
;------------------------------------------------------------
; 4eme partie: impression eventuelle
;------------------------------------------------------------
;------------------------------------------------------------
fini:
   if keyword_set(oldboite) then domdef, oldboite,GRILLE=[vargrid, 'T']
   terminedessin, _extra = ex
   if keyword_set(vraiboite) then boite = vraiboite
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
sortie:
   if keyword_set(key_performance) NE 0 THEN print, 'temps pltz', systime(1)-tempsun 
   return
end