source: trunk/MATRICE/inter.pro @ 2

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME:inter
;
; PURPOSE:calcule l''intersection de 2 matrices D'ENTIERS POSITIFS
;
; CATEGORY:calcule sur les matrices
;
; CALLING SEQUENCE:res=inter(a,b)
;
; INPUTS:a et b:arrays of positive integers, which need
;               not be sorted. Duplicate elements are ignored, as they have no
;               effect on the result
;
; KEYWORD PARAMETERS:
;
; OUTPUTS:tableau
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:
;
; The empty set is denoted by an array with the first element equal to
; -1.
;
; RESTRICTIONS:
;
; These functions will not be efficient on sparse sets with wide
; ranges, as they trade memory for efficiency. The HISTOGRAM function
; is used, which creates arrays of size equal to the range of the
; resulting set.
;
; EXAMPLE:
;
;   a = [2,4,6,8]
;   b = [6,1,3,2]
;   inter(a,b) = [ 2, 6]       ; Common elements
;
; MODIFICATION HISTORY: 
;
; http://www.dfanning.com/tips/set_operations.html
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------

FUNCTION inter, a, b
;
   case 1 of
      n_elements(a) EQ 0:return,  -1
      n_elements(b) EQ 0:return,  -1
      n_elements(a) EQ 1 AND n_elements(b) NE 1: $
       if (where(b EQ a[0]))[0] EQ -1 then return, -1 ELSE return,  a[0]
      n_elements(b) EQ 1 AND n_elements(a) NE 1: $
       if (where(a EQ b[0]))[0] EQ -1 then return, -1 ELSE return,  b[0]
      n_elements(a) EQ 1 AND n_elements(b) EQ 1: $
       if (where(a[0] EQ b[0]))[0] EQ -1 then return, -1 ELSE return,  a[0]
      ELSE:
   ENDCASE
;
minab = Min(a, Max=maxa) > Min(b, Max=maxb) ;Only need intersection of ranges
maxab = maxa < maxb

   ; If either set is empty, or their ranges don't intersect: result = NULL.

IF maxab LT minab OR maxab LT 0 THEN RETURN, -1
r = Where(Histogram(a, Min=minab, Max=maxab) $
          *Histogram(b, Min=minab, Max=maxab), count)

IF count EQ 0 THEN RETURN, -1 ELSE RETURN, r + minab
END