source: trunk/LECTURE/xncdf_lec.pro @ 2

Last change on this file since 2 was 2, checked in by opalod, 22 years ago

Initial revision
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 26.0 KB
Line 
1; La lecture de ce programme se fait de bas en haut:
2;   1) xncdf_lec
3;    -->2) xncdf_lec_event
4;       |--> 3) wid_var
5;            --> wid_var_event
6;
7pro wid_var_event,  event
8; NAME:wid_var_event
9;
10; PURPOSE:procedure appele par xmanager qd on appuie sur un bouton du
11; 2eme widget cree par wid_var
12;
13; INPUTS: event, une structure caracterisant le type d''evenement qui
14; arrive au widget numero1 2
15;
16; COMMON BLOCKS:wididbase,resultat,infovariable,indicewid,motcle
17;------------------------------------------------------------
18;------------------------------------------------------------
19;------------------------------------------------------------
20   COMMON wididbase, base
21   COMMON resultat, res
22   COMMON infovariable, cdfid, listename, contient, nomdim, tailledim, varid, varcontient
23   COMMON indicewid_var, widbase1, widbase2111, widbase212, widbase213, selectatt
24   COMMON motcle, mcatt, mccount, mcoffset, mciodir, mcshift, mcstride, mcvar
25;
26; quel est le type d''evenement?
27   widget_control, event.id, get_uvalue=uval
28   tailledimvar = tailledim[varcontient.dim]
29   if n_elements(uval) EQ 0 then return
30; case sur le type d''evenement
31   case uval OF
32      1:BEGIN                   ; on change des valeurs dans le tableau
33; on controle que les valeurs mises dans le tableau ne sont pas
34; completement fausses
35         widget_control, widbase1, get_value = table
36; agument du bon type ?
37; si le type est mauvais on change automatiquement par des valeurs par
38; defaut
39         if event.x GT (size(table))[1] then return
40         if event.y GT (size(table))[2] then return
41         if size(table[event.x, event.y], /type) GE 6 $
42          OR size(table[event.x, event.y], /type) EQ 0 then BEGIN
43            if event.x EQ 1 then $
44             widget_control, widbase1, use_table_select = [1, event.y,1, event.y] $
45             , set_value = tailledimvar[event.y] $
46            ELSE widget_control, widbase1 $
47             , use_table_select = [event.x, event.y, event.x, event.y], set_value = 0
48         endif
49; agument avec une valeur nom debile?
50         table = fix(table)
51         case event.x of
52            0:BEGIN             ; on a touche a l''offset:
53               if table[0, event.y] LT 0 then BEGIN
54                  table[0, event.y] = 0
55                  widget_control, widbase1, use_table_select = [0, event.y, 0, event.y] $
56                   , set_value = 0
57               endif
58; si il depasse la dim du tableau on le met au max et le cont a 1
59               if table[0, event.y] GT tailledimvar[event.y]/table[3, event.y] then begin
60                  widget_control, widbase1, use_table_select = [0, event.y,1, event.y] $
61                   , set_value = [tailledimvar[event.y]/table[3, event.y], 1]
62               ENDIF ELSE BEGIN
63; si avec le nouvel offset le count est trop grand, on le diminue juste
64; de ce qu''il faut!
65                  if table[1, event.y] GT $
66                   (tailledimvar[event.y]/table[3, event.y])-table[0, event.y] then begin
67                     widget_control, widbase1, use_table_select = [1, event.y, 1, event.y] $
68                      , set_value = (tailledimvar[event.y]/table[3, event.y])-table[0, event.y]
69                  endif
70               ENDELSE
71            END
72            1:BEGIN             ;on a touche au count
73               if table[1, event.y] LT 1 then BEGIN
74                  table[1, event.y] = 1
75                  widget_control, widbase1, use_table_select = [1, event.y, 1, event.y] $
76                   , set_value = 1
77               endif
78; si il est trop grand, on le diminue juste de ce qu''il faut!
79               if table[1, event.y] GT $
80                (tailledimvar[event.y]/table[3, event.y])-table[0, event.y] then BEGIN
81                  widget_control, widbase1, use_table_select = [1, event.y, 1, event.y] $
82                   , set_value = (tailledimvar[event.y]/table[3, event.y])-table[0, event.y]
83               endif
84            END
85            2:BEGIN             ; on a touche au shift
86               widget_control, widbase1, use_table_select = [2, event.y, 2, event.y] $
87                , set_value = table[2, event.y] MOD (tailledimvar[event.y]/table[3, event.y])
88            END
89            3:BEGIN             ; on touche au stride
90               if table[3, event.y] LT 1 then BEGIN
91                  table[3, event.y] = 1
92                  widget_control, widbase1, use_table_select = [3, event.y, 3, event.y] $
93                   , set_value = 1
94               endif
95               if table[3, event.y] EQ 0 then $ ; il ne doit pas etre nul
96                widget_control, widbase1, use_table_select = [3, event.y, 3, event.y] $
97                , set_value = 1
98; il ne doit pas etre trop grand
99               if table[3, event.y] GT tailledimvar[event.y] then $
100                widget_control, widbase1, use_table_select = [0, event.y,3, event.y] $
101                , set_value = [0, 1, 0, tailledimvar[event.y]] $
102               ELSE BEGIN
103                  if table[1, event.y] GT $
104                   (tailledimvar[event.y]/table[3, event.y])-table[0, event.y] then begin
105                     widget_control, widbase1, use_table_select = [1, event.y, 1, event.y] $
106                      , set_value = (tailledimvar[event.y]/table[3, event.y])-table[0, event.y]
107                  endif
108               ENDELSE
109            END
110            ELSE:
111         endcase
112      END
113      2111:BEGIN                ;on a touche aux boutons oui/non
114; on actualise le vecteur selectatt a 0 ou 1 pour l''attribut concerne
115; (numero event.id)
116         selectatt[where(widbase2111 EQ event.id)] = event.select
117      end
118      31:BEGIN                  ;on a appuye sur 'get'
119         widget_control, widbase1, get_value = table
120         table = fix(table)
121         mcshift = where(table[2, *] NE 0)
122         mcoffset = table[0, *]
123         mccount = table[1, *]
124         mcstride = table[3, *]
125         if mcshift[0] NE -1 then BEGIN ; il y a des shifts
126; on lit l''integralite des dimensions pour lesquelles il y a un shift
127            mcoffset[mcshift] = 0
128            mccount[mcshift] = tailledimvar[mcshift]
129; on active pas stride qd il n''y en a pas besoin car ca fait ecrire a
130; l''ecran qqch de louche...
131            if total(mcstride) EQ n_elements(mcstride) then $
132             ncdf_varget, cdfid, varid, res, OFFSET = mcoffset, COUNT = mccount $
133            ELSE $
134             ncdf_varget, cdfid, varid, res, OFFSET = mcoffset, COUNT = mccount, STRIDE = mcstride
135; pour faire le shift
136            mcshift = table[2, *]
137            mcoffset = table[0, *]
138            mccount = table[1, *]
139; on definit commende qui permet de faire un shift
140            commande = 'res=shift(res'
141            for dim = 0, varcontient.ndims-1 do commande = commande+','+string(table[2,dim])
142            commande = commande+')'
143            rien = execute(commande)
144; on redefinit commnade qui permet de couper les dimensions qui n''ont
145; pas ete encore coupees (c''est celles que l''on shift)
146            commande = 'res=res[' ; initialisation de la commende
147            for dim = 0, varcontient.ndims-1 do BEGIN
148               if mcshift[dim] EQ 0 then commande = commande+'*,' $
149               ELSE commande=commande+string(mcoffset[dim])+':'+string(mccount[dim]+mcoffset[dim]-1)+','
150            ENDFOR
151            commande = strmid(commande, 0, strlen(commande)-1)+']'
152            rien = execute(commande)
153; cas sans shift, on lit directement le bon bout de tableau
154         ENDIF ELSE BEGIN
155            if total(mcstride) EQ n_elements(mcstride) then $
156             ncdf_varget, cdfid, varid, res, OFFSET = mcoffset, COUNT = mccount $
157            ELSE $
158             ncdf_varget, cdfid, varid, res, OFFSET = mcoffset, COUNT = mccount, STRIDE = mcstride
159         ENDELSE
160; faut-il constituer une structure avec les attributs qui on ete selectionnes
161         if total(selectatt) NE 0 then BEGIN ; il y a des attributs selectionnes
162            res = create_struct(varcontient.name, res) ; on cree la structure
163            selectatt = where(selectatt EQ 1) ; on trouve les attributs selectiones
164            for attid = 0,  n_elements(selectatt)-1 do BEGIN ; pour lesquels on prend
165               widget_control, widbase212[selectatt[attid]], get_value = attname ; le nom
166               widget_control, widbase213[selectatt[attid]], get_value = attvalue ; la valeur
167              res = create_struct(res, attname[0], attvalue[0]) ; on concatene la structe
168            endfor
169         endif
170         widget_control, event.top, /destroy ;on ferme le 2eme widget
171         widget_control, base, /destroy ;on ferme le 1eme widget
172         ncdf_close,cdfid
173      END
174      32:                       ;cas de l''affichage d''un held (avec xdisplayfile)
175      33:widget_control, event.top, /destroy ;on ferme le 2eme widget
176      ELSE:
177   endcase
178   return
179end
180;------------------------------------------------------------
181;------------------------------------------------------------
182PRO wid_var, widid_pere
183;------------------------------------------------------------
184;------------------------------------------------------------
185;------------------------------------------------------------
186; NAME: wid_var
187;
188; PURPOSE: cette procedure gere le 2eme widget cree qd on appelle
189; xncdf_lec. ce widget concerne la lecture de la variable
190;
191; INPUTS: widid_pere: un scalere contenant l'identite du widget pere
192; qui a etait cree par xncdf_lec et qui a permis de selectionner la
193; variable a lire.
194;
195; OUTPUTS: indirectement res (le tableau ou la structure resultat)
196;
197; COMMON BLOCKS:resultat,infovariable,indicewid_var,motcle
198;
199;------------------------------------------------------------
200;------------------------------------------------------------
201;------------------------------------------------------------
202   COMMON resultat, res
203   COMMON infovariable, cdfid, listename, contient, nomdim, tailledim, varid, varcontient
204   COMMON indicewid_var, widbase1, widbase2111, widbase212, widbase213, selectatt
205   COMMON motcle, mcatt, mccount, mcoffset, mciodir, mcshift, mcstride, mcvar
206   res = -1
207;------------------------------------------------------------
208; ouverture de la fenetre de base sous forme de colonnes
209;------------------------------------------------------------
210   widbase = widget_base(/column, title='variable: '+varcontient.name, /align_center, group_leader = widid_pere)
211;------------------------------------------------------------
212; ouverture de  sous-fenetres de base ;
213;------------------------------------------------------------
214; widbase1 tableau des offsets
215;------------------------------------------------------------
216   rien = widget_label(widbase, value = ' ') ; on saute une ligne
217; defintion des lables des lignes du tableau
218   rowlab = string(tailledim[varcontient.dim])
219   for i = 0,  n_elements(rowlab)-1 do rowlab[i] = strtrim(rowlab[i], 1)
220   rowlab = nomdim[varcontient.dim]+replicate(': ', n_elements(varcontient.dim))+rowlab
221; definition des valeurs initiales du tableau
222   valinit = lonarr(4, n_elements(varcontient.dim))
223; colonne 0 : les offset
224   if keyword_set(mcoffset) AND n_elements(mcoffset) EQ varcontient.ndims THEN $
225    valinit[0,*]=mcoffset ELSE valinit[0, *] = 0
226; colonne 1 : les counts
227   if keyword_set(mccount) AND n_elements(mccount) EQ varcontient.ndims THEN  $
228    valinit[1,*]=mccount ELSE valinit[1, *] = tailledim[varcontient.dim]
229; colonne 2 : les shifts
230   if keyword_set(mcshift) AND n_elements(mcshift) EQ varcontient.ndims THEN $
231    valinit[2,*]=mcshift ELSE valinit[2, *] = 0
232; colonne 3 : les strides
233   if keyword_set(mcstride) AND n_elements(mcstride) EQ varcontient.ndims THEN $
234    valinit[3,*]=mcstride ELSE valinit[3, *] = 1
235; test des valeurs initiales du tableau
236   valinit = fix(valinit)
237   valinit[3, *] = 1 > valinit[3, *] < tailledim[varcontient.dim] ; test des strides
238   valinit[0, *] = 0 > valinit[0, *] < tailledim[varcontient.dim] ; test des offsets
239; test des counts
240   valinit[1, *] = 1 > valinit[1, *] < ((tailledim[varcontient.dim]/valinit[3, *])-valinit[0, *])
241   valinit[2, *] = valinit[2, *] MOD (tailledim[varcontient.dim]/valinit[3, *]) ; test des shifts
242; declaration du tableau
243   widbase1 = widget_table(widbase, row_labels = rowlab, value = valinit, /editable $
244                           , column_labels = ['Offset', 'Count', 'Shift', 'Stride'], uvalue = 1)
245; un petit blabla
246   rien = widget_label(widbase, value = 'ATTENTION: Faire des ''return'' pour que les valeurs', /align_center)
247   rien = widget_label(widbase, value = 'du tableau ou des textes soient bien prises en compte', /align_center)
248;------------------------------------------------------------
249; widbase2 choix des attributs
250;------------------------------------------------------------
251   rien = widget_label(widbase, value = ' ') ; on saute une ligne
252   widbase2 = widget_base(widbase, /column)
253; pour chaque attribut, on cree un widget (widbase21) qui contient en ligne un
254; bouton oui/non (widbase211), et deux wigdet text (widbase212,
255; widbase213)comportant le nom et la valeur de l''attribut.
256   widbase21 = lonarr(varcontient.natts)
257   widbase211 = lonarr(varcontient.natts)
258   widbase2111 = lonarr(varcontient.natts)
259; vecteur qui serviera a savoir quels boutons oui/non sont
260; selectiones. cf. wid_var_event
261   selectatt = lonarr(varcontient.natts)
262   selectatt[*] = 0
263   widbase212 = lonarr(varcontient.natts)
264   widbase213 = lonarr(varcontient.natts)
265   for attid = 0, varcontient.natts-1 do BEGIN ;boucle sur le nombre d''attributs
266      widbase21[attid] = widget_base(widbase2, /row)
267      name=ncdf_attname(cdfid,varid,attid)
268      ncdf_attget,cdfid,varid,name,value
269      widbase211[attid] = widget_base(widbase21[attid], /nonexclusive)
270      widbase2111[attid]  = widget_button(widbase211[attid], value = ' ', uvalue = 2111)
271      widbase212[attid] = widget_text(widbase21[attid], value = name, /editable)
272      widbase213[attid] = widget_text(widbase21[attid], value=strtrim(string(value),1), /editable)
273   endfor
274;------------------------------------------------------------
275; widbase3 boutons du bas
276;------------------------------------------------------------
277   widbase3 = widget_base(widbase, /row,/align_center)
278   widbase31=widget_button(widbase3,value='GET', uvalue=31)
279   widbase32=widget_button(widbase3,value='Help', uvalue=32)
280   widbase33=widget_button(widbase3,value='DONE', uvalue=33)
281;------------------------------------------------------------
282;execution de la fentre de base et des sous-fenetres
283;------------------------------------------------------------
284   widget_control,widbase,/realize
285;------------------------------------------------------------
286   xmanager,'wid_var',widbase
287   return
288end
289;------------------------------------------------------------
290
291PRO xncdf_lec_event, event
292;------------------------------------------------------------
293;------------------------------------------------------------
294;------------------------------------------------------------
295; NAME:xncdf_lec_event
296;
297; PURPOSE: procedure appele par xmanager qd on appuie sur un bouton du
298; 1ere widget cree par xncdf_lec
299;
300; INPUTS: event, une structure caracterisant le type d''evenement qui
301; arrive au widget numero1
302;
303; COMMON BLOCKS:resultat, infovariable, motcle
304;
305;------------------------------------------------------------
306;------------------------------------------------------------
307;------------------------------------------------------------
308   COMMON resultat, res
309   COMMON infovariable, cdfid, listename, contient, nomdim, tailledim, varid, varcontient
310   COMMON motcle, mcatt, mccount, mcoffset, mciodir, mcshift, mcstride, mcvar
311; quel est le type d''evenement?
312   widget_control, event.id, get_uvalue=uval
313; case sur le type d''evenement
314   case uval of
315      1:BEGIN                   ; on veut lire un autre fichier
316         widget_control, event.id, get_value = nom ; on recupere le nom
317         widget_control, event.top, /destroy ;on ferme le widget
318         ncdf_close,cdfid       ; on ferme le mauvais fichier qui a ete ouvert
319; on reapelle xncdf_lec
320         res = xncdf_lec(nom[0], ATT = mcatt, COUNT = mccount, OFFSET = mcoffset, IODIR = mciodir $
321                         , SHIFT = mcshift,  STRIDE = mcstride, VAR = mcvar)
322         return
323      END
324      2:BEGIN                   ; une variable est selectionee
325         varid = event.index    ; on recupere son numero ds le fichier Netcdf
326         varcontient = ncdf_varinq(cdfid,varid)
327         wid_var, event.top     ; on appelle le programme qui lance le 2eme widget. cf. + haut
328      END
329      3:BEGIN                   ; bouton done
330         widget_control, event.top, /destroy ; on tue le widget
331         ncdf_close,cdfid       ; on ferme le fichier
332      END
333      ELSE:
334   endcase
335   return
336end
337;------------------------------------------------------------
338;------------------------------------------------------------
339;------------------------------------------------------------
340;+
341; NAME: xncdf_lec
342;
343; PURPOSE: lecture d''un fichier Net Cdf avec des widgets !
344;
345; CATEGORY: lecture de fichiers avec widgets
346;
347; CALLING SEQUENCE: res=xncdf_lec([nom_fichier])
348;
349; INPUTS:
350;      OPTIONNEL, nom_fichier: c''est un string qui donne le nom du
351;       fichier a ouvrir.Si nomfichier ne contient pas le caractere
352;       separateur de repertoirte ('/' sous unix par ex), Le fichier
353;       sera cherche ds le repertoire courant
354;
355; KEYWORD PARAMETERS:
356;
357;       IODIR: string contenant le repertoire ou aller chercher le
358;       fichier a lire. Si nomfichier ne contient pas le caractere
359;       separateur de repertoirte ('/' sous unix par ex), Le fichier
360;       cherche s''appelera iodir+nom_fichier.
361;
362;       COUNT: An optional vector containing the counts to be used in
363;       reading Value. COUNT is a 1-based vector with an element for
364;       each dimension of the data to be written.The default matches
365;       the size of the variable so that all data is written out.
366;
367;       GROUP: The widget ID of the widget that calls XNCDF_LEC. When
368;       this ID is specified, a death of the caller results in a death
369;       of XNCDF_LEC.
370;
371;       OFFSET: An optional vector containing the starting position
372;       for the read. The default start position is [0, 0, ...].
373;
374;       SHIFT: un vecteur d''entiers, specifiant pour chaque dimension
375;       de combien il faut la shifter. Par defaut c''est
376;       [0,0,...]. cf. la fonction shift pour +
377;       d''explications. ATTENTION, le shift est effectue sur le
378;       tableau de taille maximum avant la reduction eventuelle
379;       determinee par OFFSET et COUNT. Par contre il est effectue
380;       apres l''extraction eventuelle cree par le STRIDE.
381;
382;       STRIDE: An optional vector containing the strides, or sampling
383;       intervals, between accessed values of the netCDF variable. The
384;       default stride vector is that for a contiguous read, [1, 1,
385;       ...].
386;
387; OUTPUTS: 2 cas possibles:
388;       1) aucun attributs n''a ete selectionne. Dans ce cas res est
389;       le tableau que l''on voulait lire.
390;       2) Des attributs ont ete selectionnes. Dans ce cas res est une
391;       structre dont le premier element portant le nom de la variable
392;       est le tableau de valeurs et les autre auguments sont les
393;       arguments selectiones
394;
395; COMMON BLOCKS: wididbase, infovariable, resultat, motcle
396;
397; SIDE EFFECTS:
398;
399; RESTRICTIONS:
400;
401; EXAMPLE: help, xncdf_lec()
402;
403; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr)
404;                      24/8/1999
405;-
406;------------------------------------------------------------
407;------------------------------------------------------------
408;------------------------------------------------------------
409FUNCTION xncdf_lec, nom, ATT = att, COUNT = count, GROUP = group, OFFSET = offset, IODIR = iodir, SHIFT = shift,  STRIDE = stride, VAR = var
410   COMMON wididbase, base
411   COMMON infovariable, cdfid, listename, contient, nomdim, tailledim, varid, varcontient
412   COMMON resultat, res
413   COMMON motcle, mcatt, mccount, mcoffset, mciodir, mcshift, mcstride, mcvar
414;------------------------------------------------------------
415; bidouille pour utiliser les mots cles (on passe par des variables
416; declarees ds un common)
417;------------------------------------------------------------
418   res = -1
419   if keyword_set(att) then mcatt = att ELSE mcatt = 0
420   if keyword_set(count) then mccount =count  ELSE mccount = 0
421   if keyword_set(offset) then mcoffset = offset ELSE mcoffset = 0
422   if keyword_set(shift) then mcshift = shift ELSE mcshift = 0
423   if keyword_set(stride) then mcstride = stride ELSE mcstride = 0
424   if keyword_set(var) then mcvar = var ELSE mcvar = 0
425;------------------------------------------------------------
426; choix du nom du fichier
427;------------------------------------------------------------
428; Quel type de machine est utiliee
429   thisOS = strupcase(strmid(!version.os_family, 0, 3))
430   CASE thisOS of
431      'MAC':sep = ':'
432      'WIN':sep = '\'
433      ELSE: sep = '/'
434   ENDCASE
435; si iodir n''est pas definit on l''initialise au repertoire courant
436   if NOT keyword_set(iodir) then cd,  current = iodir
437   mciodir = iodir
438; on complete iodir d''un caractere separateur de repertoire si besoin
439; est.
440   IF rstrpos(iodir, sep) NE strlen(iodir)-1 THEN iodir = iodir+sep
441   if n_elements(nom) EQ 0 then BEGIN ; si nom n''est pas definit
442; on en trouve un grace au programme dialog_pickfile
443      nom = dialog_pickfile(filter = iodir+'*.nc')
444      if nom[0] EQ '' then return,  -1 ; si on a rien trouve on sort
445;on complete nom par iodir si nom ne contient pas de caractere
446;separateur derepertoire
447   ENDIF ELSE if strpos(nom, sep) EQ -1 then nom = iodir+nom
448   test = findfile(nom)         ; le nom cherche correspond bien a un fichier?
449   while test[0] EQ '' OR n_elements(test) GT 1 do BEGIN ; on en cherche un tant qu''il ne correspond a rien!
450      test = test[0]
451      nom = dialog_pickfile(filter = iodir+'*.nc')
452      if nom EQ '' then return,  -1
453      test = findfile(nom)
454   endwhile
455;------------------------------------------------------------
456; ouverture du fichier nom
457;------------------------------------------------------------
458   cdfid=ncdf_open(nom)
459   contient=ncdf_inquire(cdfid)
460;------------------------------------------------------------
461; que contient le fichier??
462;------------------------------------------------------------
463; ouverture de la fenetre de base sous forme de colonnes
464   if n_elements(group) EQ 0 then base = widget_base(/column, title='Fichier: '+nom, /align_left) $
465   ELSE base = widget_base(/column, title='Fichier: '+nom, /align_left, GROUP_LEADER = group)
466; ouverture de  sous-fenetres de base ;
467;------------------------------------------------------------
468; base 1 titre portant le nom du fichier
469;------------------------------------------------------------
470   base1 = widget_base(base, /column, /align_center)
471   rien = widget_label(base1, value = 'Net Cdf filename', /align_center) ; blabla
472   rien = widget_text(base1, value = nom, /align_center, uvalue=1, /editable) ;nom du fichier que l''on peut changer
473   rien = widget_label(base1, value = ' ') ; on saute une ligne
474;------------------------------------------------------------
475; base 2 informations generales sur le fichier
476;------------------------------------------------------------
477   base2 = widget_base(base, /column)
478;------------------------------------------------------------
479; informations sur les attributs globaux
480;------------------------------------------------------------
481   if contient.ngatts NE -1 then begin
482      rien = widget_label(base2, value = 'Nombre de attributs globaux: '+ strtrim(contient.ngatts,1), /align_left)
483      for attiq=0,contient.ngatts-1 do BEGIN ; bouble sur le nombre d'attributs globaux
484         name=ncdf_attname(cdfid,attiq,/global) ;nom de l''atribut
485         ncdf_attget,cdfid,name,value,/global ;valeur de l''atribut
486         rien = widget_text(base2, value = name+': '+strtrim(string(value),1), xsize = 60, /scroll, /wrap, /align_right)
487      endfor
488      rien = widget_label(base2, value = ' ')
489   endif
490;------------------------------------------------------------
491;  informations sur les dimensions
492;------------------------------------------------------------
493   rien = widget_label(base2, value = 'Nombre de dimensions: '+strtrim(contient.ndims,1), /align_left)
494   if contient.recdim NE -1 then begin ; bouble sur le nombre de dimensions
495      ncdf_diminq,cdfid,contient.recdim,name,value ; nom et valeur de la dimension
496      rien = widget_label(base2, value = 'nom de la dimension infinie: '+name, /align_left)
497   endif
498;
499   nomdim   =strarr(contient.ndims) ; vecteur contenant le nom des dimensions
500   tailledim=lonarr(contient.ndims) ; vecteur contenant la valeur des dimensions
501   for dimiq=0,contient.ndims-1 do begin ; bouble sur le nombre de dimensions
502      ncdf_diminq,cdfid,dimiq,name,value ; nom et valeur de la dimension
503      nomdim[dimiq]=name
504      tailledim[dimiq]=value
505      rien = widget_label(base2, value = name+' de taille: '+strtrim(value,1), /align_right)
506   ENDFOR
507   rien = widget_label(base2, value = ' ') ; on saute une ligne
508;------------------------------------------------------------
509; base 3 choix de la variable
510;------------------------------------------------------------
511   base3 = widget_base(base, /column)
512   rien = widget_label(base3, value = 'Nombre de variables: '+strtrim(contient.nvars,1), /align_left)
513   base31 = widget_base(base3, /row, /align_center)
514;creation d'un vecteur listename contenant le nom de toutes les
515;variables du fichier
516   listename = strarr(contient.nvars)
517   for varid=0,contient.nvars-1 do begin
518      varcontient=ncdf_varinq(cdfid,varid) ; que contient la variable
519      listename[varid] = varcontient.name
520   endfor
521   rien= widget_label(base31, value = 'variable')
522; creation d''un bouton a menu deroulant
523   base311=widget_droplist(base31,value=listename, uvalue=2)
524   rien = widget_label(base3, value = '')
525;------------------------------------------------------------
526; base 4 bouton done
527;------------------------------------------------------------
528   base4 = widget_base(base, /row)
529   base42=widget_button(base4,value='done', uvalue=3, /align_right)
530;execution de la fentre de base et des sous-fenetres
531   widget_control,base,/realize
532;------------------------------------------------------------
533   xmanager,'xncdf_lec',base
534;------------------------------------------------------------
535;------------------------------------------------------------
536;------------------------------------------------------------
537   return, res
538end
Note: See TracBrowser for help on using the repository browser.